Ipinapaliwanag ng tutorial ang syntax at mga pangunahing gamit ng CHOOSE function at nagbibigay ng ilang di-trivial na halimbawa na nagpapakita kung paano gumamit ng CHOOSE formula sa Excel.

Ang CHOOSE ay isa sa mga iyon. Ang mga function ng Excel na maaaring hindi mukhang kapaki-pakinabang sa kanilang sarili, ngunit pinagsama sa iba pang mga function ay nagbibigay ng maraming kahanga-hangang mga benepisyo. Sa pinakapangunahing antas, ginagamit mo ang CHOOSE function upang makakuha ng value mula sa isang listahan sa pamamagitan ng pagtukoy sa posisyon ng value na iyon. Sa karagdagang sa tutorial na ito, makakahanap ka ng ilang advanced na paggamit na tiyak na sulit na galugarin.

Excel CHOOSE function - syntax at mga pangunahing gamit

Ang CHOOSE function sa Excel ay idinisenyo upang ibalik ang isang halaga mula sa listahan batay sa isang tinukoy na posisyon.

Available ang function sa Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, at Excel 2007.

Ang syntax ng CHOOSE function ay ang sumusunod:

Saan:

Index_num (kinakailangan) - ang posisyon ng value na ibabalik. Maaari itong maging anumang numero sa pagitan ng 1 at 254, isang cell reference, o ibang formula.

Value1, value2, … - isang listahan ng hanggang 254 na value na pipiliin. Kinakailangan ang Value1, opsyonal ang iba pang value. Ito ay maaaring mga numero, text value, cell reference, formula, o tinukoy na pangalan.

Narito ang isang halimbawa ng CHOOSE formula sa pinakasimpleng anyo:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

Ang formula nagbabalik "Amy" dahilAng index_num ay 3 at ang "Amy" ay ang ika-3 value sa listahan:

Excel CHOOSE function - 3 bagay na dapat tandaan!

Ang CHOOSE ay isang napakasimpleng function at halos hindi ka makakaranas ng anumang mga paghihirap sa pagpapatupad nito sa iyong mga worksheet. Kung ang resulta na ibinalik ng iyong CHOOSE formula ay hindi inaasahan o hindi ang resulta na iyong hinahanap, maaaring ito ay dahil sa mga sumusunod na dahilan:

1. Ang bilang ng mga value na mapagpipilian ay limitado sa 254.
2. Kung ang index_num ay mas mababa sa 1 o mas malaki kaysa sa bilang ng mga value sa listahan, ang #VALUE! ibinalik ang error.
3. Kung ang index_num argument ay isang fraction, ito ay pinutol sa pinakamababang integer.

Paano gamitin ang CHOOSE function sa Excel - formula mga halimbawa

Ipinapakita ng mga sumusunod na halimbawa kung paano mapalawak ng CHOOSE ang mga kakayahan ng iba pang mga function ng Excel at magbigay ng mga alternatibong solusyon sa ilang karaniwang gawain, kahit na sa mga itinuturing na hindi magagawa ng marami.

Excel CHOOSE sa halip na nested IFs

Isa sa pinakamadalas na gawain sa Excel ay ang pagbabalik ng iba't ibang value batay sa isang tinukoy na kundisyon. Sa karamihan ng mga kaso, maaari itong gawin sa pamamagitan ng paggamit ng classic na nested IF na pahayag. Ngunit ang CHOOSE function ay maaaring isang mabilis at madaling maunawaang alternatibo.

Halimbawa 1. Magbalik ng iba't ibang value batay sa kundisyon

Ipagpalagay na mayroon kang column ng mga marka ng mag-aaral at gusto mong lagyan ng label ang mga marka batay sasumusunod na kundisyon:

Ang isang paraan para gawin ito ay ang paglalagay ng ilang IF formula sa loob ng isa't isa:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

Ang isa pang paraan ay ang pumili ng label na tumutugma sa kundisyon:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

Paano gumagana ang formula na ito:

Sa index_num na argumento, sinusuri mo ang bawat kundisyon at ibabalik ang TRUE kung natutugunan ang kundisyon, FALSE kung hindi. Halimbawa, ang halaga sa cell B2 ay nakakatugon sa unang tatlong kundisyon, kaya makuha namin ang intermediate na resultang ito:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

Dahil sa karamihan sa mga formula ng Excel, ang TRUE ay katumbas ng 1 at FALSE sa 0, ang aming ang formula ay sumasailalim sa pagbabagong ito:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

Pagkatapos maisagawa ang operasyon ng karagdagan, mayroon kaming:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

Bilang resulta, ang ika-3 halaga sa ibinalik ang listahan, na "Maganda".

Mga Tip:

• Upang gawing mas flexible ang formula, maaari mong gamitin ang mga cell reference sa halip na mga hardcoded na label, halimbawa:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

• Kung wala sa iyong mga kundisyon ang TRUE, ang index_num argument ay itatakda sa 0 na pumipilit sa iyong formula na ibalik ang #VALUE! pagkakamali. Upang maiwasan ito, balutin lang ang CHOOSE sa function na IFERROR tulad nito:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

Halimbawa 2. Magsagawa ng iba't ibang kalkulasyon batay sa kundisyon

Sa katulad na paraan, ikaway maaaring gumamit ng Excel CHOOSE function upang magsagawa ng isang kalkulasyon sa isang serye ng mga posibleng kalkulasyon/formula nang hindi naglalagay ng maraming IF na pahayag sa loob ng isa't isa.

Bilang halimbawa, kalkulahin natin ang komisyon ng bawat nagbebenta depende sa kanilang mga benta:

Sa halaga ng benta sa B2, ang formula ay may sumusunod na hugis:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

Sa halip na i-hardcode ang mga porsyento sa formula, maaari kang sumangguni sa kaukulang cell sa iyong reference table, kung mayroon man. Tandaan lang na ayusin ang mga sanggunian gamit ang $ sign.

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

Excel CHOOSE formula para makabuo ng random na data

Tulad ng malamang na alam mo, ang Microsoft Excel ay may espesyal na function para bumuo mga random na integer sa pagitan ng ibaba at itaas na mga numero na iyong tinukoy - RANDBETWEEN function. Ilagay ito sa index_num argument ng CHOOSE, at bubuo ang iyong formula ng halos anumang random na data na gusto mo.

Halimbawa, ang formula na ito ay maaaring gumawa ng listahan ng mga random na resulta ng pagsusulit:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

Ang lohika ng formula ay halata: Ang RANDBETWEEN ay bumubuo ng mga random na numero mula 1 hanggang 4 at CHOOSE ay nagbabalik ng katumbas na halaga mula sa paunang-natukoy na listahan ng apat na halaga.

Tandaan. Ang RANDBETWEEN ay isang pabagu-bagong function at ito ay muling kinakalkula sa bawatpagbabagong ginawa mo sa worksheet. Bilang resulta, magbabago rin ang iyong listahan ng mga random na halaga. Upang maiwasang mangyari ito, maaari mong palitan ang mga formula ng kanilang mga halaga sa pamamagitan ng paggamit ng tampok na I-paste ang Espesyal .

PUMILI ng formula upang gumawa ng kaliwang Vlookup

Kung nakapagsagawa ka na isang vertical lookup sa Excel, alam mo na ang VLOOKUP function ay maaari lamang maghanap sa pinakakaliwang column. Sa mga sitwasyon kung kailan kailangan mong magbalik ng value sa kaliwa ng hanay ng paghahanap, maaari mong gamitin ang kumbinasyon ng INDEX / MATCH o linlangin ang VLOOKUP sa pamamagitan ng paglalagay ng CHOOSE function dito. Ganito:

Ipagpalagay na mayroon kang listahan ng mga marka sa column A, mga pangalan ng mag-aaral sa column B, at gusto mong kumuha ng marka ng isang partikular na mag-aaral. Dahil ang return column ay nasa kaliwa ng lookup column, ang isang regular na Vlookup formula ay nagbabalik ng #N/A error:

Upang ayusin ito, kunin ang CHOOSE function para magpalit ang mga posisyon ng mga column, na nagsasabi sa Excel na ang column 1 ay B at ang column 2 ay A:

=CHOOSE({1,2}, B2:B5, A2:A5)

Dahil nagbibigay kami ng array ng {1,2} sa index_num argumento, ang CHOOSE function ay tumatanggap ng mga saklaw sa value na mga argumento (karaniwan, ito ay hindi).

Ngayon, i-embed ang formula sa itaas sa table_array argument ng VLOOKUP:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

At voilà - ang isang lookup sa kaliwa ay isinasagawa nang walang sagabal!

PUMILI ng formula upang bumalik sa susunod na gumagana araw

Kung hindi ka sigurado kungdapat kang pumasok sa trabaho bukas o maaaring manatili sa bahay at i-enjoy ang iyong karapat-dapat na katapusan ng linggo, ang Excel CHOOSE function ay maaaring malaman kung kailan ang susunod na araw ng trabaho.

Ipagpalagay na ang iyong mga araw ng trabaho ay Lunes hanggang Biyernes, ang formula ang sumusunod:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Nakakalito sa unang tingin, sa malapitang pagtingin, madaling sundin ang lohika ng formula:

WEEKDAY (TODAY()) ay nagbabalik ng serial number na tumutugma sa petsa ngayon, mula 1 (Linggo) hanggang 7 (Sabado). Ang numerong ito ay papunta sa index_num argument ng aming CHOOSE formula.

Value1 - value7 (1,1,1,1,1, 3,2) tukuyin kung ilang araw ang idaragdag sa kasalukuyang petsa. Kung Linggo - Huwebes ngayon (index_num 1 - 5), magdagdag ka ng 1 upang bumalik sa susunod na araw. Kung Biyernes ngayon (index_num 6), magdagdag ka ng 3 upang bumalik sa susunod na Lunes. Kung Sabado ngayon (index_num 7), magdagdag ka ng 2 para bumalik muli sa susunod na Lunes. Oo, ganoon kasimple :)

PUMILI ng formula para magbalik ng custom na pangalan ng araw/buwan mula sa petsa

Sa mga sitwasyon kung kailan gusto mong makakuha ng pangalan ng araw sa karaniwang format gaya ng buong pangalan ( Lunes, Martes, atbp.) o maikling pangalan (Lun, Mar, atbp.), maaari mong gamitin ang TEXT function gaya ng ipinaliwanag sa halimbawang ito: Kunin ang araw ng linggo mula sa petsa sa Excel.

Kung gusto mong ibalik ang pangalan ng araw ng linggo o buwan sa custom na format, gamitin ang CHOOSE function sa sumusunod na paraan.

Upang makakuha ng araw ng linggo:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

Upang makakuha ng isangbuwan:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Kung saan ang A2 ay ang cell na naglalaman ng orihinal na petsa.

Sana ang tutorial na ito ay nagbigay sa iyo ng ilang ideya ng kung paano mo magagamit ang CHOOSE function sa Excel upang mapahusay ang iyong mga modelo ng data. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo!

I-download ang workbook ng pagsasanay

Excel CHOOSE mga halimbawa ng function