Упатството ја објаснува синтаксата и основните употреби на функцијата CHOOSE и дава неколку нетривијални примери кои покажуваат како да се користи формулата CHOOSE во Excel.

CHOOSE е една од тие Функциите на Excel кои можеби не изгледаат корисни сами по себе, но во комбинација со други функции даваат голем број на прекрасни придобивки. На најосновно ниво, ја користите функцијата CHOOSE за да добиете вредност од списокот со наведување на позицијата на таа вредност. Понатаму во ова упатство, ќе најдете неколку напредни намени кои секако вреди да се истражат.

Функцијата ИЗБЕРЕТЕ на Excel - синтакса и основни употреби

Функцијата CHOOSE во Excel е дизајниран да врати вредност од списокот врз основа на одредена позиција.

Функцијата е достапна во Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 и Excel 2007.

Синтаксата на CHOOSE функцијата е следна:

Каде:

Index_num (задолжително) - позицијата на вредноста што треба да се врати. Може да биде кој било број помеѓу 1 и 254, референца на ќелија или друга формула.

Вредност1, вредност2, … - список со најмногу 254 вредности од кои можете да изберете. Потребна е вредност1, а другите вредности се опционални. Овие можат да бидат броеви, вредности на текст, референци на ќелии, формули или дефинирани имиња.

Еве пример за CHOOSE формула во наједноставна форма:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

Формулата ја враќа „Ејми“ затоа што index_num е 3 и „Amy“ е третата вредност во листата:

Excel CHOOSE функција - 3 работи што треба да се запамети!

CHOOSE е многу обична функција и тешко дека ќе наидете на потешкотии при нејзино имплементирање во вашите работни листови. Ако резултатот вратен со формулата CHOOSE е неочекуван или не е резултатот што го баравте, тоа може да биде поради следниве причини:

1. Бројот на вредности од кои може да се избере е ограничен на 254.
2. Ако index_num е помал од 1 или поголем од бројот на вредности во списокот, #VALUE! се враќа грешката.
3. Ако аргументот index_num е дропка, тој е скратен на најнискиот цел број.

Како да се користи CHOOSE функцијата во Excel - формула примери

Следниве примери покажуваат како CHOOSE може да ги прошири можностите на другите функции на Excel и да обезбеди алтернативни решенија за некои вообичаени задачи, дури и за оние кои многумина ги сметаат за неостварливи.

Excel CHOOSE наместо вгнездени IFs

Една од најчестите задачи во Excel е враќање на различни вредности врз основа на одредена состојба. Во повеќето случаи, ова може да се направи со користење на класична вгнездена изјава IF. Но, функцијата CHOOSE може да биде брза и лесно разбирлива алтернатива.

Пример 1. Вратете различни вредности врз основа на условот

Да претпоставиме дека имате колона со резултати од учениците и сакате да означите оценките врз основа наследните услови:

Еден начин да го направите ова е да вгнездите неколку формули IF една во друга:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

Друг начин е да изберете етикета што одговара на условот:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

Како функционира оваа формула:

Во аргументот index_num , го оценувате секој услов и враќате ТОЧНО ако условот е исполнет, НЕТОЧНО во спротивно. На пример, вредноста во ќелијата B2 ги исполнува првите три услови, така што го добиваме овој среден резултат:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

Со оглед на тоа што во повеќето формули на Excel TRUE е еднакво на 1 и FALSE на 0, нашата формулата е подложена на оваа трансформација:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

Откако ќе се изврши операцијата за собирање, имаме:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

Како резултат, третата вредност во се враќа списокот, кој е „Добро“.

Совети:

• За да ја направите формулата пофлексибилна, можете да користите референци на ќелиите наместо етикети со тврд код, на пример:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

• Ако ниту еден од вашите услови не е ТОЧЕН, аргументот index_num ќе биде поставен на 0, принудувајќи ја вашата формула да ја врати #VALUE! грешка. За да го избегнете ова, едноставно завиткајте го CHOOSE во функцијата IFERROR вака:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

Пример 2. Изведете различни пресметки врз основа на условот

На сличен начин, тиможе да ја користи функцијата Excel CHOOSE за да изврши една пресметка во низа можни пресметки/формули без вгнездување на повеќе изјави за IF еден во друг.

Како пример, да ја пресметаме провизијата на секој продавач во зависност од нивната продажба:

Со продажната сума во B2, формулата го добива следниов облик:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

Наместо хардкодирање на процентите во формулата, може да се повикате на соодветната ќелија во вашата референтна табела, доколку ја има. Само не заборавајте да ги поправите референците користејќи го знакот $.

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

Excel CHOOSE формула за генерирање случајни податоци

Како што веројатно знаете, Microsoft Excel има посебна функција за генерирање случајни цели броеви помеѓу долните и горните броеви што ќе ги наведете - функција RANDBETWEEN. Вгнездувајте го во аргументот index_num на CHOOSE и вашата формула ќе генерира речиси сите случајни податоци што ги сакате.

На пример, оваа формула може да произведе листа на случајни резултати од испитот:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

Логиката на формулата е очигледна: RANDBETWEEN генерира случајни броеви од 1 до 4 и CHOOSE враќа соодветна вредност од претходно дефинираната листа со четири вредности.

Забелешка. RANDBETWEEN е испарлива функција и повторно се пресметува со секоепромената што ја правите во работниот лист. Како резултат на тоа, вашата листа на случајни вредности исто така ќе се промени. За да спречите тоа да се случи, можете да ги замените формулите со нивните вредности со користење на функцијата Залепете специјално .

ИЗБЕРЕТЕ формула за да направите лево Vlookup

Ако некогаш сте извршиле вертикално пребарување во Excel, знаете дека функцијата VLOOKUP може да пребарува само во најлевата колона. Во ситуации кога треба да вратите вредност лево од колоната за пребарување, можете или да ја користите комбинацијата INDEX / MATCH или да измамите VLOOKUP со вгнездување на функцијата CHOOSE во неа. Еве како:

Да претпоставиме дека имате листа на бодови во колоната А, имињата на учениците во колоната Б и сакате да ја вратите оценката за одреден ученик. Бидејќи колоната за враќање е лево од колоната за пребарување, обична формула Vlookup ја враќа грешката #N/A:

За да го поправите ова, земете ја функцијата CHOOSE за замена позициите на колоните, кажувајќи му на Excel дека колоната 1 е B, а колоната 2 е A:

=CHOOSE({1,2}, B2:B5, A2:A5)

Бидејќи обезбедуваме низа од {1,2} во index_num аргумент, функцијата CHOOSE прифаќа опсези во аргументите вредност (нормално, не).

Сега, вметнете ја горната формула во аргументот table_array на VLOOKUP:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

И voilà - пребарувањето лево се врши без проблем!

ИЗБЕРЕТЕ ја формулата за да се вратите следното дело ден

Ако не сте сигурни далитреба да одите на работа утре или можете да останете дома и да уживате во заслужениот викенд, функцијата Excel CHOOSE може да открие кога е следниот работен ден.

Претпоставувајќи дека вашите работни денови се од понеделник до петок, формулата оди на следниов начин:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Лешко на прв поглед, со поблизок поглед логиката на формулата е лесно да се следи:

WEEKDAY (TODAY()) враќа сериски број што одговара на денешниот датум, кој се движи од 1 (недела) до 7 (сабота). Овој број оди во аргументот index_num на нашата формула CHOOSE.

Вредност1 - вредност7 (1,1,1,1,1, 3,2) одреди колку дена да се додадат на тековниот датум. Ако денес е недела - четврток (индекс_број 1 - 5), додавате 1 за да се вратите следниот ден. Ако денес е петок (индекс_број 6), додавате 3 за да се вратите следниот понеделник. Ако денес е сабота (индекс_број 7), додавате 2 за повторно да се вратите следниот понеделник. Да, толку е едноставно :)

ИЗБЕРЕТЕ формула за враќање приспособено име на ден/месец од датумот

Во ситуации кога сакате да добиете име на ден во стандарден формат, како што е целото име ( Понеделник, вторник, итн.) или кратко име (понеделник, вторник, итн.), можете да ја користите функцијата TEXT како што е објаснето во овој пример: Земете ден од седмицата од датумот во Excel.

Ако сакате да вратете име на ден од неделата или на месец во прилагоден формат, користете ја функцијата CHOOSE на следниов начин.

За да добиете ден во неделата:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

За да добиете амесец:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Каде A2 е ќелијата што го содржи оригиналниот датум.

Се надевам дека ова упатство ви даде некои идеи за како можете да ја користите функцијата CHOOSE во Excel за да ги подобрите вашите модели на податоци. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела!

Преземете ја работната книга за вежбање

Примери на функцијата CHOOSE Excel