CHOOSE ഫംഗ്‌ഷന്റെ വാക്യഘടനയും അടിസ്ഥാന ഉപയോഗങ്ങളും ട്യൂട്ടോറിയൽ വിശദീകരിക്കുന്നു കൂടാതെ Excel-ൽ ഒരു CHOOSE ഫോർമുല എങ്ങനെ ഉപയോഗിക്കാമെന്ന് കാണിക്കുന്ന നിസ്സാരമല്ലാത്ത ചില ഉദാഹരണങ്ങൾ നൽകുന്നു.

CHOOSE അതിലൊന്നാണ്. Excel ഫംഗ്‌ഷനുകൾ സ്വന്തമായി ഉപയോഗപ്രദമാകില്ല, എന്നാൽ മറ്റ് ഫംഗ്‌ഷനുകളുമായി സംയോജിപ്പിച്ച് നിരവധി ആകർഷണീയമായ നേട്ടങ്ങൾ നൽകുന്നു. ഏറ്റവും അടിസ്ഥാന തലത്തിൽ, ആ മൂല്യത്തിന്റെ സ്ഥാനം വ്യക്തമാക്കിക്കൊണ്ട് ഒരു ലിസ്റ്റിൽ നിന്ന് ഒരു മൂല്യം ലഭിക്കുന്നതിന് നിങ്ങൾ CHOSE ഫംഗ്ഷൻ ഉപയോഗിക്കുന്നു. ഈ ട്യൂട്ടോറിയലിൽ, തീർച്ചയായും പര്യവേക്ഷണം ചെയ്യേണ്ട നിരവധി വിപുലമായ ഉപയോഗങ്ങൾ നിങ്ങൾ കണ്ടെത്തും.

Excel CHOSE ഫംഗ്‌ഷൻ - വാക്യഘടനയും അടിസ്ഥാന ഉപയോഗങ്ങളും

Excel-ലെ CHOOSE ഫംഗ്‌ഷൻ ഇതാണ് ഒരു നിർദ്ദിഷ്‌ട സ്ഥാനത്തെ അടിസ്ഥാനമാക്കി ലിസ്റ്റിൽ നിന്ന് ഒരു മൂല്യം തിരികെ നൽകാൻ രൂപകൽപ്പന ചെയ്‌തിരിക്കുന്നു.

Function Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 എന്നിവയിൽ ലഭ്യമാണ്.

CHOOSE ഫംഗ്‌ഷന്റെ വാക്യഘടന ഇപ്രകാരമാണ്:

എവിടെ:

Index_num (ആവശ്യമാണ്) - തിരികെ നൽകേണ്ട മൂല്യത്തിന്റെ സ്ഥാനം. ഇത് 1-നും 254-നും ഇടയിലുള്ള ഏത് സംഖ്യയും, ഒരു സെൽ റഫറൻസും അല്ലെങ്കിൽ മറ്റൊരു ഫോർമുലയും ആകാം.

മൂല്യം1, മൂല്യം2, … - തിരഞ്ഞെടുക്കേണ്ട 254 വരെയുള്ള മൂല്യങ്ങളുടെ ഒരു ലിസ്റ്റ്. മൂല്യം1 ആവശ്യമാണ്, മറ്റ് മൂല്യങ്ങൾ ഓപ്ഷണലാണ്. ഇവ അക്കങ്ങൾ, ടെക്‌സ്‌റ്റ് മൂല്യങ്ങൾ, സെൽ റഫറൻസുകൾ, ഫോർമുലകൾ അല്ലെങ്കിൽ നിർവചിക്കപ്പെട്ട പേരുകൾ എന്നിവ ആകാം.

ഏറ്റവും ലളിതമായ രൂപത്തിൽ തിരഞ്ഞെടുക്കാനുള്ള ഫോർമുലയുടെ ഒരു ഉദാഹരണം ഇതാ:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

സൂത്രവാക്യം കാരണം "ആമി" തിരികെ നൽകുന്നു index_num എന്നത് 3 ആണ്, കൂടാതെ "Amy" എന്നത് ലിസ്റ്റിലെ മൂന്നാമത്തെ മൂല്യമാണ്:

Excel CHOOSE ഫംഗ്‌ഷൻ - ഓർമ്മിക്കേണ്ട 3 കാര്യങ്ങൾ!

തിരഞ്ഞെടുക്കുക എന്നത് വളരെ ലളിതമായ ഒരു പ്രവർത്തനമാണ്, നിങ്ങളുടെ വർക്ക്ഷീറ്റുകളിൽ ഇത് നടപ്പിലാക്കുന്നതിൽ നിങ്ങൾക്ക് ബുദ്ധിമുട്ടുകൾ നേരിടേണ്ടിവരില്ല. നിങ്ങളുടെ CHOOSE സൂത്രവാക്യം നൽകുന്ന ഫലം അപ്രതീക്ഷിതമോ നിങ്ങൾ തിരയുന്ന ഫലം അല്ലെങ്കിലോ, അത് ഇനിപ്പറയുന്ന കാരണങ്ങളാലായിരിക്കാം:

1. തിരഞ്ഞെടുക്കേണ്ട മൂല്യങ്ങളുടെ എണ്ണം 254 ആയി പരിമിതപ്പെടുത്തിയിരിക്കുന്നു.
2. സൂചിക_സംഖ്യ 1-ൽ കുറവോ ലിസ്റ്റിലെ മൂല്യങ്ങളുടെ എണ്ണത്തേക്കാൾ വലുതോ ആണെങ്കിൽ, #VALUE! പിശക് തിരികെ ലഭിച്ചു.
3. index_num ആർഗ്യുമെന്റ് ഒരു ഭിന്നസംഖ്യയാണെങ്കിൽ, അത് ഏറ്റവും താഴ്ന്ന പൂർണ്ണസംഖ്യയിലേക്ക് ചുരുക്കിയിരിക്കുന്നു.

എക്‌സൽ - ഫോർമുലയിൽ CHOOSE ഫംഗ്‌ഷൻ എങ്ങനെ ഉപയോഗിക്കാം ഉദാഹരണങ്ങൾ

CHOOSE-ന് മറ്റ് Excel ഫംഗ്‌ഷനുകളുടെ കഴിവുകൾ എങ്ങനെ വിപുലീകരിക്കാമെന്നും ചില പൊതുവായ ജോലികൾക്ക് ബദൽ പരിഹാരങ്ങൾ നൽകാമെന്നും ഇനിപ്പറയുന്ന ഉദാഹരണങ്ങൾ കാണിക്കുന്നു. നെസ്റ്റഡ് IF-കൾ

എക്‌സെൽ-ലെ ഏറ്റവും പതിവ് ജോലികളിലൊന്ന് ഒരു നിർദ്ദിഷ്ട വ്യവസ്ഥയെ അടിസ്ഥാനമാക്കി വ്യത്യസ്ത മൂല്യങ്ങൾ തിരികെ നൽകുക എന്നതാണ്. മിക്ക കേസുകളിലും, ഒരു ക്ലാസിക് നെസ്റ്റഡ് IF പ്രസ്താവന ഉപയോഗിച്ച് ഇത് ചെയ്യാൻ കഴിയും. എന്നാൽ CHOOSE ഫംഗ്‌ഷൻ വേഗത്തിലും എളുപ്പത്തിലും മനസ്സിലാക്കാവുന്ന ഒരു ബദലായിരിക്കാം.

ഉദാഹരണം 1. വ്യവസ്ഥയെ അടിസ്ഥാനമാക്കി വ്യത്യസ്ത മൂല്യങ്ങൾ തിരികെ നൽകുക

നിങ്ങൾക്ക് വിദ്യാർത്ഥി സ്‌കോറുകളുടെ ഒരു കോളം ഉണ്ടെന്നും നിങ്ങൾ ലേബൽ ചെയ്യാൻ ആഗ്രഹിക്കുന്നുവെന്നും കരുതുക അടിസ്ഥാനമാക്കിയുള്ള സ്കോറുകൾഇനിപ്പറയുന്ന വ്യവസ്ഥകൾ:

ഇത് ചെയ്യാനുള്ള ഒരു മാർഗ്ഗം പരസ്പരം ഉള്ളിൽ കുറച്ച് IF ഫോർമുലകൾ നെസ്റ്റ് ചെയ്യുക എന്നതാണ്:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

മറ്റൊരു മാർഗ്ഗം വ്യവസ്ഥയ്ക്ക് അനുയോജ്യമായ ഒരു ലേബൽ തിരഞ്ഞെടുക്കുന്നതാണ്:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

ഈ ഫോർമുല എങ്ങനെ പ്രവർത്തിക്കുന്നു:

index_num ആർഗ്യുമെന്റിൽ, നിങ്ങൾ ഓരോ വ്യവസ്ഥയും വിലയിരുത്തുകയും നിബന്ധന പാലിക്കുകയാണെങ്കിൽ TRUE എന്ന് നൽകുകയും അല്ലാത്തപക്ഷം FALSE എന്ന് നൽകുകയും ചെയ്യുന്നു. ഉദാഹരണത്തിന്, സെൽ B2 ലെ മൂല്യം ആദ്യത്തെ മൂന്ന് വ്യവസ്ഥകൾ പാലിക്കുന്നു, അതിനാൽ നമുക്ക് ഈ ഇന്റർമീഡിയറ്റ് ഫലം ലഭിക്കും:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

മിക്ക Excel ഫോർമുലകളിലും TRUE 1 നും FALSE 0 നും തുല്യമാണ്, ഞങ്ങളുടെ ഫോർമുല ഈ പരിവർത്തനത്തിന് വിധേയമാകുന്നു:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

സങ്കലന പ്രവർത്തനം നടത്തിക്കഴിഞ്ഞാൽ, നമുക്ക്:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

ഫലമായി, 3-ാമത്തെ മൂല്യം ലിസ്റ്റ് തിരികെ നൽകി, അത് "നല്ലത്".

നുറുങ്ങുകൾ:

• സൂത്രവാക്യം കൂടുതൽ വഴക്കമുള്ളതാക്കാൻ, നിങ്ങൾക്ക് ഹാർഡ്‌കോഡ് ലേബലുകൾക്ക് പകരം സെൽ റഫറൻസുകൾ ഉപയോഗിക്കാം, ഉദാഹരണത്തിന്:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

• നിങ്ങളുടെ വ്യവസ്ഥകളൊന്നും ശരിയല്ലെങ്കിൽ, ഇൻഡക്‌സ്_നം ആർഗ്യുമെന്റ് 0 ആയി സജ്ജീകരിക്കും, #VALUE തിരികെ നൽകാൻ നിങ്ങളുടെ ഫോർമുല നിർബന്ധിതമാക്കും! പിശക്. ഇത് ഒഴിവാക്കാൻ, IFERROR ഫംഗ്‌ഷനിൽ ഇതുപോലെ പൊതിയുക:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

ഉദാഹരണം 2. വ്യവസ്ഥയെ അടിസ്ഥാനമാക്കി വ്യത്യസ്ത കണക്കുകൂട്ടലുകൾ നടത്തുക

സമാന രീതിയിൽ, നിങ്ങൾഒന്നിലധികം IF സ്റ്റേറ്റ്‌മെന്റുകൾ പരസ്പരം കൂട്ടിയിണക്കാതെ തന്നെ സാധ്യമായ കണക്കുകൂട്ടലുകളുടെ/സൂത്രവാക്യങ്ങളുടെ ഒരു ശ്രേണിയിൽ ഒരു കണക്കുകൂട്ടൽ നടത്താൻ Excel CHOOSE ഫംഗ്‌ഷൻ ഉപയോഗിക്കാം.

ഉദാഹരണമായി, ഓരോ വിൽപ്പനക്കാരനും അവരുടെ വിൽപ്പനയെ ആശ്രയിച്ച് കമ്മീഷൻ കണക്കാക്കാം:

B2-ലെ വിൽപ്പന തുകയ്‌ക്കൊപ്പം, ഫോർമുല ഇനിപ്പറയുന്ന രൂപമെടുക്കുന്നു:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

ഫോർമുലയിലെ ശതമാനങ്ങൾ ഹാർഡ്‌കോഡ് ചെയ്യുന്നതിനുപകരം, നിങ്ങളുടെ റഫറൻസ് ടേബിളിലെ അനുബന്ധ സെൽ എന്തെങ്കിലും ഉണ്ടെങ്കിൽ അത് നിങ്ങൾക്ക് റഫർ ചെയ്യാം. $ ചിഹ്നം ഉപയോഗിച്ച് റഫറൻസുകൾ ശരിയാക്കാൻ ഓർക്കുക.

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

റാൻഡം ഡാറ്റ സൃഷ്‌ടിക്കുന്നതിന് Excel തിരഞ്ഞെടുക്കുക ഫോർമുല

നിങ്ങൾക്ക് അറിയാവുന്നതുപോലെ, Microsoft Excel-ന് സൃഷ്‌ടിക്കാൻ ഒരു പ്രത്യേക ഫംഗ്‌ഷൻ ഉണ്ട് നിങ്ങൾ വ്യക്തമാക്കുന്ന താഴെയും മുകളിലുമുള്ള സംഖ്യകൾക്കിടയിലുള്ള ക്രമരഹിതമായ പൂർണ്ണസംഖ്യകൾ - RANDBETWEEN ഫംഗ്ഷൻ. CHOOSE എന്നതിന്റെ index_num ആർഗ്യുമെന്റിൽ ഇത് നെസ്റ്റ് ചെയ്യുക, നിങ്ങളുടെ ഫോർമുല നിങ്ങൾക്ക് ആവശ്യമുള്ള ഏതൊരു റാൻഡം ഡാറ്റയും സൃഷ്ടിക്കും.

ഉദാഹരണത്തിന്, ഈ ഫോർമുലയ്ക്ക് ക്രമരഹിതമായ പരീക്ഷാ ഫലങ്ങളുടെ ഒരു ലിസ്റ്റ് നിർമ്മിക്കാൻ കഴിയും:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

സൂത്രവാക്യത്തിന്റെ യുക്തി വ്യക്തമാണ്: RANDBETWEEN 1 മുതൽ 4 വരെയുള്ള ക്രമരഹിത സംഖ്യകൾ ജനറേറ്റുചെയ്യുന്നു, കൂടാതെ CHOSE നാല് മൂല്യങ്ങളുടെ മുൻ‌നിശ്ചയിച്ച പട്ടികയിൽ നിന്ന് അനുബന്ധ മൂല്യം നൽകുന്നു.

ശ്രദ്ധിക്കുക. RANDBETWEEN ഒരു അസ്ഥിരമായ പ്രവർത്തനമാണ്, അത് ഓരോന്നിലും വീണ്ടും കണക്കാക്കുന്നുനിങ്ങൾ വർക്ക്ഷീറ്റിലേക്ക് മാറ്റുക. ഫലമായി, നിങ്ങളുടെ റാൻഡം മൂല്യങ്ങളുടെ പട്ടികയും മാറും. ഇത് സംഭവിക്കുന്നത് തടയാൻ, സ്പെഷ്യൽ ഒട്ടിക്കുക ഫീച്ചർ ഉപയോഗിച്ച് നിങ്ങൾക്ക് ഫോർമുലകളെ അവയുടെ മൂല്യങ്ങൾ ഉപയോഗിച്ച് മാറ്റിസ്ഥാപിക്കാം.

ഇടത് വ്ലൂക്ക്അപ്പ് ചെയ്യാൻ ഫോർമുല തിരഞ്ഞെടുക്കുക

നിങ്ങൾ എപ്പോഴെങ്കിലും പ്രകടനം നടത്തിയിട്ടുണ്ടെങ്കിൽ Excel-ൽ ഒരു ലംബമായ ലുക്ക്അപ്പ്, VLOOKUP ഫംഗ്‌ഷന് ഇടതുവശത്തുള്ള കോളത്തിൽ മാത്രമേ തിരയാൻ കഴിയൂ എന്ന് നിങ്ങൾക്കറിയാം. ലുക്കപ്പ് കോളത്തിന്റെ ഇടതുവശത്ത് ഒരു മൂല്യം തിരികെ നൽകേണ്ട സാഹചര്യങ്ങളിൽ, നിങ്ങൾക്ക് ഒന്നുകിൽ INDEX / MATCH കോമ്പിനേഷൻ ഉപയോഗിക്കാം അല്ലെങ്കിൽ അതിൽ CHOOSE ഫംഗ്‌ഷൻ നെസ്റ്റുചെയ്‌ത് VLOOKUP തന്ത്രം മെനയാവുന്നതാണ്. എങ്ങനെയെന്നത് ഇതാ:

നിങ്ങൾക്ക് എ കോളത്തിൽ സ്‌കോറുകളുടെ ഒരു ലിസ്റ്റ് ഉണ്ടെന്നും കോളം B-യിൽ വിദ്യാർത്ഥികളുടെ പേരുകൾ ഉണ്ടെന്നും ഒരു പ്രത്യേക വിദ്യാർത്ഥിയുടെ സ്കോർ വീണ്ടെടുക്കാൻ നിങ്ങൾ ആഗ്രഹിക്കുന്നുവെന്നും കരുതുക. റിട്ടേൺ കോളം ലുക്കപ്പ് കോളത്തിന്റെ ഇടതുവശത്തായതിനാൽ, ഒരു സാധാരണ Vlookup ഫോർമുല #N/A പിശക് നൽകുന്നു:

ഇത് പരിഹരിക്കാൻ, സ്വാപ്പ് ചെയ്യാൻ CHOOSE ഫംഗ്‌ഷൻ നേടുക നിരകളുടെ സ്ഥാനങ്ങൾ, കോളം 1 B ഉം കോളം 2 A ഉം ആണെന്ന് Excel-നോട് പറയുന്നു:

=CHOOSE({1,2}, B2:B5, A2:A5)

കാരണം ഞങ്ങൾ index_num<2-ൽ {1,2} എന്ന അറേ നൽകുന്നു> ആർഗ്യുമെന്റ്, CHOOSE ഫംഗ്ഷൻ മൂല്യം ആർഗ്യുമെന്റുകളിലെ ശ്രേണികൾ അംഗീകരിക്കുന്നു (സാധാരണയായി, ഇത് അങ്ങനെയല്ല).

ഇപ്പോൾ, മുകളിലുള്ള ഫോർമുല table_array ആർഗ്യുമെന്റിലേക്ക് ഉൾച്ചേർക്കുക. VLOOKUP:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

ഒപ്പം voilà - ഇടത്തോട്ട് ഒരു ലുക്ക്അപ്പ് ഒരു തടസ്സവുമില്ലാതെ നടത്തുന്നു!

അടുത്ത ജോലിയിലേക്ക് മടങ്ങാൻ ഫോർമുല തിരഞ്ഞെടുക്കുക ദിവസം

നിങ്ങൾക്ക് ഉറപ്പില്ലെങ്കിൽനിങ്ങൾ നാളെ ജോലിക്ക് പോകണം അല്ലെങ്കിൽ വീട്ടിലിരുന്ന് നിങ്ങൾക്ക് അർഹമായ വാരാന്ത്യം ആസ്വദിക്കാം, Excel CHOOSE ഫംഗ്‌ഷന് അടുത്ത പ്രവൃത്തി ദിവസം എപ്പോഴാണെന്ന് കണ്ടെത്താനാകും.

നിങ്ങളുടെ പ്രവൃത്തി ദിവസങ്ങൾ തിങ്കൾ മുതൽ വെള്ളി വരെ ആണെന്ന് കരുതുക, ഫോർമുല ഇനിപ്പറയുന്ന രീതിയിൽ പോകുന്നു:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

ആദ്യ കാഴ്ചയിൽ തന്നെ കൗശലകരമാണ്, സൂക്ഷ്മമായി നോക്കുമ്പോൾ ഫോർമുലയുടെ യുക്തി പിന്തുടരാൻ എളുപ്പമാണ്:

WEEKDAY (ഇന്ന് ()) 1 (ഞായർ) മുതൽ 7 (ശനി) വരെയുള്ള ഇന്നത്തെ തീയതിയുമായി ബന്ധപ്പെട്ട ഒരു സീരിയൽ നമ്പർ നൽകുന്നു. ഈ നമ്പർ ഞങ്ങളുടെ CHOSE ഫോർമുലയുടെ index_num ആർഗ്യുമെന്റിലേക്ക് പോകുന്നു.

Value1 - value7 (1,1,1,1,1, 3,2) നിലവിലെ തീയതിയിലേക്ക് എത്ര ദിവസം ചേർക്കണമെന്ന് നിർണ്ണയിക്കുക. ഇന്ന് ഞായർ - വ്യാഴം (സൂചിക_സംഖ്യ 1 - 5) ആണെങ്കിൽ, അടുത്ത ദിവസം തിരികെ നൽകാൻ നിങ്ങൾ 1 ചേർക്കുക. ഇന്ന് വെള്ളിയാഴ്ചയാണെങ്കിൽ (സൂചിക_സംഖ്യ 6), അടുത്ത തിങ്കളാഴ്ച മടങ്ങുന്നതിന് നിങ്ങൾ 3 ചേർക്കുക. ഇന്ന് ശനിയാഴ്ചയാണെങ്കിൽ (സൂചിക_സംഖ്യ 7), അടുത്ത തിങ്കളാഴ്ച്ച വീണ്ടും മടങ്ങുന്നതിന് നിങ്ങൾ 2 ചേർക്കുക. അതെ, ഇത് വളരെ ലളിതമാണ് :)

തീയതി മുതൽ ഒരു ഇഷ്‌ടാനുസൃത ദിവസം/മാസ നാമം നൽകുന്നതിനുള്ള ഫോർമുല തിരഞ്ഞെടുക്കുക

നിങ്ങൾക്ക് പൂർണ്ണമായ പേര് പോലുള്ള സ്റ്റാൻഡേർഡ് ഫോർമാറ്റിൽ ഒരു ദിവസത്തെ പേര് ലഭിക്കാൻ താൽപ്പര്യപ്പെടുന്ന സാഹചര്യങ്ങളിൽ ( തിങ്കൾ, ചൊവ്വ മുതലായവ) അല്ലെങ്കിൽ ഹ്രസ്വ നാമം (തിങ്കൾ, ചൊവ്വ, മുതലായവ), ഈ ഉദാഹരണത്തിൽ വിശദീകരിച്ചിരിക്കുന്നതുപോലെ നിങ്ങൾക്ക് TEXT ഫംഗ്ഷൻ ഉപയോഗിക്കാം: Excel-ൽ തീയതി മുതൽ ആഴ്ചയിലെ ദിവസം നേടുക.

നിങ്ങൾക്ക് വേണമെങ്കിൽ ഇഷ്‌ടാനുസൃത ഫോർമാറ്റിൽ ആഴ്‌ചയിലെ ഒരു ദിവസമോ മാസത്തിന്റെ പേരോ തിരികെ നൽകുക, ഇനിപ്പറയുന്ന രീതിയിൽ CHOOSE ഫംഗ്‌ഷൻ ഉപയോഗിക്കുക.

ആഴ്‌ചയിലെ ഒരു ദിവസം ലഭിക്കാൻ:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

ലഭിക്കാൻമാസം:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

എ2 യഥാർത്ഥ തീയതി അടങ്ങുന്ന സെൽ എവിടെയാണ് നിങ്ങളുടെ ഡാറ്റാ മോഡലുകൾ മെച്ചപ്പെടുത്തുന്നതിന് Excel-ൽ CHOOSE ഫംഗ്ഷൻ എങ്ങനെ ഉപയോഗിക്കാം. വായിച്ചതിന് നന്ദി, അടുത്ത ആഴ്‌ച ഞങ്ങളുടെ ബ്ലോഗിൽ നിങ്ങളെ കാണുമെന്ന് പ്രതീക്ഷിക്കുന്നു!

പ്രാക്ടീസ് വർക്ക്ബുക്ക് ഡൗൺലോഡ് ചെയ്യുക

Excel CHOOSE ഫംഗ്‌ഷൻ ഉദാഹരണങ്ങൾ