Vodič objašnjava sintaksu i osnovnu upotrebu funkcije CHOOSE i pruža nekoliko netrivijalnih primjera koji pokazuju kako koristiti formulu CHOOSE u Excelu.

CHOOSE je jedan od onih Excel funkcije koje možda ne izgledaju korisne same po sebi, ali u kombinaciji s drugim funkcijama daju niz sjajnih prednosti. Na najosnovnijoj razini, koristite funkciju CHOOSE da biste dobili vrijednost sa liste navođenjem pozicije te vrijednosti. Dalje u ovom vodiču, naći ćete nekoliko naprednih upotreba koje svakako vrijedi istražiti.

Excel funkcija CHOOSE - sintaksa i osnovne upotrebe

Funkcija CHOOSE u Excelu je dizajniran da vrati vrijednost sa liste na osnovu specificirane pozicije.

Funkcija je dostupna u Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 i Excel 2007.

Sintaksa funkcije CHOOSE je sljedeća:

Gdje:

Broj_indeksa (obavezno) - pozicija vrijednosti koju treba vratiti. To može biti bilo koji broj između 1 i 254, referenca ćelije ili druga formula.

Vrijednost1, vrijednost2, … - lista do 254 vrijednosti od kojih možete izabrati. Vrijednost1 je obavezna, ostale vrijednosti su opcione. To mogu biti brojevi, tekstualne vrijednosti, reference ćelija, formule ili definirana imena.

Evo primjera ODABIR formule u najjednostavnijem obliku:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

Formula vraća "Amy" jer index_num je 3, a "Amy" je treća vrijednost na listi:

Excel funkcija CHOOSE - 3 stvari koje treba zapamtiti!

CHOOSE je vrlo jednostavna funkcija i teško da ćete naići na bilo kakve poteškoće pri implementaciji iste u svoje radne listove. Ako je rezultat koji vraća vaša CHOOSE formula neočekivan ili nije rezultat koji ste tražili, to može biti iz sljedećih razloga:

1. Broj vrijednosti koje možete izabrati je ograničen na 254.
2. Ako je broj_indeksa manji od 1 ili veći od broja vrijednosti na listi, #VALUE! greška se vraća.
3. Ako je argument broj_indeksa razlomak, skraćuje se na najniži cijeli broj.

Kako koristiti funkciju CHOOSE u Excelu - formula primjeri

Sljedeći primjeri pokazuju kako CHOOSE može proširiti mogućnosti drugih Excel funkcija i pružiti alternativna rješenja za neke uobičajene zadatke, čak i za one koje mnogi smatraju neizvodljivim.

Excel CHOOSE umjesto ugniježđeni IF

Jedan od najčešćih zadataka u Excelu je vraćanje različitih vrijednosti na osnovu specificiranog uslova. U većini slučajeva, to se može učiniti korištenjem klasičnog ugniježđenog IF izraza. Ali funkcija CHOOSE može biti brza i lako razumljiva alternativa.

Primjer 1. Vrati različite vrijednosti na osnovu uslova

Pretpostavimo da imate kolonu rezultata učenika i želite da označite bodovi zasnovani naslijedeći uslovi:

Jedan od načina da to učinite je da ugnijezdite nekoliko IF formula jedna u drugu:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

Drugi način je da odaberete oznaku koja odgovara uvjetu:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

Kako ova formula funkcionira:

U argumentu indeks_num procjenjujete svaki uslov i vraćate TRUE ako je uvjet ispunjen, FALSE u suprotnom. Na primjer, vrijednost u ćeliji B2 ispunjava prva tri uslova, tako da dobijamo ovaj srednji rezultat:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

S obzirom da je u većini Excel formula TRUE jednako 1, a FALSE 0, naš formula prolazi kroz ovu transformaciju:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

Nakon što se izvrši operacija sabiranja, imamo:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

Kao rezultat, 3. vrijednost u vraća se lista, što je "Dobro".

Savjeti:

• Da biste formulu učinili fleksibilnijom, možete koristiti reference ćelija umjesto čvrsto kodiranih oznaka, na primjer:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

• Ako nijedan od vaših uslova nije TRUE, argument indeks_num će biti postavljen na 0 čime će vaša formula da vrati #VRIJEDNOST! greška. Da biste to izbjegli, jednostavno umotajte CHOOSE u funkciju IFERROR na sljedeći način:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

Primjer 2. Izvršite različite proračune na osnovu uslova

Na sličan način, timože koristiti Excel funkciju CHOOSE da izvrši jednu kalkulaciju u nizu mogućih izračuna/formula bez ugniježđenja više IF iskaza jedan u drugi.

Na primjer, izračunajmo proviziju svakog prodavača ovisno o njihovoj prodaji:

Sa iznosom prodaje u B2, formula ima sljedeći oblik:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

Umjesto tvrdog kodiranja postotaka u formuli, možete se pozvati na odgovarajuću ćeliju u vašoj referentnoj tabeli, ako postoji. Samo zapamtite da popravite reference pomoću znaka $.

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

Excel IZABERITE formulu za generiranje nasumičnih podataka

Kao što vjerojatno znate, Microsoft Excel ima posebnu funkciju za generiranje nasumični cijeli brojevi između donjeg i gornjeg broja koje navedete - funkcija RANDBETWEEN. Ugnijezdite ga u argument index_num za CHOOSE i vaša formula će generirati gotovo sve nasumične podatke koje želite.

Na primjer, ova formula može proizvesti listu nasumičnih rezultata ispita:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

Logika formule je očigledna: RANDBETWEEN generiše nasumične brojeve od 1 do 4, a CHOOSE vraća odgovarajuću vrijednost sa unaprijed definirane liste od četiri vrijednosti.

Napomena. RANDBETWEEN je promjenjiva funkcija i preračunava se sa svakimpromjene koje napravite na radnom listu. Kao rezultat, vaša lista nasumičnih vrijednosti će se također promijeniti. Da biste spriječili da se to dogodi, možete zamijeniti formule njihovim vrijednostima korištenjem funkcije Specijalno zalijepi .

ODABRAJTE formulu da izvršite lijevo Vlookup

Ako ste ikada izvodili vertikalno traženje u Excelu, znate da funkcija VLOOKUP može pretraživati ​​samo u krajnjoj lijevoj koloni. U situacijama kada trebate vratiti vrijednost lijevo od kolone za traženje, možete koristiti kombinaciju INDEX / MATCH ili prevariti VLOOKUP tako što ćete u njega ugniježditi funkciju CHOOSE. Evo kako:

Pretpostavimo da imate listu rezultata u koloni A, imena učenika u koloni B i želite da preuzmete rezultat određenog učenika. Budući da je povratni stupac lijevo od kolone za traženje, obična formula Vlookupa vraća grešku #N/A:

Da biste ovo popravili, zamijenite funkciju CHOOSE pozicije kolona, ​​govoreći Excelu da je kolona 1 B, a kolona 2 A:

=CHOOSE({1,2}, B2:B5, A2:A5)

Zato što isporučujemo niz {1,2} u indeks_num argument, funkcija CHOOSE prihvata opsege u argumentima value (obično ne).

Sada ugradite gornju formulu u argument table_array argumenta VLOOKUP:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

I voilà - traženje ulijevo se izvodi bez zastoja!

ODABERITE formulu za povratak na sljedeći rad dan

Ako niste sigurni da lisutra biste trebali ići na posao ili možete ostati kod kuće i uživati ​​u zasluženom vikendu, Excel funkcija IZBOR može saznati kada je sljedeći radni dan.

Pod pretpostavkom da su vaši radni dani od ponedjeljka do petka, formula ide na sljedeći način:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Na prvi pogled škakljivo, ako se bolje pogleda logiku formule je lako pratiti:

WEKDAY (TODAY()) vraća serijski broj koji odgovara današnjem datumu, u rasponu od 1 (nedjelja) do 7 (subota). Ovaj broj ide u argument indeks_num naše formule CHOOSE.

Vrijednost1 - vrijednost7 (1,1,1,1,1, 3,2) odrediti koliko dana dodati tekućem datumu. Ako je danas nedjelja - četvrtak (indeks_broj 1 - 5), dodajete 1 za povratak sljedećeg dana. Ako je danas petak (indeks_broj 6), dodajete 3 za povratak sljedećeg ponedjeljka. Ako je danas subota (indeks_broj 7), dodajete 2 da biste se ponovo vratili sljedećeg ponedjeljka. Da, tako je jednostavno :)

ODABERITE formulu za vraćanje prilagođenog imena dana/mjeseca od datuma

U situacijama kada želite da dobijete naziv dana u standardnom formatu kao što je puno ime ( ponedjeljak, utorak, itd.) ili kratki naziv (pon, uto, itd.), možete koristiti funkciju TEXT kao što je objašnjeno u ovom primjeru: Dobijte dan u sedmici od datuma u Excelu.

Ako želite vratite naziv dana u nedelji ili meseca u prilagođenom formatu, koristite funkciju CHOOSE na sledeći način.

Da biste dobili dan u nedelji:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

Da biste dobili amjesec:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Gdje je A2 ćelija koja sadrži originalni datum.

Nadam se da vam je ovaj vodič dao neke ideje o kako možete koristiti funkciju CHOOSE u Excelu da poboljšate svoje modele podataka. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeće sedmice!

Preuzmite radnu svesku za vježbu

Excel IZABERITE primjere funkcija