ਟਿਊਟੋਰਿਅਲ ਸੰਟੈਕਸ ਅਤੇ CHOOSE ਫੰਕਸ਼ਨ ਦੇ ਬੁਨਿਆਦੀ ਉਪਯੋਗਾਂ ਦੀ ਵਿਆਖਿਆ ਕਰਦਾ ਹੈ ਅਤੇ ਕੁਝ ਗੈਰ-ਮਾਮੂਲੀ ਉਦਾਹਰਣਾਂ ਪ੍ਰਦਾਨ ਕਰਦਾ ਹੈ ਜੋ ਦਿਖਾਉਂਦੇ ਹੋਏ ਕਿ ਐਕਸਲ ਵਿੱਚ ਇੱਕ CHOOSE ਫਾਰਮੂਲਾ ਕਿਵੇਂ ਵਰਤਣਾ ਹੈ।

CHOOSE ਇਹਨਾਂ ਵਿੱਚੋਂ ਇੱਕ ਹੈ। ਐਕਸਲ ਫੰਕਸ਼ਨ ਜੋ ਆਪਣੇ ਆਪ ਲਾਭਦਾਇਕ ਨਹੀਂ ਲੱਗ ਸਕਦੇ, ਪਰ ਹੋਰ ਫੰਕਸ਼ਨਾਂ ਦੇ ਨਾਲ ਮਿਲ ਕੇ ਬਹੁਤ ਸਾਰੇ ਸ਼ਾਨਦਾਰ ਲਾਭ ਦਿੰਦੇ ਹਨ। ਸਭ ਤੋਂ ਬੁਨਿਆਦੀ ਪੱਧਰ 'ਤੇ, ਤੁਸੀਂ ਉਸ ਮੁੱਲ ਦੀ ਸਥਿਤੀ ਨੂੰ ਨਿਸ਼ਚਿਤ ਕਰਕੇ ਸੂਚੀ ਵਿੱਚੋਂ ਇੱਕ ਮੁੱਲ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ CHOOSE ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਦੇ ਹੋ। ਇਸ ਟਿਊਟੋਰਿਅਲ ਵਿੱਚ ਅੱਗੇ, ਤੁਹਾਨੂੰ ਕਈ ਉੱਨਤ ਵਰਤੋਂ ਮਿਲਣਗੀਆਂ ਜੋ ਨਿਸ਼ਚਿਤ ਤੌਰ 'ਤੇ ਖੋਜਣ ਯੋਗ ਹਨ।

Excel CHOOSE ਫੰਕਸ਼ਨ - ਸੰਟੈਕਸ ਅਤੇ ਬੁਨਿਆਦੀ ਵਰਤੋਂ

ਐਕਸਲ ਵਿੱਚ CHOOSE ਫੰਕਸ਼ਨ ਹੈ। ਇੱਕ ਨਿਰਧਾਰਤ ਸਥਿਤੀ ਦੇ ਅਧਾਰ ਤੇ ਸੂਚੀ ਵਿੱਚੋਂ ਇੱਕ ਮੁੱਲ ਵਾਪਸ ਕਰਨ ਲਈ ਤਿਆਰ ਕੀਤਾ ਗਿਆ ਹੈ।

ਫੰਕਸ਼ਨ Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, ਅਤੇ Excel 2007 ਵਿੱਚ ਉਪਲਬਧ ਹੈ।

CHOOSE ਫੰਕਸ਼ਨ ਦਾ ਸੰਟੈਕਸ ਇਸ ਤਰ੍ਹਾਂ ਹੈ:

ਕਿੱਥੇ:

Index_num (ਲੋੜੀਂਦਾ) - ਵਾਪਸ ਕਰਨ ਲਈ ਮੁੱਲ ਦੀ ਸਥਿਤੀ। ਇਹ 1 ਅਤੇ 254 ਦੇ ਵਿਚਕਾਰ ਕੋਈ ਵੀ ਸੰਖਿਆ ਹੋ ਸਕਦਾ ਹੈ, ਇੱਕ ਸੈੱਲ ਸੰਦਰਭ, ਜਾਂ ਕੋਈ ਹੋਰ ਫਾਰਮੂਲਾ।

ਮੁੱਲ1, ਮੁੱਲ2, … - 254 ਤੱਕ ਮੁੱਲਾਂ ਦੀ ਸੂਚੀ ਜਿਸ ਵਿੱਚੋਂ ਚੁਣਨਾ ਹੈ। ਮੁੱਲ1 ਦੀ ਲੋੜ ਹੈ, ਹੋਰ ਮੁੱਲ ਵਿਕਲਪਿਕ ਹਨ। ਇਹ ਨੰਬਰ, ਟੈਕਸਟ ਮੁੱਲ, ਸੈੱਲ ਸੰਦਰਭ, ਫਾਰਮੂਲੇ, ਜਾਂ ਪਰਿਭਾਸ਼ਿਤ ਨਾਮ ਹੋ ਸਕਦੇ ਹਨ।

ਇੱਥੇ ਸਰਲ ਰੂਪ ਵਿੱਚ ਇੱਕ CHOOSE ਫਾਰਮੂਲੇ ਦੀ ਇੱਕ ਉਦਾਹਰਨ ਹੈ:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

ਫਾਰਮੂਲਾ "ਐਮੀ" ਵਾਪਸ ਕਰਦਾ ਹੈ ਕਿਉਂਕਿ index_num 3 ਹੈ ਅਤੇ "Amy" ਸੂਚੀ ਵਿੱਚ ਤੀਜਾ ਮੁੱਲ ਹੈ:

Excel CHOOSE ਫੰਕਸ਼ਨ - ਯਾਦ ਰੱਖਣ ਵਾਲੀਆਂ 3 ਚੀਜ਼ਾਂ!

CHOOSE ਇੱਕ ਬਹੁਤ ਹੀ ਸਾਦਾ ਫੰਕਸ਼ਨ ਹੈ ਅਤੇ ਤੁਹਾਨੂੰ ਇਸ ਨੂੰ ਆਪਣੀਆਂ ਵਰਕਸ਼ੀਟਾਂ ਵਿੱਚ ਲਾਗੂ ਕਰਨ ਵਿੱਚ ਮੁਸ਼ਕਿਲ ਹੀ ਨਹੀਂ ਆਵੇਗੀ। ਜੇਕਰ ਤੁਹਾਡੇ CHOOSE ਫਾਰਮੂਲੇ ਦੁਆਰਾ ਵਾਪਸ ਕੀਤਾ ਨਤੀਜਾ ਅਚਾਨਕ ਹੈ ਜਾਂ ਉਹ ਨਤੀਜਾ ਨਹੀਂ ਹੈ ਜਿਸਦੀ ਤੁਸੀਂ ਭਾਲ ਕਰ ਰਹੇ ਸੀ, ਤਾਂ ਇਹ ਹੇਠਾਂ ਦਿੱਤੇ ਕਾਰਨਾਂ ਕਰਕੇ ਹੋ ਸਕਦਾ ਹੈ:

1. ਚੋਣ ਲਈ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ 254 ਤੱਕ ਸੀਮਿਤ ਹੈ।
2. ਜੇ ਇੰਡੈਕਸ_ਨਮ ਸੂਚੀ ਵਿੱਚ ਮੁੱਲਾਂ ਦੀ ਸੰਖਿਆ ਤੋਂ 1 ਤੋਂ ਘੱਟ ਜਾਂ ਵੱਧ ਹੈ, ਤਾਂ #VALUE! ਗਲਤੀ ਵਾਪਸ ਕੀਤੀ ਜਾਂਦੀ ਹੈ।
3. ਜੇਕਰ index_num ਆਰਗੂਮੈਂਟ ਇੱਕ ਅੰਸ਼ ਹੈ, ਤਾਂ ਇਸਨੂੰ ਸਭ ਤੋਂ ਹੇਠਲੇ ਪੂਰਨ ਅੰਕ ਵਿੱਚ ਕੱਟਿਆ ਜਾਂਦਾ ਹੈ।

ਐਕਸਲ ਵਿੱਚ CHOOSE ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਿਵੇਂ ਕਰੀਏ - ਫਾਰਮੂਲਾ ਉਦਾਹਰਨਾਂ

ਹੇਠੀਆਂ ਉਦਾਹਰਨਾਂ ਦਿਖਾਉਂਦੀਆਂ ਹਨ ਕਿ ਕਿਵੇਂ CHOOSE ਹੋਰ ਐਕਸਲ ਫੰਕਸ਼ਨਾਂ ਦੀਆਂ ਸਮਰੱਥਾਵਾਂ ਨੂੰ ਵਧਾ ਸਕਦਾ ਹੈ ਅਤੇ ਕੁਝ ਆਮ ਕੰਮਾਂ ਲਈ ਵਿਕਲਪਿਕ ਹੱਲ ਪ੍ਰਦਾਨ ਕਰ ਸਕਦਾ ਹੈ, ਇੱਥੋਂ ਤੱਕ ਕਿ ਉਹਨਾਂ ਲਈ ਵੀ ਜਿਨ੍ਹਾਂ ਨੂੰ ਬਹੁਤ ਸਾਰੇ ਲੋਕਾਂ ਦੁਆਰਾ ਅਸੰਭਵ ਮੰਨਿਆ ਜਾਂਦਾ ਹੈ।

ਇਸਦੀ ਬਜਾਏ ਐਕਸਲ ਚੁਣੋ। ਨੈਸਟਡ IFs

ਐਕਸਲ ਵਿੱਚ ਸਭ ਤੋਂ ਵੱਧ ਅਕਸਰ ਕੀਤੇ ਜਾਣ ਵਾਲੇ ਕੰਮਾਂ ਵਿੱਚੋਂ ਇੱਕ ਇੱਕ ਨਿਰਧਾਰਤ ਸਥਿਤੀ ਦੇ ਅਧਾਰ ਤੇ ਵੱਖ-ਵੱਖ ਮੁੱਲਾਂ ਨੂੰ ਵਾਪਸ ਕਰਨਾ ਹੈ। ਜ਼ਿਆਦਾਤਰ ਮਾਮਲਿਆਂ ਵਿੱਚ, ਇਹ ਕਲਾਸਿਕ ਨੇਸਟਡ IF ਸਟੇਟਮੈਂਟ ਦੀ ਵਰਤੋਂ ਕਰਕੇ ਕੀਤਾ ਜਾ ਸਕਦਾ ਹੈ। ਪਰ CHOOSE ਫੰਕਸ਼ਨ ਇੱਕ ਤੇਜ਼ ਅਤੇ ਸਮਝਣ ਵਿੱਚ ਆਸਾਨ ਵਿਕਲਪ ਹੋ ਸਕਦਾ ਹੈ।

ਉਦਾਹਰਨ 1. ਸਥਿਤੀ ਦੇ ਆਧਾਰ 'ਤੇ ਵੱਖ-ਵੱਖ ਮੁੱਲ ਵਾਪਸ ਕਰੋ

ਮੰਨ ਲਓ ਕਿ ਤੁਹਾਡੇ ਕੋਲ ਵਿਦਿਆਰਥੀ ਸਕੋਰਾਂ ਦਾ ਇੱਕ ਕਾਲਮ ਹੈ ਅਤੇ ਤੁਸੀਂ ਲੇਬਲ ਦੇਣਾ ਚਾਹੁੰਦੇ ਹੋ ਦੇ ਆਧਾਰ 'ਤੇ ਸਕੋਰਹੇਠ ਲਿਖੀਆਂ ਸ਼ਰਤਾਂ:

ਇਸ ਨੂੰ ਕਰਨ ਦਾ ਇੱਕ ਤਰੀਕਾ ਹੈ ਕੁਝ IF ਫਾਰਮੂਲਿਆਂ ਨੂੰ ਇੱਕ ਦੂਜੇ ਦੇ ਅੰਦਰ ਨੇਸਟ ਕਰਨਾ:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

ਇੱਕ ਹੋਰ ਤਰੀਕਾ ਹੈ ਸਥਿਤੀ ਦੇ ਅਨੁਸਾਰੀ ਇੱਕ ਲੇਬਲ ਚੁਣਨਾ:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

ਇਹ ਫਾਰਮੂਲਾ ਕਿਵੇਂ ਕੰਮ ਕਰਦਾ ਹੈ:

index_num ਆਰਗੂਮੈਂਟ ਵਿੱਚ, ਤੁਸੀਂ ਹਰੇਕ ਸ਼ਰਤ ਦਾ ਮੁਲਾਂਕਣ ਕਰਦੇ ਹੋ ਅਤੇ ਜੇਕਰ ਸ਼ਰਤ ਪੂਰੀ ਹੁੰਦੀ ਹੈ ਤਾਂ TRUE ਵਾਪਸ ਕਰੋ, ਨਹੀਂ ਤਾਂ FALSE। ਉਦਾਹਰਨ ਲਈ, ਸੈੱਲ B2 ਵਿੱਚ ਮੁੱਲ ਪਹਿਲੀਆਂ ਤਿੰਨ ਸ਼ਰਤਾਂ ਨੂੰ ਪੂਰਾ ਕਰਦਾ ਹੈ, ਇਸਲਈ ਸਾਨੂੰ ਇਹ ਵਿਚਕਾਰਲਾ ਨਤੀਜਾ ਮਿਲਦਾ ਹੈ:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

ਇਹ ਦੇਖਦੇ ਹੋਏ ਕਿ ਜ਼ਿਆਦਾਤਰ ਐਕਸਲ ਫਾਰਮੂਲੇ ਵਿੱਚ TRUE 1 ਅਤੇ FALSE ਨੂੰ 0 ਦੇ ਬਰਾਬਰ ਹੈ, ਸਾਡੇ ਫਾਰਮੂਲਾ ਇਸ ਪਰਿਵਰਤਨ ਤੋਂ ਗੁਜ਼ਰਦਾ ਹੈ:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

ਐਡੀਸ਼ਨ ਓਪਰੇਸ਼ਨ ਕੀਤੇ ਜਾਣ ਤੋਂ ਬਾਅਦ, ਸਾਡੇ ਕੋਲ ਹੈ:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

ਨਤੀਜੇ ਵਜੋਂ, ਵਿੱਚ ਤੀਜਾ ਮੁੱਲ ਸੂਚੀ ਵਾਪਸ ਕੀਤੀ ਜਾਂਦੀ ਹੈ, ਜੋ ਕਿ "ਚੰਗਾ" ਹੈ।

ਸੁਝਾਅ:

• ਫਾਰਮੂਲੇ ਨੂੰ ਵਧੇਰੇ ਲਚਕਦਾਰ ਬਣਾਉਣ ਲਈ, ਤੁਸੀਂ ਹਾਰਡਕੋਡ ਕੀਤੇ ਲੇਬਲਾਂ ਦੀ ਬਜਾਏ ਸੈੱਲ ਸੰਦਰਭਾਂ ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦੇ ਹੋ, ਉਦਾਹਰਨ ਲਈ:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

• ਜੇਕਰ ਤੁਹਾਡੀ ਕੋਈ ਵੀ ਸ਼ਰਤ ਸਹੀ ਨਹੀਂ ਹੈ, ਤਾਂ ਇੰਡੈਕਸ_ਨਮ ਆਰਗੂਮੈਂਟ ਨੂੰ 0 'ਤੇ ਸੈੱਟ ਕੀਤਾ ਜਾਵੇਗਾ ਜੋ ਤੁਹਾਡੇ ਫਾਰਮੂਲੇ ਨੂੰ #VALUE ਵਾਪਸ ਕਰਨ ਲਈ ਮਜਬੂਰ ਕਰੇਗਾ! ਗਲਤੀ ਇਸ ਤੋਂ ਬਚਣ ਲਈ, ਬਸ IFERROR ਫੰਕਸ਼ਨ ਵਿੱਚ CHOOSE ਨੂੰ ਇਸ ਤਰ੍ਹਾਂ ਲਪੇਟੋ:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

ਉਦਾਹਰਨ 2. ਸਥਿਤੀ ਦੇ ਆਧਾਰ 'ਤੇ ਵੱਖ-ਵੱਖ ਗਣਨਾਵਾਂ ਕਰੋ

ਇਸੇ ਤਰ੍ਹਾਂ, ਤੁਸੀਂਇੱਕ ਦੂਜੇ ਦੇ ਅੰਦਰ ਇੱਕ ਤੋਂ ਵੱਧ IF ਸਟੇਟਮੈਂਟਾਂ ਨੂੰ ਨੈਸਟ ਕੀਤੇ ਬਿਨਾਂ ਸੰਭਾਵਿਤ ਗਣਨਾਵਾਂ/ਫਾਰਮੂਲਿਆਂ ਦੀ ਇੱਕ ਲੜੀ ਵਿੱਚ ਇੱਕ ਗਣਨਾ ਕਰਨ ਲਈ ਐਕਸਲ CHOOSE ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦਾ ਹੈ।

ਉਦਾਹਰਣ ਵਜੋਂ, ਆਓ ਹਰੇਕ ਵਿਕਰੇਤਾ ਦੀ ਵਿਕਰੀ ਦੇ ਆਧਾਰ 'ਤੇ ਕਮਿਸ਼ਨ ਦੀ ਗਣਨਾ ਕਰੀਏ:

B2 ਵਿੱਚ ਵਿਕਰੀ ਦੀ ਰਕਮ ਦੇ ਨਾਲ, ਫਾਰਮੂਲਾ ਹੇਠ ਦਿੱਤੀ ਸ਼ਕਲ ਲੈਂਦਾ ਹੈ:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

ਫਾਰਮੂਲੇ ਵਿੱਚ ਪ੍ਰਤੀਸ਼ਤ ਨੂੰ ਹਾਰਡਕੋਡ ਕਰਨ ਦੀ ਬਜਾਏ, ਤੁਸੀਂ ਆਪਣੀ ਸੰਦਰਭ ਸਾਰਣੀ ਵਿੱਚ ਸੰਬੰਧਿਤ ਸੈੱਲ ਦਾ ਹਵਾਲਾ ਦੇ ਸਕਦੇ ਹੋ, ਜੇਕਰ ਕੋਈ ਹੈ। ਸਿਰਫ਼ $ ਚਿੰਨ੍ਹ ਦੀ ਵਰਤੋਂ ਕਰਕੇ ਸੰਦਰਭਾਂ ਨੂੰ ਠੀਕ ਕਰਨਾ ਯਾਦ ਰੱਖੋ।

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

ਬੇਤਰਤੀਬ ਡੇਟਾ ਤਿਆਰ ਕਰਨ ਲਈ ਐਕਸਲ ਚੁਣੋ ਫਾਰਮੂਲਾ

ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਸ਼ਾਇਦ ਜਾਣਦੇ ਹੋਵੋਗੇ, ਮਾਈਕ੍ਰੋਸਾਫਟ ਐਕਸਲ ਵਿੱਚ ਤਿਆਰ ਕਰਨ ਲਈ ਇੱਕ ਵਿਸ਼ੇਸ਼ ਫੰਕਸ਼ਨ ਹੈ ਹੇਠਾਂ ਅਤੇ ਉੱਪਰਲੇ ਨੰਬਰਾਂ ਦੇ ਵਿਚਕਾਰ ਬੇਤਰਤੀਬ ਪੂਰਨ ਅੰਕ ਜੋ ਤੁਸੀਂ ਨਿਰਧਾਰਤ ਕਰਦੇ ਹੋ - RANDBETWEEN ਫੰਕਸ਼ਨ। ਇਸਨੂੰ CHOOSE ਦੇ index_num ਆਰਗੂਮੈਂਟ ਵਿੱਚ ਨੇਸਟ ਕਰੋ, ਅਤੇ ਤੁਹਾਡਾ ਫਾਰਮੂਲਾ ਲਗਭਗ ਕੋਈ ਵੀ ਬੇਤਰਤੀਬ ਡੇਟਾ ਤਿਆਰ ਕਰੇਗਾ ਜੋ ਤੁਸੀਂ ਚਾਹੁੰਦੇ ਹੋ।

ਉਦਾਹਰਨ ਲਈ, ਇਹ ਫਾਰਮੂਲਾ ਬੇਤਰਤੀਬ ਪ੍ਰੀਖਿਆ ਨਤੀਜਿਆਂ ਦੀ ਇੱਕ ਸੂਚੀ ਤਿਆਰ ਕਰ ਸਕਦਾ ਹੈ:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

ਫਾਰਮੂਲੇ ਦਾ ਤਰਕ ਸਪੱਸ਼ਟ ਹੈ: RANDBETWEEN 1 ਤੋਂ 4 ਤੱਕ ਬੇਤਰਤੀਬੇ ਸੰਖਿਆਵਾਂ ਬਣਾਉਂਦਾ ਹੈ ਅਤੇ CHOOSE ਚਾਰ ਮੁੱਲਾਂ ਦੀ ਪੂਰਵ-ਪਰਿਭਾਸ਼ਿਤ ਸੂਚੀ ਵਿੱਚੋਂ ਇੱਕ ਅਨੁਸਾਰੀ ਮੁੱਲ ਦਿੰਦਾ ਹੈ।

ਨੋਟ ਕਰੋ। RANDBETWEEN ਇੱਕ ਅਸਥਿਰ ਫੰਕਸ਼ਨ ਹੈ ਅਤੇ ਇਹ ਹਰ ਇੱਕ ਨਾਲ ਮੁੜ ਗਣਨਾ ਕਰਦਾ ਹੈਤੁਹਾਡੇ ਦੁਆਰਾ ਵਰਕਸ਼ੀਟ ਵਿੱਚ ਬਦਲੋ। ਨਤੀਜੇ ਵਜੋਂ, ਤੁਹਾਡੀ ਬੇਤਰਤੀਬ ਮੁੱਲਾਂ ਦੀ ਸੂਚੀ ਵੀ ਬਦਲ ਜਾਵੇਗੀ। ਅਜਿਹਾ ਹੋਣ ਤੋਂ ਰੋਕਣ ਲਈ, ਤੁਸੀਂ ਪੇਸਟ ਸਪੈਸ਼ਲ ਵਿਸ਼ੇਸ਼ਤਾ ਦੀ ਵਰਤੋਂ ਕਰਕੇ ਫਾਰਮੂਲੇ ਨੂੰ ਉਹਨਾਂ ਦੇ ਮੁੱਲਾਂ ਨਾਲ ਬਦਲ ਸਕਦੇ ਹੋ।

ਖੱਬੇ Vlookup ਕਰਨ ਲਈ ਫਾਰਮੂਲਾ ਚੁਣੋ

ਜੇਕਰ ਤੁਸੀਂ ਕਦੇ ਪ੍ਰਦਰਸ਼ਨ ਕੀਤਾ ਹੈ ਐਕਸਲ ਵਿੱਚ ਇੱਕ ਲੰਬਕਾਰੀ ਖੋਜ, ਤੁਸੀਂ ਜਾਣਦੇ ਹੋ ਕਿ VLOOKUP ਫੰਕਸ਼ਨ ਸਿਰਫ ਖੱਬੇ-ਸਭ ਤੋਂ ਵੱਧ ਕਾਲਮ ਵਿੱਚ ਖੋਜ ਕਰ ਸਕਦਾ ਹੈ। ਉਹਨਾਂ ਸਥਿਤੀਆਂ ਵਿੱਚ ਜਦੋਂ ਤੁਹਾਨੂੰ ਲੁੱਕਅਪ ਕਾਲਮ ਦੇ ਖੱਬੇ ਪਾਸੇ ਇੱਕ ਮੁੱਲ ਵਾਪਸ ਕਰਨ ਦੀ ਲੋੜ ਹੁੰਦੀ ਹੈ, ਤੁਸੀਂ ਜਾਂ ਤਾਂ INDEX/MATCH ਸੁਮੇਲ ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦੇ ਹੋ ਜਾਂ ਇਸ ਵਿੱਚ CHOOSE ਫੰਕਸ਼ਨ ਨੂੰ ਨੇਸਟ ਕਰਕੇ VLOOKUP ਨੂੰ ਚਲਾ ਸਕਦੇ ਹੋ। ਇਹ ਕਿਵੇਂ ਹੈ:

ਮੰਨ ਲਓ ਕਿ ਤੁਹਾਡੇ ਕੋਲ ਕਾਲਮ A ਵਿੱਚ ਸਕੋਰਾਂ ਦੀ ਸੂਚੀ ਹੈ, ਕਾਲਮ B ਵਿੱਚ ਵਿਦਿਆਰਥੀਆਂ ਦੇ ਨਾਮ ਹਨ, ਅਤੇ ਤੁਸੀਂ ਕਿਸੇ ਖਾਸ ਵਿਦਿਆਰਥੀ ਦਾ ਸਕੋਰ ਪ੍ਰਾਪਤ ਕਰਨਾ ਚਾਹੁੰਦੇ ਹੋ। ਕਿਉਂਕਿ ਰਿਟਰਨ ਕਾਲਮ ਲੁੱਕਅਪ ਕਾਲਮ ਦੇ ਖੱਬੇ ਪਾਸੇ ਹੈ, ਇੱਕ ਨਿਯਮਤ Vlookup ਫਾਰਮੂਲਾ #N/A ਗਲਤੀ ਦਿੰਦਾ ਹੈ:

ਇਸ ਨੂੰ ਠੀਕ ਕਰਨ ਲਈ, ਸਵੈਪ ਕਰਨ ਲਈ CHOOSE ਫੰਕਸ਼ਨ ਪ੍ਰਾਪਤ ਕਰੋ ਕਾਲਮਾਂ ਦੀ ਸਥਿਤੀ, ਐਕਸਲ ਨੂੰ ਦੱਸਦੀ ਹੈ ਕਿ ਕਾਲਮ 1 ਬੀ ਹੈ ਅਤੇ ਕਾਲਮ 2 ਏ ਹੈ:

=CHOOSE({1,2}, B2:B5, A2:A5)

ਕਿਉਂਕਿ ਅਸੀਂ ਇੰਡੈਕਸ_ਨਮ<2 ਵਿੱਚ {1,2} ਦੀ ਇੱਕ ਐਰੇ ਸਪਲਾਈ ਕਰਦੇ ਹਾਂ> ਆਰਗੂਮੈਂਟ, CHOOSE ਫੰਕਸ਼ਨ ਮੁੱਲ ਆਰਗੂਮੈਂਟਾਂ ਵਿੱਚ ਰੇਂਜਾਂ ਨੂੰ ਸਵੀਕਾਰ ਕਰਦਾ ਹੈ (ਆਮ ਤੌਰ 'ਤੇ, ਇਹ ਨਹੀਂ ਹੁੰਦਾ)।

ਹੁਣ, ਉਪਰੋਕਤ ਫਾਰਮੂਲੇ ਨੂੰ ਟੇਬਲ_ਐਰੇ ਆਰਗੂਮੈਂਟ ਵਿੱਚ ਸ਼ਾਮਲ ਕਰੋ VLOOKUP:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

ਅਤੇ voilà - ਖੱਬੇ ਪਾਸੇ ਦੀ ਤਲਾਸ਼ ਬਿਨਾਂ ਕਿਸੇ ਰੁਕਾਵਟ ਦੇ ਕੀਤੀ ਜਾਂਦੀ ਹੈ!

ਅਗਲੇ ਕੰਮ 'ਤੇ ਵਾਪਸ ਜਾਣ ਲਈ ਫਾਰਮੂਲਾ ਚੁਣੋ ਦਿਨ

ਜੇ ਤੁਸੀਂ ਯਕੀਨੀ ਨਹੀਂ ਹੋ ਕਿ ਕੀਤੁਹਾਨੂੰ ਕੱਲ੍ਹ ਕੰਮ 'ਤੇ ਜਾਣਾ ਚਾਹੀਦਾ ਹੈ ਜਾਂ ਘਰ 'ਤੇ ਰਹਿ ਕੇ ਵੀਕਐਂਡ ਦਾ ਆਨੰਦ ਮਾਣ ਸਕਦੇ ਹੋ, Excel CHOOSE ਫੰਕਸ਼ਨ ਇਹ ਪਤਾ ਲਗਾ ਸਕਦਾ ਹੈ ਕਿ ਅਗਲਾ ਕੰਮ ਦਾ ਦਿਨ ਕਦੋਂ ਹੈ।

ਇਹ ਮੰਨ ਕੇ ਕਿ ਤੁਹਾਡੇ ਕੰਮਕਾਜੀ ਦਿਨ ਸੋਮਵਾਰ ਤੋਂ ਸ਼ੁੱਕਰਵਾਰ ਹਨ, ਫਾਰਮੂਲਾ ਇਸ ਤਰ੍ਹਾਂ ਚਲਦਾ ਹੈ:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

32>

ਪਹਿਲੀ ਨਜ਼ਰ ਵਿੱਚ ਮੁਸ਼ਕਲ, ਇੱਕ ਨਜ਼ਦੀਕੀ ਨਜ਼ਰ ਨਾਲ ਫਾਰਮੂਲੇ ਦੇ ਤਰਕ ਦਾ ਪਾਲਣ ਕਰਨਾ ਆਸਾਨ ਹੈ:

ਹਫ਼ਤੇ ਦਾ ਦਿਨ (TODAY()) 1 (ਐਤਵਾਰ) ਤੋਂ 7 (ਸ਼ਨੀਵਾਰ) ਤੱਕ, ਅੱਜ ਦੀ ਮਿਤੀ ਨਾਲ ਸੰਬੰਧਿਤ ਸੀਰੀਅਲ ਨੰਬਰ ਵਾਪਸ ਕਰਦਾ ਹੈ। ਇਹ ਨੰਬਰ ਸਾਡੇ CHOOSE ਫਾਰਮੂਲੇ ਦੇ index_num ਆਰਗੂਮੈਂਟ 'ਤੇ ਜਾਂਦਾ ਹੈ।

Value1 - value7 (1,1,1,1,1, 3,2) ਨਿਰਧਾਰਤ ਕਰੋ ਕਿ ਮੌਜੂਦਾ ਮਿਤੀ ਵਿੱਚ ਕਿੰਨੇ ਦਿਨ ਜੋੜਨੇ ਹਨ। ਜੇਕਰ ਅੱਜ ਐਤਵਾਰ - ਵੀਰਵਾਰ (ਸੂਚਕ_ਨਮ 1 - 5) ਹੈ, ਤਾਂ ਤੁਸੀਂ ਅਗਲੇ ਦਿਨ ਵਾਪਸ ਕਰਨ ਲਈ 1 ਜੋੜਦੇ ਹੋ। ਜੇਕਰ ਅੱਜ ਸ਼ੁੱਕਰਵਾਰ ਹੈ (ਇੰਡੈਕਸ_ਨਮ 6), ਤਾਂ ਤੁਸੀਂ ਅਗਲੇ ਸੋਮਵਾਰ ਵਾਪਸ ਆਉਣ ਲਈ 3 ਜੋੜਦੇ ਹੋ। ਜੇਕਰ ਅੱਜ ਸ਼ਨੀਵਾਰ ਹੈ (ਸੂਚੀ_ਅੰਕ 7), ਤਾਂ ਤੁਸੀਂ ਅਗਲੇ ਸੋਮਵਾਰ ਨੂੰ ਦੁਬਾਰਾ ਵਾਪਸ ਆਉਣ ਲਈ 2 ਜੋੜਦੇ ਹੋ। ਹਾਂ, ਇਹ ਬਹੁਤ ਸੌਖਾ ਹੈ :)

ਤਾਰੀਖ ਤੋਂ ਇੱਕ ਕਸਟਮ ਦਿਨ/ਮਹੀਨੇ ਦਾ ਨਾਮ ਵਾਪਸ ਕਰਨ ਲਈ ਫਾਰਮੂਲਾ ਚੁਣੋ

ਉਸ ਸਥਿਤੀਆਂ ਵਿੱਚ ਜਦੋਂ ਤੁਸੀਂ ਇੱਕ ਦਿਨ ਦਾ ਨਾਮ ਮਿਆਰੀ ਫਾਰਮੈਟ ਵਿੱਚ ਪ੍ਰਾਪਤ ਕਰਨਾ ਚਾਹੁੰਦੇ ਹੋ ਜਿਵੇਂ ਕਿ ਪੂਰਾ ਨਾਮ ( ਸੋਮਵਾਰ, ਮੰਗਲਵਾਰ, ਆਦਿ) ਜਾਂ ਛੋਟਾ ਨਾਮ (ਸੋਮ, ਮੰਗਲਵਾਰ, ਆਦਿ), ਤੁਸੀਂ ਟੈਕਸਟ ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦੇ ਹੋ ਜਿਵੇਂ ਕਿ ਇਸ ਉਦਾਹਰਨ ਵਿੱਚ ਦੱਸਿਆ ਗਿਆ ਹੈ: ਐਕਸਲ ਵਿੱਚ ਮਿਤੀ ਤੋਂ ਹਫ਼ਤੇ ਦਾ ਦਿਨ ਪ੍ਰਾਪਤ ਕਰੋ।

ਜੇ ਤੁਸੀਂ ਚਾਹੁੰਦੇ ਹੋ ਇੱਕ ਕਸਟਮ ਫਾਰਮੈਟ ਵਿੱਚ ਹਫ਼ਤੇ ਦੇ ਇੱਕ ਦਿਨ ਜਾਂ ਇੱਕ ਮਹੀਨੇ ਦਾ ਨਾਮ ਵਾਪਸ ਕਰੋ, ਹੇਠ ਦਿੱਤੇ ਤਰੀਕੇ ਨਾਲ CHOOSE ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰੋ।

ਹਫ਼ਤੇ ਦਾ ਇੱਕ ਦਿਨ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

ਏ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈਮਹੀਨਾ:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

ਜਿੱਥੇ A2 ਅਸਲੀ ਮਿਤੀ ਵਾਲਾ ਸੈੱਲ ਹੈ।

ਮੈਨੂੰ ਉਮੀਦ ਹੈ ਕਿ ਇਸ ਟਿਊਟੋਰਿਅਲ ਨੇ ਤੁਹਾਨੂੰ ਕੁਝ ਵਿਚਾਰ ਦਿੱਤੇ ਹਨ ਤੁਸੀਂ ਆਪਣੇ ਡੇਟਾ ਮਾਡਲਾਂ ਨੂੰ ਵਧਾਉਣ ਲਈ Excel ਵਿੱਚ CHOOSE ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਿਵੇਂ ਕਰ ਸਕਦੇ ਹੋ। ਮੈਂ ਪੜ੍ਹਨ ਲਈ ਤੁਹਾਡਾ ਧੰਨਵਾਦ ਕਰਦਾ ਹਾਂ ਅਤੇ ਅਗਲੇ ਹਫ਼ਤੇ ਤੁਹਾਨੂੰ ਸਾਡੇ ਬਲੌਗ 'ਤੇ ਮਿਲਣ ਦੀ ਉਮੀਦ ਕਰਦਾ ਹਾਂ!

ਪ੍ਰੈਕਟਿਸ ਵਰਕਬੁੱਕ ਡਾਊਨਲੋਡ ਕਰੋ

ਐਕਸਲ ਫੰਕਸ਼ਨ ਉਦਾਹਰਨਾਂ ਚੁਣੋ