La lernilo klarigas la sintakson kaj bazajn uzojn de la funkcio CHOOSE kaj provizas kelkajn ne-trivialajn ekzemplojn montrante kiel uzi CHOOSE-formulon en Excel.

CHOOSE estas unu el tiuj. Excel-funkcioj, kiuj eble ne aspektas utilaj per si mem, sed kombinitaj kun aliaj funkcioj, donas kelkajn mirindajn avantaĝojn. Je la plej baza nivelo, vi uzas la funkcion ELEKTI por ricevi valoron el listo specifante la pozicion de tiu valoro. Plue en ĉi tiu lernilo, vi trovos plurajn altnivelajn uzojn, kiujn certe esplorindas.

Excel-ELEKTI-funkcio - sintakso kaj bazaj uzoj

La ELEKTI-funkcio en Excel estas desegnita por redoni valoron de la listo bazita sur specifa pozicio.

La funkcio disponeblas en Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 kaj Excel 2007.

La sintakso de la funkcio ELEKTI estas jena:

Kie:

Indeksa_num (postulata) - la pozicio de la valoro redonota. Ĝi povas esti ajna nombro inter 1 kaj 254, ĉela referenco, aŭ alia formulo.

Valoro1, valoro2, … - listo de ĝis 254 valoroj el kiuj elekti. Valoro1 estas postulata, aliaj valoroj estas laŭvolaj. Ĉi tiuj povas esti nombroj, tekstaj valoroj, ĉelreferencoj, formuloj aŭ difinitaj nomoj.

Jen ekzemplo de ELEKTI formulo en la plej simpla formo:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

La formulo resendas "Amy" ĉar index_num estas 3 kaj "Amy" estas la 3-a valoro en la listo:

Excel ELEKTI funkcion - 3 memorindaj aferoj!

ELEKTI estas tre simpla funkcio kaj vi apenaŭ renkontos malfacilaĵojn efektivigi ĝin en viaj laborfolioj. Se la rezulto resendita de via CHOOSE-formulo estas neatendita aŭ ne la rezulto, kiun vi serĉis, tio povas esti pro la sekvaj kialoj:

1. La nombro da valoroj elekteblaj estas limigita al 254.
2. Se index_num estas malpli ol 1 aŭ pli granda ol la nombro da valoroj en la listo, la #VALORO! eraro estas resendita.
3. Se la argumento index_num estas frakcio, ĝi estas detranĉita al la plej malalta entjero.

Kiel uzi CHOOS-funkcion en Excel - formulo ekzemploj

La sekvaj ekzemploj montras kiel CHOOSE povas etendi la kapablojn de aliaj Excel-funkcioj kaj disponigi alternativajn solvojn al iuj oftaj taskoj, eĉ al tiuj kiuj estas konsiderataj nefareblaj de multaj.

Excel CHOOSE anstataŭe de nestitaj IF-oj

Unu el la plej oftaj taskoj en Excel estas redoni malsamajn valorojn bazitajn sur specifa kondiĉo. Plejofte, ĉi tio povas esti farita uzante klasikan nestitan IF deklaron. Sed la funkcio ELEKTI povas esti rapida kaj facile komprenebla alternativo.

Ekzemplo 1. Redonu malsamajn valorojn laŭ kondiĉo

Supozi vi havas kolumnon de studentaj poentoj kaj vi volas etikedi la poentoj bazitaj sur lajenaj kondiĉoj:

Unu maniero fari tion estas nesti kelkajn IF-formulojn unu en la alian:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

Alia maniero estas elekti etikedon respondan al la kondiĉo:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

Kiel ĉi tiu formulo funkcias:

En la argumento index_num , vi taksas ĉiun kondiĉon kaj redonas VERA se la kondiĉo estas plenumita, FALSE alie. Ekzemple, la valoro en ĉelo B2 plenumas la unuajn tri kondiĉojn, do ni ricevas ĉi tiun mezan rezulton:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

Konsiderante ke en la plej multaj Excel-formuloj VERA egalas al 1 kaj FALSA al 0, nia formulo suferas ĉi tiun transformon:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

Post kiam la aldono estas farita, ni havas:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

Kiel rezulto, la 3-a valoro en la listo estas resendita, kiu estas "Bona".

Konsiletoj:

• Por pli fleksebla la formulo, vi povas uzi ĉelreferencojn anstataŭ malmolkodigitaj etikedoj, ekzemple:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

• Se neniu el viaj kondiĉoj estas VERA, la argumento index_num estos agordita al 0 devigante vian formulon redoni la #VALORO! eraro. Por eviti ĉi tion, simple envolvu CHOOS en la funkcio IFERROR tiel:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

Ekzemplo 2. Faru malsamajn kalkulojn bazitajn sur kondiĉo

Simile, vipovas uzi la Excel-ELEKTI-funkcion por fari unu kalkulon en serio de eblaj kalkuloj/formuloj sen nestumi plurajn IF-deklarojn unu en la alian.

Ekzemple, ni kalkulu la komisionon de ĉiu vendisto depende de iliaj vendoj:

Kun la vendokvanto en B2, la formulo prenas la jenan formon:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

Anstataŭ malmola kodigo de la procentoj en la formulo, vi povas raporti al la responda ĉelo en via referenca tabelo, se ekzistas. Nur memoru ripari la referencojn per la $-signo.

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

Excel ELEKTU formulon por generi hazardajn datumojn

Kiel vi verŝajne scias, Microsoft Excel havas specialan funkcion por generi hazardaj entjeroj inter la malsupraj kaj supraj nombroj kiujn vi specifas - funkcio RANDBETWEEN. Nestu ĝin en la argumento index_num de CHOOSE, kaj via formulo generos preskaŭ ajnajn hazardajn datumojn, kiujn vi volas.

Ekzemple, ĉi tiu formulo povas produkti liston de hazardaj ekzamenrezultoj:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

La logiko de la formulo estas evidenta: RANDBETWEEN generas hazardajn nombrojn de 1 ĝis 4 kaj CHOOS resendas respondan valoron el la antaŭdifinita listo de kvar valoroj.

Notu. RANDBETWEEN estas volatila funkcio kaj ĝi rekalkulas kun ĉiuŝanĝo, kiun vi faras al la laborfolio. Kiel rezulto, via listo de hazardaj valoroj ankaŭ ŝanĝiĝos. Por eviti ke tio okazu, vi povas anstataŭigi formulojn per iliaj valoroj uzante la funkcion Alglui Specialan .

ELEKTU formulon por fari maldekstran Vserĉon

Se vi iam faris vertikala serĉo en Excel, vi scias, ke la funkcio VLOOKUP nur povas serĉi en la plej maldekstra kolumno. En situacioj, kiam vi devas redoni valoron maldekstre de la serĉkolumno, vi povas aŭ uzi la kombinaĵon INDEX / MATCH aŭ trompi VLOOKUP nestante la funkcion ELEKTI en ĝi. Jen kiel:

Supoze, ke vi havas liston de poentoj en kolumno A, studentajn nomojn en kolumno B, kaj vi volas retrovi poentaron de aparta studento. Ĉar la revena kolumno estas maldekstre de la serĉa kolumno, regula Vlookup-formulo liveras la eraron #N/A:

Por ripari ĉi tion, ricevu la funkcion CHOOS por interŝanĝi. la pozicioj de kolumnoj, dirante al Excel, ke kolumno 1 estas B kaj kolumno 2 estas A:

=CHOOSE({1,2}, B2:B5, A2:A5)

Ĉar ni provizas tabelon de {1,2} en la indeksa_num argumento, la COOSE-funkcio akceptas intervalojn en la argumentoj valora (normale, ĝi ne).

Nun, enmetu la supran formulon en la argumenton table_array de VSERĈO:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

Kaj voilà - serĉo maldekstre estas farata senprobleme!

ELEKTU formulon por reveni sekvan laboron tago

Se vi ne certas ĉuvi devus iri labori morgaŭ aŭ povas resti hejme kaj ĝui vian merititan semajnfinon, la Excel-ELEKTI-funkcio povas ekscii kiam estas la sekva labortago.

Suponante, ke viaj labortagoj estas de lundo ĝis vendredo, la formulo. iras jene:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Delikata unuavide, pli detale rigardante la logiko de la formulo estas facile sekvi:

Semajntago (HODIAŬ()) liveras serian numeron respondan al la hodiaŭa dato, de 1 (dimanĉo) ĝis 7 (sabato). Ĉi tiu nombro iras al la argumento index_num de nia ELEKTI formulo.

Valoro1 - valoro7 (1,1,1,1,1, 3,2) determini kiom da tagoj aldoni al la nuna dato. Se hodiaŭ estas dimanĉo - ĵaŭdo (index_num 1 - 5), vi aldonu 1 por reveni la sekvan tagon. Se hodiaŭ estas vendredo (index_num 6), vi aldonu 3 por reveni la venontan lundon. Se hodiaŭ estas sabato (index_num 7), vi aldonu 2 por reveni la venontan lundon denove. Jes, estas tiel simpla :)

ELEKTU formulon por redoni propran tagan/monatan nomon de dato

En situacioj kiam vi volas ricevi tagan nomon en la norma formato kiel plena nomo ( lundo, mardo, ktp.) aŭ mallonga nomo (lun, mardo, ktp.), vi povas uzi la TEKSTO-funkcion kiel klarigite en ĉi tiu ekzemplo: Akiri tagon de semajno de dato en Excel.

Se vi volas redonu semajntagon aŭ monatan nomon en laŭmenda formato, uzu la funkcion ELEKTI en la sekva maniero.

Por ricevi semajnotagon:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

Por akiri amonato:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Kie A2 estas la ĉelo enhavanta la originan daton.

Mi esperas, ke ĉi tiu lernilo donis al vi kelkajn ideojn pri kiel vi povas uzi la funkcion ELEKTI en Excel por plibonigi viajn datummodelojn. Mi dankas vin pro legado kaj esperas vidi vin en nia blogo venontsemajne!

Elŝutu ekzerclibron

Excel ELEKTI funkcioekzemploj