Tutoriali shpjegon sintaksën dhe përdorimet bazë të funksionit CHOOSE dhe ofron disa shembuj jo të parëndësishëm që tregojnë se si të përdoret një formulë CHOOSE në Excel.

CHOOSE është një nga ato Funksionet e Excel-it që mund të mos duken të dobishme më vete, por të kombinuara me funksione të tjera japin një sërë përfitimesh të jashtëzakonshme. Në nivelin më themelor, ju përdorni funksionin CHOOSE për të marrë një vlerë nga një listë duke specifikuar pozicionin e asaj vlere. Më tej në këtë tutorial, do të gjeni disa përdorime të avancuara që sigurisht ia vlen të eksplorohen.

Funksioni CHOOSE Excel - sintaksa dhe përdorimet bazë

Funksioni CHOOSE në Excel është projektuar për të kthyer një vlerë nga lista bazuar në një pozicion të caktuar.

Funksioni është i disponueshëm në Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 dhe Excel 2007.

Sintaksa e funksionit CHOOSE është si më poshtë:

Ku:

Index_num (kërkohet) - pozicioni i vlerës që duhet kthyer. Mund të jetë çdo numër midis 1 dhe 254, një referencë qelize ose një formulë tjetër.

Vlera1, vlera2, … - një listë me deri në 254 vlera nga të cilat mund të zgjidhni. Kërkohet vlera 1, vlerat e tjera janë opsionale. Këto mund të jenë numra, vlera teksti, referenca qelizash, formula ose emra të përcaktuar.

Këtu është një shembull i një formule CHOOSE në formën më të thjeshtë:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

Formula kthen “Amy” sepse indeksi_num është 3 dhe "Amy" është vlera e tretë në listë:

Funksioni CHOOSE Excel - 3 gjëra për t'u mbajtur mend!

CHOOSE është një funksion shumë i thjeshtë dhe vështirë se do të hasni në ndonjë vështirësi për ta zbatuar atë në fletët tuaja të punës. Nëse rezultati i kthyer nga formula juaj CHOOSE është i papritur ose nuk është rezultati që po kërkoni, mund të jetë për arsyet e mëposhtme:

1. Numri i vlerave për të zgjedhur është i kufizuar në 254.
2. Nëse indeksi_num është më i vogël se 1 ose më i madh se numri i vlerave në listë, #VALUE! gabimi është kthyer.
3. Nëse argumenti index_num është një fraksion, ai shkurtohet në numrin e plotë më të ulët.

Si të përdoret funksioni CHOOSE në Excel - formula shembuj

Shembujt e mëposhtëm tregojnë se si CHOOSE mund të zgjerojë aftësitë e funksioneve të tjera të Excel dhe të ofrojë zgjidhje alternative për disa detyra të zakonshme, madje edhe për ato që konsiderohen të pamundura nga shumë njerëz.

Excel CHOOSE në vend të IF të mbivendosur

Një nga detyrat më të shpeshta në Excel është të ktheni vlera të ndryshme bazuar në një kusht të caktuar. Në shumicën e rasteve, kjo mund të bëhet duke përdorur një deklaratë klasike të mbivendosur IF. Por funksioni CHOOSE mund të jetë një alternativë e shpejtë dhe e lehtë për t'u kuptuar.

Shembulli 1. Ktheni vlera të ndryshme bazuar në kusht

Duke supozuar se keni një kolonë të rezultateve të studentëve dhe dëshironi të etiketoni pikët e bazuara nëkushtet e mëposhtme:

Një mënyrë për ta bërë këtë është të futni disa formula IF brenda njëra-tjetrës:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

Një mënyrë tjetër është të zgjidhni një etiketë që korrespondon me kushtin:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

Si funksionon kjo formulë:

Në argumentin indeksi_num , ju vlerësoni çdo kusht dhe ktheni TRUE nëse kushti plotësohet, FALSE ndryshe. Për shembull, vlera në qelizën B2 plotëson tre kushtet e para, kështu që marrim këtë rezultat të ndërmjetëm:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

Duke pasur parasysh që në shumicën e formulave të Excel-it TRUE barazohet me 1 dhe FALSE me 0, formula i nënshtrohet këtij transformimi:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

Pasi të kryhet operacioni i mbledhjes, kemi:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

Si rezultat, vlerën e 3-të në lista është kthyer, e cila është "Mirë".

Këshilla:

• Për ta bërë formulën më fleksibël, mund të përdorni referencat e qelizave në vend të etiketave të koduara, për shembull:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

  Shiko gjithashtu: Si të ndërroni kolonat dhe rreshtat në Excel
• Nëse asnjë nga kushtet tuaja nuk është e VËRTETË, argumenti indeksi_num do të vendoset në 0 duke e detyruar formulën tuaj të kthejë #VALUE! gabim. Për të shmangur këtë, thjesht mbështillni CHOOSE në funksionin IFERROR si kjo:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

Shembulli 2. Kryeni llogaritje të ndryshme bazuar në kusht

Në një mënyrë të ngjashme, jumund të përdorë funksionin Excel CHOOSE për të kryer një llogaritje në një seri llogaritjesh/formulash të mundshme pa futur deklarata të shumta IF brenda njëra-tjetrës.

Si shembull, le të llogarisim komisionin e secilit shitës në varësi të shitjeve të tyre:

Me shumën e shitjeve në B2, formula merr formën e mëposhtme:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

Në vend të kodimit të fortë të përqindjeve në formulë, ju mund t'i referoheni qelizës përkatëse në tabelën tuaj të referencës, nëse ka ndonjë. Vetëm mos harroni të rregulloni referencat duke përdorur shenjën $.

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

Excel CHOOSE formule për të gjeneruar të dhëna të rastësishme

Siç e dini, Microsoft Excel ka një funksion të veçantë për të gjeneruar numra të plotë të rastit midis numrave të poshtëm dhe të sipërm që specifikoni - funksioni RANDBETWEEN. Vendoseni atë në argumentin indeksi_num të CHOOSE dhe formula juaj do të gjenerojë pothuajse çdo të dhënë të rastësishme që dëshironi.

Për shembull, kjo formulë mund të prodhojë një listë të rezultateve të rastësishme të provimit:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

Logjika e formulës është e qartë: RANDBETWEEN gjeneron numra të rastësishëm nga 1 në 4 dhe CHOOSE kthen një vlerë korresponduese nga lista e paracaktuar me katër vlera.

Shënim. RANDBETWEEN është një funksion i paqëndrueshëm dhe rillogaritet me çdondryshimi që bëni në fletën e punës. Si rezultat, lista juaj e vlerave të rastësishme do të ndryshojë gjithashtu. Për të parandaluar që kjo të ndodhë, mund të zëvendësoni formulat me vlerat e tyre duke përdorur veçorinë Ngjit Special .

ZGJIDHni formulën për të bërë një Vlookup majtas

Nëse keni kryer ndonjëherë një kërkim vertikal në Excel, ju e dini se funksioni VLOOKUP mund të kërkojë vetëm në kolonën më të majtë. Në situatat kur duhet të ktheni një vlerë në të majtë të kolonës së kërkimit, mund të përdorni ose kombinimin INDEX / MATCH ose të mashtroni VLOOKUP duke futur në të funksionin CHOOSE. Ja se si:

Si të supozojmë se keni një listë pikësh në kolonën A, emrat e studentëve në kolonën B dhe dëshironi të rikuperoni një pikë të një studenti të caktuar. Meqenëse kolona e kthimit është në të majtë të kolonës së kërkimit, një formulë e rregullt Vlookup kthen gabimin #N/A:

Për ta rregulluar këtë, merrni funksionin CHOOSE për ta ndërruar pozicionet e kolonave, duke i thënë Excel-it që kolona 1 është B dhe kolona 2 është A:

=CHOOSE({1,2}, B2:B5, A2:A5)

Sepse ne ofrojmë një grup prej {1,2} në indeksi_num argument, funksioni CHOOSE pranon vargjet në argumentet value (normalisht, nuk e bën).

Tani, futni formulën e mësipërme në argumentin tabelë_array të VLOOKUP:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

Dhe voilà - një kërkim në të majtë kryhet pa asnjë pengesë!

ZGJIDH formulën për t'u kthyer në punë tjetër ditë

Nëse nuk jeni të sigurt nëseju duhet të shkoni në punë nesër ose mund të qëndroni në shtëpi dhe të shijoni fundjavën tuaj të merituar, funksioni Excel CHOOSE mund të zbulojë se kur është dita tjetër e punës.

Duke supozuar se ditët tuaja të punës janë nga e hëna në të premte, formula shkon si më poshtë:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

E ndërlikuar në pamje të parë, me një vështrim më të afërt, logjika e formulës është e lehtë për t'u ndjekur:

WEEKDAY (TODAY()) kthen një numër serial që korrespondon me datën e sotme, duke filluar nga 1 (e diel) deri në 7 (e shtunë). Ky numër shkon te argumenti indeksi_num i formulës sonë CHOOSE.

Vlera1 - vlera7 (1,1,1,1,1, 3,2) përcaktoni sa ditë t'i shtoni datës aktuale. Nëse sot është e diel - e enjte (indeksi_num 1 - 5), ju shtoni 1 për ta kthyer ditën tjetër. Nëse sot është e premte (indeksi_num 6), ju shtoni 3 për t'u kthyer të hënën tjetër. Nëse sot është e shtunë (indeksi_num 7), ju shtoni 2 për t'u kthyer sërish të hënën tjetër. Po, është kaq e thjeshtë :)

ZGJIDH formulën për të kthyer një emër të personalizuar të ditës/muajit nga data

Në situatat kur dëshironi të merrni një emër dite në formatin standard, si p.sh. emri i plotë ( E hënë, e martë, etj.) ose emri i shkurtër (e hënë, e martë, etj.), mund të përdorni funksionin TEXT siç shpjegohet në këtë shembull: Merrni ditën e javës nga data në Excel.

Nëse dëshironi të ktheni emrin e një dite të javës ose të muajit në një format të personalizuar, përdorni funksionin CHOOSE në mënyrën e mëposhtme.

Për të marrë një ditë të javës:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

Për të marrë njëmuaj:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Ku A2 është qeliza që përmban datën origjinale.

Shpresoj që ky tutorial t'ju ketë dhënë disa ide për si mund të përdorni funksionin CHOOSE në Excel për të përmirësuar modelet tuaja të të dhënave. Ju falënderoj që lexoni dhe shpresoj t'ju shohim në blogun tonë javën e ardhshme!

Shkarko librin e punës praktike

Excel CHOOSE shembuj të funksionit