ٹیوٹوریل CHOOSE فنکشن کے نحو اور بنیادی استعمال کی وضاحت کرتا ہے اور چند غیر معمولی مثالیں فراہم کرتا ہے جس میں دکھایا گیا ہے کہ Excel میں CHOOSE فارمولہ کیسے استعمال کیا جائے۔

CHOOSE ان میں سے ایک ہے۔ ایکسل فنکشنز جو خود کارآمد نظر نہیں آتے، لیکن دوسرے فنکشنز کے ساتھ مل کر بہت سے زبردست فائدے دیتے ہیں۔ سب سے بنیادی سطح پر، آپ اس قدر کی پوزیشن بتا کر فہرست سے قدر حاصل کرنے کے لیے CHOOSE فنکشن استعمال کرتے ہیں۔ اس ٹیوٹوریل میں مزید، آپ کو کئی ایسے جدید استعمالات ملیں گے جو یقیناً دریافت کرنے کے قابل ہیں۔

Excel CHOOSE فنکشن - نحو اور بنیادی استعمالات

ایکسل میں CHOOSE فنکشن ہے ایک مخصوص پوزیشن کی بنیاد پر فہرست سے قدر واپس کرنے کے لیے ڈیزائن کیا گیا ہے۔

فنکشن Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, اور Excel 2007 میں دستیاب ہے۔

CHOOSE فنکشن کا نحو درج ذیل ہے:

کہاں:

Index_num (ضروری) - واپس کرنے کے لیے قدر کی پوزیشن۔ یہ 1 اور 254 کے درمیان کوئی بھی نمبر ہو سکتا ہے، سیل کا حوالہ، یا کوئی اور فارمولا۔

Value1, value2, … - 254 اقدار تک کی فہرست جن میں سے انتخاب کرنا ہے۔ ویلیو 1 درکار ہے، دیگر اقدار اختیاری ہیں۔ یہ نمبرز، ٹیکسٹ ویلیوز، سیل ریفرینسز، فارمولے، یا متعین نام ہو سکتے ہیں۔

یہاں سادہ ترین فارمولے میں CHOOSE فارمولے کی ایک مثال ہے:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

فارمولہ "امی" واپس کرتا ہے کیونکہ1>CHOOSE ایک بہت ہی سادہ فنکشن ہے اور آپ کو اپنی ورک شیٹس میں اسے لاگو کرنے میں مشکل سے ہی کوئی مشکل پیش آئے گی۔ اگر آپ کے CHOOSE فارمولے کے ذریعے واپس آنے والا نتیجہ غیر متوقع ہے یا وہ نتیجہ نہیں ہے جس کی آپ تلاش کر رہے تھے، تو یہ درج ذیل وجوہات کی وجہ سے ہو سکتا ہے:

1. منتخب کرنے کے لیے اقدار کی تعداد 254 تک محدود ہے۔
2. اگر انڈیکس_num فہرست میں موجود اقدار کی تعداد سے 1 سے کم یا زیادہ ہے، تو #VALUE! غلطی واپس آ گئی ہے۔
3. اگر انڈیکس_نم دلیل ایک حصہ ہے، تو اسے سب سے کم عدد میں چھوٹا کر دیا جاتا ہے۔

ایکسل میں CHOOSE فنکشن کا استعمال کیسے کریں - فارمولہ مثالیں

مندرجہ ذیل مثالیں بتاتی ہیں کہ کس طرح CHOOSE دوسرے ایکسل فنکشنز کی صلاحیتوں کو بڑھا سکتا ہے اور کچھ عام کاموں کے لیے متبادل حل فراہم کر سکتا ہے، یہاں تک کہ ان کاموں کے لیے بھی جنہیں بہت سے لوگ ناقابل عمل سمجھتے ہیں۔

کی بجائے ایکسل کا انتخاب کریں nested IFs

ایکسل میں اکثر کاموں میں سے ایک مخصوص حالت کی بنیاد پر مختلف اقدار کو واپس کرنا ہے۔ زیادہ تر معاملات میں، یہ کلاسک نیسٹڈ IF سٹیٹمنٹ کا استعمال کر کے کیا جا سکتا ہے۔ لیکن CHOOSE فنکشن ایک فوری اور سمجھنے میں آسان متبادل ہو سکتا ہے۔

مثال 1. شرط کی بنیاد پر مختلف اقدار واپس کریں

فرض کریں کہ آپ کے پاس طلبہ کے اسکورز کا کالم ہے اور آپ لیبل لگانا چاہتے ہیں۔ کی بنیاد پر سکوردرج ذیل شرائط:

ایسا کرنے کا ایک طریقہ یہ ہے کہ کچھ IF فارمولوں کو ایک دوسرے کے اندر اندر رکھیں:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

دوسرا طریقہ یہ ہے کہ شرط کے مطابق لیبل کا انتخاب کیا جائے:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

27>

یہ فارمولا کیسے کام کرتا ہے:

index_num دلیل میں، آپ ہر شرط کا جائزہ لیتے ہیں اور اگر شرط پوری ہو جاتی ہے تو TRUE واپس کرتے ہیں، دوسری صورت میں FALSE۔ مثال کے طور پر، سیل B2 کی قدر پہلی تین شرائط کو پورا کرتی ہے، اس لیے ہمیں یہ درمیانی نتیجہ ملتا ہے:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

یہ دیکھتے ہوئے کہ ایکسل کے زیادہ تر فارمولوں میں TRUE 1 اور FALSE سے 0 کے برابر ہے، ہمارے فارمولہ اس تبدیلی سے گزرتا ہے:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

اضافہ آپریشن انجام دینے کے بعد، ہمارے پاس ہے:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

نتیجے کے طور پر، میں تیسری قدر فہرست لوٹائی جاتی ہے، جو کہ "اچھا" ہے۔

تجاویز:

• فارمولے کو مزید لچکدار بنانے کے لیے، آپ ہارڈ کوڈ شدہ لیبلز کے بجائے سیل حوالہ جات استعمال کرسکتے ہیں، مثال کے طور پر:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

• اگر آپ کی کوئی بھی شرط درست نہیں ہے تو، index_num دلیل کو 0 پر سیٹ کیا جائے گا اور آپ کے فارمولے کو #VALUE واپس کرنے پر مجبور کیا جائے گا۔ غلطی اس سے بچنے کے لیے، بس IFERROR فنکشن میں CHOOSE کو اس طرح لپیٹیں:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

مثال 2. حالت کی بنیاد پر مختلف حسابات انجام دیں

اسی طرح، تمایک دوسرے کے اندر ایک سے زیادہ IF سٹیٹمنٹس کو nesting کیے بغیر ممکنہ حسابات/فارمولوں کی ایک سیریز میں ایک حساب کرنے کے لیے Excel CHOOSE فنکشن استعمال کر سکتا ہے۔

مثال کے طور پر، آئیے ہر بیچنے والے کے کمیشن کو ان کی فروخت کے لحاظ سے شمار کرتے ہیں:

B2 میں فروخت کی رقم کے ساتھ، فارمولہ درج ذیل شکل اختیار کرتا ہے:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

فارمولے میں فیصد کو ہارڈ کوڈنگ کرنے کے بجائے، اگر کوئی ہے تو آپ اپنے حوالہ جدول میں متعلقہ سیل سے رجوع کر سکتے ہیں۔ صرف $ سائن کا استعمال کرتے ہوئے حوالہ جات کو ٹھیک کرنا یاد رکھیں۔

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

بے ترتیب ڈیٹا بنانے کے لیے ایکسل کا انتخاب کریں

جیسا کہ آپ شاید جانتے ہوں گے کہ مائیکروسافٹ ایکسل میں تخلیق کرنے کے لیے ایک خاص فنکشن ہوتا ہے۔ نیچے اور اوپر والے نمبروں کے درمیان بے ترتیب عدد جو آپ بتاتے ہیں - RANDBETWEEN فنکشن۔ اسے CHOOSE کے index_num دلیل میں داخل کریں، اور آپ کا فارمولا تقریباً کوئی بھی بے ترتیب ڈیٹا تیار کرے گا جو آپ چاہتے ہیں۔

مثال کے طور پر، یہ فارمولہ بے ترتیب امتحان کے نتائج کی فہرست بنا سکتا ہے:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

فارمولے کی منطق واضح ہے: RANDBETWEEN 1 سے 4 تک بے ترتیب نمبر تیار کرتا ہے اور CHOOSE چار اقدار کی پہلے سے طے شدہ فہرست سے متعلقہ قدر لوٹاتا ہے۔

نوٹ۔ RANDBETWEEN ایک غیر مستحکم فعل ہے اور یہ ہر ایک کے ساتھ دوبارہ حساب کرتا ہے۔ورک شیٹ میں جو آپ بناتے ہیں اسے تبدیل کریں۔ نتیجے کے طور پر، آپ کی بے ترتیب اقدار کی فہرست بھی بدل جائے گی۔ ایسا ہونے سے روکنے کے لیے، آپ پیسٹ اسپیشل فیچر کا استعمال کرکے فارمولوں کو ان کی اقدار سے بدل سکتے ہیں۔

بائیں Vlookup کرنے کے لیے فارمولے کا انتخاب کریں

اگر آپ نے کبھی پرفارم کیا ہے ایکسل میں ایک عمودی تلاش، آپ جانتے ہیں کہ VLOOKUP فنکشن صرف بائیں طرف والے کالم میں تلاش کر سکتا ہے۔ ایسے حالات میں جب آپ کو تلاش کے کالم کے بائیں طرف ایک قدر واپس کرنے کی ضرورت ہو، آپ یا تو INDEX/MATCH مجموعہ استعمال کر سکتے ہیں یا اس میں CHOOSE فنکشن کو گھونسلا کر VLOOKUP کو چال سکتے ہیں۔ یہ ہے طریقہ:

فرض کریں کہ آپ کے پاس کالم A میں اسکورز کی فہرست ہے، کالم B میں طلباء کے نام ہیں، اور آپ کسی خاص طالب علم کے اسکور کو بازیافت کرنا چاہتے ہیں۔ چونکہ واپسی کا کالم تلاش کے کالم کے بائیں طرف ہے، اس لیے ایک باقاعدہ Vlookup فارمولہ #N/A خرابی لوٹاتا ہے:

اس کو ٹھیک کرنے کے لیے، تبدیل کرنے کے لیے CHOOSE فنکشن حاصل کریں۔ کالموں کی پوزیشنز، ایکسل کو بتاتے ہوئے کہ کالم 1 B ہے اور کالم 2 A ہے:

=CHOOSE({1,2}, B2:B5, A2:A5)

کیونکہ ہم index_num<2 میں {1,2} کی صف فراہم کرتے ہیں۔> argument، CHOOSE فنکشن value دلائل میں رینجز کو قبول کرتا ہے (عام طور پر ایسا نہیں ہوتا)۔

اب، اوپر والے فارمولے کو table_array argument میں ایمبیڈ کریں۔ VLOOKUP:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

اور voilà - بائیں طرف ایک تلاش بغیر کسی رکاوٹ کے انجام دیا جاتا ہے!

اگلے کام پر واپس آنے کے لیے فارمولہ منتخب کریں دن

اگر آپ کو یقین نہیں ہے کہ آیاآپ کو کل کام پر جانا چاہیے یا گھر پر رہ کر اپنے اچھے ویک اینڈ سے لطف اندوز ہو سکتے ہیں، Excel CHOOSE فنکشن یہ معلوم کر سکتا ہے کہ اگلا کام کا دن کب ہے۔

یہ فرض کرتے ہوئے کہ آپ کے کام کے دن پیر تا جمعہ ہیں، فارمولہ اس طرح جاتا ہے:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

پہلی نظر میں مشکل، قریب سے دیکھنے پر فارمولے کی منطق پر عمل کرنا آسان ہے:

ہفتہ ہفتہ (TODAY()) آج کی تاریخ سے متعلق ایک سیریل نمبر لوٹاتا ہے، 1 (اتوار) سے 7 (ہفتہ) تک۔ یہ نمبر ہمارے CHOOSE فارمولے کے index_num دلیل پر جاتا ہے۔

Value1 - value7 (1,1,1,1,1,1, 3,2) طے کریں کہ موجودہ تاریخ میں کتنے دنوں کا اضافہ کرنا ہے۔ اگر آج اتوار - جمعرات ہے (انڈیکس_ نمبر 1 - 5)، تو آپ اگلے دن واپس کرنے کے لیے 1 کا اضافہ کرتے ہیں۔ اگر آج جمعہ ہے (انڈیکس_نمبر 6)، تو آپ اگلے پیر کو واپس آنے کے لیے 3 کا اضافہ کریں۔ اگر آج ہفتہ ہے (انڈیکس_نمبر 7)، تو آپ اگلے پیر کو دوبارہ واپس آنے کے لیے 2 کا اضافہ کریں۔ ہاں، یہ اتنا آسان ہے :)

تاریخ سے حسب ضرورت دن/مہینے کا نام واپس کرنے کے لیے فارمولہ منتخب کریں

ایسے حالات میں جب آپ کسی دن کا نام معیاری فارمیٹ میں حاصل کرنا چاہتے ہیں جیسے کہ پورا نام ( پیر، منگل، وغیرہ) یا مختصر نام (پیر، منگل، وغیرہ)، آپ ٹیکسٹ فنکشن استعمال کر سکتے ہیں جیسا کہ اس مثال میں بیان کیا گیا ہے: ایکسل میں تاریخ سے ہفتہ کا دن حاصل کریں۔

اگر آپ چاہتے ہیں ہفتے کا ایک دن یا مہینے کا نام حسب ضرورت فارمیٹ میں واپس کریں، CHOOSE فنکشن کو درج ذیل طریقے سے استعمال کریں۔

ہفتے کا ایک دن حاصل کرنے کے لیے:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

ایک حاصل کرنے کے لئےمہینہ:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

جہاں A2 سیل ہے جس میں اصل تاریخ ہے۔

مجھے امید ہے کہ اس ٹیوٹوریل سے آپ کو کچھ آئیڈیاز ملے ہوں گے آپ اپنے ڈیٹا ماڈلز کو بڑھانے کے لیے Excel میں CHOOSE فنکشن کا استعمال کیسے کر سکتے ہیں۔ میں پڑھنے کے لیے آپ کا شکریہ ادا کرتا ہوں اور امید کرتا ہوں کہ آپ کو اگلے ہفتے ہمارے بلاگ پر ملوں گا!

پریکٹس ورک بک ڈاؤن لوڈ کریں

Excel CHOOSE فنکشن کی مثالیں