Tutorial menerangkan sintaks dan kegunaan asas fungsi CHOOSE dan menyediakan beberapa contoh bukan remeh yang menunjukkan cara menggunakan formula CHOOSE dalam Excel.

CHOOSE ialah salah satu daripadanya Fungsi Excel yang mungkin tidak kelihatan berguna dengan sendirinya, tetapi digabungkan dengan fungsi lain memberikan beberapa faedah yang hebat. Pada peringkat paling asas, anda menggunakan fungsi CHOOSE untuk mendapatkan nilai daripada senarai dengan menentukan kedudukan nilai tersebut. Selanjutnya dalam tutorial ini, anda akan menemui beberapa kegunaan lanjutan yang pastinya berbaloi untuk diterokai.

Fungsi Excel CHOOSE - sintaks dan kegunaan asas

Fungsi CHOOSE dalam Excel ialah direka untuk mengembalikan nilai daripada senarai berdasarkan kedudukan yang ditentukan.

Fungsi ini tersedia dalam Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 dan Excel 2007.

Sintaks fungsi CHOOSE adalah seperti berikut:

Di mana:

Nombor_Indeks (diperlukan) - kedudukan nilai untuk dikembalikan. Ia boleh menjadi sebarang nombor antara 1 dan 254, rujukan sel atau formula lain.

Nilai1, nilai2, … - senarai sehingga 254 nilai untuk dipilih. Nilai1 diperlukan, nilai lain adalah pilihan. Ini boleh berupa nombor, nilai teks, rujukan sel, formula atau nama yang ditentukan.

Berikut ialah contoh formula CHOOSE dalam bentuk paling ringkas:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

Formula mengembalikan "Amy" kerana index_num ialah 3 dan "Amy" ialah nilai ke-3 dalam senarai:

Fungsi Excel CHOOSE - 3 perkara yang perlu diingat!

CHOOSE ialah fungsi yang sangat jelas dan anda tidak akan menghadapi sebarang kesukaran untuk melaksanakannya dalam lembaran kerja anda. Jika hasil yang dikembalikan oleh formula CHOOSE anda tidak dijangka atau bukan hasil yang anda cari, ini mungkin disebabkan oleh sebab berikut:

1. Bilangan nilai untuk dipilih adalah terhad kepada 254.
2. Jika nombor_indeks kurang daripada 1 atau lebih besar daripada bilangan nilai dalam senarai, nilai #VALUE! ralat dikembalikan.
3. Jika argumen index_num ialah pecahan, ia dipotong kepada integer terendah.

Cara menggunakan fungsi CHOOSE dalam Excel - formula contoh

Contoh berikut menunjukkan cara CHOOSE boleh memanjangkan keupayaan fungsi Excel yang lain dan menyediakan penyelesaian alternatif kepada beberapa tugas biasa, malah kepada tugas yang dianggap tidak boleh dilaksanakan oleh ramai.

Excel CHOOSE dan bukannya nested IFs

Salah satu tugas yang paling kerap dalam Excel ialah mengembalikan nilai yang berbeza berdasarkan syarat yang ditentukan. Dalam kebanyakan kes, ini boleh dilakukan dengan menggunakan pernyataan IF bersarang klasik. Tetapi fungsi CHOOSE boleh menjadi alternatif yang cepat dan mudah difahami.

Contoh 1. Kembalikan nilai yang berbeza berdasarkan syarat

Andaikan anda mempunyai lajur markah pelajar dan anda ingin melabelkan markah berdasarkansyarat berikut:

Salah satu cara untuk melakukannya ialah dengan meletakkan beberapa formula IF di dalam satu sama lain:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

Cara lain ialah memilih label yang sepadan dengan syarat:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

Cara formula ini berfungsi:

Dalam argumen index_num , anda menilai setiap syarat dan mengembalikan TRUE jika syarat dipenuhi, FALSE sebaliknya. Sebagai contoh, nilai dalam sel B2 memenuhi tiga syarat pertama, jadi kami mendapat hasil perantaraan ini:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

Memandangkan dalam kebanyakan formula Excel TRUE bersamaan dengan 1 dan FALSE kepada 0, kami formula mengalami transformasi ini:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

Selepas operasi penambahan dilakukan, kita mempunyai:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

Hasilnya, nilai ke-3 dalam senarai dikembalikan, iaitu "Baik".

Petua:

• Untuk menjadikan formula lebih fleksibel, anda boleh menggunakan rujukan sel dan bukannya label berkod keras, contohnya:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

• Jika tiada syarat anda adalah BENAR, argumen index_num akan ditetapkan kepada 0 memaksa formula anda mengembalikan #VALUE! kesilapan. Untuk mengelakkan ini, hanya bungkus CHOOSE dalam fungsi IFERROR seperti ini:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

Contoh 2. Lakukan pengiraan berbeza berdasarkan keadaan

Dengan cara yang sama, awakboleh menggunakan fungsi Excel CHOOSE untuk melakukan satu pengiraan dalam satu siri pengiraan/formula yang mungkin tanpa meletakkan berbilang penyata IF di dalam satu sama lain.

Sebagai contoh, mari kita mengira komisen setiap penjual bergantung pada jualan mereka:

Dengan jumlah jualan dalam B2, formula mengambil bentuk berikut:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

Daripada mengekod keras peratusan dalam formula, anda boleh merujuk kepada sel yang sepadan dalam jadual rujukan anda, jika ada. Ingatlah untuk membetulkan rujukan menggunakan tanda $.

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

Formula PILIH Excel untuk menjana data rawak

Seperti yang anda ketahui, Microsoft Excel mempunyai fungsi khas untuk menjana integer rawak antara nombor bawah dan atas yang anda tentukan - fungsi RANDBETWEEN. Sarangkannya dalam argumen index_num CHOOSE dan formula anda akan menjana hampir semua data rawak yang anda inginkan.

Sebagai contoh, formula ini boleh menghasilkan senarai keputusan peperiksaan rawak:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

Logik formula adalah jelas: RANDBETWEEN menjana nombor rawak dari 1 hingga 4 dan CHOOSE mengembalikan nilai yang sepadan daripada senarai empat nilai yang dipratakrifkan.

Nota. RANDBETWEEN ialah fungsi yang tidak menentu dan ia dikira semula dengan setiapubah yang anda buat pada lembaran kerja. Akibatnya, senarai nilai rawak anda juga akan berubah. Untuk mengelakkan perkara ini berlaku, anda boleh menggantikan formula dengan nilainya dengan menggunakan ciri Tampal Khas .

PILIH formula untuk melakukan Vlookup kiri

Jika anda pernah melakukan carian menegak dalam Excel, anda tahu bahawa fungsi VLOOKUP hanya boleh mencari dalam lajur paling kiri. Dalam situasi apabila anda perlu mengembalikan nilai di sebelah kiri lajur carian, anda boleh sama ada menggunakan kombinasi INDEX / MATCH atau menipu VLOOKUP dengan menyarangkan fungsi CHOOSE ke dalamnya. Begini caranya:

Andaikan anda mempunyai senarai markah dalam lajur A, nama pelajar dalam lajur B dan anda ingin mendapatkan semula markah pelajar tertentu. Memandangkan lajur pulangan berada di sebelah kiri lajur carian, formula Vlookup biasa mengembalikan ralat #N/A:

Untuk membetulkannya, dapatkan fungsi CHOOSE untuk menukar kedudukan lajur, memberitahu Excel bahawa lajur 1 ialah B dan lajur 2 ialah A:

=CHOOSE({1,2}, B2:B5, A2:A5)

Kerana kami membekalkan tatasusunan {1,2} dalam nombor_indeks argumen, fungsi CHOOSE menerima julat dalam argumen nilai (biasanya, ia tidak).

Sekarang, benamkan formula di atas ke dalam argumen table_array bagi VLOOKUP:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

Dan voilà - carian ke kiri dilakukan tanpa sebarang halangan!

PILIH formula untuk kembali berfungsi seterusnya hari

Jika anda tidak pasti sama adaanda harus pergi bekerja esok atau boleh tinggal di rumah dan menikmati hujung minggu anda yang sepatutnya, fungsi Excel CHOOSE boleh mengetahui bila hari kerja berikutnya.

Dengan mengandaikan hari bekerja anda adalah Isnin hingga Jumaat, formulanya adalah seperti berikut:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Sukar pada pandangan pertama, apabila dilihat lebih dekat logik formula mudah diikuti:

HARI MINGGU (TODAY()) mengembalikan nombor siri yang sepadan dengan tarikh hari ini, antara 1 (Ahad) hingga 7 (Sabtu). Nombor ini pergi ke argumen index_num formula CHOOSE kami.

Nilai1 - nilai7 (1,1,1,1,1, 3,2) tentukan berapa hari untuk ditambah pada tarikh semasa. Jika hari ini Ahad - Khamis (index_num 1 - 5), anda tambah 1 untuk kembali pada hari berikutnya. Jika hari ini hari Jumaat (index_num 6), anda menambah 3 untuk kembali pada Isnin depan. Jika hari ini hari Sabtu (indeks_nombor 7), anda menambah 2 untuk kembali Isnin depan sekali lagi. Ya, semudah itu :)

PILIH formula untuk mengembalikan nama hari/bulan tersuai dari tarikh

Dalam situasi apabila anda ingin mendapatkan nama hari dalam format standard seperti nama penuh ( Isnin, Selasa, dsb.) atau nama pendek (Isnin, Sel, dsb.), anda boleh menggunakan fungsi TEKS seperti yang dijelaskan dalam contoh ini: Dapatkan hari dalam minggu dari tarikh dalam Excel.

Jika anda ingin kembalikan nama hari dalam minggu atau bulan dalam format tersuai, gunakan fungsi CHOOSE dengan cara berikut.

Untuk mendapatkan hari dalam seminggu:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

Untuk mendapatkan abulan:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Di mana A2 ialah sel yang mengandungi tarikh asal.

Saya harap tutorial ini telah memberi anda beberapa idea tentang bagaimana anda boleh menggunakan fungsi CHOOSE dalam Excel untuk meningkatkan model data anda. Saya berterima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan!

Muat turun buku kerja latihan

Excel CHOOSE contoh fungsi