টিউটোরিয়ালটি CHOOSE ফাংশনের সিনট্যাক্স এবং মৌলিক ব্যবহারগুলি ব্যাখ্যা করে এবং এক্সেলে কীভাবে একটি CHOOSE সূত্র ব্যবহার করতে হয় তা দেখানো কয়েকটি অ-তুচ্ছ উদাহরণ প্রদান করে।

CHOOSE হল এর মধ্যে একটি এক্সেল ফাংশনগুলি যেগুলি তাদের নিজের থেকে কার্যকর নাও লাগতে পারে, কিন্তু অন্যান্য ফাংশনগুলির সাথে মিলিত অনেকগুলি দুর্দান্ত সুবিধা দেয়৷ সবচেয়ে মৌলিক স্তরে, আপনি সেই মানের অবস্থান নির্দিষ্ট করে একটি তালিকা থেকে একটি মান পেতে CHOOSE ফাংশন ব্যবহার করেন। এই টিউটোরিয়ালে আরও, আপনি বেশ কিছু উন্নত ব্যবহার পাবেন যা অবশ্যই অন্বেষণের যোগ্য৷

Excel CHOOSE ফাংশন - সিনট্যাক্স এবং মৌলিক ব্যবহারগুলি

এক্সেলের CHOOSE ফাংশন হল একটি নির্দিষ্ট অবস্থানের উপর ভিত্তি করে তালিকা থেকে একটি মান ফেরত দেওয়ার জন্য ডিজাইন করা হয়েছে।

ফাংশনটি Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, এবং Excel 2007-এ উপলব্ধ৷

CHOOSE ফাংশনের সিনট্যাক্স নিম্নরূপ:

কোথায়:

Index_num (প্রয়োজনীয়) - ফেরত দেওয়ার জন্য মানের অবস্থান। এটি 1 এবং 254 এর মধ্যে যেকোন সংখ্যা হতে পারে, একটি সেল রেফারেন্স, বা অন্য সূত্র।

মান1, মান2, … - 254টি পর্যন্ত মানের একটি তালিকা যা থেকে বেছে নিতে হবে। মান1 প্রয়োজন, অন্যান্য মান ঐচ্ছিক। এগুলি সংখ্যা, পাঠ্য মান, ঘরের রেফারেন্স, সূত্র বা সংজ্ঞায়িত নাম হতে পারে৷

এখানে সবচেয়ে সহজ ফর্মে একটি বেছে নিন সূত্রের একটি উদাহরণ:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

সূত্র "অ্যামি" ফেরত দেয় কারণ index_num হল 3 এবং "Amy" হল তালিকার 3য় মান:

Excel CHOOSE ফাংশন - 3টি জিনিস মনে রাখতে হবে!

CHOOSE একটি খুব সাধারণ ফাংশন এবং আপনি এটিকে আপনার ওয়ার্কশীটে প্রয়োগ করতে খুব কমই কোনো অসুবিধার সম্মুখীন হবেন। যদি আপনার চয়ন সূত্র দ্বারা প্রত্যাবর্তিত ফলাফলটি অপ্রত্যাশিত হয় বা আপনি যে ফলাফলটি খুঁজছিলেন তা না হয় তবে এটি নিম্নলিখিত কারণে হতে পারে:

1. বাছাই করার জন্য মানগুলির সংখ্যা 254 তে সীমাবদ্ধ৷
2. যদি index_num তালিকার মানের সংখ্যা থেকে 1 এর কম বা বেশি হয়, তাহলে #VALUE! ত্রুটি ফেরত দেওয়া হয়।
3. যদি index_num আর্গুমেন্টটি একটি ভগ্নাংশ হয়, তাহলে এটিকে সর্বনিম্ন পূর্ণসংখ্যাতে ছেঁটে ফেলা হয়।

এক্সেল-এ কীভাবে চয়ন ফাংশন ব্যবহার করবেন - সূত্র উদাহরণ

নিম্নলিখিত উদাহরণগুলি দেখায় যে কীভাবে CHOOSE অন্যান্য এক্সেল ফাংশনগুলির ক্ষমতাকে প্রসারিত করতে পারে এবং কিছু সাধারণ কাজগুলির বিকল্প সমাধান প্রদান করতে পারে, এমনকি যেগুলিকে অনেকেই অসম্ভাব্য বলে মনে করেন৷

এর পরিবর্তে এক্সেল চয়ন করুন৷ নেস্টেড IFs

এক্সেলের সবচেয়ে ঘন ঘন কাজগুলির মধ্যে একটি হল একটি নির্দিষ্ট শর্তের উপর ভিত্তি করে বিভিন্ন মান প্রদান করা। বেশিরভাগ ক্ষেত্রে, এটি একটি ক্লাসিক নেস্টেড IF স্টেটমেন্ট ব্যবহার করে করা যেতে পারে। কিন্তু CHOOSE ফাংশন একটি দ্রুত এবং সহজে বোঝার বিকল্প হতে পারে।

উদাহরণ 1. শর্তের উপর ভিত্তি করে বিভিন্ন মান ফেরত দিন

ধরুন আপনার কাছে ছাত্র স্কোরের একটি কলাম আছে এবং আপনি লেবেল দিতে চান। উপর ভিত্তি করে স্কোরনিম্নলিখিত শর্তাবলী:

এটি করার একটি উপায় হল কয়েকটি IF সূত্র একে অপরের ভিতরে নেস্ট করা:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

অন্য উপায় হল শর্তের সাথে সঙ্গতিপূর্ণ একটি লেবেল বেছে নেওয়া:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

27>

এই সূত্রটি কীভাবে কাজ করে:

index_num আর্গুমেন্টে, আপনি প্রতিটি শর্তের মূল্যায়ন করেন এবং শর্ত পূরণ হলে TRUE ফেরত দেন, অন্যথায় FALSE। উদাহরণস্বরূপ, সেল B2-এর মানটি প্রথম তিনটি শর্ত পূরণ করে, তাই আমরা এই মধ্যবর্তী ফলাফলটি পাই:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

প্রদত্ত যে বেশিরভাগ এক্সেল সূত্রে TRUE 1 এবং FALSE-এর সাথে 0 এর সমান, আমাদের সূত্রটি এই রূপান্তরের মধ্য দিয়ে যায়:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

সংযোজন অপারেশন সঞ্চালিত হওয়ার পরে, আমাদের আছে:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

ফলে, 3য় মান তালিকাটি ফেরত দেওয়া হয়, যা "ভাল"৷

টিপস:

• সূত্রটিকে আরও নমনীয় করতে, আপনি হার্ডকোডযুক্ত লেবেলের পরিবর্তে সেল রেফারেন্স ব্যবহার করতে পারেন, উদাহরণস্বরূপ:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

• যদি আপনার কোনো শর্তই সত্য না হয়, তাহলে index_num আর্গুমেন্টটি 0 এ সেট করা হবে যাতে আপনার সূত্রটি #VALUE ফেরত দিতে বাধ্য হয়! ত্রুটি. এটি এড়াতে, IFERROR ফাংশনে বেছে নিন এইভাবে মোড়ানো:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

উদাহরণ 2. শর্তের উপর ভিত্তি করে বিভিন্ন গণনা সম্পাদন করুন

একইভাবে, আপনিএকাধিক IF স্টেটমেন্ট একে অপরের ভিতরে না রেখে সম্ভাব্য গণনা/সূত্রের একটি সিরিজে একটি গণনা সম্পাদন করতে Excel CHOOSE ফাংশন ব্যবহার করতে পারে।

উদাহরণস্বরূপ, আসুন প্রতিটি বিক্রেতার তাদের বিক্রয়ের উপর নির্ভর করে কমিশন গণনা করা যাক:

B2-এ বিক্রয়ের পরিমাণের সাথে, সূত্রটি নিম্নলিখিত আকার নেয়:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

সূত্রে শতাংশ হার্ডকোড করার পরিবর্তে, আপনি আপনার রেফারেন্স টেবিলের সংশ্লিষ্ট কক্ষটি উল্লেখ করতে পারেন, যদি থাকে। শুধু $ চিহ্ন ব্যবহার করে রেফারেন্সগুলি ঠিক করতে মনে রাখবেন।

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

এলোমেলো ডেটা তৈরি করতে এক্সেল চয়ন করুন সূত্র

আপনি সম্ভবত জানেন, মাইক্রোসফ্ট এক্সেল তৈরি করার জন্য একটি বিশেষ ফাংশন রয়েছে নীচের এবং উপরের সংখ্যাগুলির মধ্যে র্যান্ডম পূর্ণসংখ্যা যা আপনি নির্দিষ্ট করেছেন - RANDBETWEEN ফাংশন৷ CHOOSE এর index_num আর্গুমেন্টে এটিকে নেস্ট করুন এবং আপনার সূত্রটি আপনার পছন্দের প্রায় যেকোনো র্যান্ডম ডেটা তৈরি করবে।

উদাহরণস্বরূপ, এই সূত্রটি এলোমেলো পরীক্ষার ফলাফলের একটি তালিকা তৈরি করতে পারে:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

সূত্রের যুক্তিটি সুস্পষ্ট: RANDBETWEEN 1 থেকে 4 পর্যন্ত র্যান্ডম সংখ্যা তৈরি করে এবং CHOOSE চারটি মানের পূর্বনির্ধারিত তালিকা থেকে একটি সংশ্লিষ্ট মান প্রদান করে।

নোট। RANDBETWEEN হল একটি উদ্বায়ী ফাংশন এবং এটি প্রতিটির সাথে পুনরায় গণনা করেআপনি ওয়ার্কশীটে পরিবর্তন করুন। ফলস্বরূপ, আপনার এলোমেলো মানগুলির তালিকাও পরিবর্তিত হবে। এটি যাতে না ঘটে তার জন্য, আপনি পেস্ট স্পেশাল বৈশিষ্ট্যটি ব্যবহার করে সূত্রগুলিকে তাদের মানগুলির সাথে প্রতিস্থাপন করতে পারেন৷

একটি বাম Vlookup করতে সূত্র বেছে নিন

যদি আপনি কখনও পারফর্ম করে থাকেন Excel এ একটি উল্লম্ব লুকআপ, আপনি জানেন যে VLOOKUP ফাংশন শুধুমাত্র বাম-সবচেয়ে কলামে অনুসন্ধান করতে পারে। এমন পরিস্থিতিতে যখন আপনাকে লুকআপ কলামের বাম দিকে একটি মান ফেরত দিতে হবে, আপনি হয় INDEX/MATCH সংমিশ্রণটি ব্যবহার করতে পারেন বা এতে CHOOSE ফাংশনটি নেস্ট করে VLOOKUP কৌশল করতে পারেন৷ এখানে কিভাবে:

ধরুন আপনার কলাম A-তে স্কোরের একটি তালিকা আছে, কলাম B-এ ছাত্রদের নাম, এবং আপনি একটি নির্দিষ্ট ছাত্রের স্কোর পুনরুদ্ধার করতে চান। যেহেতু রিটার্ন কলামটি লুকআপ কলামের বাম দিকে থাকে, তাই একটি নিয়মিত Vlookup সূত্র #N/A ত্রুটি প্রদান করে:

এটি ঠিক করতে, অদলবদল করার জন্য CHOOSE ফাংশনটি পান কলামের অবস্থান, এক্সেলকে বলে যে কলাম 1 হল B এবং কলাম 2 হল A:

=CHOOSE({1,2}, B2:B5, A2:A5)

কারণ আমরা index_num<2 এ {1,2} এর একটি অ্যারে সরবরাহ করি> আর্গুমেন্ট, CHOOSE ফাংশন মান আর্গুমেন্টের রেঞ্জ গ্রহণ করে (সাধারণত, এটি হয় না)।

এখন, উপরের সূত্রটিকে টেবিল_অ্যারে আর্গুমেন্টে এম্বেড করুন VLOOKUP:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

এবং voilà - বাম দিকে একটি লুকআপ কোন বাধা ছাড়াই সঞ্চালিত হয়!

পরবর্তী কাজ করার জন্য ফর্মুলা বেছে নিন দিন

যদি আপনি নিশ্চিত না হন যে কিনাআপনার আগামীকাল কর্মস্থলে যেতে হবে বা বাড়িতে থাকতে হবে এবং আপনার প্রাপ্য সপ্তাহান্ত উপভোগ করতে পারেন, Excel CHOOSE ফাংশনটি পরবর্তী কাজের দিন কখন তা খুঁজে বের করতে পারে।

আপনার কর্মদিবস সোমবার থেকে শুক্রবার, সূত্র এইভাবে যায়:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

প্রথম দর্শনে চতুর, ঘনিষ্ঠভাবে দেখার পর সূত্রটির যুক্তি অনুসরণ করা সহজ:

সাপ্তাহিক (TODAY()) 1 (রবিবার) থেকে 7 (শনিবার) পর্যন্ত আজকের তারিখের সাথে সম্পর্কিত একটি ক্রমিক নম্বর প্রদান করে। এই সংখ্যাটি আমাদের বেছে নেওয়া সূত্রের index_num আর্গুমেন্টে যায়।

Value1 - value7 (1,1,1,1,1, 3,2) বর্তমান তারিখে কত দিন যোগ করতে হবে তা নির্ধারণ করুন। যদি আজ রবিবার হয় - বৃহস্পতিবার (সূচক_সংখ্যা 1 - 5), আপনি পরের দিন ফেরত দিতে 1 যোগ করুন। যদি আজ শুক্রবার হয় (সূচক_সংখ্যা 6), আপনি পরের সোমবার ফিরতে 3 যোগ করুন। যদি আজ শনিবার হয় (সূচক_সংখ্যা 7), আপনি পরের সোমবার আবার ফিরে আসতে 2 যোগ করুন। হ্যাঁ, এটা খুবই সহজ :)

তারিখ থেকে একটি কাস্টম দিন/মাসের নাম ফেরত দিতে সূত্র বেছে নিন

পরিস্থিতিতে যখন আপনি একটি দিনের নাম পেতে চান স্ট্যান্ডার্ড ফরম্যাটে যেমন পুরো নাম ( সোমবার, মঙ্গলবার, ইত্যাদি) বা সংক্ষিপ্ত নাম (সোম, মঙ্গল, ইত্যাদি), আপনি এই উদাহরণে ব্যাখ্যা করা TEXT ফাংশনটি ব্যবহার করতে পারেন: এক্সেলে তারিখ থেকে সপ্তাহের দিন পান৷

যদি আপনি চান সপ্তাহের একটি দিন বা একটি মাসের নাম একটি কাস্টম ফর্ম্যাটে ফেরত দিন, নিম্নলিখিত উপায়ে CHOOSE ফাংশনটি ব্যবহার করুন৷

সপ্তাহের একটি দিন পেতে:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

একটি পেতেমাস:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

যেখানে A2 হল আসল তারিখ সম্বলিত ঘর৷

আমি আশা করি এই টিউটোরিয়ালটি আপনাকে কিছু ধারণা দিয়েছে কিভাবে আপনি আপনার ডেটা মডেল উন্নত করতে Excel এ CHOOSE ফাংশন ব্যবহার করতে পারেন। আমি পড়ার জন্য আপনাকে ধন্যবাদ এবং আশা করি আগামী সপ্তাহে আমাদের ব্লগে আপনাকে দেখতে পাব!

অভ্যাস ওয়ার্কবুক ডাউনলোড করুন

এক্সেল ফাংশনের উদাহরণগুলি চয়ন করুন