Oʻquv qoʻllanma CHOOSE funksiyasining sintaksisi va asosiy qoʻllanilishini tushuntiradi va Excelda CHOOSE formulasidan qanday foydalanishni koʻrsatuvchi bir necha ahamiyatsiz misollarni taqdim etadi.

CANLASH shulardan biri. O'z-o'zidan foydali ko'rinmasligi mumkin bo'lgan Excel funktsiyalari, ammo boshqa funktsiyalar bilan birgalikda bir qator ajoyib afzalliklarni beradi. Eng asosiy darajada, siz ushbu qiymatning o'rnini belgilash orqali ro'yxatdan qiymat olish uchun CHOOSE funksiyasidan foydalanasiz. Ushbu qoʻllanmada siz albatta oʻrganishga arziydigan bir qancha ilgʻor foydalanish usullarini topasiz.

Excel CHOOSE funksiyasi - sintaksis va asosiy foydalanish

Excel-dagi CHOOSE funksiyasi belgilangan pozitsiyaga asoslangan ro'yxatdan qiymatni qaytarish uchun mo'ljallangan.

Funksiya Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 va Excel 2007 da mavjud.

CHOSE funksiyasining sintaksisi quyidagicha:

Bu erda:

Indeks_num (zarur) - qaytariladigan qiymatning pozitsiyasi. Bu 1 dan 254 gacha bo'lgan istalgan raqam, katakcha havolasi yoki boshqa formula bo'lishi mumkin.

Qiymat1, qiymat2, … - tanlash uchun 254 tagacha qiymatlar ro'yxati. Qiymat 1 talab qilinadi, boshqa qiymatlar ixtiyoriy. Bu raqamlar, matn qiymatlari, hujayra havolalari, formulalar yoki belgilangan nomlar bo'lishi mumkin.

Mana, eng oddiy shakldagi CHOSSE formulasiga misol:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

Formula "Emi" ni qaytaradi, chunki indeks_num 3 va "Emi" ro'yxatdagi 3-qiymat:

Excel CHOOSE funksiyasi - 3 ta narsani eslab qolish kerak!

CANLASH - bu juda oddiy funktsiya va uni ish varaqlaringizda amalga oshirishda qiyinchilikka duch kelmaysiz. Agar CHOOSE formulasi tomonidan qaytarilgan natija kutilmagan boʻlsa yoki siz qidirayotgan natija boʻlmasa, bu quyidagi sabablarga koʻra boʻlishi mumkin:

1. Tanlash uchun qiymatlar soni 254 ta bilan cheklangan.
2. Agar indeks_raqami roʻyxatdagi qiymatlar sonidan 1 dan kichik yoki kattaroq boʻlsa, #VALUE! xato qaytarildi.
3. Agar index_num argumenti kasr bo'lsa, u eng kichik butun songa qisqartiriladi.

Excelda CHOOSE funksiyasidan qanday foydalanish - formula misollar

Quyidagi misollar CHOOSE qanday qilib boshqa Excel funksiyalarining imkoniyatlarini kengaytirishi va ba'zi umumiy vazifalarga, hattoki ko'pchilik tomonidan bajarib bo'lmaydigan deb hisoblanganlarga ham muqobil yechimlar berishi mumkinligini ko'rsatadi.

Excel o'rniga CHOOSE o'rnatilgan IFs

Excelda eng tez-tez bajariladigan vazifalardan biri belgilangan shart asosida turli qiymatlarni qaytarishdir. Aksariyat hollarda buni klassik ichki o'rnatilgan IF iborasi yordamida amalga oshirish mumkin. Lekin CHOOSE funksiyasi tez va tushunarli muqobil bo‘lishi mumkin.

1-misol. Shartga qarab turli qiymatlarni qaytaring

Aytaylik, sizda talaba ballari ustuni bor va siz uni belgilashni xohlaysiz. ga asoslangan ballarquyidagi shartlar:

Buni qilishning bir usuli bir nechta IF formulalarini bir-birining ichiga joylashtirish:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

Yana bir usul - shartga mos keladigan yorliqni tanlash:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

Ushbu formula qanday ishlaydi:

indeks_num argumentida siz har bir shartni baholaysiz va agar shart bajarilsa TRUE, aks holda FALSE qiymatini qaytarasiz. Masalan, B2 katakchadagi qiymat dastlabki uchta shartga javob beradi, shuning uchun biz ushbu oraliq natijani olamiz:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

Excel formulalarining aksariyatida TRUE 1 ga va FALSE 0 ga teng ekanligini hisobga olsak, bizning formula shu transformatsiyadan o'tadi:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

Qo'shish amali bajarilgandan so'ng bizda:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

Natijada 3-qiymat roʻyxat qaytariladi, bu “Yaxshi”.

Maslahatlar:

• Formulani yanada moslashuvchan qilish uchun qattiq kodlangan teglar oʻrniga hujayra havolalaridan foydalanishingiz mumkin, masalan:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

• Agar shartlaringizdan hech biri TO'G'ri bo'lmasa, indeks_num argumenti 0 ga o'rnatiladi va formulangizni #VALUE qiymatini qaytarishga majbur qiladi! xato. Bunga yo'l qo'ymaslik uchun IFERROR funksiyasiga CHOOSE ni shunday o'rang:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

Misol 2. Shartga qarab turli hisoblarni bajaring

Shunga o'xshash tarzda, sizbir nechta IF ko'rsatmalarini bir-birining ichiga joylashtirmasdan, bir qator mumkin bo'lgan hisob-kitoblar/formulalarda bitta hisobni bajarish uchun Excel CHOOSE funksiyasidan foydalanishi mumkin.

Misol sifatida, har bir sotuvchining sotuv hajmiga qarab komissiyasini hisoblaylik:

B2 dagi savdo summasi bilan formula quyidagi shaklni oladi:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

Formuladagi foizlarni qattiq kodlash o'rniga, agar mavjud bo'lsa, mos yozuvlar jadvalidagi tegishli katakka murojaat qilishingiz mumkin. Faqat $ belgisi yordamida havolalarni tuzatishni unutmang.

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

Excel Tasodifiy ma'lumotlarni yaratish uchun formulani TANLASH

Sizga ma'lumki, Microsoft Excelda yaratish uchun maxsus funksiya mavjud. Siz belgilagan pastki va yuqori raqamlar orasidagi tasodifiy butun sonlar - RANDBETWEEN funksiyasi. Uni CHOOSE ning indeks_num argumentiga joylashtiring va formulangiz siz xohlagan deyarli har qanday tasodifiy maʼlumotlarni yaratadi.

Masalan, bu formula tasodifiy imtihon natijalari roʻyxatini yaratishi mumkin:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

Formula mantig'i aniq: RANDBETWEEN 1 dan 4 gacha tasodifiy sonlarni hosil qiladi va CHOOSE oldindan belgilangan to'rtta qiymat ro'yxatidan mos keladigan qiymatni qaytaradi.

Eslatma. RANDBETWEEN o'zgaruvchan funksiya bo'lib, u har birida qayta hisoblab chiqadiish varag'iga o'zgartirish kiriting. Natijada, tasodifiy qiymatlar ro'yxati ham o'zgaradi. Buning oldini olish uchun Maxsus joylashtirish funksiyasidan foydalanib, formulalarni qiymatlari bilan almashtirishingiz mumkin.

Chapdagi Vlookup uchun formulani TANLASH

Agar biror marta bajargan boʻlsangiz Excelda vertikal qidiruv, VLOOKUP funksiyasi faqat eng chap ustunda qidirishi mumkinligini bilasiz. Qidiruv ustunining chap tomonidagi qiymatni qaytarishingiz kerak bo'lgan holatlarda siz INDEX / MATCH kombinatsiyasidan foydalanishingiz yoki unga CHOOSE funksiyasini joylashtirish orqali VLOOKUPni aldashingiz mumkin. Mana shunday:

Ayda sizda A ustunida ballar ro'yxati, B ustunida talabalar ismlari bor va siz ma'lum bir talabaning ballini olishni xohlaysiz. Qaytish ustuni qidirish ustunining chap tomonida joylashganligi sababli, oddiy Vlookup formulasi #N/A xatosini qaytaradi:

Buni tuzatish uchun CHOOSE funksiyasini almashtiring. ustunlar joylashuvi, Excelga 1-ustun B va 2-ustun A ekanligini bildiradi:

=CHOOSE({1,2}, B2:B5, A2:A5)

Chunki biz indeks_raqami<2 da {1,2} massivini taqdim etamiz> argumentda CHOOSE funksiyasi qiymat argumentlaridagi diapazonlarni qabul qiladi (odatda bunday emas).

Endi yuqoridagi formulani jadval_massivi argumentiga kiriting. VLOOKUP:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

Va voilà - chapdan qidirish muammosiz amalga oshiriladi!

Keyingi ishni qaytarish uchun formulani tanlang. kun

Agar ishonchingiz komil bo'lmasaertaga ishga borishingiz kerak yoki uyda qolib, munosib dam olish kunlaridan zavqlanishingiz mumkin, Excel CHOOSE funksiyasi keyingi ish kuni qachon ekanligini bilib oladi.

Ish kuningiz dushanbadan jumagacha bo'lganini faraz qilsangiz, formula quyidagicha bo'ladi:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Bir qarashda qiyin, yaqinroq qarasak formula mantig'iga amal qilish oson:

WEEKDAY (TODAY()) 1 (yakshanba) dan 7 (shanba) gacha boʻlgan bugungi sanaga mos keladigan seriya raqamini qaytaradi. Bu raqam TANLASH formulamizning indeks_num argumentiga tushadi.

Qiymat1 - qiymat7 (1,1,1,1,1, 3,2) joriy sanaga necha kun qo'shish kerakligini aniqlang. Agar bugun yakshanba - payshanba (index_num 1 - 5) bo'lsa, keyingi kunga qaytish uchun 1 qo'shasiz. Agar bugun juma (index_num 6) bo'lsa, keyingi dushanbaga qaytish uchun 3 qo'shasiz. Agar bugun shanba (index_num 7) bo'lsa, keyingi dushanbaga qaytish uchun 2 qo'shasiz. Ha, bu juda oddiy :)

Sanadan boshlab kun/oy nomini qaytarish uchun formulani TANLASH

Standart formatda kun nomini olishni istagan holatlarda, masalan, toʻliq ism ( dushanba, seshanba va h.k.) yoki qisqa ism (dushanba, seshanba va h.k.), ushbu misolda tushuntirilganidek TEXT funksiyasidan foydalanishingiz mumkin: Excelda sanadan boshlab haftaning kunini oling.

Agar xohlasangiz haftaning bir kuni yoki oy nomini moslashtirilgan formatda qaytaring, CHOOSE funksiyasidan quyidagi tarzda foydalaning.

Hafta kunini olish uchun:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

Olish uchunoy:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Bu erda A2 asl sanani o'z ichiga olgan katakdir.

Umid qilamanki, bu qo'llanma sizga bir nechta fikrlarni berdi. ma'lumotlar modellaringizni yaxshilash uchun Excelda CHOOSE funksiyasidan qanday foydalanishingiz mumkin. O'qiganingiz uchun tashakkur va kelgusi hafta blogimizda ko'rishga umid qilaman!

Mashq qilish kitobini yuklab oling

Excel CHOOSE funksiyasi misollari