Hướng dẫn giải thích cú pháp và cách sử dụng cơ bản của hàm CHOOSE, đồng thời cung cấp một số ví dụ điển hình về cách sử dụng công thức CHOOSE trong Excel.

CHOOSE là một trong số đó Các hàm Excel tự nó có thể không hữu ích, nhưng khi kết hợp với các hàm khác sẽ mang lại một số lợi ích tuyệt vời. Ở cấp độ cơ bản nhất, bạn sử dụng hàm CHOOSE để lấy giá trị từ danh sách bằng cách chỉ định vị trí của giá trị đó. Tiếp theo trong hướng dẫn này, bạn sẽ tìm thấy một số cách sử dụng nâng cao chắc chắn đáng để khám phá.

Hàm CHOOSE trong Excel - cú pháp và cách sử dụng cơ bản

Hàm CHOOSE trong Excel là được thiết kế để trả về một giá trị từ danh sách dựa trên một vị trí đã chỉ định.

Hàm này khả dụng trong Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 và Excel 2007.

Cú pháp của hàm CHOOSE như sau:

Trong đó:

Index_num (bắt buộc) - vị trí của giá trị cần trả về. Nó có thể là bất kỳ số nào trong khoảng từ 1 đến 254, một tham chiếu ô hoặc một công thức khác.

Giá trị1, giá trị2, … - một danh sách gồm tối đa 254 giá trị để chọn. Giá trị 1 là bắt buộc, các giá trị khác là tùy chọn. Đây có thể là số, giá trị văn bản, tham chiếu ô, công thức hoặc tên đã xác định.

Dưới đây là ví dụ về công thức CHOOSE ở dạng đơn giản nhất:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

Công thức trả về "Amy" vì index_num là 3 và "Amy" là giá trị thứ 3 trong danh sách:

Hàm CHOOSE trong Excel - 3 điều cần nhớ!

CHOOSE là một hàm rất đơn giản và bạn sẽ hầu như không gặp bất kỳ khó khăn nào khi triển khai nó trong trang tính của mình. Nếu kết quả trả về bởi công thức CHOOSE của bạn không như mong đợi hoặc không phải là kết quả bạn đang tìm kiếm, thì có thể là do những lý do sau:

1. Số lượng giá trị để chọn bị giới hạn ở 254.
2. Nếu index_num nhỏ hơn 1 hoặc lớn hơn số lượng giá trị trong danh sách, lỗi #VALUE! lỗi được trả về.
3. Nếu đối số index_num là một phân số, nó sẽ bị cắt bớt thành số nguyên thấp nhất.

Cách sử dụng hàm CHOOSE trong Excel - công thức ví dụ

Các ví dụ sau đây cho thấy cách CHOOSE có thể mở rộng khả năng của các hàm Excel khác và cung cấp các giải pháp thay thế cho một số tác vụ phổ biến, ngay cả đối với những tác vụ được nhiều người coi là không khả thi.

Excel CHOOSE thay vì IF lồng nhau

Một trong những tác vụ thường xuyên nhất trong Excel là trả về các giá trị khác nhau dựa trên một điều kiện cụ thể. Trong hầu hết các trường hợp, điều này có thể được thực hiện bằng cách sử dụng câu lệnh IF lồng nhau cổ điển. Tuy nhiên, hàm CHOOSE có thể là một cách thay thế nhanh chóng và dễ hiểu.

Ví dụ 1. Trả về các giá trị khác nhau dựa trên điều kiện

Giả sử bạn có một cột điểm của học sinh và bạn muốn gắn nhãn điểm số dựa trênđiều kiện sau:

Một cách để thực hiện việc này là lồng một vài công thức IF bên trong nhau:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

Một cách khác là chọn nhãn tương ứng với điều kiện:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

Cách thức hoạt động của công thức này:

Trong đối số index_num , bạn đánh giá từng điều kiện và trả về TRUE nếu điều kiện được đáp ứng, FALSE nếu không đáp ứng. Ví dụ: giá trị trong ô B2 đáp ứng ba điều kiện đầu tiên, vì vậy chúng tôi nhận được kết quả trung gian sau:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

Vì trong hầu hết các công thức Excel, TRUE tương đương với 1 và FALSE tương đương với 0, công thức trải qua quá trình biến đổi này:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

Sau khi thực hiện phép cộng, chúng ta có:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

Kết quả là giá trị thứ 3 trong danh sách được trả về, đó là "Tốt".

Mẹo:

• Để làm cho công thức linh hoạt hơn, bạn có thể sử dụng tham chiếu ô thay vì nhãn được mã hóa cứng, ví dụ:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

• Nếu không có điều kiện nào của bạn là TRUE, thì đối số index_num sẽ được đặt thành 0 buộc công thức của bạn phải trả về lỗi #VALUE! lỗi. Để tránh điều này, chỉ cần bọc CHOOSE trong hàm IFERROR như sau:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

Ví dụ 2. Thực hiện các phép tính khác nhau dựa trên điều kiện

Theo cách tương tự, bạncó thể sử dụng hàm CHOOSE của Excel để thực hiện một phép tính trong một loạt các phép tính/công thức khả thi mà không cần lồng nhiều câu lệnh IF vào nhau.

Ví dụ: hãy tính hoa hồng của từng người bán tùy thuộc vào doanh số bán hàng của họ:

Với số tiền bán hàng ở B2, công thức có dạng như sau:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

Thay vì mã hóa cứng tỷ lệ phần trăm trong công thức, bạn có thể tham khảo ô tương ứng trong bảng tham chiếu của mình, nếu có. Chỉ cần nhớ sửa các tham chiếu bằng ký hiệu $.

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

CHỌN công thức Excel để tạo dữ liệu ngẫu nhiên

Có thể bạn đã biết, Microsoft Excel có một chức năng đặc biệt để tạo số nguyên ngẫu nhiên giữa số dưới cùng và số trên cùng mà bạn chỉ định - hàm RANDBETWEEN. Lồng nó vào đối số index_num của CHOOSE và công thức của bạn sẽ tạo hầu hết mọi dữ liệu ngẫu nhiên mà bạn muốn.

Ví dụ: công thức này có thể tạo danh sách kết quả bài kiểm tra ngẫu nhiên:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

Logic của công thức rất rõ ràng: RANDBETWEEN tạo các số ngẫu nhiên từ 1 đến 4 và CHOOSE trả về một giá trị tương ứng từ danh sách bốn giá trị được xác định trước.

Lưu ý. RANDBETWEEN là một hàm dễ bay hơi và nó tính toán lại với mỗithay đổi bạn thực hiện với trang tính. Do đó, danh sách các giá trị ngẫu nhiên của bạn cũng sẽ thay đổi. Để tránh điều này xảy ra, bạn có thể thay thế các công thức bằng các giá trị của chúng bằng cách sử dụng tính năng Dán Đặc biệt .

CHỌN công thức để thực hiện Vlookup bên trái

Nếu bạn đã từng thực hiện tra cứu theo chiều dọc trong Excel, bạn biết rằng hàm VLOOKUP chỉ có thể tìm kiếm ở cột ngoài cùng bên trái. Trong các tình huống khi bạn cần trả về một giá trị ở bên trái của cột tra cứu, bạn có thể sử dụng tổ hợp INDEX/MATCH hoặc thủ thuật VLOOKUP bằng cách lồng hàm CHOOSE vào đó. Đây là cách thực hiện:

Giả sử bạn có danh sách điểm ở cột A, tên học sinh ở cột B và bạn muốn truy xuất điểm của một học sinh cụ thể. Vì cột trả về nằm bên trái cột tra cứu nên công thức Vlookup thông thường sẽ trả về lỗi #N/A:

Để khắc phục điều này, hãy sử dụng hàm CHOOSE để hoán đổi vị trí của các cột, cho Excel biết rằng cột 1 là B và cột 2 là A:

=CHOOSE({1,2}, B2:B5, A2:A5)

Bởi vì chúng tôi cung cấp một mảng {1,2} trong index_num đối số, hàm CHOOSE chấp nhận phạm vi trong các đối số giá trị (thông thường, hàm này không chấp nhận).

Bây giờ, hãy nhúng công thức trên vào đối số table_array của VLOOKUP:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

Và thế là xong - tra cứu bên trái được thực hiện mà không gặp trở ngại nào!

CHỌN công thức để quay lại hoạt động tiếp theo day

Nếu bạn không chắc liệubạn nên đi làm vào ngày mai hoặc có thể ở nhà và tận hưởng ngày cuối tuần xứng đáng của mình, hàm CHOOSE của Excel có thể tìm hiểu ngày làm việc tiếp theo là khi nào.

Giả sử ngày làm việc của bạn là từ thứ Hai đến thứ Sáu, công thức như sau:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Thoạt nhìn thì khó hiểu, nhưng khi xem xét kỹ hơn thì logic của công thức rất dễ hiểu:

WEEKDAY (TODAY()) trả về một số sê-ri tương ứng với ngày hôm nay, nằm trong khoảng từ 1 (Chủ Nhật) đến 7 (Thứ Bảy). Con số này đi đến đối số index_num của công thức CHOOSE.

Value1 - value7 (1,1,1,1,1, 3,2) xác định số ngày cần thêm vào ngày hiện tại. Nếu hôm nay là Chủ Nhật - Thứ Năm (index_num 1 - 5) thì bạn thêm 1 để trả về ngày hôm sau. Nếu hôm nay là thứ Sáu (index_num 6), bạn thêm 3 để trả về vào thứ Hai tới. Nếu hôm nay là Thứ Bảy (index_num 7), bạn thêm 2 để quay trở lại vào Thứ Hai tuần sau. Đúng vậy, thật đơn giản :)

CHỌN công thức để trả về tên ngày/tháng tùy chỉnh từ ngày

Trong trường hợp bạn muốn lấy tên ngày ở định dạng chuẩn, chẳng hạn như tên đầy đủ ( Thứ Hai, Thứ Ba, v.v.) hoặc tên viết tắt (Thứ Hai, Thứ Ba, v.v.), bạn có thể sử dụng hàm TEXT như được giải thích trong ví dụ sau: Nhận ngày trong tuần từ ngày trong Excel.

Nếu bạn muốn trả lại ngày trong tuần hoặc tên tháng ở định dạng tùy chỉnh, hãy sử dụng hàm CHOOSE theo cách sau.

Để nhận ngày trong tuần:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

Để có được mộttháng:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Trong đó A2 là ô chứa ngày ban đầu.

Tôi hy vọng hướng dẫn này đã cung cấp cho bạn một số ý tưởng về cách bạn có thể sử dụng hàm CHOOSE trong Excel để nâng cao mô hình dữ liệu của mình. Tôi cảm ơn bạn đã đọc và hy vọng sẽ gặp bạn trên blog của chúng tôi vào tuần tới!

Tải xuống sách bài tập thực hành

Các ví dụ về hàm CHOOSE trong Excel