Die tutoriaal verduidelik die sintaksis en basiese gebruike van die KIES-funksie en verskaf 'n paar nie-onbeduidende voorbeelde wat wys hoe om 'n KIES-formule in Excel te gebruik.

KIES is een van daardie Excel-funksies wat dalk nie op hul eie bruikbaar lyk nie, maar gekombineer met ander funksies bied 'n aantal wonderlike voordele. Op die mees basiese vlak gebruik jy die KIES-funksie om 'n waarde uit 'n lys te kry deur die posisie van daardie waarde te spesifiseer. Verder in hierdie tutoriaal sal jy verskeie gevorderde gebruike vind wat beslis die moeite werd is om te verken.

Excel KIES-funksie - sintaksis en basiese gebruike

Die KIES-funksie in Excel is ontwerp om 'n waarde van die lys op grond van 'n gespesifiseerde posisie terug te gee.

Die funksie is beskikbaar in Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 en Excel 2007.

Die sintaksis van die KIES-funksie is soos volg:

Waar:

Indeks_getal (vereis) - die posisie van die waarde om terug te keer. Dit kan enige getal tussen 1 en 254, 'n selverwysing of 'n ander formule wees.

Waarde1, waarde2, … - 'n lys van tot 254 waardes om van te kies. Waarde1 word vereis, ander waardes is opsioneel. Dit kan getalle, tekswaardes, selverwysings, formules of gedefinieerde name wees.

Hier is 'n voorbeeld van 'n KIES-formule in die eenvoudigste vorm:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

Die formule gee "Amy" terug omdat indeks_getal is 3 en "Amy" is die 3de waarde in die lys:

Excel KIES-funksie - 3 dinge om te onthou!

KIES is 'n baie eenvoudige funksie en jy sal skaars probleme ondervind om dit in jou werkkaarte te implementeer. As die resultaat wat deur jou KIES-formule teruggegee word, onverwags is of nie die resultaat is waarna jy gesoek het nie, kan dit om die volgende redes wees:

1. Die aantal waardes om van te kies is beperk tot 254.
2. As indeks_getal minder as 1 of groter is as die aantal waardes in die lys, sal die #WAARDE! fout word teruggestuur.
3. As die indeks_getal -argument 'n breuk is, word dit afgekap tot die laagste heelgetal.

Hoe om KIES-funksie in Excel te gebruik - formule voorbeelde

Die volgende voorbeelde wys hoe KIES die vermoëns van ander Excel-funksies kan uitbrei en alternatiewe oplossings kan bied vir sommige algemene take, selfs vir dié wat deur baie as onuitvoerbaar beskou word.

Excel KIES in plaas van geneste IF's

Een van die mees algemene take in Excel is om verskillende waardes op grond van 'n gespesifiseerde toestand terug te gee. In die meeste gevalle kan dit gedoen word deur 'n klassieke geneste IF-stelling te gebruik. Maar die KIES-funksie kan 'n vinnige en maklik verstaanbare alternatief wees.

Voorbeeld 1. Gee verskillende waardes op grond van toestand terug

Gestel jy het 'n kolom met studentetellings en jy wil etiketteer die tellings gebaseer op dievolgende voorwaardes:

Een manier om dit te doen is om 'n paar IF-formules in mekaar te nes:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

'n Ander manier is om 'n etiket te kies wat ooreenstem met die toestand:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

Hoe hierdie formule werk:

In die indeks_getal argument, evalueer jy elke voorwaarde en gee WAAR as die voorwaarde nagekom word, anders ONWAAR. Byvoorbeeld, die waarde in sel B2 voldoen aan die eerste drie voorwaardes, so ons kry hierdie intermediêre resultaat:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

Gegewe dat in die meeste Excel-formules WAAR gelykstaande is aan 1 en ONWAAR aan 0, ons formule ondergaan hierdie transformasie:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

Nadat die optelbewerking uitgevoer is, het ons:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

As gevolg hiervan is die 3de waarde in die lys word teruggestuur, wat "Goed".

Wenke:

• Om die formule meer buigsaam te maak, kan jy selverwysings in plaas van hardgekodeerde etikette gebruik, byvoorbeeld:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

• As nie een van jou voorwaardes WAAR is nie, sal die indeks_getal -argument op 0 gestel word, wat jou formule dwing om die #WAARDE! fout. Om dit te vermy, draai KIES eenvoudig in die IFERROR-funksie soos volg:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

Voorbeeld 2. Doen verskillende berekeninge gebaseer op toestand

Op 'n soortgelyke wyse, jykan die Excel KIES-funksie gebruik om een ​​berekening in 'n reeks moontlike berekeninge/formules uit te voer sonder om veelvuldige IF-stellings binne-in mekaar te nes.

As 'n voorbeeld, kom ons bereken die kommissie van elke verkoper na gelang van hul verkope:

Met die verkoopsbedrag in B2 neem die formule die volgende vorm aan:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

In plaas daarvan om die persentasies in die formule hard te kodeer, jy kan verwys na die ooreenstemmende sel in jou verwysingstabel, indien daar enige is. Onthou net om die verwysings reg te maak deur die $ teken te gebruik.

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

Excel KIES formule om ewekansige data te genereer

Soos jy waarskynlik weet, het Microsoft Excel 'n spesiale funksie om te genereer ewekansige heelgetalle tussen die onderste en boonste getalle wat jy spesifiseer - RANDBETWEEN funksie. Nest dit in die indeks_getal -argument van KIES, en jou formule sal byna enige ewekansige data genereer wat jy wil hê.

Byvoorbeeld, hierdie formule kan 'n lys van ewekansige eksamenresultate produseer:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

Die formule se logika is voor die hand liggend: RANDBETWEEN genereer ewekansige getalle van 1 tot 4 en KIES gee 'n ooreenstemmende waarde van die voorafbepaalde lys van vier waardes terug.

Let wel. RANDBETWEEN is 'n vlugtige funksie en dit herbereken met elkeverandering wat jy aan die werkblad maak. As gevolg hiervan sal jou lys van ewekansige waardes ook verander. Om te voorkom dat dit gebeur, kan jy formules met hul waardes vervang deur die Plak Spesiale -funksie te gebruik.

KIES formule om 'n linker Vlookup te doen

As jy al ooit uitgevoer het 'n vertikale opsoek in Excel, weet jy dat die VLOOKUP-funksie slegs in die linkerkolom kan soek. In situasies wanneer jy 'n waarde aan die linkerkant van die opsoekkolom moet terugstuur, kan jy óf die INDEX / MATCH-kombinasie gebruik óf VLOOKUP mislei deur die KIES-funksie daarin te nes. Dit is hoe:

Gestel jy het 'n lys tellings in kolom A, studentename in kolom B, en jy wil 'n telling van 'n spesifieke student ophaal. Aangesien die terugkeerkolom aan die linkerkant van die opsoekkolom is, gee 'n gewone Vlookup-formule die #N/A-fout terug:

Om dit reg te stel, kry die CHOOSE-funksie om te ruil die posisies van kolomme, wat vir Excel sê dat kolom 1 B is en kolom 2 A is:

=CHOOSE({1,2}, B2:B5, A2:A5)

Omdat ons 'n skikking van {1,2} in die indeks_getal<2 verskaf> argument, aanvaar die KIES-funksie reekse in die waarde -argumente (normaalweg nie).

Besluit nou die formule hierbo in die tabelskikking -argument van VLOOKUP:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

En voilà - 'n opsoek na links word sonder probleme uitgevoer!

KIES formule om volgende werk terug te keer dag

As jy nie seker is ofjy moet môre werk toe gaan of by die huis kan bly en jou welverdiende naweek geniet, die Excel KIES-funksie kan uitvind wanneer die volgende werksdag is.

Gestel jou werksdae is Maandag tot Vrydag, die formule gaan soos volg:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Moeilik met die eerste oogopslag, as jy van nader kyk, is die formule se logika maklik om te volg:

WEEKDAG (TODAY()) gee 'n reeksnommer terug wat ooreenstem met vandag se datum, wat wissel van 1 (Sondag) tot 7 (Saterdag). Hierdie getal gaan na die indeks_getal -argument van ons KIES-formule.

Waarde1 - waarde7 (1,1,1,1,1, 3,2) bepaal hoeveel dae om by die huidige datum te voeg. As vandag Sondag - Donderdag is (indeks_getal 1 - 5), voeg jy 1 by om die volgende dag terug te gee. As vandag Vrydag is (indeks_getal 6), voeg jy 3 by om volgende Maandag terug te keer. As vandag Saterdag is (indeks_nommer 7), voeg jy 2 by om volgende Maandag weer terug te keer. Jip, dit is so eenvoudig :)

KIES formule om 'n pasgemaakte dag/maand naam vanaf datum terug te gee

In situasies wanneer jy 'n dagnaam in die standaardformaat wil kry, soos volle naam ( Maandag, Dinsdag, ens.) of kort naam (Ma, Di, ens.), kan jy die TEKS-funksie gebruik soos in hierdie voorbeeld verduidelik: Kry dag van week vanaf datum in Excel.

As jy wil gee 'n dag van die week of 'n maandnaam in 'n pasgemaakte formaat, gebruik die KIES-funksie op die volgende manier.

Om 'n dag van die week te kry:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

Om 'nmaand:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Waar A2 die sel is wat die oorspronklike datum bevat.

Ek hoop hierdie tutoriaal het vir jou 'n paar idees gegee van hoe jy die KIES-funksie in Excel kan gebruik om jou datamodelle te verbeter. Ek bedank jou vir die lees en hoop om jou volgende week op ons blog te sien!

Laai oefenwerkboek af

Excel KIES funksie voorbeelde