Təlimat CHOOSE funksiyasının sintaksisini və əsas istifadələrini izah edir və Excel-də SEÇ düsturundan necə istifadə olunacağını göstərən bir neçə qeyri-ciddi nümunə təqdim edir.

SEÇİM onlardan biridir. Öz-özünə faydalı görünməyən, lakin digər funksiyalarla birləşən Excel funksiyaları bir sıra möhtəşəm üstünlüklər verir. Ən əsas səviyyədə siz həmin dəyərin mövqeyini təyin edərək siyahıdan dəyər əldə etmək üçün SEÇİN funksiyasından istifadə edirsiniz. Bu dərslikdə siz, şübhəsiz ki, araşdırmağa dəyər olan bir neçə qabaqcıl istifadə tapacaqsınız.

Excel CHOOSE funksiyası - sintaksis və əsas istifadələr

Excel-də SEÇİM funksiyası müəyyən mövqeyə əsaslanan siyahıdan dəyəri qaytarmaq üçün nəzərdə tutulmuşdur.

Funksiya Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 və Excel 2007-də ​​mövcuddur.

SEÇİM funksiyasının sintaksisi aşağıdakı kimidir:

Burada:

İndeks_num (tələb olunur) - qaytarılacaq dəyərin mövqeyi. Bu, 1 ilə 254 arasında istənilən rəqəm, xana arayışı və ya başqa düstur ola bilər.

Dəyər1, dəyər2, … - seçmək üçün 254-ə qədər dəyərin siyahısı. Dəyər1 tələb olunur, digər dəyərlər isteğe bağlıdır. Bunlar rəqəmlər, mətn dəyərləri, xana istinadları, düsturlar və ya müəyyən edilmiş adlar ola bilər.

Budur, ən sadə formada SEÇİN düsturunun nümunəsi:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

Düstur çünki "Amy" qaytarır index_num 3-dür və "Amy" siyahıda 3-cü dəyərdir:

Excel CHOOSE funksiyası - yadda saxlamaq lazım olan 3 şey!

SEÇİM çox sadə funksiyadır və siz onu iş vərəqlərinizdə tətbiq edərkən çətin ki, heç bir çətinliklə üzləşməyəcəksiniz. CHOOSE düsturunuz tərəfindən qaytarılan nəticə gözlənilməzdirsə və ya axtardığınız nəticə deyilsə, bu, aşağıdakı səbəblərə görə ola bilər:

1. Seçmək üçün dəyərlərin sayı 254 ilə məhdudlaşır.
2. Əgər indeks_num 1-dən azdırsa və ya siyahıdakı dəyərlərin sayından böyükdürsə, #VALUE! xəta qaytarılır.
3. Əgər index_num arqumenti kəsrdirsə, o, ən aşağı tam ədədə kəsilir.

Excel-də SEÇİM funksiyasından necə istifadə olunur - düstur nümunələr

Aşağıdakı nümunələr SEÇİN-in digər Excel funksiyalarının imkanlarını necə genişləndirə biləcəyini və bəzi ümumi tapşırıqlara, hətta çoxları tərəfindən qeyri-mümkün hesab edilənlərə alternativ həllər təqdim edə biləcəyini göstərir.

Excel əvəzinə SEÇİN iç içə IF-lər

Excel-də ən çox görülən tapşırıqlardan biri müəyyən edilmiş şərt əsasında müxtəlif dəyərləri qaytarmaqdır. Əksər hallarda bu, klassik iç içə IF ifadəsindən istifadə etməklə edilə bilər. Lakin SEÇİN funksiyası tez və asan başa düşülən alternativ ola bilər.

Nümunə 1. Şərtə əsasən müxtəlif dəyərləri qaytarın

Fərz edək ki, sizdə tələbə balları sütunu var və siz etiketləmək istəyirsiniz ballar əsasındaaşağıdakı şərtlər:

Bunu etmənin bir yolu bir neçə IF düsturunu bir-birinə yerləşdirməkdir:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

Başqa bir yol şərtə uyğun etiket seçməkdir:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

Bu düstur necə işləyir:

index_num arqumentində siz hər bir şərti qiymətləndirirsiniz və şərt yerinə yetirilərsə TRUE, əks halda YANLIŞ qaytarırsınız. Məsələn, B2 xanasındakı dəyər ilk üç şərtə cavab verir, ona görə də bu ara nəticəni alırıq:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

Excel düsturlarının əksəriyyətində TRUE-nin 1-ə, FALSE-in isə 0-a bərabər olduğunu nəzərə alsaq, bizim düstur bu transformasiyaya məruz qalır:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

Əlavə əməliyyatı yerinə yetirildikdən sonra bizdə:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

Nəticədə 3-cü qiymət siyahı qaytarılır, bu, "Yaxşı"dır.

Məsləhətlər:

• Düsulu daha çevik etmək üçün sərt kodlu etiketlər əvəzinə xana istinadlarından istifadə edə bilərsiniz, məsələn:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

• Şərtlərinizdən heç biri DOĞRU deyilsə, index_num arqumenti 0-a təyin ediləcək və düsturunuz #VALUE dəyərini qaytarmağa məcbur ediləcək! səhv. Bunun qarşısını almaq üçün sadəcə olaraq SEÇİM düyməsini IFERROR funksiyasına bu şəkildə sarın:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

Nümunə 2. Şərtə əsasən müxtəlif hesablamalar aparın

Oxşar şəkildə, Sənbir neçə IF ifadəsini bir-birinin içində yerləşdirmədən mümkün hesablamalar/düsturlar silsiləsində bir hesablamanı yerinə yetirmək üçün Excel CHOOSE funksiyasından istifadə edə bilər.

Nümunə olaraq, satışlarından asılı olaraq hər bir satıcının komissiyasını hesablayaq:

B2-də satış məbləği ilə düstur aşağıdakı formanı alır:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

Düsturdakı faizləri sərt kodlaşdırmaq əvəzinə, Əgər varsa, istinad cədvəlinizdə müvafiq xanaya müraciət edə bilərsiniz. Sadəcə $ işarəsindən istifadə edərək istinadları düzəltməyi unutmayın.

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

Excel Təsadüfi məlumat yaratmaq üçün SEÇİN düsturu

Yəqin bildiyiniz kimi, Microsoft Excel-in yaratmaq üçün xüsusi funksiyası var. müəyyən etdiyiniz alt və yuxarı ədədlər arasında təsadüfi tam ədədlər - RANDBETWEEN funksiyası. Onu SEÇİN-in index_num arqumentində yerləşdirin və düsturunuz demək olar ki, istədiyiniz hər hansı təsadüfi məlumat yaradacaq.

Məsələn, bu düstur təsadüfi imtahan nəticələrinin siyahısını yarada bilər:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

Düsturun məntiqi aydındır: RANDBETWEEN 1-dən 4-ə qədər təsadüfi ədədlər yaradır və CHOOSE əvvəlcədən təyin edilmiş dörd dəyər siyahısından müvafiq dəyəri qaytarır.

Qeyd. RANDBETWEEN uçucu funksiyadır və hər dəfə yenidən hesablanıriş vərəqində etdiyiniz dəyişiklik. Nəticədə, təsadüfi dəyərlərin siyahısı da dəyişəcək. Bunun baş verməsinin qarşısını almaq üçün Xüsusi Yapışdırın funksiyasından istifadə etməklə düsturları onların dəyərləri ilə əvəz edə bilərsiniz.

Sol Vlookup etmək üçün düstur SEÇİN

Əgər siz heç vaxt həyata keçirmisinizsə Excel-də şaquli axtarış, bilirsiniz ki, VLOOKUP funksiyası yalnız ən sol sütunda axtarış edə bilər. Axtarış sütununun soluna dəyəri qaytarmaq lazım olduğu hallarda siz ya INDEX / MATCH kombinasiyasından istifadə edə bilərsiniz, ya da CHOOSE funksiyasını içəri daxil etməklə VLOOKUP-u hiylə edə bilərsiniz. Budur:

Fərz edək ki, A sütununda balların siyahısı, B sütununda tələbə adları var və siz konkret tələbənin xalını əldə etmək istəyirsiniz. Qayıdış sütunu axtarış sütununun solunda olduğundan, adi Vlookup düsturu #N/A xətasını qaytarır:

Bunu düzəltmək üçün dəyişdirmək üçün SEÇİN funksiyasını əldə edin. sütunların mövqeləri, Excel-ə 1-ci sütunun B və 2-ci sütunun A olduğunu bildirir:

=CHOOSE({1,2}, B2:B5, A2:A5)

Çünki biz index_num<2-də {1,2} massivi təqdim edirik> arqument, SEÇİN funksiyası dəyər arqumentlərində diapazonları qəbul edir (adətən, belə deyil).

İndi yuxarıdakı düsturu cədvəl_massivi arqumentinə yerləşdirin. VLOOKUP:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

Və voilà - sola axtarış problemsiz həyata keçirilir!

Növbəti işə qayıtmaq üçün düstur SEÇİN gün

Əgər əmin deyilsinizsəsiz sabah işə getməli və ya evdə qalıb layiqli həftə sonunuzdan zövq ala bilərsiniz, Excel CHOOSE funksiyası növbəti iş gününün nə vaxt olduğunu öyrənə bilər.

İş günlərinizin bazar ertəsindən cümə gününə qədər olduğunu fərz etsək, formula aşağıdakı kimi gedir:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

İlk baxışda çətin, yaxından baxdıqda düsturun məntiqinə əməl etmək asandır:

HƏFTƏ GÜNÜ (TODAY()) 1 (bazar) ilə 7 (şənbə) arasında dəyişən bugünkü tarixə uyğun seriya nömrəsini qaytarır. Bu nömrə SEÇİN düsturumuzun indeks_num arqumentinə gedir.

Dəyər1 - dəyər7 (1,1,1,1,1, 3,2) cari tarixə neçə gün əlavə olunacağını müəyyənləşdirin. Bu gün bazar günüdürsə - cümə axşamı (index_num 1 - 5), növbəti günə qayıtmaq üçün 1 əlavə edirsiniz. Əgər bu gün cümə günüdürsə (index_num 6), gələn bazar ertəsi qayıtmaq üçün 3 əlavə edirsiniz. Bu gün şənbə günüdürsə (index_num 7), növbəti bazar ertəsi yenidən qayıtmaq üçün 2 əlavə edirsiniz. Bəli, bu qədər sadədir :)

Tarixdən etibarən fərdi gün/ay adını qaytarmaq üçün düstur SEÇİN

Tam ad kimi standart formatda gün adını almaq istədiyiniz hallarda ( Bazar ertəsi, Çərşənbə axşamı və s.) və ya qısa ad (Bazar ertəsi, Çərşənbə axşamı və s.), siz bu nümunədə izah edildiyi kimi MƏTN funksiyasından istifadə edə bilərsiniz: Excel-də tarixdən həftənin gününü əldə edin.

Əgər istəyirsinizsə həftənin gününü və ya ay adını fərdi formatda qaytarın, SEÇİM funksiyasından aşağıdakı şəkildə istifadə edin.

Həftənin gününü əldə etmək üçün:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

Almaq üçünay:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

A2 orijinal tarixi ehtiva edən xanadır.

Ümid edirəm ki, bu dərslik sizə bəzi fikirlər verdi. məlumat modellərinizi təkmilləşdirmək üçün Excel-də SEÇİM funksiyasından necə istifadə edə bilərsiniz. Oxuduğunuz üçün sizə təşəkkür edirəm və sizi gələn həftə bloqumuzda görməyə ümid edirəm!

Təcrübə iş kitabını endirin

Excel CHOOSE funksiya nümunələri