De tutorial ferklearret de syntaksis en basisgebrûk fan 'e CHOOSE-funksje en jout in pear net-triviale foarbylden dy't sjen litte hoe't jo in CHOOSE-formule yn Excel brûke kinne.

CHOOSE is ien fan dy Excel-funksjes dy't miskien net nuttich op har eigen sjogge, mar kombineare mei oare funksjes jouwe in oantal bjusterbaarlike foardielen. Op it meast basale nivo brûke jo de CHOOSE-funksje om in wearde út in list te heljen troch de posysje fan dy wearde op te jaan. Fierderop yn dizze tutorial fine jo ferskate avansearre gebrûk dy't grif de muoite wurdich binne om te ferkennen.

Excel CHOOSE-funksje - syntaksis en basisgebrûk

De CHOOSE-funksje yn Excel is ûntworpen om in wearde werom te jaan fan 'e list basearre op in spesifisearre posysje.

De funksje is beskikber yn Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 en Excel 2007.

De syntaksis fan 'e KIES-funksje is as folget:

Wêr:

Index_num (ferplicht) - de posysje fan de wearde dy't weromkomt. It kin elk getal wêze tusken 1 en 254, in selferwizing, of in oare formule.

Wearde1, wearde2, ... - in list mei maksimaal 254 wearden wêrút te kiezen. Wearde1 is fereaske, oare wearden binne opsjoneel. Dit kinne sifers, tekstwearden, selferwizings, formules of definieare nammen wêze.

Hjir is in foarbyld fan in CHOOSE-formule yn de ienfâldichste foarm:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

De formule jout "Amy" omdat index_num is 3 en "Amy" is de 3e wearde yn 'e list:

Excel CHOOSE-funksje - 3 dingen om te ûnthâlden!

KIES is in heul gewoane funksje en jo sille amper problemen hawwe mei it útfieren fan it yn jo wurkblêden. As it resultaat weromjûn troch jo CHOOSE-formule ûnferwachts is of net it resultaat wêr't jo nei sochten, kin it wêze om de folgjende redenen:

1. It oantal wearden om út te kiezen is beheind ta 254.
2. As index_num minder dan 1 of grutter is as it oantal wearden yn 'e list, dan sil de #VALUE! flater wurdt weromjûn.
3. As it argumint index_num in fraksje is, wurdt it ôfkoarte ta it leechste getal.

Hoe kinne jo de funksje KIES brûke yn Excel - formule foarbylden

De folgjende foarbylden litte sjen hoe't CHOOSE de mooglikheden fan oare Excel-funksjes útwreidzje kin en alternative oplossingen foar guon mienskiplike taken leverje, sels foar dyjingen dy't troch in protte as net-útfierber wurde beskôge.

Excel CHOOSE ynstee fan geneste IF's

Ien fan 'e meast foarkommende taken yn Excel is om ferskate wearden werom te jaan op basis fan in spesifisearre betingst. Yn 'e measte gefallen kin dit dien wurde troch in klassike geneste IF-ferklearring te brûken. Mar de CHOOSE-funksje kin in fluch en maklik te begripen alternatyf wêze.

Foarbyld 1. Jou ferskillende wearden werom op basis fan betingst

Stel dat jo in kolom mei studinteskoares hawwe en jo wolle labelje de skoares basearre op defolgjende betingsten:

Ien manier om dit te dwaan is in pear IF-formules yn elkoar te nesteljen:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

In oare manier is om in label te kiezen dat oerienkomt mei de betingst:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

Hoe wurket dizze formule:

Yn it argumint index_num evaluearje jo elke betingst en jouwe TRUE werom as de betingst foldien is, oars FALSE. Bygelyks, de wearde yn sel B2 foldocht oan de earste trije betingsten, dus wy krije dit tuskenresultaat:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

Sjoen dat yn de measte Excel-formules TRUE lyk is oan 1 en FALSE oan 0, ús formule ûndergiet dizze transformaasje:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

Nei't de tafoegingsoperaasje is útfierd, hawwe wy:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

As resultaat is de 3e wearde yn 'e list wurdt weromjûn, dat is "Goed".

Tips:

• Om de formule fleksibeler te meitsjen, kinne jo selferwizings brûke ynstee fan hurdkodearre labels, bygelyks:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

• As gjin fan jo betingsten TRUE is, sil it argumint index_num op 0 ynsteld wurde, wat jo formule twingt om de #VALUE! fersin. Om dit foar te kommen, ferpleatse KIES gewoan yn 'e IFERROR-funksje sa:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

Foarbyld 2. Fiere ferskillende berekkeningen út basearre op betingst

Op in fergelykbere wize, jokin de Excel CHOOSE-funksje brûke om ien berekkening út te fieren yn in rige fan mooglike berekkeningen/formules sûnder meardere IF-útspraken yn elkoar te nesteljen.

Litte wy as foarbyld de kommisje fan elke ferkeaper berekkenje ôfhinklik fan har ferkeap:

Mei it ferkeapbedrach yn B2 nimt de formule de folgjende foarm oan:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

Ynstee fan hardkodearjen fan de persintaazjes yn 'e formule, jo kinne ferwize nei de oerienkommende sel yn jo referinsjetabel, as d'r ien is. Unthâld gewoan de ferwizings te reparearjen mei it $ teken.

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

Excel CHOOSE formule om willekeurige gegevens te generearjen

Sa't jo wierskynlik witte, hat Microsoft Excel in spesjale funksje om te generearjen willekeurige hiele getallen tusken de ûnderste en boppeste nûmers dy't jo oantsjutte - RANDBETWEEN funksje. Nest it yn it index_num argumint fan CHOOSE, en jo formule sil hast alle willekeurige gegevens generearje dy't jo wolle.

Dizze formule kin bygelyks in list mei willekeurige eksamenresultaten meitsje:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

De logika fan 'e formule is fanselssprekkend: RANDBETWEEN genereart willekeurige getallen fan 1 oant 4 en CHOOSE jout in oerienkommende wearde werom út 'e foarôf definieare list fan fjouwer wearden.

Opmerking. RANDBETWEEN is in flechtich funksje en it recalculates mei elkferoaring dy't jo meitsje oan it wurkblêd. As gefolch sil jo list mei willekeurige wearden ek feroarje. Om foar te kommen dat dit bart, kinne jo formules ferfange troch har wearden troch de funksje Spesjaal plakke te brûken.

KIES formule om in linkse Vlookup te dwaan

As jo ​​oait útfierd hawwe in fertikale opsykje yn Excel, jo witte dat de VLOOKUP-funksje allinich kin sykje yn 'e lofterste kolom. Yn situaasjes as jo in wearde links fan 'e opsykkolom moatte weromjaan, kinne jo de INDEX / MATCH-kombinaasje brûke of VLOOKUP ferrifelje troch de CHOOSE-funksje deryn te nestelen. Hjir is hoe:

Stel dat jo in list hawwe mei skoares yn kolom A, studintnammen yn kolom B, en jo wolle in skoare fan in bepaalde studint ophelje. Om't de weromkommende kolom links fan 'e opsykkolom is, jout in reguliere Vlookup-formule de #N/A-flater werom:

Om dit te reparearjen, krije jo de CHOOSE-funksje om te wikseljen de posysjes fan kolommen, fertellen Excel dat kolom 1 is B en kolom 2 is A:

=CHOOSE({1,2}, B2:B5, A2:A5)

Om't wy in array fan {1,2} leverje yn it index_num argumint, aksepteart de CHOOSE-funksje berik yn de wearde -arguminten (normaal net).

No, ynbêde de boppesteande formule yn it tabel_array -argumint fan VLOOKUP:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

En voilà - in opsykje nei lofts wurdt sûnder problemen útfierd!

KIES formule om werom te gean nei folgjende wurking day

As jo ​​net wis binne oftjo moatte moarn nei it wurk gean of thús bliuwe kinne en genietsje fan jo wolfertsjinne wykein, de Excel CHOOSE-funksje kin útfine wannear't de folgjende wurkdei is.

Ungeande fan jo wurkdagen binne moandei oant en mei freed, de formule giet as folget:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Lekker op it earste gesicht, by in tichterby besjen is de logika fan de formule maklik te folgjen:

WEEKDAY (TODAY ()) jout in searjenûmer oerienkommende mei de datum fan hjoed, fariearjend fan 1 (Snein) oant 7 (Sneon). Dit nûmer giet nei it index_num argumint fan ús CHOOSE formule.

Wearde1 - wearde7 (1,1,1,1,1, 3,2) bepale hoefolle dagen ta te foegjen oan de aktuele datum. As hjoed snein - tongersdei is (index_num 1 - 5), foegje jo 1 ta om de oare deis werom te kommen. As hjoed freed is (index_num 6), foegje jo 3 ta om kommende moandei werom te kommen. As hjoed sneon is (index_num 7), foegje jo 2 ta om kommende moandei wer werom te kommen. Ja, it is sa ienfâldich :)

KIES formule om in oanpaste dei/moannenamme fan datum werom te jaan

Yn situaasjes as jo in deinamme wolle krije yn it standertformaat lykas folsleine namme ( Moandei, tiisdei, ensfh.) of koarte namme (moandei, di, ensfh.), kinne jo de TEKST-funksje brûke lykas útlein yn dit foarbyld: Krij dei fan 'e wike fan datum yn Excel.

As jo ​​wolle werom in dei fan de wike of in moanne namme yn in oanpaste opmaak, brûk de KIES funksje op de folgjende wize.

Om in dei fan de wike te krijen:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

Om amoanne:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Wêr't A2 de sel is mei de oarspronklike datum.

Ik hoopje dat dizze tutorial jo wat ideeën jûn hat fan hoe't jo de KIES-funksje yn Excel kinne brûke om jo gegevensmodellen te ferbetterjen. Ik tankje jo foar it lêzen en hoopje jo nije wike op ús blog te sjen!

Download oefenwurkboek

Excel CHOOSE-funksjefoarbylden