Edukien taula
Tutorialak COOSE funtzioaren sintaxia eta oinarrizko erabilerak azaltzen ditu eta adibide ez-trivial batzuk eskaintzen ditu, Excel-en CHOOSE formula bat nola erabili erakusten dutenak.
CHOOSE horietako bat da. Berez erabilgarriak ez diren Excel funtzioek, baina beste funtzio batzuekin konbinatuta, onura izugarriak ematen dituzte. Oinarrizko mailan, AUKERATU funtzioa erabiltzen duzu zerrenda bateko balio bat lortzeko balio horren posizioa zehaztuz. Aurrerago tutorial honetan, esploratzeko moduko hainbat erabilera aurreratu aurkituko dituzu.
Excel AUKERATU funtzioa - sintaxia eta oinarrizko erabilerak
Excel-en AUKERATU funtzioa da. zehaztutako posizio batean oinarritutako zerrendako balio bat itzultzeko diseinatua.
Funtzioa Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 eta Excel 2007-n dago erabilgarri.
AUKERATU funtzioaren sintaxia hau da:
AUKERATU (indize_zenbakia, balioa1, [balioa2], ...)Non:
Index_zenbakia (beharrezkoa) - itzuli beharreko balioaren posizioa. 1 eta 254 arteko edozein zenbaki izan daiteke, gelaxka-erreferentzia bat edo beste formula bat.
Balioa1, balioa2, … - 254 balioen zerrenda bat aukeratzeko. Balioa1 beharrezkoa da, beste balio batzuk aukerakoak dira. Hauek zenbakiak, testu-balioak, gelaxka-erreferentziak, formulak edo definitutako izenak izan daitezke.
Hona hemen AUKERATU formula baten adibidea forma sinpleenean:
=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")
Formula "Amy" itzultzen duelako index_num 3 da eta "Amy" zerrendako 3. balioa da:
Excel COOSE funtzioa - 3 gauza gogoratu!
AUKERATU oso funtzio arrunta da eta nekez izango duzu zailtasunik zure lan-orrietan ezartzeko. AUKERATU formulak itzultzen duen emaitza ustekabekoa bada edo bilatzen ari zaren emaitza ez bada, arrazoi hauengatik izan daiteke:
- Aukeratzeko balio kopurua 254ra mugatzen da.
- index_num zerrendako balio kopurua 1 baino txikiagoa edo handiagoa bada, #BALIOA! errorea itzultzen da.
- index_num argumentua frakzio bat bada, osoko txikienera moztuko da.
Nola erabili CHOSE funtzioa Excel-en - formula adibideak
Ondoko adibideek CHOOSEk Excel-eko beste funtzio batzuen gaitasunak nola heda ditzakeen eta ohiko zeregin batzuetarako irtenbide alternatiboak nola eman ditzakeen erakusten dute, baita askok bideraezintzat jotzen dituztenei ere.
Excel-ek CHOOSE-ren ordez. habiaratuak IFs
Excel-en zeregin ohikoenetako bat baldintza zehatz batean oinarritutako balio desberdinak itzultzea da. Kasu gehienetan, IF adierazpen habiaratu klasiko bat erabiliz egin daiteke. Baina AUKERATU funtzioa alternatiba azkarra eta ulerterraza izan daiteke.
1. Adibidea. Baldintzaren araberako balio desberdinak itzuli
Demagun ikasleen puntuazioen zutabe bat duzula eta etiketatu nahi duzula. puntuazioan oinarritutabaldintza hauek:
| Emaitza | Puntuazioa |
| Eskaria | 0 - 50 |
| Pozik | 51 - 100 |
| Ona | 101 - 150 |
| Bikaina | 151 baino gehiago |
Horretarako modu bat IF formula batzuk elkarren barruan habiatzea da:
=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))
Beste modu bat baldintzari dagokion etiketa aukeratzea da:
=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")
Formula honek nola funtzionatzen duen:
index_num argumentuan, baldintza bakoitza ebaluatzen duzu eta TRUE itzuliko duzu baldintza betetzen bada, FALSE bestela. Adibidez, B2 gelaxkako balioak lehen hiru baldintzak betetzen ditu, beraz, tarteko emaitza hau lortuko dugu:
=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")
Excel formula gehienetan TRUE 1 eta FALSE 0 balio duela kontuan hartuta, gure formulak eraldaketa hau jasaten du:
=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")
Batuketa eragiketa egin ondoren, hau dugu:
=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")
Ondorioz, 3. balioa. zerrenda itzultzen da, hau da, "Ona".
Aholkuak:
- Formula malguagoa izan dadin, gelaxka-erreferentziak erabil ditzakezu gogor kodetutako etiketen ordez, adibidez:
=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4) - Zure baldintzetako bat ere EGIA ez bada, index_num argumentua 0-n ezarriko da zure formula #BALIOA itzultzera behartuz! akatsa. Hori ekiditeko, itzulbiratu AUKERATU IFERROR funtzioan honela:
=IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")
Adibidea 2. Egin kalkulu desberdinak baldintzaren arabera
Antzeko moduan, zukExcel COOSE funtzioa erabil dezake kalkulu/formula posible batzuen kalkulu bat egiteko IF adierazpen anitz bata bestearen barruan habiaratu gabe.
Adibide gisa, kalkula dezagun saltzaile bakoitzaren komisioa bere salmenten arabera:
| Komisioa | Salmentak |
| %5 | $0 eta $50 |
| % 7 | $51 eta $100 |
| %10 | $101 baino gehiago |
B2-ko salmenta-kopurua izanik, formulak forma hau hartzen du:
=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)
Formulan ehunekoak gogor kodetu beharrean, zure erreferentzia-taulan dagokion gelaxkara jo dezakezu, baldin badago. Gogoratu erreferentziak $ ikurra erabiliz konpontzea.
=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)
Excel AUKERATU formula ausazko datuak sortzeko
Ziurrenik dakizunez, Microsoft Excel-ek funtzio berezi bat du sortzeko. Zehazten dituzun beheko eta goiko zenbakien arteko ausazko osoak - RANDBETWEEN funtzioa. Habia ezazu CHOOSEren index_num argumentuan, eta zure formulak nahi dituzun ia ausazko datuak sortuko ditu.
Adibidez, formula honek ausazko azterketen emaitzen zerrenda sor dezake:
=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")
Formularen logika begi-bistakoa da: RANDBETWEENek 1etik 4ra bitarteko ausazko zenbakiak sortzen ditu eta COOSEk lau balioen zerrendatik dagokion balio bat itzultzen du.
Oharra. RANDBETWEEN funtzio lurrunkorra da eta bakoitzarekin birkalkulatzen dulan-orrian egiten duzun aldaketa. Ondorioz, ausazko balioen zerrenda ere aldatuko da. Hori gerta ez dadin, formulak beren balioekin ordezka ditzakezu Itsatsi berezia funtzioa erabiliz.
AUKETU formula ezkerreko Bilaketa bat egiteko
Inoiz egin baduzu. Excel-en bilaketa bertikala, badakizu VLOOKUP funtzioak ezkerreko zutabean soilik bilatu dezakeela. Bilaketa-zutabearen ezkerrera balio bat itzuli behar duzun egoeretan, INDEX / MATCH konbinazioa erabil dezakezu edo VLOOKUP engainatu AUKERA funtzioa bertan habiatuz. Hona hemen nola:
Demagun A zutabean puntuazio zerrenda bat duzula, B zutabean ikasleen izenak eta ikasle jakin baten puntuazioa berreskuratu nahi duzula. Itzultzeko zutabea bilaketa-zutabearen ezkerrean dagoenez, Vlookup formula arrunt batek #N/A errorea itzultzen du:
Hau konpontzeko, lortu COOSE funtzioa trukatzeko. zutabeen posizioak, Excel-i 1 zutabea B dela eta 2. zutabea A dela esanez:
=CHOOSE({1,2}, B2:B5, A2:A5)
{1,2}-ko array bat hornitzen dugulako index_num argumentuan, COOSE funtzioak balioa argumentuetako barrutiak onartzen ditu (normalean, ez du).
Orain, txertatu goiko formula taula_array argumentuan. VLOOKUP:
=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)
Eta voilà - ezkerrera begirada bat oztoporik gabe egiten da!
Aukeratu formula hurrengo lanera itzultzeko eguna
Ziur ez bazaudebihar lanera joan beharko zenuke edo etxean geratu zaitezke eta merezitako asteburua gozatu, Excel COOSE funtzioak hurrengo lan eguna noiz den jakin dezake.
Zure lan egunak astelehenetik ostiralera direla suposatuz, formula honela doa:
=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)
Lehen begiratuan delikatua, hurbilagotik begiratuta formularen logika erraza da:
ASTEEGUNA (GAUR()) serie-zenbakia itzultzen du gaurko datari dagokiona, 1etik (igandea) eta 7ra (larunbata) bitartekoa. Zenbaki hau gure COOSE formulako index_num argumentura doa.
Balioa1 - balioa7 (1,1,1,1,1, 3,2) zehaztu zenbat egun gehitu uneko datari. Gaur igandea - osteguna bada (index_num 1 - 5), gehitu 1 hurrengo egunean itzultzeko. Gaur ostirala bada (index_num 6), gehitu 3 datorren astelehenean itzultzeko. Gaur larunbata bada (index_num 7), gehitu 2 hurrengo astelehenean berriro itzultzeko. Bai, hain erraza da :)
AUKETU formula egun/hilabeteko izen pertsonalizatua itzultzeko datatik aurrera
Egunaren izena formatu estandarrean lortu nahi duzun egoeretan, hala nola izen osoa ( Astelehena, asteartea, etab.) edo izen laburra (al., asteartea, etab.), adibide honetan azaltzen den bezala erabil dezakezu TESTU funtzioa: Lortu asteko eguna datatik aurrera Excel-en.
Nahi baduzu. itzuli asteko egun bat edo hilabete baten izena formatu pertsonalizatuan, erabili AUKERATU funtzioa modu honetan.
Asteko egun bat lortzeko:
=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")
A lortzekohilabetea:
=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")
Non A2 jatorrizko data duen gelaxka den.
Espero dut tutorial honek ideia batzuk eman dizkizula. Excel-en AUKERATU funtzioa nola erabil dezakezun zure datu-ereduak hobetzeko. Eskerrik asko irakurtzeagatik eta datorren astean gure blogean ikustea espero dut!
Deskargatu praktika-koadernoa
Excel AUKERATU funtzioen adibideak
