Taula de continguts
El tutorial ofereix una breu introducció a la sintaxi de la funció ADDRESS i mostra com utilitzar-la per retornar una adreça de cel·la d'Excel i molt més.
Per crear una referència de cel·la a Excel, cal que pot escriure les coordenades de columna i fila manualment. Alternativament, podeu obtenir una adreça de cel·la d'Excel a partir dels números de fila i columna proporcionats a la funció ADREÇA. Gairebé inútil per si mateixa, en combinació amb altres funcions, aquesta tècnica pot ser l'única solució en situacions en què no és possible fer referència a una cel·la directament.
Funció ADREÇA d'Excel - sintaxi i usos bàsics
La funció ADREÇA està dissenyada per obtenir una adreça de cel·la a Excel basada en els números de fila i columna especificats. Una adreça de cel·la es retorna com a cadena de text, no com a referència real.
La funció està disponible a totes les versions d'Excel per a Microsoft 365 - Excel 2007.
La sintaxi de la funció ADRESSE és de la següent manera:
ADDRESS(núm_fila, núm_columna, [núm_abs], [a1], [text_full])Els dos primers arguments són obligatoris:
núm_fila - la fila número que cal utilitzar a la referència de la cel·la.
núm_columna : el número de columna per crear la referència de la cel·la.
Els tres últims arguments, que especifiquen el format de referència de la cel·la, són opcional:
abs_num - el tipus de referència, absolut o relatiu. Pot prendre qualsevol dels números següents; el valor per defecte és absolut.
- 1 o s'omet -referència de cel·la absoluta com $A$1
- 2 - referència mixta: columna relativa i fila absoluta com A$1
- 3 - referència mixta: columna absoluta i fila relativa com $A1
- 4 - referència de cel·la relativa com ara A1
a1 - l'estil de referència, A1 o R1C1. Si s'omet, s'utilitza l'estil A1 predeterminat.
- 1 o TRUE o omès: retorna l'adreça de la cel·la a l'estil de referència A1 on les columnes són lletres i les files són números.
- 0 o FALSE: retorna l'adreça de la cel·la a l'estil de referència R1C1 on les files i les columnes es representen amb números.
sheet_text : el nom del full de treball que cal incloure a la referència externa. El nom del full s'ha de proporcionar com una cadena de text i entre cometes, p. "Full 2". Si s'omet, no s'utilitza cap nom de full de treball i l'adreça per defecte és el full actual.
Per exemple:
=ADDRESS(1,1) : retorna l'adreça de la primera cel·la (és a dir, la cel·la a la intersecció de la primera fila i la primera columna) com a referència de cel·la absoluta $A$1.
=ADDRESS(1,1,4) : retorna l'adreça de la primera cel·la com a referència de cel·la relativa A1.
A la taula següent, trobareu uns quants tipus de referència més que es poden tornar amb les fórmules ADDRESS.
| Fórmula | Resultat | Descripció |
| =ADDRESS(1,2) | $B$1 | Cel·la absolutareferència |
| =ADDRESS(1,2,4) | B1 | Referència de cel·la relativa |
| =ADDRESS(1,2,2) | B$1 | Columna relativa i fila absoluta |
| =ADDRESS(1,2,3) | $B1 | Columna absoluta i fila relativa |
| =ADDRESS(1,2,1,FALSE) | R1C2 | Referència absoluta a l'estil R1C1 |
| =ADDRESS(1,2,4,FALSE) | R[1]C[2] | Referència relativa a l'estil R1C1 |
| =ADDRESS(1,2,1,,"Full2") | Full2!$B$1 | Referència absoluta a un altre full |
| =ADDRESS(1,2,4,,"Sheet2") | Sheet2!B1 | Referència relativa a un altre full |
Com utilitzar la funció ADREÇA a Excel - exemples de fórmules
Els exemples següents mostren com utilitzar la funció ADREÇA dins de fórmules més grans per aconseguir més tasques difícils.
Retorna el valor d'una cel·la en una fila i una columna determinades
Si el teu objectiu és obtenir un valor d'una cel·la específica en funció dels números de fila i columna, fes servir l'opció divertida ADRESSE cció juntament amb INDIRECT:
INDIRECT(ADDRESS(núm_fila, núm_columna))La funció ADREÇA mostra l'adreça de la cel·la com a text. La funció INDIRECTA converteix aquest text en una referència normal i retorna el valor de la cel·la corresponent.
Per exemple, per obtenir un valor de cel·la basat en el número de fila a E1 i el número de columna a E2, utilitzeu aquesta fórmula. :
=INDIRECT(ADDRESS(E1,E2))
Obteniu l'adreçad'una cel·la amb el valor més alt o més baix
En aquest exemple, primer trobarem els valors més alt i més baix de l'interval B2:B7 utilitzant les funcions MAX i MIN i emetem aquests valors en cel·les especials:
Cel·la E2: =MAX(B2:B7)
Cel·la F2: =MIN(B2:B7)
I aleshores, utilitzarem ADDRESS en combinació amb la funció MATCH per obteniu les adreces de cel·la.
Cel·la amb el valor màxim:
=ADDRESS(MATCH(E2,B:B,0), COLUMN(B2))
Cel·la amb el valor mínim:
=ADDRESS(MATCH(F2,B:B,0), COLUMN(B2))
En cas que no vulgueu els valors més alt i més baix en cel·les separades, podeu anidar la funció MAX/MIN al primer argument de MATCH. Per exemple:
Cel·la amb el valor més alt:
=ADDRESS(MATCH(MAX(B2:B7),B:B,0), COLUMN(B2))
Cel·la amb el valor més baix:
=ADDRESS(MATCH(MIN(B2:B7),B:B,0), COLUMN(B2))
Com aquestes fórmules work
Per trobar el número de fila, feu servir la funció MATCH(lookup_value, lookup_array, [match_type]) que retorna una posició relativa de lookup_value a lookup_array. A la nostra fórmula, el valor de cerca és el nombre que retorna la funció MAX o MIN, i la matriu de cerca és la columna sencera. En conseqüència, una posició relativa del valor de cerca a la matriu coincideix exactament amb el número de fila del full.
Per trobar el número de columna, feu servir la funció COLUM. Per descomptat, res no us impedeix escriure el número directament a la fórmula, però COLUMN estalvia la molèstia del recompte manual en cas que la columna de destinació estigui al mig del full.
Obteniu una lletra de columna.des d'un número de columna
Per convertir qualsevol número donat en una lletra de columna, utilitzeu la funció ADRESSE dins de SUBSTITUTE:
SUBSTITUTE(ADDRESS(1, column_number,4),"1 ","")Com a exemple, busquem la lletra de la columna corresponent al número d'A2:
=SUBSTITUTE(ADDRESS(1,A2,4),"1","")
Mirant els resultats següents, podem dir que la primera columna al full hi ha A, que és evident; la 10a columna és J, la 50a columna és AX i la 100a columna és CV:
Com funciona aquesta fórmula
Per començar, configureu el Funció ADDRESS per retornar una referència relativa a la primera cel·la de la columna de destinació:
- Per al número de fila, utilitzeu 1.
- Per al número de columna, proporcioneu la referència a la cel·la que conté el número, A2 al nostre exemple.
- Per a l'argument abs_num, introduïu 4.
Com a resultat, ADDRESS(1,A2,4) retornaria A1.
Per desfer-se de la coordenada de fila, emboliqueu la fórmula anterior a la funció SUBSTITUTE i substituïu "1" per una cadena buida (""). Fet!
Obtenir l'adreça d'un interval amb nom
Per trobar l'adreça d'un interval amb nom a Excel, primer haureu d'obtenir les referències de la primera i l'última cel·la i després unir-les. . Això funciona de manera una mica diferent a l'Excel predinàmic (2019 i anterior) i a l'Excel dinàmic de matriu (Office 365 i Excel 2021). Els exemples següents són per a Excel 2019 - Excel 2007. Les instruccions per a Excel 365 i Excel 2021 sónaquí.
Com obtenir l'adreça de la primera cel·la d'un interval
Per retornar una referència a la primera cel·la d'un interval amb nom, utilitzeu aquesta fórmula genèrica:
ADDRESS(ROW( interval),COLUMN( interval))Suposant que l'interval s'anomena "Vendes", la fórmula real és la següent:
=ADDRESS(ROW(Sales), COLUMN(Sales))
I retorna l'adreça de la cel·la superior esquerra de l'interval:
En aquesta fórmula, les funcions FILA i COLUMNA retornen una matriu de tots els números de fila i columna de el rang, respectivament. A partir d'aquests números, la funció ADDRESS crea una matriu d'adreces de cel·les. Però com que la fórmula s'introdueix en una sola cel·la, només es mostra el primer element de la matriu, que correspon a la primera cel·la de l'interval.
Com obtenir l'adreça de l'última cel·la d'un interval
Per trobar l'adreça de l'última cel·la d'un interval amb nom, utilitzeu aquesta fórmula genèrica:
ADDRESS(ROW( range)+ROWS( range)-1 ,COLUMN( interval)+COLUMNS( interval)-1)Aplicada al nostre interval anomenat "Vendes", la fórmula pren la forma següent:
=ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)
I retorna la referència a la cel·la inferior dreta de l'interval:
Aquesta vegada, necessitem càlculs una mica més complexos per resoldre la fila nombre. Com en l'exemple anterior, la funció ROW ens proporciona una matriu de tots els números de fila de l'interval, {4;5;6;7} en el nostre cas. Hem de "desplaçar" aquests nombres pel nombre total de files menys 1, de manera queel primer element de la matriu es converteix en l'últim número de fila. Per trobar el recompte total de files, utilitzem la funció ROWS i restem 1 del seu resultat: (4-1=3). Aleshores, afegim 3 a cada element de la matriu inicial per fer el desplaçament requerit: {4;5;6;7} + 3 = {7;8;9;10}.
El número de columna és es calcula de manera similar: {2,3,4}+3-1 = {4,5,6}
A partir de les matrius anteriors de números de fila i columna, la funció ADRESSE reuneix una matriu d'adreces de cel·les , però només retorna la primera corresponent a l'última cel·la de l'interval.
També es pot aconseguir el mateix resultat escollint els valors màxims de les matrius dels números de fila i columna. Tanmateix, això només funciona en una fórmula de matriu, que requereix prémer Ctrl + Maj + Retorn per completar correctament:
=ADDRESS(MAX(ROW(Sales)), MAX(COLUMN(Sales)))
Com obtenir l'adreça completa d'un interval amb nom
Per retornar l'adreça completa d'un interval amb nom, només cal que concatenar les dues fórmules dels exemples anteriors i inserir l'operador d'interval (:) entremig.
ADDRESS(ROW( interval) , COLUMN( interval)) & ":" & ADREÇA(FILA( interval) + FILES( interval)-1, COLUMNA( interval) + COLUMNES( interval)-1)Per tal que funcioni per al nostre conjunt de dades de mostra, substituïm l'"interval" genèric pel nom de l'interval real "Vendes":
=ADDRESS(ROW(Sales), COLUMN(Sales)) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)
I obtenim l'adreça de l'interval completa com a Referència absoluta $B$4:$D$7:
Per retornar l'intervaladreça com a referència relativa (sense el signe $, com B4:D7), establiu l'argument abs_num a les dues funcions ADDRESS a 4:
=ADDRESS(ROW(Sales), COLUMN(Sales), 4) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1, 4)
Naturalment, el es poden fer els mateixos canvis en fórmules individuals per a la primera i l'última cel·la, i el resultat serà semblant a aquest:
Com obtenir l'adreça d'un interval amb nom a Excel 365 i Excel 2021
A diferència del comportament tradicional "una fórmula - una cel·la" en versions anteriors, a l'Excel nou, qualsevol fórmula que pugui retornar diversos valors ho fa automàticament. Aquest comportament s'anomena vessament.
Per exemple, en lloc de retornar l'adreça de la primera cel·la, la fórmula següent mostra les adreces de totes i cadascuna de les cel·les d'un rang anomenat:
=ADDRESS(ROW(Sales), COLUMN(Sales))
Per obtenir l'adreça de la primera cel·la només, cal que habiliteu la intersecció implícita, que s'activa de manera predeterminada a Excel 2019 i versions anteriors. Per a això, poseu el símbol @ (operador d'intersecció implícit) abans dels noms d'interval:
=ADDRESS(@ROW(Sales), @COLUMN(Sales))
De manera similar, podeu corregir altres fórmules.
Per obtenir última cel·la de l'interval:
=ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)
Per obtenir l' adreça d'un interval anomenat :
=ADDRESS(@ROW(Sales), @COLUMN(Sales)) & ":" & ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)
La captura de pantalla següent mostra els resultats:
Consell. Quan obriu un full de treball amb fórmules creades en una versió anterior a l'Excel de matriu dinàmica, Excel insereix automàticament un operador d'intersecció implícit.
Així és com podeuretorna una adreça de cel·la a Excel. Per veure amb més detall totes les fórmules que es tracten en aquest tutorial, us convidem a descarregar el nostre quadern de treball de mostra a continuació. Us agraeixo la lectura i esperem veure-us al nostre bloc la setmana vinent!
Quader de pràctiques per descarregar
Funció ADREÇA d'Excel - exemples de fórmules (fitxer .xlsx)
