"Skep" beteken gewoonlik om iets in 'n reeks of 'n ketting aan mekaar te koppel. Hierdie bewerking word gebruik wanneer jy teks van verskeie Google Blaaie-selle moet aansluit. Hierdie artikel versamel die gewildste en maklikste oplossings om jou te help om die samevoegingraaisel op te los.

Hoe groot jou datastel ook al is, jy kan dalk die taak teëkom om veelvuldige selle in Google Blaaie saam te kombineer. En ek twyfel nie dat jy nie net wil voorkom dat alle waardes verloor nie, maar ook 'n paar kommas, spasies of ander karakters wil byvoeg, of selfs daardie rekords met ander teks moet skei.

Wel, sigblaaie bied verskeie nutsmiddels vir hierdie taak.

Google Sheets CONCAT-funksie

Die CONCAT-funksie is 'n vereenvoudigde weergawe van Google Sheets CONCATENATE:

Om selle met hierdie funksie te verbind, moet jy die vereiste waardes lys:

• waarde1 – 'n rekord waarby waarde2 aangeheg moet word.
• waarde2 – die waarde om aan te sluit.

Om een ​​string uit 2 teks- of numeriese eenhede te kry, sal die formule soos hieronder lyk, met elke rekord in dubbelaanhalingstekens:

=CONCAT("2019:","The Lion King")

In werklikheid is jou data heel waarskynlik reeds in selle. Jy kan direk na daardie selle verwys in plaas daarvan om elke nommer of teks as 'n argument neer te sit. Die reële-data-formule sal dus soos volg wees:

=CONCAT(A2,B2)

Wenk. Om jou formule na die hele kolom te kopieer, kies die selmet die formule en dubbelklik op die vierkantjie regs onder in die sel. Die hele kolom sal outomaties gevul word met die formule, tot aan die einde van die tabel.

Soos jy kan sien, is die funksie baie eenvoudig, maar dit het groot swak punte :

• dit smelt net twee selle in Google Blaaie op 'n slag saam.
• dit kan nie kolomme, rye of ander groot datareekse kombineer nie, dit neem slegs enkele selle. As jy probeer om verskeie selle te koppel, sal jy óf 'n fout kry óf net die eerste twee waardes sal saamgevoeg word, soos volg:

  =CONCAT(A2:A11,B2:B11)

  

CONCAT-alternatief: aaneenskakelingsoperateur ampersand (&)

Daar is baie verskillende operateurs vir verskeie doeleindes in formules. Aaneenskakeling is nie 'n uitsondering nie. Deur 'n ampersand-karakter (&) in formules in plaas van die CONCAT-funksie te gebruik, sal jy dieselfde resultaat gee:

=A2&B2

Maar min weet jy dat hierdie aaneenskakelingsoperateur meer buigsaam is. Hier is wat dit kan doen:

1. Voeg meer as twee waardes op 'n slag saam:

   =A2&B2&C2

   

2. Nie net om selle saam te voeg nie in Google Sheets, maar skei hulle ook met verskeie karakters:

   =A2&" "&B2&"; "&C2

   

As jy steeds nie die gewenste resultaat kry met hierdie opsies , daar is nog een funksie om te probeer.

Hoe om CONCATENATE in Google Sheets te gebruik

Ek glo die Google Sheets CONCATENATE-funksie is die eerste een wat gebruik wordwanneer dit kom by die byvoeging van verskeie rekords saam.

KOPPEL teksstringe en nommers in Google Blaaie aan

Die formulepatroon bestaan ​​uit die volgende argumente:

• string1 is die eerste string waaraan jy ander waardes wil voeg. Hierdie argument word vereis.
• string2, … staan ​​vir alle ander stringe wat jy dalk wil byvoeg. Hierdie argument is opsioneel.

Let wel. Die uitkomsrekord sal bestaan ​​uit die snare in die volgorde van hul verskyning in die formule.

As ek die formule by my data aanpas, sal ek hierdie kry:

=CONCATENATE(A2,B2,C2)

Of, aangesien die funksie reekse aanvaar:

=CONCATENATE(A2:D2)

Jy kan dadelik die eerste voordeel van Google Sheets CONCATENATE opmerk: dit verbind maklik oor twee selle met beide teks en syfers.

Google Sheets: voeg stringe saam met skeiers

Om selle in Google Blaaie te kombineer, is die helfte van die werk. Maar om die resultaat mooi en leesbaar te laat lyk, moet jy 'n paar ekstra karakters byvoeg.

As jy die formule so hou, sal dit net alles aanmekaar plak: BonnieJacksonCA , BonnieJacksonIN , ens. Maar Google Sheets CONCATENATE neem karakters ook as argumente.

Om dus 'n paar skeiers by te voeg vir leesbaarheid, noem hulle in dubbele aanhalingstekens in die formule:

=CONCATENATE(A2," ",B2,", ",C2)

Hier wil ek A2 & B2 met spasie en skei B2 van C2 met 'n komma enspasie:

Jy is vry om byna enige karakter in die funksie soos hierdie te gebruik, tog vereis 'n reëlbreuk 'n ander benadering.

Wenk. As daar leë selle in sommige van die kolomme is wat jy saamvoeg, is daar nog een funksie waarin jy dalk belangstel. TEXTJOIN voeg nie bloot selle in Google Blaaie saam nie, maar ignoreer spasies:

=TEXTJOIN(" ",TRUE,A2:C2)

Hier is hoe dit werk:

1. Dui die verlangde skeidingsteken as 'n eerste argument aan – spasie (" ") vir my.
2. Sit WAAR as 'n tweede argument om leë selle oor te slaan of ONWAAR om hulle by die resultaat in te sluit.
3. Voer die reeks in om saam te voeg.

Sluit aan met reëlbreuk in Google Blaaie

Alhoewel dit duidelik is hoe om die meeste skeidingstekens vir die funksie in te voer, kan jy nie 'n reëlbreuk op dieselfde manier daar tik nie. Maar gelukkig laat Google jou baie verskillende kaarte speel.

Daar is 'n funksie wat help om spesiale karakters te kry – dit word CHAR genoem. Jy sien, elke karakter het 'n plek in die Unicode-tabel. Jy hoef net die rangnommer van die karakter van daardie tabel na die funksie toe te voer en laasgenoemde sal die karakter self terugstuur.

Hier is 'n formule om die reëlbreuk te kry:

=CHAR(10)

Voeg dit by die formule om aaneen te skakel met die reëlbreuk in Google Sheets:

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)

Kombineer datum en tyd in Google Sheets

As jy probeer om datum en tyd in Google Sheets te kombineer deur een van die metodes te gebruikhierbo, sal dit nie werk nie. Jou sigblad sal nommers gee:

Om datum en tyd in Google Sheets korrek te kombineer, gebruik die TEXT-funksie:

• waar nommer enige nommer, datum of tyd is wat jy in die verlangde formaat wil kry
• en formaat is die patroon wat jy wil hê sien as gevolg daarvan.

Wenk. In my voorbeeld gaan ek na selle met datums en tye verwys, maar jy is vry om datum/tyd-eenhede of selfs sulke funksies soos DATUM of TYD direk in die formule te gebruik.

1. Ek gebruik die eerste TEKS-formule om die datumformaat van 7/9/2019 na 9 Jul 2019 te verander:

   =TEXT(B2,"D MMM YYYY")

2. Die tweede TEKS gee die tyd terug:

   =TEXT(C2,"HH:MM:SS")

3. Deur hierdie in CONCATENATE te gebruik, laat Google Blaaie my datum en tyd in die verlangde formaat met ander karakters of teks kombineer:

   =CONCATENATE(TEXT(B2,"D MMM YYYY"),", ",TEXT(C2,"HH:MM:SS"))

Kombineer kolomme in Google Sheets

Met effense aanpassings is al die maniere wat ek genoem het in staat om kolomme in Google Sheets saam te voeg.

Voorbeeld 1. Google Sheets CONCAT

Om hele kolomme in Google Sheets met CONCAT saam te voeg, kies die hele reeks wat die resultaat moet bevat (C2:C11 in my geval) en voer jou formule-omvou in dit in ARRAYFORMULA:

=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))

Let wel. Jy kan die CONCATENATE-funksie gebruik, maar dit sal alle rekords binne een sel aansluit, aangesien dit maklik verskeie selle en datareekse saamsmelt.

Voorbeeld 2.Aaneenskakelingsoperateur

Skep skikkingsformules om kolomme in Google Blaaie te kombineer met die ampersand en voeg terselfdertyd skeiers by:

=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)

Dit lyk goed, maar ek moet 'n paar groot nadele uitwys.

As jy te veel kolomme het, kan die opsomming van almal 'n pyn in die nek word, veral as jy per ongeluk enige karakters oorslaan/dupliseer/vermeng .

As jy ook besluit om later meer kolomme by die formule te voeg, sal jy elke bestaande reeks in die formule met die hand moet wysig.

Die volgende voorbeeld los hierdie probleme op.

Voorbeeld 3. Google Sheets QUERY

Google Sheets QUERY-funksie is ook geskik om verskeie kolomme in Google Sheets saam te voeg. Kyk gerus:

=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))

Jy dink dalk hierdie vreemde formule is buite jou bereik, maar laat ek alles vir jou uitlê:

1. =TRANSPOSE(A2:D10) verander die rye data in kolomme.
2. =QUERY(TRANSPOSE(A2:D10),,9^9) voeg rekords in elke kolom saam na die top selle.

   Wenk. Wanneer ek 9^9 in die formule plaas, maak ek seker dat alle rye van alle kolomme in die eerste ry ingetrek sal word asof dit opskrifte is. Dit is 9^9 aangesien hierdie uitdrukking alle moontlike selle in die sigblad insluit (onthou jy die limiet vir 10M selle?) en is maklik om te onthou. :)

3. =TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9)) neem daardie kopry van QUERY en verander dit in 'n kolom soos dieeen wat ek het.

Hier is die voordele om kolomme in Google Blaaie saam te voeg deur QUERY te gebruik:

• jy hoef nie die hele kolom te kies soos jy doen nie vir skikkingsformules
• hoef jy nie elke kolom in die formule te noem nie, tensy hulle nie-aangrensend is nie. In hierdie geval, so sal die formule lyk:

  =TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

Skakel en voeg teks by posisie

Jy weet reeds dat jy ontbrekende teks, nommers kan byvoeg , en karakters na jou snare deur die CONCATENATE-funksie te gebruik.

Wenk. Sien meer formules daaroor in hierdie tutoriaal.

Maar as daar te veel rekords is om aan te sluit, kan enige ekstra karakters jou formule verder uitbrei as wat jy beplan het. In gevalle soos hierdie is dit beter om selle in Google Blaaie saam te voeg soos hulle is of eenvoudige afbakenings soos spasie te gebruik en die teks daarna by te voeg. 'n Spesiale hulpmiddel van ons sal jou help.

Voeg teks by volgens posisie voeg enige tekens en stringe in volgens die posisie wat jy spesifiseer, geen formules is nodig nie. Kom ek wys jou hoe dit werk.

In die vorige voorbeeld het QUERY name en telefoonnommers vir my aangesluit. Maar ek wil graag landafkortings byvoeg: (VSA/CA) voor telefoonnommers wat begin met +1 en VK voor +44 :

Verdeel selle in Google Sheets

As jy selle in Google Sheets kombineer, is die kans goed dat jy hulle een of ander tyd sal moet terugsplit . Daar is drie maniere om dit te doen:

1. Bou 'n formulegebruik Google Sheets SPLIT-funksie.
2. Gebruik die standaard sigbladinstrument – ​​Verdeel teks na kolomme.
3. Of probeer die verbeterde weergawe van die ingeboude nutsding – Verdeel teks na kolomme vir Google Sheets:

Dit laat jou toe om selle te verdeel deur enige skeidingsteken of selfs stelle skeiers, hulle as een te behandel en voegwoorde in te sluit indien nodig. Dit bied ook die opsie om selle in Google Sheets volgens posisie te verdeel.

Wenk. Daar is 'n opsie om data uit Google Blaaie-selle te onttrek eerder as om die inhoud te verdeel.

Hoe om selle in Google Blaaie sonder formules saam te voeg

As die bemeestering van verskillende formules nie deel van jou plan is nie, sal jy voordeel trek uit ons Merge Values-byvoeging. Die byvoeging sluit vinnig rekords in rye, kolomme of die hele reeks selle aan. Die opsies is glashelder, en al wat jy moet doen is om die reeks te kies en te besluit hoe die resultaat moet lyk.

1. Jy kan kies om kolomme te kombineer in Google Blaaie — selfs nie-aangrensendes, skei hulle met kommas en spasies, en plaas die resultaat regs van die oorspronklike rekords:

As jy belangstel in die instrument, kan jy kykdeur alles wat dit doen op hierdie spesiale bladsy of in hierdie kort video-tutoriaal:

Leer hoe om Kombineer duplikaatrye in hierdie video te gebruik :

Ek hoop jy het nou al besluit watter van die maniere die beste by jou geval pas. As jy enige ander metodes in gedagte het, deel asseblief met ons in die kommentaar afdeling hieronder :)