"Upojiti" obično znači povezati nešto zajedno u niz ili lanac. Ova se operacija koristi kad god trebate spojiti tekst iz više ćelija Google tablica. Ovaj članak prikuplja najpopularnija i najjednostavnija rješenja koja će vam pomoći riješiti zagonetku ulančavanja.

Koliko god velik bio vaš skup podataka, možete naići na zadatak kombiniranja više ćelija u Google tablicama. I ne sumnjam da ćete htjeti ne samo sačuvati sve vrijednosti od gubitka, već i dodati neke zareze, razmake ili druge znakove, ili čak odvojiti te zapise drugim tekstom.

Pa, proračunske tablice nude nekoliko alata za ovaj zadatak.

Funkcija CONCAT Google tablica

Funkcija CONCAT je pojednostavljena verzija CONCATENATE Google tablica:

Da biste spojili ćelije s ovom funkcijom, trebate navesti potrebne vrijednosti:

• vrijednost1 – zapis kojem treba dodati vrijednost2.
• vrijednost2 – vrijednost koju treba spojiti.

Da biste dobili jedan niz od 2 tekstualne ili numeričke jedinice, formula će izgledati ovako, sa svakim zapisom u dvostrukim navodnicima:

=CONCAT("2019:","The Lion King")

U stvarnosti su vaši podaci najvjerojatnije već u ćelijama. Možete se izravno pozvati na te ćelije umjesto da stavljate svaki broj ili tekst kao argument. Dakle, formula stvarnih podataka bit će ovakva:

=CONCAT(A2,B2)

Savjet. Da biste kopirali formulu u cijeli stupac, odaberite ćelijus formulom i dvaput kliknite kvadratić u donjem desnom kutu ćelije. Cijeli stupac će se automatski popuniti formulom, do samog kraja tablice.

Kao što možete vidjeti, funkcija je super jednostavna, ali ima velike slabe točke :

• spaja samo dvije ćelije u Google tablicama odjednom.
• ne može kombinirati stupce, retke ili druge velike raspone podataka, uzima samo pojedinačne ćelije. Ako pokušate spojiti više ćelija, ili ćete dobiti pogrešku ili će samo prve dvije vrijednosti biti spojene, ovako:

  =CONCAT(A2:A11,B2:B11)

  

CONCAT alternativa: operator ulančavanja ampersand (&)

Postoji mnogo različitih operatora za različite svrhe u formulama. Ulančavanje nije iznimka. Upotreba znaka ampersand (&) u formulama umjesto funkcije CONCAT pružit će vam isti rezultat:

=A2&B2

Ali malo što znate da je ovaj operator ulančavanja fleksibilniji. Evo što može učiniti:

1. Spoji više od dvije vrijednosti odjednom:

   =A2&B2&C2

   

2. Ne samo spojiti ćelije u Google tablicama, ali ih također odvojite raznim znakovima:

   =A2&" "&B2&"; "&C2

   

Ako i dalje ne dobijete željeni rezultat s ovim opcijama , postoji još jedna funkcija za isprobati.

Kako koristiti CONCATENATE u Google tablicama

Vjerujem da je funkcija CONCATENATE Google tablica prva koja se koristikada je u pitanju dodavanje nekoliko zapisa zajedno.

SPOJITE tekstualne nizove i brojeve u Google tablicama

Uzorak formule sastoji se od sljedećih argumenata:

• niz1 je prvi niz kojem želite dodati druge vrijednosti. Ovaj argument je obavezan.
• niz2, … označava sve druge nizove koje možda želite dodati. Ovaj argument nije obavezan.

Napomena. Zapis ishoda sastojat će se od nizova prema redoslijedu njihovog pojavljivanja u formuli.

Ako prilagodim formulu svojim podacima, dobit ću ovo:

=CONCATENATE(A2,B2,C2)

Ili, budući da funkcija prihvaća raspone:

=CONCATENATE(A2:D2)

Možete odmah primijetiti prvu prednost Google tablica CONCATENATE: lako spaja dvije ćelije s tekstom i brojevima.

Google tablice: spaja nizove s razdjelnicima

Kombiniranje ćelija u Google tablicama pola je posla. Ali da bi rezultat izgledao lijepo i čitljivo, trebali biste dodati neke dodatne znakove.

Ako zadržite formulu onakvom kakva jest, ona će samo spojiti sve zajedno: BonnieJacksonCA , BonnieJacksonIN , itd. Ali Google Sheets CONCATENATE također uzima znakove kao argumente.

Dakle, da biste dodali neke separatore za čitljivost, spomenite ih u dvostrukim navodnicima u formuli:

=CONCATENATE(A2," ",B2,", ",C2)

Ovdje želim spojiti A2 & B2 razmakom i odvojite B2 od C2 zarezom irazmak:

Slobodni ste koristiti gotovo bilo koji znak u ovakvoj funkciji, ali prijelom retka zahtijeva drugačiji pristup.

Savjet. U slučaju da postoje prazne ćelije u nekim od stupaca koje spajate, postoji još jedna funkcija koja bi vas mogla zanimati. TEXTJOIN ne samo da spaja ćelije u Google tablicama, već zanemaruje prazne:

=TEXTJOIN(" ",TRUE,A2:C2)

Evo kako to funkcionira:

1. Naznačite željeni graničnik kao prvi argument – ​​ razmak (" ") za mene.
2. Stavite TRUE kao drugi argument za preskakanje praznih ćelija ili FALSE za uključivanje u rezultat.
3. Unesite raspon za spajanje.

Spajanje s prijelomom retka u Google tablicama

Iako je očito kako unijeti većinu graničnika u funkciju, tamo ne možete upisati prijelom retka na isti način. Ali srećom, Google vam omogućuje da igrate mnogo različitih karata.

Postoji funkcija koja pomaže u dobivanju posebnih znakova – zove se CHAR. Vidite, svaki znak ima svoje mjesto u Unicode tablici. Samo trebate unijeti redni broj znaka iz te tablice u funkciju i ova će vratiti sam znak.

Evo formule za dobivanje prijeloma retka:

=CHAR(10)

Dodajte ga formuli za spajanje s prijelomom retka u Google tablicama:

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)

Kombinirajte datum i vrijeme u Google tablicama

Ako pokušate kombinirati datum i vrijeme u Google tablicama pomoću jedne od metodagore, neće raditi. Vaša će proračunska tablica vratiti brojeve:

Da biste ispravno kombinirali datum i vrijeme u Google tablicama, koristite funkciju TEXT:

• gdje je broj bilo koji broj, datum ili vrijeme koje želite dobiti u željenom formatu
• a format je obrazac koji želite vidjeti kao rezultat.

Savjet. U svom primjeru, referencirati ću ćelije s datumima i vremenima, ali možete slobodno koristiti jedinice datuma/vremena ili čak funkcije kao što su DATUM ili VRIJEME izravno u formuli.

1. Koristim prvu formulu TEKST za promjenu formata datuma iz 9.7.2019 u 9.srpnja 2019 :

   =TEXT(B2,"D MMM YYYY")

2. Drugi TEXT vraća vrijeme:

   =TEXT(C2,"HH:MM:SS")

3. Koristeći ih u CONCATENATE-u, Google tablice mi omogućuju kombiniranje datuma i vremena u željenom formatu s drugim znakovima ili tekstom:

   =CONCATENATE(TEXT(B2,"D MMM YYYY"),", ",TEXT(C2,"HH:MM:SS"))

Kombinirajte stupce u Google tablicama

Uz male prilagodbe, svi načini koje sam spomenuo mogu spojiti stupce u Google tablicama.

Primjer 1. Google tablice CONCAT

Da biste spojili cijele stupce u Google tablicama s CONCAT-om, odaberite cijeli raspon koji bi trebao sadržavati rezultat (C2:C11 u mom slučaju) i unesite prelamanje formule to u ARRAYFORMULA:

=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))

Napomena. Možete koristiti funkciju CONCATENATE, ali ona će spojiti sve zapise unutar jedne ćelije budući da jednostavno spaja više ćelija i raspona podataka.

Primjer 2.Operator ulančavanja

Stvorite formule niza za kombiniranje stupaca u Google tablicama pomoću znaka & i dodavanje separatora u isto vrijeme:

=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)

Ovo izgleda dobro, ali moram istaknuti neke velike nedostatke.

Ako imate previše stupaca, nabrajanje svih može postati bol u vratu, pogotovo ako slučajno preskočite/duplicirate/pomiješate znakove .

Također, ako kasnije odlučite dodati više stupaca u formulu, morat ćete ručno urediti svaki postojeći raspon u formuli.

Sljedeći primjer rješava ove probleme.

Primjer 3. QUERY Google tablica

Funkcija QUERY Google tablica također je prikladna za spajanje nekoliko stupaca u Google tablicama. Pogledajte:

=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))

Možda mislite da je ova čudna formula izvan vašeg razumijevanja, ali dopustite mi da vam iznesem sve dijelove:

1. =TRANSPOSE(A2:D10) pretvara retke podataka u stupce.
2. =QUERY(TRANSPOSE(A2:D10),,9^9) spaja zapise u svakom stupcu u gornje stanice.

   Savjet. Kad stavim 9^9 u formulu, osiguravam da će svi retci iz svih stupaca biti povučeni u prvi red kao da su zaglavlja. To je 9^9 jer ovaj izraz uključuje sve moguće ćelije u proračunskoj tablici (sjećate se ograničenja za 10M ćelija?) i lako ga je zapamtiti. :)

3. =TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9)) uzima taj redak zaglavlja iz QUERY i pretvara ga u stupac poputjedan imam.

Ovo su prednosti spajanja stupaca u Google tablicama pomoću QUERY:

• ne morate odabrati cijeli stupac kao što to činite za formule polja
• ne morate spominjati svaki stupac u formuli osim ako nisu susjedni. U ovom slučaju, evo kako će formula izgledati:

  =TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

  Vidi također: 12 popularnih funkcija Google tablica s gotovim formulama Google tablica

Spoji i dodaj tekst po poziciji

Već znaš da možeš dodati tekst koji nedostaje, brojeve , i znakove u nizove pomoću funkcije CONCATENATE.

Savjet. Pogledajte više formula o tome u ovom vodiču.

Ali ako postoji previše zapisa za spajanje, svi dodatni znakovi mogu proširiti vašu formulu daleko iznad onoga što ste planirali. U ovakvim slučajevima bolje je spojiti ćelije u Google tablicama kakve jesu ili koristiti jednostavne razdjelnike poput razmaka i dodati tekst nakon toga. Naš poseban alat će vam pomoći.

Dodavanje teksta po položaju umeće sve znakove i nizove po položaju koji navedete, nisu potrebne nikakve formule. Dopustite da vam pokažem kako radi.

U prethodnom primjeru QUERY je spojio imena i telefonske brojeve za mene. Ali želio bih dodati kratice zemalja: (SAD/CA) ispred telefonskih brojeva koji počinju s +1 i UK ispred +44 :

Razdijelite ćelije u Google tablicama

Ako kombinirate ćelije u Google tablicama, velike su šanse da ćete ih morati ponovo podijeliti u nekom trenutku . Postoje tri načina za to:

1. Izradite formulukoristeći Google Sheets SPLIT funkciju.
2. Koristite standardni instrument proračunske tablice – Podijeli tekst u stupce.
3. Ili isprobajte poboljšanu verziju ugrađenog alata – Podijeli tekst na stupce za Google Sheets:

Omogućuje vam da podijelite ćelije bilo kojim graničnikom ili čak skupom separatora, tretirajući ih kao jednu i uključujući veznike ako je potrebno. Također nudi opciju dijeljenja ćelija u Google tablicama po položaju.

Savjet. Postoji opcija izdvajanja podataka iz ćelija Google tablica umjesto dijeljenja sadržaja.

Kako spojiti ćelije u Google tablicama bez formula

Ako svladavanje različitih formula nije dio vašeg plana, iskoristite prednosti našeg dodatka Merge Values. Dodatak brzo spaja zapise u retke, stupce ili cijeli raspon ćelija. Njegove opcije su kristalno jasne, a sve što trebate učiniti je odabrati raspon i odlučiti kako bi rezultat trebao izgledati.

1. Možete odabrati kombinirati stupce u Google tablicama — čak i one koji nisu susjedni, odvojite ih zarezima i razmacima i postavite rezultat desno od originalnih zapisa:

Ako ste zainteresirani za alat, možete pogledatikroz sve što radi na ovoj posebnoj stranici ili u ovom kratkom video vodiču:

U ovom videu saznajte kako koristiti kombiniranje duplikata redaka :

Nadam se da ste do sada odlučili koji od načina najbolje odgovara vašem slučaju. Ako imate neke druge metode na umu, podijelite s nama u odjeljku za komentare ispod :)