"Konkateerimine" tähendab tavaliselt millegi ühendamist jadaks või ahelaks. Seda operatsiooni kasutatakse alati, kui teil on vaja ühendada teksti mitmest Google Sheetsi lahtrist. See artikkel kogub kokku kõige populaarsemad ja lihtsamad lahendused, mis aitavad teil lahendada konkateerimise mõistatust.

Ükskõik kui suur on teie andmekogum, võib teil tekkida ülesanne ühendada mitu lahtrit Google Sheetsis kokku. Ja ma ei kahtle, et te ei taha mitte ainult kõiki väärtusi kaotada, vaid lisada ka mõned komad, tühikud või muud tähemärgid või isegi eraldada need kirjed muu tekstiga.

Noh, arvutustabelid pakuvad selle ülesande täitmiseks mitmeid vahendeid.

Google Sheets CONCAT funktsioon

Funktsioon CONCAT on lihtsustatud versioon Google Sheetsi CONCATENATE funktsioonist:

Selle funktsiooniga lahtrite ühendamiseks peate loetlema nõutavad väärtused:

• väärtus1 - kirje, millele tuleks lisada väärtus2.
• value2 - väärtus, millega liituda.

Et saada 2 tekstist või numbrilisest üksusest üks string, näeb valem välja nagu allpool, kusjuures iga kirje on topeltlauseis:

=CONCAT("2019:", "Lõvikuningas")

Tegelikkuses on teie andmed tõenäoliselt juba lahtrites. Te võite viidata nendele lahtritele otse, selle asemel, et panna iga number või tekst argumendiks. Seega on tegelike andmete valem selline:

=CONCAT(A2,B2)

Vihje. Valemi kopeerimiseks kogu veergu, valige valemiga lahter ja tehke topeltklõps lahtri paremas alumises nurgas oleval väikesel ruudul. Kogu veerg täidetakse automaatselt valemiga, kuni tabeli lõpuni.

Nagu näete, on see funktsioon väga lihtne, kuid sellel on suured nõrgad kohad :

• see ühendab Google Sheetsis korraga ainult kaks lahtrit.
• ei saa ühendada veerge, ridu või muid suuri andmevahemikke, vaid ainult üksikuid lahtreid. Kui püüate ühendada mitu lahtrit, saate kas vea või ühendatakse ainult kaks esimest väärtust, näiteks nii:

  =CONCAT(A2:A11,B2:B11)

  

CONCAT alternatiiv: ühendamise operaator ampersand (&)

Valemites on palju erinevaid operaatoreid erinevatel eesmärkidel. Konkateerimine ei ole erand. Kasutades valemites ampersandi märki (&) funktsiooni CONCAT asemel, saate sama tulemuse:

=A2&B2

Kuid te ei tea, et see ühendamisoperaator on paindlikum. Siin on, mida ta saab teha:

1. Ühendage korraga rohkem kui kaks väärtust:

   =A2&B2&C2

   

2. Google Sheetsis mitte ainult lahtrite ühendamine, vaid ka nende eraldamine erinevate tähtedega:

   =A2&" "&B2&"; "&C2

   

Kui te ei saa nende valikutega ikka veel soovitud tulemust, siis on veel üks funktsioon, mida proovida.

Kuidas kasutada CONCATENATE'i Google Sheetsis

Ma usun, et Google Sheets CONCATENATE funktsioon on esimene, mida kasutada, kui tegemist on mitme kirje liitmisega kokku.

Tekstijoonte ja numbrite KONKATEERIMINE Google Sheetsis

Valemi muster koosneb järgmistest argumentidest:

• string1 on esimene string, millele soovite teisi väärtusi lisada. See argument on nõutav.
• string2, ... tähistab kõiki muid stringisid, mida võib-olla soovite lisada. See argument on vabatahtlik.

Märkus. Tulemuste kirje koosneb stringidest nende esinemise järjekorras valemis.

Kui ma kohandan valemi oma andmetega, saan ma selle:

=CONCATENATE(A2,B2,C2)

Või, kuna funktsioon aktsepteerib vahemikke:

=CONCATENATE(A2:D2)

Google Sheetsi CONCATENATE'i esimene eelis on kohe märgatav: see ühendab hõlpsasti üle kahe lahtri, kus on nii teksti kui ka numbreid.

Google Sheets: stringide ühendamine eraldajatega

Lahtrite ühendamine Google Sheetsis on pool tööd. Aga et tulemus näeks ilus ja loetav välja, peaksite lisama mõned lisatähised.

Kui te jätate valemi sellisena, nagu see on, siis liimib see lihtsalt kõik kokku: BonnieJacksonCA , BonnieJacksonIN , jne. Kuid Google Sheets CONCATENATE võtab argumentidena ka tähemärke.

Seega, et lisada loetavuse huvides mõned eraldusjooned, mainige need valemis kahekordsetes jutumärkides:

=CONCATENATE(A2," ",B2,", ",C2)

Siin ma tahan liita A2 & B2 tühikuga ja eraldada B2 ja C2 komaga ja tühikuga:

Te võite kasutada peaaegu kõiki sümboleid sellises funktsioonis, kuid reavahetuse puhul on vaja teistsugust lähenemist.

Vihje. Juhul, kui mõnes ühendatavas veerus on tühjad lahtrid, on veel üks funktsioon, mis võib teid huvitada. TEXTJOIN ei ühenda Google Sheetsis mitte lihtsalt lahtreid, vaid ignoreerib tühje lahtreid:

=TEXTJOIN(" ",TRUE,A2:C2)

See toimib järgmiselt:

1. Märkige esimese argumendina soovitud eraldaja - kosmos (" ") minu jaoks.
2. Pane TÕELINE teise argumendina tühjade lahtrite vahelejätmiseks või VALE lisada need tulemusse.
3. Sisestage ühendatav vahemik.

Sidumine koos reavahetusega Google'i lehtedel

Kuigi on ilmselge, kuidas sisestada enamikku eraldusjooni funktsiooni, ei saa sinna samamoodi sisestada reavahet. Aga õnneks laseb Google mängida palju erinevaid kaarte.

On olemas funktsioon, mis aitab saada erimärke - selle nimi on CHAR. Näed, igal märgil on koht Unicode'i tabelis. Sa pead lihtsalt sisestama selle tabeli märgi järjekorranumbri funktsioonile ja viimane tagastab märgi ise.

Siin on valem, et saada reavahe:

=CHAR(10)

Lisage see valemile, et seda Google Sheetsis reavahetusega liita:

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)

Kuupäeva ja kellaaja kombineerimine Google Sheetsis

Kui proovite Google Sheetsis kuupäeva ja kellaaega kombineerida, kasutades üht ülaltoodud meetodit, ei toimi see. Teie tabelis kuvatakse numbrid:

Kuupäeva ja kellaaja korrektseks ühendamiseks Google Sheetsis kasutage funktsiooni TEXT:

• kus number on mis tahes number, kuupäev või kellaaeg, mida soovite saada soovitud formaadis.
• ja formaat on see muster, mida te tahaksite selle tulemusena näha.

Vihje. Minu näites viitan ma kuupäevade ja kellaaegadega lahtritele, kuid te võite vabalt kasutada kuupäeva/aja ühikuid või isegi selliseid funktsioone nagu DATE või TIME otse valemis.

1. Ma kasutan esimest TEXT valemit, et muuta kuupäeva formaat alates 7/9/2019 aadressile 9 juuli 2019 :

   =TEXT(B2, "D MMM YYYY")

2. Teine TEXT tagastab aja:

   =TEXT(C2, "HH:MM:SS")

3. Kasutades neid CONCATENATE, võimaldab Google Sheets mul ühendada kuupäeva ja kellaaega soovitud formaadis teiste märkide või tekstiga:

   =CONCATENATE(TEXT(B2, "D MMM YYYY"),", ",TEXT(C2, "HH:MM:SS"))

Veergude kombineerimine Google Sheetsis

Väikeste kohandustega on kõik minu poolt mainitud viisid võimelised Google Sheetsis veerge ühendama.

Näide 1. Google Sheets CONCAT

Tervete veergude ühendamiseks Google Sheetsis CONCATiga valige kogu vahemik, mis peaks sisaldama tulemust (minu puhul C2:C11), ja sisestage oma valem, mis mähib selle ARRAYFORMULA-sse:

=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))

Märkus. Sa võid kasutada funktsiooni CONCATENATE, kuid see ühendab kõik kirjed ühes lahtris, kuna see liidab hõlpsasti mitu lahtrit ja andmevälja.

Näide 2. Konkateerimisoperaator

Loo massiivi valemid, et kombineerida Google Sheetsis veerge, kasutades ampersandi ja lisades samal ajal eraldajaid:

=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)

See näeb hea välja, kuid ma pean välja tooma mõned suured miinused.

Kui teil on liiga palju veerge, võib nende kõigi loetlemine muutuda tülikaks, eriti kui te kogemata jätate mõne tähemärgi vahele/dubleerite/segate kokku.

Samuti, kui otsustate hiljem lisada valemile rohkem veerge, peate iga olemasolevat vahemikku valemis käsitsi muutma.

Järgmine näide lahendab need probleemid.

Näide 3. Google Sheets QUERY

Google Sheets QUERY funktsioon sobib ka mitme veeru ühendamiseks Google Sheetsis. Vaadake:

=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))

Te võite arvata, et see kummaline valem on teile arusaamatu, kuid las ma panen teile selle kõik tükid selgeks:

1. =TRANSPOSE(A2:D10) muudab andmete read veergudeks.
2. =QUERY(TRANSPOSE(A2:D10),,9^9) ühendab kirjed igas veerus ülemisse lahtrisse.

   Vihje. Kui ma panen 9^9 valemisse, veendun, et kõik read kõigist veergudest tõmmatakse esimesse rea nagu pealkirjad. See on 9^9 kuna see väljendus hõlmab kõiki võimalikke lahtreid tabelis (mäletate 10M lahtri piirangut?) ja seda on lihtne meeles pidada :)

3. =TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9)) võtab selle päise rea QUERY-st ja muudab selle selliseks veeruks nagu mul on.

Siin on eelised ühendamine veerud Google Sheets kasutades QUERY:

• te ei pea valima kogu veergu, nagu massiivi valemite puhul.
• te ei pea iga veergu valemis mainima, välja arvatud juhul, kui need ei ole kõrvuti. Sellisel juhul näeb valem välja järgmine:

  =TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

Konkateerige ja lisage teksti positsioonide kaupa

Sa juba tead, et sa saad lisada oma stringidele puuduvat teksti, numbreid ja sümboleid, kasutades funktsiooni CONCATENATE.

Vihje. Vaata selle kohta rohkem valemeid selles õpetuses.

Kui aga ühendatavaid kirjeid on liiga palju, võib iga lisatähis teie valemit pikendada kaugemale, kui te planeerisite. Sellistel juhtudel on parem ühendada lahtrid Google Sheetsis sellisena, nagu nad on, või kasutada lihtsaid eraldajaid, nagu tühik, ja lisada tekst pärast seda. Meie spetsiaalne tööriist aitab teid.

Lisa tekst positsiooni järgi sisestab mis tahes märgid ja stringid määratud positsiooni järgi, mingeid valemeid ei ole vaja. Näitan teile, kuidas see töötab.

Eelmises näites QUERY ühendas minu jaoks nimed ja telefoninumbrid. Aga ma tahaksin lisada riikide lühendeid: (USA/CA) enne telefoninumbreid, mis algavad +1 ja UK enne +44 :

Google Sheets'i lahtrite jagamine

Kui ühendate Google Sheetsis lahtreid, on tõenäoline, et peate need mingil hetkel tagasi jagama. Selleks on kolm võimalust:

1. Koostage valem, kasutades Google Sheetsi SPLIT funktsiooni.
2. Kasutage standardset tabelarvutusinstrumenti - Jagage tekst veergudeks.
3. Või proovige sisseehitatud tööriista täiustatud versiooni - Split text to columns for Google Sheets:

See võimaldab jagada lahtreid mis tahes eraldaja või isegi eraldajate kogumi järgi, käsitledes neid kui ühte ja lisades vajaduse korral sidekohti. Samuti pakub see võimalust jagada lahtreid Google Sheetsis positsioonide järgi.

Vihje. Google Sheetsi lahtritest on võimalik andmeid ekstraheerida, mitte jagada nende sisu.

Kuidas ühendada lahtrid Google Sheetsis ilma valemiteta

Kui erinevate valemite valdamine ei ole teie plaanis, siis on teile kasulik meie lisavõimalus Merge Values. Lisavõimalus ühendab kiiresti kirjed ridades, veergudes või kogu rakkude vahemikus. Selle valikud on kristallselged ja kõik, mida te peate tegema, on valida vahemik ja otsustada, kuidas tulemus peaks välja nägema.

1. Saate valida, kas ühendada veerud Google Sheetsis - isegi mitte-erinevad, eraldage need komadega ja tühikutega ning paigutage tulemus algsetest kirjetest paremale:

Kui olete selle tööriista vastu huvi tundnud, saate vaadata kõike, mida see teeb, sellel erilehel või selles lühikeses videoõpetuses:

Selles videos saate teada, kuidas kasutada dubleerivate ridade kombineerimist:

Loodan, et olete nüüdseks otsustanud, milline viis sobib teie puhul kõige paremini. Kui teil on meeles mõni muu meetod, palun jagage seda meiega allpool kommentaaride sektsioonis :)