"Konkatenacija" obično znači povezati nešto zajedno u nizu ili lancu. Ova operacija se koristi kad god trebate spojiti tekst iz više ćelija Google Sheets. Ovaj članak prikuplja najpopularnija i najjednostavnija rješenja koja će vam pomoći da riješite zagonetku spajanja.

Koliko god vaš skup podataka bio velik, možda ćete naići na zadatak kombiniranja više ćelija u Google tablicama zajedno. I ne sumnjam da ćete htjeti ne samo spriječiti gubitak svih vrijednosti, već i dodati neke zareze, razmake ili druge znakove, ili čak odvojiti te zapise drugim tekstom.

Pa, proračunske tablice nude nekoliko alata za ovaj zadatak.

Google Sheets CONCAT funkcija

Funkcija CONCAT je pojednostavljena verzija Google Sheets CONCATENATE:

Da biste pridružili ćelije ovom funkcijom, morate navesti potrebne vrijednosti:

• vrijednost1 – zapis kojem treba dodati vrijednost2.
• value2 – vrijednost za spajanje.

Da biste dobili jedan niz od 2 tekstualne ili numeričke jedinice, formula će izgledati kao ispod, sa svakim zapisom u dvostrukim navodnicima:

=CONCAT("2019:","The Lion King")

U stvarnosti, vaši podaci su najvjerovatnije već u ćelijama. Možete se direktno pozivati ​​na te ćelije umjesto da zapisujete svaki broj ili tekst kao argument. Dakle, formula stvarnih podataka će biti ovakva:

=CONCAT(A2,B2)

Savjet. Da biste kopirali formulu u cijeli stupac, odaberite ćelijusa formulom i dvaput kliknite na mali kvadrat u donjem desnom uglu ćelije. Cijela kolona će se automatski popuniti formulom, do samog kraja tabele.

Kao što vidite, funkcija je super jednostavna, ali ima velikih slabih tačaka :

• spaja samo dvije ćelije u Google tablicama istovremeno.
• ne može kombinovati kolone, redove ili druge velike opsege podataka, uzima samo pojedinačne ćelije. Ako pokušate spojiti više ćelija, ili ćete dobiti grešku ili će se spojiti samo prve dvije vrijednosti, ovako:

  =CONCAT(A2:A11,B2:B11)

  

CONCAT alternativa: ampersand operatora konkatenacije (&)

Postoji mnogo različitih operatora za različite svrhe u formulama. Konkatenacija nije izuzetak. Korištenje znaka ampersand (&) u formulama umjesto funkcije CONCAT pružit će vam isti rezultat:

=A2&B2

Ali malo znate da je ovaj operator konkatenacije fleksibilniji. Evo šta može učiniti:

1. Spajanje više od dvije vrijednosti istovremeno:

   =A2&B2&C2

   

2. Ne samo spajanje ćelija u Google Sheets, ali ih i razdvojite raznim znakovima:

   =A2&" "&B2&"; "&C2

   

Ako i dalje ne dobijete željeni rezultat sa ovim opcijama , postoji još jedna funkcija koju treba isprobati.

Kako koristiti CONCATENATE u Google Sheets

Vjerujem da je funkcija Google Sheets CONCATENATE prva koja se koristikada se radi o dodavanju nekoliko zapisa zajedno.

KONKATENIRAJ tekstualne nizove i brojeve u Google Sheets

Obrazac formule sastoji se od sljedećih argumenata:

• string1 je prvi niz kojem želite dodati druge vrijednosti. Ovaj argument je obavezan.
• string2, … označava sve ostale nizove koje možda želite da dodate. Ovaj argument nije obavezan.

Napomena. Zapis o ishodu će se sastojati od nizova po redoslijedu njihovog pojavljivanja u formuli.

Ako prilagodim formulu svojim podacima, dobit ću ovo:

=CONCATENATE(A2,B2,C2)

Ili, pošto funkcija prihvaća raspone:

=CONCATENATE(A2:D2)

Odmah možete primijetiti prvu prednost Google Sheets CONCATENATE: lako se spaja preko dvije ćelije s tekstom i brojevima.

Google Sheets: spajanje nizova sa separatorima

Kombinovanje ćelija u Google tabelama je pola posla. Ali da bi rezultat izgledao lijepo i čitljivo, trebali biste dodati nekoliko dodatnih znakova.

Ako zadržite formulu kakva jeste, ona će samo zalijepiti sve zajedno: BonnieJacksonCA , BonnieJacksonIN , itd. Ali Google Sheets CONCATENATE također uzima znakove kao argumente.

Dakle, da biste dodali neke separatore radi čitljivosti, spomenite ih u dvostrukim navodnicima u formuli:

=CONCATENATE(A2," ",B2,", ",C2)

Ovdje želim spojiti A2 & B2 sa razmakom i B2 od C2 odvojite zarezom irazmak:

Možete koristiti skoro svaki znak u ovoj funkciji, ali prijelom reda zahtijeva drugačiji pristup.

Savjet. U slučaju da postoje prazne ćelije u nekim od kolona koje spajate, postoji još jedna funkcija koja bi vas mogla zanimati. TEXTJOIN ne samo da spaja ćelije u Google tablicama, već zanemaruje prazna mjesta:

=TEXTJOIN(" ",TRUE,A2:C2)

Evo kako to funkcionira:

1. Navedite željeni graničnik kao prvi argument – ​​ razmak (" ") za mene.
2. Stavite TRUE kao drugi argument za preskakanje praznih ćelija ili FALSE da ih uključite u rezultat.
3. Unesite raspon za spajanje.

Konkatenacija s prijelomom reda u Google Sheets

Iako je očigledno kako unijeti većinu graničnika u funkciju, tamo ne možete upisati prijelom reda na isti način. Ali, srećom, Google vam omogućava da igrate mnogo različitih karata.

Postoji funkcija koja pomaže da dobijete posebne znakove – zove se CHAR. Vidite, svaki znak ima svoje mjesto u Unicode tabeli. Vi samo trebate unijeti redni broj znaka iz te tablice u funkciju i ova će vratiti sam znak.

Evo formule za dobivanje prijeloma reda:

=CHAR(10)

Dodajte ga u formulu za spajanje s prijelomom reda u Google Sheets:

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)

Kombinirajte datum i vrijeme u Google Sheets

Ako pokušate kombinirati datum i vrijeme u Google Sheets koristeći jedan od metodagore, neće raditi. Vaša tabela će vratiti brojeve:

Da biste pravilno kombinovali datum i vrijeme u Google tablicama, koristite funkciju TEXT:

• gdje je broj bilo koji broj, datum ili vrijeme koje želite dobiti u željenom formatu
• a format je obrazac koji želite vidjeti kao rezultat.

Savjet. U mom primjeru, ja ću referencirati ćelije s datumima i vremenima, ali možete slobodno koristiti jedinice datuma/vremena ili čak funkcije kao što su DATUM ili VRIJEME direktno u formuli.

1. Koristim prvu TEXT formulu da promijenim format datuma iz 9.7.2019 u 9. jul 2019 :

   =TEXT(B2,"D MMM YYYY")

2. Drugi TEKST vraća vrijeme:

   =TEXT(C2,"HH:MM:SS")

3. Upotrebom ovih u CONCATENATE, Google Sheets mi omogućava da kombiniram datum i vrijeme u željenom formatu s drugim znakovima ili tekstom:

   =CONCATENATE(TEXT(B2,"D MMM YYYY"),", ",TEXT(C2,"HH:MM:SS"))

Kombinujte kolone u Google Sheets

Uz mala podešavanja, svi načini koje sam spomenuo mogu spojiti kolone u Google Sheets.

Primjer 1. Google Sheets CONCAT

Da spojite cijele stupce u Google Sheets sa CONCAT, odaberite cijeli raspon koji bi trebao sadržavati rezultat (C2:C11 u mom slučaju) i unesite svoj omotač formule to u ARRAYFORMULI:

=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))

Napomena. Možete koristiti funkciju CONCATENATE, ali ona će spojiti sve zapise unutar jedne ćelije jer lako spaja više ćelija i raspona podataka.

Primjer 2.Operator konkatenacije

Kreirajte formule niza za kombiniranje stupaca u Google tablicama koristeći znak ampersanda i dodajte separatore u isto vrijeme:

=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)

Ovo izgleda dobro, ali moram istaći neke velike nedostatke.

Ako imate previše kolona, ​​njihovo nabrajanje može postati bol u vratu, posebno ako slučajno preskočite/duplicirate/pomiješate bilo koje znakove .

Također, ako kasnije odlučite dodati još kolona formuli, morat ćete ručno urediti svaki postojeći raspon u formuli.

Sljedeći primjer rješava ove probleme.

Primjer 3. Google Sheets QUERY

Google Sheets QUERY funkcija je također pogodna za spajanje nekoliko kolona u Google Sheets. Pogledajte:

=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))

Možda mislite da je ova čudna formula izvan vašeg razumijevanja, ali dozvolite mi da vam izložim sve njene dijelove:

1. =TRANSPOSE(A2:D10) pretvara redove podataka u kolone.
2. =QUERY(TRANSPOSE(A2:D10),,9^9) spaja zapise u svakoj koloni u gornje ćelije.

   Savjet. Kada stavim 9^9 u formulu, uvjeravam se da će svi redovi iz svih kolona biti povučeni u prvi red kao da su zaglavlja. To je 9^9 jer ovaj izraz uključuje sve moguće ćelije u proračunskoj tabeli (sjećate li se ograničenja za 10M ćelija?) i lako se pamti. :)

3. =TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9)) uzima taj red zaglavlja iz QUERY i pretvara ga u stupac kao što jejedan koji imam.

Evo prednosti spajanja kolona u Google tablicama pomoću QUERY:

• ne morate odabrati cijelu kolonu kao što to radite za formule niza
• ne morate spominjati svaki stupac u formuli osim ako nisu susjedni. U ovom slučaju, evo kako će formula izgledati:

  =TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

  Vidi_takođe: Kako otkriti listove u Excelu: prikažite više ili sve skrivene listove

Konkatenirajte i dodajte tekst po poziciji

Već znate da možete dodati tekst koji nedostaje, brojeve , i znakove u vaše stringove pomoću funkcije CONCATENATE.

Savjet. Pogledajte više formula o tome u ovom vodiču.

Ali ako ima previše zapisa za pridruživanje, bilo koji dodatni znakovi mogu proširiti vašu formulu daleko od onoga što ste planirali. U ovakvim slučajevima, bolje je spojiti ćelije u Google Sheets kakve jesu ili koristiti jednostavne graničnike poput razmaka i dodati tekst nakon toga. Naš poseban alat će vam pomoći.

Dodavanje teksta po poziciji umeće sve znakove i nizove prema poziciji koju odredite, formule nisu potrebne. Dozvolite mi da vam pokažem kako to funkcionira.

U prethodnom primjeru QUERY mi je spojio imena i brojeve telefona. Ali želim dodati kratice zemalja: (SAD/CA) prije brojeva telefona koji počinju sa +1 i UK prije +44 :

Podijelite ćelije u Google tablicama

Ako kombinirate ćelije u Google tablicama, velike su šanse da ćete ih morati ponovno podijeliti u nekom trenutku . Postoje tri načina da to učinite:

1. Napravite formulupomoću funkcije Google Sheets SPLIT.
2. Koristite standardni instrument za proračunske tablice – Podijelite tekst na stupce.
3. Ili isprobajte poboljšanu verziju ugrađenog alata – Podijelite tekst na stupce za Google Sheets:

Omogućuje vam da podijelite ćelije bilo kojim graničnikom ili čak skupovima separatora, tretirajući ih kao jedno i uključujući veznike ako je potrebno. Također nudi opciju podjele ćelija u Google Sheets prema poziciji.

Savjet. Postoji opcija za izdvajanje podataka iz ćelija Google Sheets umjesto podjele sadržaja.

Kako spojiti ćelije u Google Sheets bez formula

Ako savladavanje različitih formula nije dio vašeg plana, vi ćete iskoristite naš dodatak Merge Values. Dodatak brzo spaja zapise u redove, kolone ili cijeli raspon ćelija. Njegove opcije su kristalno jasne, a sve što trebate učiniti je odabrati raspon i odlučiti kako bi rezultat trebao izgledati.

1. Možete odabrati da kombinujete stupce u Google Sheets — čak i one koji nisu susjedni, odvojite ih zarezima i razmacima, a rezultat postavite desno od originalnih zapisa:

Ako ste zainteresovani za alat, možete pogledatikroz sve što radi na ovoj posebnoj stranici ili u ovom kratkom video tutorijalu:

Naučite kako koristiti Kombiniraj duplirane redove u ovom videu :

Nadam se da ste do sada odlučili koji od načina najbolje odgovara vašem slučaju. Ako imate bilo kakve druge metode na umu, podijelite ih s nama u odeljku za komentare ispod :)