"Concatenate" biasanya berarti menautkan sesuatu bersama-sama dalam satu rangkaian atau rantai. Operasi ini digunakan setiap kali Anda perlu menggabungkan teks dari beberapa sel Google Sheets. Artikel ini mengumpulkan solusi paling populer dan mudah untuk membantu Anda memecahkan teka-teki penggabungan.

Seberapa pun besarnya dataset Anda, Anda mungkin menemukan tugas untuk menggabungkan beberapa sel di Google Sheets bersama-sama. Dan saya yakin Anda tidak hanya ingin menjaga semua nilai agar tidak hilang, tetapi juga menambahkan beberapa koma, spasi, atau karakter lain, atau bahkan memisahkan catatan tersebut dengan teks lain.

Nah, spreadsheet menawarkan beberapa alat bantu untuk tugas ini.

Fungsi CONCAT Google Sheets

Fungsi CONCAT adalah versi sederhana dari Google Sheets CONCATENATE:

Untuk menggabungkan sel dengan fungsi ini, Anda perlu membuat daftar nilai yang diperlukan:

• nilai1 - catatan di mana nilai2 harus ditambahkan.
• nilai2 - nilai untuk bergabung.

Untuk mendapatkan satu string dari 2 unit teks atau numerik, rumusnya akan terlihat seperti di bawah ini, dengan setiap record dalam tanda kutip ganda:

=CONCAT("2019:", "The Lion King")

Pada kenyataannya, data kamu kemungkinan besar sudah ada dalam cell. Kamu bisa mereferensikan cell-cell tersebut secara langsung daripada meletakkan setiap angka atau teks sebagai argumen. Jadi rumus data nyatanya akan menjadi seperti ini:

=CONCAT(A2,B2)

Tip. Untuk menyalin rumus Anda ke seluruh kolom, pilih sel dengan rumus dan klik dua kali kotak kecil di sudut kanan bawah sel. Seluruh kolom akan secara otomatis terisi dengan rumus, sampai akhir tabel.

Seperti yang bisa Anda lihat, fungsi ini sangat sederhana, tetapi memiliki titik lemah :

• itu hanya menggabungkan dua sel di Google Sheets pada satu waktu.
• tidak dapat menggabungkan kolom, baris, atau rentang data besar lainnya, hanya dibutuhkan sel tunggal. Jika Anda mencoba menggabungkan beberapa sel, Anda akan mendapatkan kesalahan atau hanya dua nilai pertama yang akan digabungkan, seperti ini:

  =CONCAT(A2:A11,B2:B11)

  

Alternatif CONCAT: operator penggabungan ampersand (&)

Ada banyak operator berbeda untuk berbagai tujuan dalam rumus. Penggabungan bukan pengecualian. Menggunakan karakter ampersand (&) dalam rumus alih-alih fungsi CONCAT akan memberi Anda hasil yang sama:

= A2 & amp; B2

Tetapi sedikit yang Anda ketahui bahwa operator penggabungan ini lebih fleksibel. Berikut ini apa yang bisa dilakukannya:

1. Menggabungkan lebih dari dua nilai sekaligus:

   = A2 & amp; B2 & amp; C2

   

2. Tidak hanya menggabungkan sel di Google Sheets, tetapi juga memisahkannya dengan berbagai karakter:

   =A2&" "&B2&"; "&C2

   

Jika Anda masih belum mendapatkan hasil yang diinginkan dengan opsi-opsi ini, masih ada satu fungsi lagi untuk dicoba.

Cara menggunakan CONCATENATE di Google Sheets

Saya percaya fungsi Google Sheets CONCATENATE adalah yang pertama digunakan ketika harus menambahkan beberapa catatan bersama.

MENGGABUNGKAN string teks dan angka di Google Sheets

Pola rumus terdiri dari argumen berikut:

• string1 adalah string pertama yang ingin Anda tambahkan nilai lain. Argumen ini diperlukan.
• string2, ... adalah singkatan dari semua string lain yang mungkin ingin Anda tambahkan. Argumen ini bersifat opsional.

Catatan. Catatan hasil akan terdiri dari string-string sesuai urutan kemunculannya dalam formula.

Jika saya mengadaptasi rumus ke data saya, saya akan mendapatkan ini:

=CONCATENATE(A2,B2,C2)

Atau, karena fungsi menerima rentang:

=CONCATENATE(A2:D2)

Anda dapat segera melihat keuntungan pertama dari Google Sheets CONCATENATE: dengan mudah menggabungkan lebih dari dua sel dengan teks dan angka.

Google Sheets: menggabungkan string dengan pemisah

Menggabungkan sel di Google Spreadsheet adalah setengah dari pekerjaan. Tetapi untuk membuat hasilnya terlihat cantik dan mudah dibaca, Anda harus menambahkan beberapa karakter tambahan.

Jika Anda mempertahankan formula apa adanya, ini hanya akan merekatkan semuanya: BonnieJacksonCA , BonnieJacksonIN , dll. Tetapi Google Sheets CONCATENATE juga mengambil karakter sebagai argumen.

Jadi, untuk menambahkan beberapa pemisah agar mudah dibaca, sebutkan dalam tanda kutip ganda dalam rumus:

=CONCATENATE(A2," ",B2,", ",C2)

Di sini saya ingin menggabungkan A2 & B2 dengan spasi dan memisahkan B2 dari C2 dengan koma dan spasi:

Anda bebas menggunakan hampir semua karakter dalam fungsi seperti ini, namun jeda baris memerlukan pendekatan yang berbeda.

Tip. Jika ada sel kosong di beberapa kolom yang Anda gabungkan, ada satu fungsi lagi yang mungkin Anda minati. TEXTJOIN tidak hanya menggabungkan sel di Google Sheets tetapi juga mengabaikan kekosongan:

=TEXTJOIN(" ", TRUE, A2: C2)

Begini cara kerjanya:

1. Tunjukkan pembatas yang diinginkan sebagai argumen pertama - ruang (" ") untuk saya.
2. Taruh BENAR sebagai argumen kedua untuk melewati sel kosong atau SALAH untuk menyertakan mereka dalam hasil.
3. Masukkan kisaran yang akan digabungkan.

Gabungkan dengan jeda baris di Google Sheets

Meskipun sudah jelas bagaimana cara memasukkan sebagian besar pembatas ke fungsi tersebut, Anda tidak dapat mengetikkan pemisah baris dengan cara yang sama di sana. Tapi untungnya Google memungkinkan Anda memainkan banyak kartu yang berbeda.

Ada fungsi yang membantu untuk mendapatkan karakter khusus - namanya CHAR. Anda lihat, setiap karakter memiliki tempat di tabel Unicode. Anda hanya perlu memasukkan nomor urut karakter dari tabel itu ke fungsi dan fungsi itu akan mengembalikan karakter itu sendiri.

Berikut ini rumus untuk mendapatkan jeda baris:

=CHAR(10)

Tambahkan ke rumus untuk digabungkan dengan jeda baris di Google Sheets:

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)

Gabungkan tanggal dan waktu di Google Sheets

Jika Anda mencoba menggabungkan tanggal dan waktu di Google Spreadsheet menggunakan salah satu metode di atas, itu tidak akan berhasil. Spreadsheet Anda akan mengembalikan angka:

Untuk menggabungkan tanggal dan waktu di Google Sheets dengan benar, gunakan fungsi TEXT:

• di mana nomor adalah angka, tanggal, atau waktu yang ingin Anda dapatkan dalam format yang diinginkan
• dan format adalah pola yang ingin Anda lihat sebagai hasilnya.

Tip. Dalam contoh saya, saya akan mereferensikan sel dengan tanggal dan waktu, tetapi Anda bebas menggunakan unit tanggal/waktu atau bahkan fungsi seperti TANGGAL atau WAKTU secara langsung dalam rumus.

1. Saya menggunakan rumus TEXT pertama untuk mengubah format tanggal dari 7/9/2019 untuk 9 Jul 2019 :

   =TEXT(B2, "D MMM YYYY")

2. TEXT kedua mengembalikan waktu:

   =TEXT(C2, "HH:MM:SS")

3. Dengan menggunakan ini di CONCATENATE, Google Sheets memungkinkan saya menggabungkan tanggal dan waktu dalam format yang diinginkan dengan karakter atau teks lain:

   =CONCATENATE(TEXT(B2, "D MMM YYYY"),", ",TEXT(C2, "HH:MM:SS"))

Menggabungkan kolom di Google Sheets

Dengan sedikit penyesuaian, semua cara yang saya sebutkan mampu menggabungkan kolom di Google Sheets.

Contoh 1. Google Sheets CONCAT

Untuk menggabungkan seluruh kolom di Google Sheets dengan CONCAT, pilih seluruh rentang yang seharusnya berisi hasilnya (C2: C11 dalam kasus saya) dan masukkan rumus Anda yang membungkusnya dalam ARRAYFORMULA:

=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))

Catatan. Anda bisa menggunakan fungsi CONCATENATE, tetapi ini akan menggabungkan semua rekaman dalam satu sel karena dengan mudah menggabungkan beberapa sel dan rentang data.

Contoh 2. Operator penggabungan

Buat rumus array untuk menggabungkan kolom di Google Sheets menggunakan ampersand dan tambahkan pemisah pada saat yang bersamaan:

=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)

Ini terlihat bagus, tetapi saya harus menunjukkan beberapa kekurangan utama.

Jika Anda memiliki terlalu banyak kolom, mencacah semuanya bisa menjadi sangat merepotkan, khususnya jika Anda secara tidak sengaja melewatkan/menduplikasi/mencampuradukkan karakter apa pun.

Selain itu, jika Anda memutuskan untuk menambahkan lebih banyak kolom ke rumus nanti, Anda harus mengedit setiap rentang yang ada dalam rumus secara manual.

Contoh berikutnya memecahkan masalah ini.

Contoh 3. Google Sheets QUERY

Fungsi Google Sheets QUERY juga cocok untuk menggabungkan beberapa kolom di Google Sheets. Lihatlah:

=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))

Anda mungkin berpikir bahwa formula aneh ini berada di luar jangkauan Anda, tetapi izinkan saya memaparkan semua bagiannya untuk Anda:

1. =TRANSPOSE(A2:D10) mengubah baris data menjadi kolom.
2. =QUERY(TRANSPOSE(A2:D10),,9^9) menggabungkan record di setiap kolom ke sel teratas.

   Tip. Ketika saya menaruh 9^9 ke dalam rumus, saya pastikan semua baris dari semua kolom akan ditarik ke baris pertama seolah-olah mereka adalah header. 9^9 karena ekspresi ini mencakup semua sel yang mungkin ada di spreadsheet (ingat batas untuk 10M sel?) dan mudah diingat. :)

3. =TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))) mengambil baris header itu dari QUERY dan mengubahnya menjadi kolom seperti yang saya dapatkan.

Berikut adalah keuntungan dari penggabungan kolom di Google Sheets menggunakan QUERY:

• Anda tidak perlu memilih seluruh kolom seperti yang Anda lakukan untuk rumus array
• Anda tidak perlu menyebutkan setiap kolom dalam rumusnya kecuali jika kolom-kolom tersebut tidak berdekatan. Dalam kasus ini, berikut adalah bagaimana rumusnya akan terlihat:

  =TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

Menggabungkan dan menambahkan teks berdasarkan posisi

Anda sudah tahu bahwa Anda dapat menambahkan teks, angka, dan karakter yang hilang ke string Anda menggunakan fungsi CONCATENATE.

Tip. Lihat lebih banyak rumus tentang itu dalam tutorial ini.

Tetapi jika ada terlalu banyak catatan untuk digabungkan, karakter tambahan apa pun dapat memperpanjang rumus Anda jauh melampaui apa yang telah Anda rencanakan. Dalam kasus seperti ini, lebih baik menggabungkan sel di Google Sheets sebagaimana adanya atau menggunakan pembatas sederhana seperti spasi dan menambahkan teks setelah itu. Alat khusus kami akan membantu Anda.

Tambahkan teks berdasarkan posisi menyisipkan karakter dan string apa pun berdasarkan posisi yang Anda tentukan, tidak diperlukan rumus. Izinkan saya menunjukkan cara kerjanya.

Pada contoh sebelumnya QUERY menggabungkan nama dan nomor telepon untuk saya. Tetapi saya ingin menambahkan singkatan negara: (AMERIKA SERIKAT/CA) sebelum nomor telepon yang dimulai dengan +1 dan INGGRIS sebelum +44 :

Membagi sel di Google Sheets

Jika Anda menggabungkan sel di Google Spreadsheet, kemungkinan besar Anda perlu memisahkannya kembali di beberapa titik. Ada tiga cara untuk melakukannya:

1. Buat rumus menggunakan fungsi SPLIT Google Sheets.
2. Gunakan instrumen spreadsheet standar - Pisahkan teks ke kolom.
3. Atau coba versi yang disempurnakan dari alat bawaan - Pisahkan teks ke kolom untuk Google Sheets:

Ini memungkinkan Anda membagi sel dengan pembatas apa pun atau bahkan set pemisah, memperlakukannya sebagai satu dan termasuk konjungsi jika perlu. Ini juga menawarkan opsi untuk membagi sel di Google Sheets berdasarkan posisi.

Tip. Ada opsi untuk mengekstrak data dari sel Google Sheets daripada membagi isinya.

Cara menggabungkan sel di Google Sheets tanpa rumus

Jika menguasai berbagai rumus bukan bagian dari rencana Anda, Anda akan mendapatkan keuntungan dari add-on Merge Values kami. Add-on ini dengan cepat menggabungkan catatan dalam baris, kolom, atau seluruh rentang sel. Pilihannya sangat jelas, dan yang harus Anda lakukan hanyalah memilih rentang dan memutuskan bagaimana hasilnya akan terlihat.

1. Anda dapat memilih untuk menggabungkan kolom di Google Sheets - bahkan yang tidak berdekatan, pisahkan dengan koma dan spasi, dan letakkan hasilnya di sebelah kanan catatan asli:

Jika Anda tertarik dengan alat ini, Anda bisa melihat semua yang dilakukannya pada halaman khusus ini atau dalam video tutorial singkat ini:

Pelajari cara menggunakan Gabungkan Baris Duplikat dalam video ini:

Saya harap sekarang Anda telah memutuskan cara mana yang paling sesuai dengan kasus Anda. Jika Anda memiliki metode lain dalam pikiran Anda, silakan berbagi dengan kami di bagian komentar di bawah :)