"Lidh" zakonisht do të thotë të lidhësh diçka së bashku në një seri ose një zinxhir. Ky operacion përdoret sa herë që ju duhet të bashkoni tekst nga disa qeliza të Fletëve të Google. Ky artikull mbledh zgjidhjet më të njohura dhe më të lehta për t'ju ndihmuar të zgjidhni enigmën e lidhjes.

Sado i madh të jetë grupi juaj i të dhënave, mund të hasni në detyrën e kombinimit të disa qelizave në Fletët e Google së bashku. Dhe nuk kam dyshim se ju do të dëshironi jo vetëm që të mos humbni të gjitha vlerat, por gjithashtu të shtoni disa presje, hapësira ose karaktere të tjera, apo edhe t'i ndani ato regjistrime me tekst tjetër.

Epo, tabelat ofrojnë disa mjete për këtë detyrë.

Funksioni CONCAT i Fletëve Google

Funksioni CONCAT është një version i thjeshtuar i Fletëve Google CONCATENATE:

Për të bashkuar qelizat me këtë funksion, duhet të listoni vlerat e kërkuara:

• vlera1 – një rekord të cilit duhet t'i bashkëngjitet vlera2.
• vlera2 – vlera për t'u bashkuar.

Për të marrë një varg nga 2 njësi teksti ose numerike, formula do të duket si më poshtë, me çdo rekord në thonjëza të dyfishta:

=CONCAT("2019:","The Lion King")

Në realitet, të dhënat tuaja ka shumë të ngjarë tashmë në qeliza. Ju mund t'u referoheni atyre qelizave drejtpërdrejt në vend që të vendosni çdo numër ose tekst si argument. Pra, formula e të dhënave reale do të jetë si kjo:

=CONCAT(A2,B2)

Këshillë. Për të kopjuar formulën tuaj në të gjithë kolonën, zgjidhni qelizënme formulën dhe klikoni dy herë katrorin e vogël në këndin e poshtëm djathtas të qelizës. E gjithë kolona do të plotësohet automatikisht me formulën, deri në fund të tabelës.

Siç mund ta shihni, funksioni është shumë i thjeshtë, por ka pika të dobëta kryesore :

• bashkon vetëm dy qeliza në Fletët e Google në të njëjtën kohë.
• nuk mund të kombinojë kolona, ​​rreshta ose vargje të tjera të mëdha të të dhënave, merr vetëm qeliza të vetme. Nëse përpiqeni të bashkoni disa qeliza, ose do të merrni një gabim ose do të bashkohen vetëm dy vlerat e para, si kjo:

  =CONCAT(A2:A11,B2:B11)

  

Alternativa CONCAT: ampersand i operatorit të bashkimit (&)

Ka shumë operatorë të ndryshëm për qëllime të ndryshme në formula. Lidhja nuk është përjashtim. Përdorimi i një karakteri ampersand (&) në formula në vend të funksionit CONCAT do t'ju japë të njëjtin rezultat:

=A2&B2

Por pak dini se ky operator i lidhjes është më fleksibël. Ja çfarë mund të bëjë:

1. Të bashkojë më shumë se dy vlera në të njëjtën kohë:

   =A2&B2&C2

   

2. Jo vetëm të bashkojë qelizat në Google Sheets, por edhe ndani ato me karaktere të ndryshme:

   =A2&" "&B2&"; "&C2

   

Nëse ende nuk e merrni rezultatin e dëshiruar me këto opsione , ka një funksion tjetër për të provuar.

Si të përdoret CONCATENATE në Fletët e Google

Unë besoj se funksioni i Fletëve të Google CONCATENATE është i pari që përdoretkur bëhet fjalë për shtimin e disa rekordeve së bashku.

KONCATENATE vargjet dhe numrat e tekstit në Fletët e Google

Modeli i formulës përbëhet nga argumentet e mëposhtme:

• string1 është vargu i parë që dëshironi të shtoni vlera të tjera. Ky argument kërkohet.
• string2, … qëndron për të gjitha vargjet e tjera që mund të dëshironi të shtoni. Ky argument është opsional.

Shënim. Regjistrimi i rezultateve do të përbëhet nga vargjet sipas rendit të paraqitjes së tyre në formulë.

Nëse e përshtat formulën me të dhënat e mia, do të marr këtë:

=CONCATENATE(A2,B2,C2)

Ose, pasi funksioni pranon intervalet:

=CONCATENATE(A2:D2)

Mund të vëreni menjëherë avantazhin e parë të Fletëve të Google CONCATENATE: ai bashkohet lehtësisht mbi dy qeliza si me tekst ashtu edhe me numra.

Fletët e Google: lidh vargjet me ndarës

Kombinimi i qelizave në Fletët e Google është gjysma e punës. Por që rezultati të duket i bukur dhe i lexueshëm, duhet të shtoni disa karaktere shtesë.

Nëse e mbani formulën siç është, ajo thjesht do të ngjitë gjithçka së bashku: BonnieJacksonCA , BonnieJacksonIN , etj. Por Google Sheets CONCATENATE merr edhe karaktere si argumente.

Kështu, për të shtuar disa ndarës për lexueshmëri, përmendini ato në thonjëza të dyfishta në formulën:

=CONCATENATE(A2," ",B2,", ",C2)

Këtu dua të bashkoj A2 & B2 me hapësirë ​​dhe ndani B2 nga C2 me presje dhehapësirë:

Ju jeni të lirë të përdorni pothuajse çdo karakter në funksionin si ky, megjithatë një ndërprerje e linjës kërkon një qasje të ndryshme.

Këshillë. Në rast se ka qeliza boshe në disa nga kolonat që po bashkoni, ka një funksion tjetër për të cilin mund të jeni të interesuar. TEXTJOIN jo thjesht bashkon qelizat në Fletët e Google, por injoron boshllëqet:

=TEXTJOIN(" ",TRUE,A2:C2)

Ja se si funksionon:

1. Tregoni përcaktuesin e dëshiruar si argument të parë – hapësirë (" ") për mua.
2. Vendos E VËRTETË si një argument i dytë për të kapërcyer qelizat bosh ose FALSE për t'i përfshirë ato në rezultat.
3. Fut intervalin për t'u bashkuar.

Lidhja me ndërprerjen e linjës në Fletët e Google

Ndërsa është e qartë se si të futni shumicën e ndarësve në funksion, nuk mund të shkruani një ndërprerje rreshti në të njëjtën mënyrë atje. Por, për fat të mirë, Google ju lejon të luani shumë letra të ndryshme.

Ka një funksion që ndihmon për të marrë karaktere të veçanta – quhet CHAR. E shihni, çdo personazh ka një vend në tabelën Unicode. Thjesht duhet të futni numrin rendor të karakterit nga ajo tabelë në funksion dhe ky i fundit do të kthejë vetë karakterin.

Këtu është një formulë për të marrë ndarjen e rreshtit:

=CHAR(10)

Shtojeni atë në formulë për t'u lidhur me ndërprerjen e linjës në Fletët e Google:

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)

Kombinoni datën dhe kohën në Fletët e Google

Nëse përpiqeni të kombinoni datën dhe orën në Fletët e Google duke përdorur një nga metodatmë lart, nuk do të funksionojë. Tabela juaj do të kthejë numrat:

Për të kombinuar saktë datën dhe kohën në Fletët e Google, përdorni funksionin TEXT:

• ku numri është çdo numër, datë ose orë që dëshironi të merrni në formatin e dëshiruar
• dhe format është modeli që dëshironi të shih si rezultat.

Këshillë. Në shembullin tim, unë do t'i referohem qelizave me data dhe orë, por ju jeni të lirë të përdorni njësitë e datës/kohës apo edhe funksione të tilla si DATE ose TIME direkt në formulë.

1. Unë përdor formulën e parë TEXT për të ndryshuar formatin e datës nga 7/9/2019 në 9 korrik 2019 :

   =TEXT(B2,"D MMM YYYY")

2. TEXT-i i dytë kthen kohën:

   =TEXT(C2,"HH:MM:SS")

3. Duke përdorur këto në CONCATENATE, Google Sheets më lejon të kombinoj datën dhe kohën në formatin e dëshiruar me karaktere ose tekst të tjerë:

   =CONCATENATE(TEXT(B2,"D MMM YYYY"),", ",TEXT(C2,"HH:MM:SS"))

Kombinoni kolonat në Fletët e Google

Me rregullime të vogla, të gjitha mënyrat që përmenda janë në gjendje të bashkojnë kolonat në Fletët e Google.

Shembull 1. Fletët e Google CONCAT

Për të bashkuar kolona të tëra në Fletët e Google me CONCAT, zgjidhni të gjithë gamën që duhet të përmbajë rezultatin (C2:C11 në rastin tim) dhe futni mbështjelljen tuaj të formulës atë në ARRAYFORMULA:

=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))

Shënim. Mund të përdorni funksionin CONCATENATE, por ai do të bashkojë të gjitha regjistrimet brenda një qelize pasi bashkon lehtësisht shumë qeliza dhe diapazon të dhënash.

Shembulli 2.Operatori i bashkimit

Krijo formula grupi për të kombinuar kolonat në Fletët e Google duke përdorur ampersand dhe shtoni ndarës në të njëjtën kohë:

=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)

Kjo duket mirë, por më duhet të theksoj disa kundër të mëdha.

Nëse keni shumë kolona, ​​numërimi i të gjithave mund të bëhet një dhimbje në qafë, veçanërisht nëse aksidentalisht kapërceni/kopjoni/përzieni ndonjë karakter .

Gjithashtu, nëse vendosni të shtoni më shumë kolona në formulë më vonë, do t'ju duhet të modifikoni manualisht çdo varg ekzistues në formulë.

Shembulli tjetër i zgjidh këto probleme.

Shembulli 3. Fletët e Google QUERY

Funksioni i Fletëve të Google QUERY është gjithashtu i përshtatshëm për të bashkuar disa kolona në Fletët e Google. Hidhini një sy:

=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))

Ju mund të mendoni se kjo formulë e çuditshme është përtej zotërimit tuaj, por më lejoni t'ju tregoj të gjitha pjesët e saj:

1. =TRANSPOSE(A2:D10) i kthen rreshtat e të dhënave në kolona.
2. =QUERY(TRANSPOSE(A2:D10),,9^9) bashkon të dhënat në secilën kolonë në qelizat e sipërme.

   Këshillë. Kur vendos 9^9 në formulë, sigurohem që të gjitha rreshtat nga të gjitha kolonat të tërhiqen në rreshtin e parë sikur të ishin kokë. Është 9^9 pasi kjo shprehje përfshin të gjitha qelizat e mundshme në fletëllogaritëse (e mbani mend kufirin për 10 milion qeliza?) dhe është e lehtë për t'u mbajtur mend. :)

3. =TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9)) merr atë rreshtin e kokës nga QUERY dhe e kthen atë në një kolonë sinjë që kam.

Këtu janë përfitimet e bashkimit të kolonave në Fletët e Google duke përdorur QUERY:

• nuk keni nevojë të zgjidhni të gjithë kolonën siç bëni për formulat e vargjeve
• nuk keni nevojë të përmendni secilën kolonë në formulë nëse nuk janë të afërta. Në këtë rast, ja se si do të duket formula:

  =TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

Lidhni dhe shtoni tekst sipas pozicionit

Ju tashmë e dini se mund të shtoni tekst që mungon, numra , dhe karaktere në vargjet tuaja duke përdorur funksionin CONCATENATE.

Këshillë. Shihni më shumë formula për këtë në këtë tutorial.

Por nëse ka shumë regjistrime për t'u bashkuar, çdo karakter shtesë mund ta zgjerojë formulën tuaj përtej asaj që keni planifikuar. Në raste të tilla, është më mirë të bashkoni qelizat në Google Sheets ashtu siç janë ose të përdorni ndarës të thjeshtë si hapësira dhe të shtoni tekstin pas kësaj. Një mjet i yni i veçantë do t'ju ndihmojë.

Shtoni tekst sipas pozicionit, çdo karakter dhe varg sipas pozicionit që specifikoni, nuk nevojiten formula. Më lejoni t'ju tregoj se si funksionon.

Në shembullin e mëparshëm QUERY bashkoi emrat dhe numrat e telefonit për mua. Por unë do të doja të shtoja shkurtesat e shteteve: (SHBA/CA) përpara numrave të telefonit që fillojnë me +1 dhe UK përpara +44 :

Ndani qelizat në Fletët e Google

Nëse kombinoni qelizat në Fletët e Google, shanset janë që do t'ju duhet t'i ndani ato përsëri në një moment . Ka tre mënyra për ta bërë këtë:

1. Ndërtoni një formulëduke përdorur funksionin SPLIT të Fletëve të Google.
2. Përdor instrumentin standard të fletëllogaritjes – Ndani tekstin në kolona.
3. Ose provoni versionin e përmirësuar të mjetit të integruar – Ndani tekstin në kolona për Fletët e Google:

Kjo ju lejon të ndani qelizat me çdo kufizues apo edhe grupe ndarësish, duke i trajtuar ato si një dhe duke përfshirë lidhëzat nëse është e nevojshme. Ai gjithashtu ofron mundësinë për të ndarë qelizat në Fletët e Google sipas pozicionit.

Këshillë. Ekziston një opsion për të nxjerrë të dhëna nga qelizat e "Fletëve të Google" në vend që të ndash përmbajtjen.

Si të bashkoni qelizat në "Fletët e Google" pa formula

Nëse zotërimi i formulave të ndryshme nuk është pjesë e planit tuaj, do përfitoni nga shtesa jonë Merge Values. Shtesa bashkon shpejt regjistrimet në rreshta, kolona ose të gjithë gamën e qelizave. Opsionet e tij janë të qarta, dhe gjithçka që duhet të bëni është të zgjidhni gamën dhe të vendosni se si duhet të duket rezultati.

1. Mund të zgjidhni të kombinoni kolonat në Fletët e Google — edhe ato që nuk janë ngjitur, ndajini ato me presje dhe hapësira dhe vendoseni rezultatin në të djathtë të regjistrimeve origjinale:

Nëse jeni të interesuar për mjetin, mund të shikonipërmes gjithçkaje që bën në këtë faqe të veçantë ose në këtë udhëzues të shkurtër video:

Mësoni se si të përdorni Kombinoni rreshtat e dublikuar në këtë video :

Shpresoj që deri tani të keni vendosur se cila nga mënyrat i përshtatet më mirë rastit tuaj. Nëse keni ndonjë metodë tjetër në mendje, ju lutemi ndani me ne në seksionin e komenteve më poshtë :)