Mae "concatenate" fel arfer yn golygu cysylltu rhywbeth â'i gilydd mewn cyfres neu gadwyn. Defnyddir y llawdriniaeth hon pryd bynnag y bydd angen i chi ymuno â thestun o sawl cell Google Sheets. Mae'r erthygl hon yn casglu'r atebion mwyaf poblogaidd a hawdd i'ch helpu i ddatrys y pos cydgadwyneiddio.

Pa mor fawr yw eich set ddata, efallai y byddwch yn dod ar draws y dasg o gyfuno celloedd lluosog yn Google Sheets gyda'i gilydd. Ac nid oes gennyf unrhyw amheuaeth y byddwch nid yn unig am gadw pob gwerth rhag colli, ond hefyd ychwanegu rhai atalnodau, bylchau, neu nodau eraill, neu hyd yn oed wahanu'r cofnodion hynny â thestun arall.

Wel, mae taenlenni'n cynnig sawl teclyn ar gyfer y dasg hon.

Fwythiant CONCAT Google Sheets

Mae'r ffwythiant CONCAT yn fersiwn symlach o Google Sheets CONCATENATE:

I ymuno â chelloedd â'r ffwythiant hwn, mae angen i chi restru'r gwerthoedd gofynnol:

• value1 – cofnod y dylid atodi gwerth2 iddo.
• gwerth2 – y gwerth i ymuno.

I gael un llinyn o 2 destun neu uned rifol, bydd y fformiwla yn edrych fel isod, gyda phob cofnod mewn dyfynodau dwbl:

=CONCAT("2019:","The Lion King")

Mewn gwirionedd, mae eich data fwy na thebyg eisoes mewn celloedd. Gallwch gyfeirio at y celloedd hynny yn uniongyrchol yn lle rhoi pob rhif neu destun i lawr fel dadl. Felly bydd y fformiwla data real fel hyn:

=CONCAT(A2,B2)

>

Awgrym. I gopïo'ch fformiwla i'r golofn gyfan, dewiswch y gellgyda'r fformiwla a dwbl-gliciwch y sgwâr bach yng nghornel dde isaf y gell. Bydd y golofn gyfan yn cael ei llenwi'n awtomatig â'r fformiwla, tan ddiwedd y tabl.

Fel y gwelwch, mae'r ffwythiant yn hynod o syml, ond mae ganddi pwyntiau gwan mawr :

> mae'n uno dim ond dwy gell yn Google Sheets ar y tro.<9
• ni all gyfuno colofnau, rhesi, nac ystodau data mawr eraill, dim ond celloedd sengl y mae'n eu cymryd. Os ceisiwch ymuno â chelloedd lluosog, byddwch naill ai'n cael gwall neu dim ond y ddau werth cyntaf a fydd yn cael eu huno, fel hyn:

  =CONCAT(A2:A11,B2:B11)

  

Dewis amgen CONCAT: gweithredwr concatenation ampersand (&)

Mae llawer o weithredwyr gwahanol at wahanol ddibenion mewn fformiwlâu. Nid yw concatenation yn eithriad. Bydd defnyddio nod ampersand (&) mewn fformiwlâu yn lle'r ffwythiant CONCAT yn rhoi'r un canlyniad i chi:

=A2&B2

Ond ychydig wyddoch chi bod y gweithredwr concatenation hwn yn fwy hyblyg. Dyma beth y gall ei wneud:

1. Uno mwy na dau werth ar y tro:

   =A2&B2&C2

   

Nid dim ond uno celloedd yn Google Sheets, ond hefyd gwahanwch nhw gyda nodau amrywiol:

=A2&" "&B2&"; "&C2

Os nad ydych yn dal i gael y canlyniad dymunol gyda'r opsiynau hyn , mae un ffwythiant arall i geisio.

Sut i ddefnyddio CONCATENATE yn Google Sheets

Credaf mai swyddogaeth CONCATENATE Google Sheets yw'r un gyntaf i'w defnyddiopan ddaw'n fater o atodi sawl cofnod at ei gilydd.

Llinynnau testun CONCATENATE a rhifau yn Google Sheets

Mae patrwm y fformiwla yn cynnwys y dadleuon canlynol:

• llinyn1 yw'r llinyn cyntaf yr ydych am atodi gwerthoedd eraill iddo. Mae angen y ddadl hon.
• llinyn2, ... yn sefyll am bob llinyn arall efallai yr hoffech ei atodi. Mae'r arg hon yn ddewisol.

Sylwch. Bydd y cofnod canlyniad yn cynnwys y llinynnau yn nhrefn eu hymddangosiad yn y fformiwla.

Os byddaf yn addasu'r fformiwla i'm data, byddaf yn cael hyn:

=CONCATENATE(A2,B2,C2)

Neu, gan fod y ffwythiant yn derbyn ystodau:

=CONCATENATE(A2:D2)

Gallwch sylwi ar unwaith ar fantais gyntaf Google Sheets CONCATENATE: mae'n ymuno'n hawdd dros ddwy gell gyda thestun a rhifau.

Talenni Google: cydgatenate llinynnau gyda gwahanyddion

Mae cyfuno celloedd yn Google Sheets yn hanner y gwaith. Ond i wneud i'r canlyniad edrych yn bert a darllenadwy, dylech ychwanegu rhai nodau ychwanegol.

Os ydych yn cadw'r fformiwla fel y mae, bydd yn gludo popeth at ei gilydd: BonnieJacksonCA , BonnieJacksonIN , ac ati. Ond mae Google Sheets CONCATENATE yn cymryd nodau fel dadleuon hefyd.

Felly, i ychwanegu rhai gwahanyddion er mwyn eu darllen, soniwch amdanynt mewn dyfynodau dwbl yn y fformiwla:

=CONCATENATE(A2," ",B2,", ",C2)

Yma rydw i eisiau cydgadwynu A2 & B2 gyda gofod a B2 ar wahân i C2 gyda choma aspace:

Rydych yn rhydd i ddefnyddio bron unrhyw nod yn y ffwythiant fel hyn, ond eto mae toriad llinell yn gofyn am ddull gwahanol.

Awgrym. Rhag ofn bod celloedd gwag yn rhai o'r colofnau rydych chi'n eu cyfuno, mae un swyddogaeth arall efallai y bydd gennych chi ddiddordeb ynddi. Mae TEXTJOIN nid yn unig yn uno celloedd yn Google Sheets ond yn anwybyddu bylchau:

=TEXTJOIN(" ",TRUE,A2:C2)

Dyma sut mae'n gweithio:

1. Nodwch y amffinydd dymunol fel dadl gyntaf – gofod (" ") i mi.
2. Rhowch TRUE fel ail arg i hepgor celloedd gwag neu FALSE i'w cynnwys yn y canlyniad.
3. Rhowch yr amrediad i uno.

20> Cydgadwynwch â toriad llinell yn Google Sheets

Er ei bod yn amlwg sut i nodi'r rhan fwyaf o amffinyddion i'r swyddogaeth, ni allwch deipio toriad llinell yr un ffordd yno. Ond yn ffodus mae Google yn gadael i chi chwarae llawer o wahanol gardiau.

Mae yna swyddogaeth sy'n helpu i gael nodau arbennig - fe'i gelwir yn CHAR. Rydych chi'n gweld, mae gan bob cymeriad le yn y tabl Unicode. Does ond angen bwydo rhif trefnol y nod o'r tabl hwnnw i'r ffwythiant a bydd yr olaf yn dychwelyd y nod ei hun.

Dyma fformiwla i gael y toriad llinell:

=CHAR(10) <3

Ychwanegwch ef at y fformiwla i gydgadwynu â'r toriad llinell yn Google Sheets:

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)

Cyfunwch ddyddiad ac amser yn Google Sheets<21

Os ceisiwch gyfuno dyddiad ac amser yn Google Sheets gan ddefnyddio un o'r dulliauuchod, ni fydd yn gweithio. Bydd eich taenlen yn dychwelyd rhifau:

I gyfuno dyddiad ac amser yn Google Sheets yn gywir, defnyddiwch y ffwythiant TEXT:

=TEXT(rhif, fformat)

8>lle mae rhif yn unrhyw rif, dyddiad, neu amser yr hoffech ei gael yn y fformat dymunol
• a fformat yw'r patrwm yr hoffech ei gael gweld o ganlyniad.

Awgrym. Yn fy enghraifft, rydw i'n mynd i gyfeirio celloedd gyda dyddiadau ac amseroedd, ond rydych chi'n rhydd i ddefnyddio unedau dyddiad / amser neu hyd yn oed swyddogaethau o'r fath fel DYDDIAD neu AMSER yn uniongyrchol yn y fformiwla.

1. Rwy'n defnyddio'r fformiwla TESTUN cyntaf i newid y fformat dyddiad o 7/9/2019 i 9 Gorff 2019 :

   =TEXT(B2,"D MMM YYYY")

2. Mae'r ail DESTUN yn dychwelyd yr amser:

   =TEXT(C2,"HH:MM:SS")

3. Gan ddefnyddio'r rhain yn CONCATENATE, mae Google Sheets yn gadael i mi gyfuno dyddiad ac amser yn y fformat dymunol gyda nodau neu destun eraill:

   =CONCATENATE(TEXT(B2,"D MMM YYYY"),", ",TEXT(C2,"HH:MM:SS"))

Cyfuno colofnau yn Google Sheets

Gyda mân addasiadau, mae'r holl ffyrdd y soniais amdanynt yn gallu uno colofnau yn Google Sheets.

Enghraifft 1. Google Sheets CONCAT

I uno colofnau cyfan yn Google Sheets â CONCAT, dewiswch yr ystod gyfan a ddylai gynnwys y canlyniad (C2:C11 yn fy achos i) a rhowch eich fformiwla lapio ei fod yn ARRAYFORMULA:

=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))

Nodyn. Gallech ddefnyddio'r swyddogaeth CONCATENATE, ond bydd yn ymuno â'r holl gofnodion o fewn un gell gan ei fod yn uno celloedd lluosog ac ystodau data yn hawdd.

Enghraifft 2.Gweithredwr cydgadwynu

Creu fformiwlâu arae i gyfuno colofnau yn Google Sheets gan ddefnyddio'r ampersand ac ychwanegu gwahanyddion ar yr un pryd:

=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)

Mae hyn yn edrych yn dda, ond mae'n rhaid i mi dynnu sylw at rai anfanteision mawr.

Os oes gennych ormod o golofnau, gall eu rhifo i gyd ddod yn boen yn y gwddf, yn enwedig os byddwch yn hepgor/dyblygu/cymysgu unrhyw nodau yn ddamweiniol. .

Hefyd, os penderfynwch ychwanegu mwy o golofnau i'r fformiwla yn ddiweddarach, bydd yn rhaid i chi olygu pob ystod sy'n bodoli yn y fformiwla â llaw.

Mae'r enghraifft nesaf yn datrys y problemau hyn.

Enghraifft 3. Google Sheets QUERY

Mae swyddogaeth Google Sheets QUERY hefyd yn addas i uno sawl colofn yn Google Sheets. Edrychwch:

=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))

Efallai eich bod yn meddwl bod y fformiwla ryfedd hon y tu hwnt i'ch gafael, ond gadewch i mi osod ei holl ddarnau allan i chi:<3

1. =Mae TRANSPOSE(A2:D10) yn troi'r rhesi data yn golofnau.
2. =QUERY(TRANSPOSE(A2:D10),,9^9) yn cyfuno cofnodion ym mhob colofn i'r celloedd uchaf.

   Awgrym. Pan fyddaf yn rhoi 9^9 yn y fformiwla, rwy'n gwneud yn siŵr y bydd pob rhes o bob colofn yn cael ei thynnu i mewn i'r rhes gyntaf fel pe baent yn benawdau. Mae'n 9^9 gan fod yr ymadrodd hwn yn cynnwys pob cell bosibl yn y daenlen (cofiwch y terfyn ar gyfer celloedd 10M?) ac mae'n hawdd ei gofio. :)

3. =TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9)) yn cymryd y rhes pennyn honno o QUERY ac yn ei throi'n golofn fel yun sydd gennyf.

Dyma fanteision cyfuno colofnau yn Google Sheets gan ddefnyddio QUERY:

• nid oes angen i chi ddewis y golofn gyfan fel y gwnewch ar gyfer fformiwlâu arae
• nid oes angen i chi sôn am bob colofn yn y fformiwla oni bai eu bod heb fod yn gyfagos. Yn yr achos hwn, dyma sut y bydd y fformiwla yn edrych:

  =TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

Cydgadwynu ac ychwanegu testun fesul safle

Rydych eisoes yn gwybod y gallwch ychwanegu testun coll, rhifau , a nodau i'ch tannau gan ddefnyddio'r ffwythiant CONCATENATE.

Awgrym. Gweler mwy o fformiwlâu ar hynny yn y tiwtorial hwn.

Ond os oes gormod o gofnodion i ymuno â nhw, gall unrhyw nodau ychwanegol ymestyn eich fformiwla ymhell y tu hwnt i'r hyn rydych wedi'i gynllunio. Mewn achosion fel hyn, mae'n well uno celloedd yn Google Sheets fel y maent neu ddefnyddio amffinyddion syml fel gofod ac ychwanegu'r testun ar ôl hynny. Bydd teclyn arbennig o'n un ni yn eich helpu chi.

Mae ychwanegu testun wrth safle yn mewnosod unrhyw nodau a llinynnau wrth y safle rydych chi'n ei nodi, does dim angen fformiwlâu. Gadewch i mi ddangos i chi sut mae'n gweithio.

Yn yr enghraifft flaenorol ymunodd QUERY enwau a rhifau ffôn i mi. Ond hoffwn ychwanegu byrfoddau gwlad: (UDA/CA) cyn rhifau ffôn sy'n dechrau gyda +1 a UK cyn +44 :

Rhannu celloedd yn Google Sheets

Os ydych chi'n cyfuno celloedd yn Google Sheets, mae'n debygol y bydd angen i chi eu rhannu'n ôl rywbryd . Mae tair ffordd o wneud hynny:

1. Adeiladu fformiwlagan ddefnyddio swyddogaeth Google Sheets SPLIT.
2. Defnyddiwch yr offeryn taenlen safonol – Rhannwch destun i golofnau.
3. Neu rhowch gynnig ar y fersiwn uwch o'r offeryn adeiledig - Rhannu testun i golofnau ar gyfer Google Sheets:

Mae'n gadael i chi hollti celloedd gan unrhyw amffinydd neu hyd yn oed setiau o wahanyddion, gan eu trin fel un a chynnwys cysyllteiriau os oes angen. Mae hefyd yn cynnig yr opsiwn i rannu celloedd yn Google Sheets yn ôl safle.

Awgrym. Mae opsiwn i dynnu data o gelloedd Google Sheets yn hytrach na rhannu'r cynnwys.

Sut i uno celloedd yn Google Sheets heb fformiwlâu

Os nad yw meistroli gwahanol fformiwlâu yn rhan o'ch cynllun, fe fyddwch elwa o'n hychwanegiad Gwerthoedd Cyfuno. Mae'r ychwanegiad yn ymuno'n gyflym â chofnodion mewn rhesi, colofnau, neu'r ystod gyfan o gelloedd. Mae ei opsiynau'n gwbl glir, a'r cyfan sydd angen i chi ei wneud yw dewis yr ystod a phenderfynu sut y dylai'r canlyniad edrych.

1. Gallwch ddewis cyfuno colofnau yn Google Sheets — hyd yn oed y rhai nad ydynt yn gyfagos, gwahanwch nhw gyda choma a bylchau, a rhowch y canlyniad i'r dde o'r cofnodion gwreiddiol:

Os oes gennych ddiddordeb yn yr offeryn, gallwch edrychtrwy bopeth y mae'n ei wneud ar y dudalen arbennig hon neu yn y tiwtorial fideo byr hwn:

Dysgwch sut i ddefnyddio Cyfuno Rhesi Dyblyg yn y fideo hwn :

Rwy'n gobeithio erbyn hyn eich bod wedi penderfynu pa un o'r ffyrdd sy'n gweddu orau i'ch achos. Os oes gennych unrhyw ddulliau eraill mewn golwg, rhannwch gyda ni yn yr adran sylwadau isod :)