"Concatenate" معمولاً به معنای پیوند دادن چیزی به یکدیگر در یک سری یا یک زنجیره است. این عملیات هر زمان که نیاز به پیوستن متن از چندین سلول Google Sheets داشته باشید استفاده می شود. این مقاله محبوب‌ترین و آسان‌ترین راه‌حل‌ها را جمع‌آوری می‌کند تا به شما در حل معمای الحاق کمک کند.

هر چقدر مجموعه داده شما بزرگ باشد، ممکن است با وظیفه ترکیب چندین سلول در Google Sheets مواجه شوید. و من شک ندارم که شما نه تنها می خواهید همه مقادیر را از دست ندهید، بلکه برخی از کاماها، فاصله ها یا کاراکترهای دیگر را نیز اضافه کنید، یا حتی آن رکوردها را با متن دیگر جدا کنید.

خب، صفحات گسترده چندین ابزار ارائه می دهند. برای این کار.

عملکرد CONCAT کاربرگ‌نگار Google

عملکرد CONCAT یک نسخه ساده شده از Google Sheets CONCATENATE است:

برای پیوستن به سلول‌ها با این تابع، باید مقادیر مورد نیاز را فهرست کنید:

• value1 - رکوردی که مقدار2 باید به آن اضافه شود.
• value2 – مقداری که باید به آن ملحق شد.

برای به دست آوردن یک رشته از 2 متن یا واحد عددی، فرمول به شکل زیر خواهد بود و هر رکورد در دو گیومه است:

=CONCAT("2019:","The Lion King")

در واقع، داده های شما به احتمال زیاد در حال حاضر در سلول ها هستند. شما می توانید به جای قرار دادن هر عدد یا متن به عنوان آرگومان، مستقیماً به آن سلول ها مراجعه کنید. بنابراین فرمول داده واقعی به این صورت خواهد بود:

=CONCAT(A2,B2)

نکته. برای کپی فرمول خود در کل ستون، سلول را انتخاب کنیدبا فرمول و مربع کوچک در گوشه سمت راست پایین سلول دوبار کلیک کنید. کل ستون به طور خودکار با فرمول، تا انتهای جدول پر می شود.

همانطور که می بینید، عملکرد فوق العاده ساده است، اما دارای نقاط ضعف عمده :

• در هر بار تنها دو سلول را در برگه های Google ادغام می کند.
• نمی‌تواند ستون‌ها، ردیف‌ها یا سایر محدوده‌های کلان داده را ترکیب کند، فقط سلول‌های تکی را می‌گیرد. اگر سعی کنید چندین سلول را به هم بپیوندید، یا با خطا مواجه می شوید یا فقط دو مقدار اول به هم متصل می شوند، مانند این:

  =CONCAT(A2:A11,B2:B11)

  

جایگزین CONCAT: آمپرسند عملگر الحاق (&)

عملگرهای مختلف زیادی برای اهداف مختلف در فرمول ها وجود دارد. الحاق یک استثنا نیست. استفاده از یک کاراکتر آمپرسند (&) در فرمول ها به جای تابع CONCAT نتیجه یکسانی را برای شما به ارمغان می آورد:

=A2&B2

اما کمی می دانید که این عملگر الحاق انعطاف پذیرتر است. کاری که می تواند انجام دهد این است:

1. بیش از دو مقدار را در یک زمان ادغام کنید:

   =A2&B2&C2

   

2. نه فقط سلول ها را ادغام کنید در Google Sheets، اما همچنین آنها را با کاراکترهای مختلف جدا کنید:

   =A2&" "&B2&"; "&C2

   

اگر هنوز با این گزینه ها به نتیجه دلخواه نرسیدید ، یک تابع دیگر وجود دارد که باید امتحان کنید.

نحوه استفاده از CONCATENATE در کاربرگ‌نگار Google

به اعتقاد من تابع Google Sheets CONCATENATE اولین موردی است که استفاده می‌کندوقتی نوبت به الحاق چندین رکورد به هم می رسد.

CONCATENATE رشته های متنی و اعداد در Google Sheets

الگوی فرمول از آرگومان های زیر تشکیل شده است:

• string1 اولین رشته ای است که می خواهید مقادیر دیگری را به آن اضافه کنید. این آرگومان مورد نیاز است.
• string2, … مخفف تمام رشته های دیگری است که ممکن است بخواهید اضافه کنید. این آرگومان اختیاری است.

توجه داشته باشید. رکورد نتیجه شامل رشته ها به ترتیب ظاهر آنها در فرمول خواهد بود.

اگر فرمول را با داده های خود تطبیق دهم، این را دریافت خواهم کرد:

=CONCATENATE(A2,B2,C2)

یا، چون تابع محدوده ها را می پذیرد:

=CONCATENATE(A2:D2)

می‌توانید فوراً متوجه اولین مزیت کاربرگ‌نگار Google CONCATENATE شوید: به راحتی به دو سلول با متن و اعداد متصل می‌شود.

کاربرگ‌نگار Google: رشته‌ها را با جداکننده‌ها به هم متصل می‌کند

ترکیب سلول‌ها در Google Sheets نیمی از کار است. اما برای اینکه نتیجه زیبا و خوانا به نظر برسد، باید چند کاراکتر اضافی اضافه کنید.

اگر فرمول را همانطور که هست نگه دارید، فقط همه چیز را به هم می چسباند: BonnieJacksonCA ، BonnieJacksonIN و غیره. اما Google Sheets CONCATENATE کاراکترها را نیز به عنوان آرگومان می گیرد.

بنابراین، برای افزودن چند جداکننده برای خوانایی، آنها را در دو نقل قول در فرمول ذکر کنید:

=CONCATENATE(A2," ",B2,", ",C2)

در اینجا می‌خواهم A2 & B2 با فاصله و جدا B2 از C2 با کاما وspace:

شما آزاد هستید که تقریباً از هر کاراکتری در تابعی مانند این استفاده کنید، اما شکست خط نیاز به رویکرد متفاوتی دارد.

نکته. اگر سلول‌های خالی در برخی از ستون‌هایی که ادغام می‌کنید وجود داشته باشد، یک تابع دیگر وجود دارد که ممکن است به آن علاقه داشته باشید. TEXTJOIN به سادگی سلول‌ها را در Google Sheets ادغام نمی‌کند، بلکه خالی‌ها را نادیده می‌گیرد:

=TEXTJOIN(" ",TRUE,A2:C2)

چگونه کار می کند:

1. جداکننده مورد نظر را به عنوان اولین آرگومان مشخص کنید – فضا (" ") برای من.
2. TRUE به عنوان آرگومان دوم برای رد شدن از سلول های خالی یا FALSE برای گنجاندن آنها در نتیجه.
3. محدوده را برای ادغام وارد کنید.

اتصال با شکست خط در برگه‌های Google

در حالی که نحوه وارد کردن بیشتر جداکننده‌ها به تابع واضح است، نمی‌توانید شکست خط را به همان صورت در آنجا تایپ کنید. اما خوشبختانه Google به شما اجازه می‌دهد کارت‌های مختلف را بازی کنید.

یک عملکرد وجود دارد که به دریافت کاراکترهای خاص کمک می‌کند – آن CHAR نامیده می‌شود. ببینید، هر کاراکتر جایی در جدول یونیکد دارد. شما فقط باید عدد ترتیبی کاراکتر را از آن جدول به تابع وارد کنید و دومی خود کاراکتر را برمی گرداند.

در اینجا یک فرمول برای بدست آوردن شکست خط وجود دارد:

=CHAR(10)

آن را به فرمول اضافه کنید تا با شکست خط در Google Sheets الحاق شود:

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)

ترکیب تاریخ و زمان در Google Sheets

اگر سعی می‌کنید تاریخ و زمان را با استفاده از یکی از روش‌ها در Google Sheets ترکیب کنیددر بالا، کار نخواهد کرد. صفحه گسترده شما اعداد را برمی گرداند:

برای ترکیب صحیح تاریخ و زمان در Google Sheets، از تابع TEXT استفاده کنید:

• که در آن number هر عدد، تاریخ یا زمانی است که می‌خواهید در قالب دلخواه دریافت کنید
• و قالب الگویی است که می‌خواهید نتیجه را ببینید.

نکته. در مثالم، من به سلول‌های دارای تاریخ و زمان اشاره می‌کنم، اما شما آزاد هستید که از واحدهای تاریخ/زمان یا حتی توابعی مانند DATE یا TIME مستقیماً در فرمول استفاده کنید.

1. من از اولین فرمول TEXT برای تغییر قالب تاریخ از 7/9/2019 به 9 ژوئیه 2019 استفاده می کنم:

   =TEXT(B2,"D MMM YYYY")

2. TEXT دوم زمان را برمی گرداند:

   =TEXT(C2,"HH:MM:SS")

3. با استفاده از این موارد در CONCATENATE، Google Sheets به من امکان می دهد تاریخ و زمان را در قالب دلخواه با سایر کاراکترها یا متن ترکیب کنم:

   =CONCATENATE(TEXT(B2,"D MMM YYYY"),", ",TEXT(C2,"HH:MM:SS"))

ترکیب ستون‌ها در Google Sheets

با تنظیمات جزئی، همه راه‌هایی که ذکر کردم می‌توانند ستون‌ها را در Google Sheets ادغام کنند.

مثال 1. Google Sheets CONCAT

برای ادغام کل ستون‌ها در Google Sheets با CONCAT، کل محدوده‌ای را که باید حاوی نتیجه باشد (در مورد من C2:C11) انتخاب کنید و فرمول خود را وارد کنید. آن را در ARRAYFORMULA:

=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))

توجه داشته باشید. می توانید از تابع CONCATENATE استفاده کنید، اما همه رکوردها را در یک سلول به هم می پیوندد زیرا به راحتی چندین سلول و محدوده داده را ادغام می کند.

مثال 2.عملگر الحاق

ایجاد فرمول های آرایه برای ترکیب ستون ها در Google Sheets با استفاده از علامت علامت و افزودن جداکننده ها به طور همزمان:

=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)

این خوب به نظر می رسد، اما باید به برخی از معایب اصلی اشاره کنم.

اگر ستون های زیادی دارید، شمارش همه آنها می تواند باعث درد در گردن شود، به خصوص اگر به طور تصادفی از هر یک از کاراکترها رد شوید/تکپی کنید/با هم ترکیب کنید. .

همچنین، اگر تصمیم دارید بعداً ستون‌های بیشتری به فرمول اضافه کنید، باید هر محدوده موجود در فرمول را به صورت دستی ویرایش کنید.

مثال بعدی این مشکلات را حل می‌کند.

مثال 3. Google Sheets QUERY

Google Sheets QUERY تابع همچنین برای ادغام چندین ستون در Google Sheets مناسب است. نگاهی بیندازید:

=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))

شاید فکر کنید که این فرمول عجیب فراتر از درک شماست، اما اجازه دهید تمام قطعات آن را برای شما بیان کنم:

1. =TRANSPOSE(A2:D10) ردیف های داده را به ستون تبدیل می کند.
2. =QUERY(TRANSPOSE(A2:D10),,9^9) رکوردهای هر ستون را در ستون ادغام می کند. سلول های بالا

   نکته. وقتی 9^9 را در فرمول قرار می‌دهم، مطمئن می‌شوم که تمام سطرها از همه ستون‌ها به سطر اول کشیده می‌شوند، انگار که سربرگ هستند. این عبارت 9^9 است زیرا این عبارت شامل تمام سلول های ممکن در صفحه گسترده است (محدودیت 10M سلول را به خاطر دارید؟) و به راحتی قابل یادآوری است. :)

3. =TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9)) آن ردیف سرصفحه را از QUERY می گیرد و به ستونی مانندیکی از آنها را دارم.

در اینجا مزایای ادغام ستون‌ها در کاربرگ‌نگار Google با استفاده از QUERY آمده است:

• نیازی نیست کل ستون را همانطور که انجام می‌دهید انتخاب کنید برای فرمول های آرایه
• شما نیازی به ذکر هر ستون در فرمول ندارید، مگر اینکه آنها غیر مجاور باشند. در این مورد، فرمول به این صورت خواهد بود:

  =TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

متن را بر اساس موقعیت به هم متصل کنید و اضافه کنید

از قبل می دانید که می توانید متن، اعداد گمشده را اضافه کنید. و کاراکترهای رشته های خود را با استفاده از تابع CONCATENATE.

نکته. فرمول های بیشتری را در این آموزش ببینید.

اما اگر رکوردهای زیادی برای پیوستن وجود دارد، هر کاراکتر اضافی می تواند فرمول شما را فراتر از آنچه برنامه ریزی کرده اید گسترش دهد. در مواردی مانند این، بهتر است سلول‌ها را در Google Sheets به همان شکلی که هستند ادغام کنید یا از جداکننده‌های ساده مانند فاصله استفاده کنید و بعد از آن متن را اضافه کنید. یک ابزار ویژه ما به شما کمک خواهد کرد.

اضافه کردن متن بر اساس موقعیت، هر نویسه و رشته را بر اساس موقعیتی که مشخص می‌کنید درج می‌کند، هیچ فرمولی لازم نیست. اجازه دهید به شما نشان دهم که چگونه کار می‌کند.

در مثال قبلی QUERY نام‌ها و شماره‌های تلفن را برای من اضافه کرد. اما می‌خواهم اختصارات کشور را اضافه کنم: (USA/CA) قبل از شماره تلفن‌هایی که با +1 و UK قبل از +44<شروع می‌شوند. 2>:

تقسیم سلول‌ها در Google Sheets

اگر سلول‌ها را در کاربرگ‌نگار Google ترکیب می‌کنید، به احتمال زیاد مجبور خواهید بود آنها را دوباره تقسیم کنید. . سه راه برای انجام این کار وجود دارد:

1. یک فرمول بسازیدبا استفاده از عملکرد SPLIT برگه‌های Google.
2. از ابزار صفحه‌گسترده استاندارد استفاده کنید – متن را به ستون‌ها تقسیم کنید.
3. یا نسخه پیشرفته ابزار داخلی را امتحان کنید – متن را به ستون‌ها برای Google Sheets تقسیم کنید:

به شما امکان می‌دهد سلول‌ها را با هر جداکننده یا حتی مجموعه‌ای از جداکننده‌ها تقسیم کنید، آنها را به عنوان یک تلقی کنید و در صورت لزوم، ربط‌ها را نیز اضافه کنید. همچنین گزینه ای برای تقسیم سلول ها در Google Sheets بر اساس موقعیت ارائه می دهد.

نکته. گزینه‌ای برای استخراج داده‌ها از سلول‌های کاربرگ‌نگار Google به جای تقسیم محتوا وجود دارد.

نحوه ادغام سلول‌ها در کاربرگ‌نگار Google بدون فرمول

اگر تسلط بر فرمول‌های مختلف بخشی از برنامه شما نیست، از افزونه Merge Values ​​ما بهره مند شوید. این افزونه به سرعت به رکوردها در ردیف‌ها، ستون‌ها یا کل محدوده سلول‌ها می‌پیوندد. گزینه‌های آن کاملاً واضح هستند، و تنها کاری که باید انجام دهید این است که محدوده را انتخاب کنید و تصمیم بگیرید که نتیجه چگونه باشد.

1. شما می‌توانید ترکیب ستون‌ها را در Google Sheets انتخاب کنید — حتی موارد غیر مجاور، آنها را با کاما و فاصله جدا کنید و نتیجه را در سمت راست رکوردهای اصلی قرار دهید:

اگر به این ابزار علاقه دارید، می توانید نگاه کنیداز طریق هر کاری که در این صفحه خاص انجام می دهد یا در این آموزش ویدیویی کوتاه:

در این ویدیو نحوه استفاده از ترکیب ردیف های تکراری را بیاموزید. :

امیدوارم تا به حال تصمیم گرفته باشید که کدام یک از راه ها برای پرونده شما مناسب تر است. اگر روش دیگری در ذهن دارید، لطفاً در بخش نظرات زیر با ما به اشتراک بگذارید :)