"Конкатенація" зазвичай означає з'єднання чогось послідовно або ланцюжком. Ця операція використовується, коли потрібно об'єднати текст з декількох комірок Google Таблиць. У цій статті зібрані найпопулярніші і прості рішення, які допоможуть вам вирішити головоломку з конкатенацією.

Яким би великим не був ваш набір даних, ви можете зіткнутися із завданням об'єднати кілька комірок в Google Таблицях разом. І я не сумніваюся, що вам захочеться не тільки зберегти всі значення, але й додати якісь коми, пробіли чи інші символи, або навіть відокремити ці записи іншим текстом.

Що ж, електронні таблиці пропонують кілька інструментів для цього завдання.

Функція CONCAT Google Sheets

Функція CONCAT є спрощеною версією функції Google Sheets CONCATENATE:

Для об'єднання комірок за допомогою цієї функції потрібно перерахувати необхідні значення:

• значення1 - запис, до якого додається значення2.
• значення2 - цінність, до якої варто приєднатися.

Для отримання одного рядка з 2 текстових або числових одиниць формула буде виглядати так, як показано нижче, де кожен запис береться в подвійні лапки:

=CONCAT("2019:", "Король Лев")

Насправді, ваші дані, швидше за все, вже знаходяться в комірках. Ви можете посилатися на ці комірки безпосередньо, замість того, щоб вводити кожне число або текст в якості аргументу. Таким чином, формула для реальних даних буде виглядати наступним чином:

=CONCAT(A2,B2)

Порада: Щоб скопіювати формулу на весь стовпець, виділіть комірку з формулою і двічі клацніть по маленькому квадратику в правому нижньому куті комірки. Формулою буде автоматично заповнений весь стовпець, до самого кінця таблиці.

Як бачите, функція надпроста, але вона має велике значення слабкі місця :

• об'єднує лише дві комірки в Google Таблицях за один раз.
• він не може об'єднувати стовпці, рядки або інші великі діапазони даних, він бере тільки окремі клітинки. Якщо ви спробуєте об'єднати кілька клітинок, ви або отримаєте помилку, або об'єднаються тільки перші два значення, як на цьому прикладі:

  =CONCAT(A2:A11,B2:B11)

  

Альтернатива CONCAT: оператор конкатенації амперсанд (&)

У формулах існує безліч різних операторів для різних цілей. Конкатенація не є винятком. Використання у формулах символу амперсанда (&) замість функції CONCAT дасть вам той же результат:

=A2&B2

Але мало хто знає, що цей оператор конкатенації більш гнучкий. Ось що він може:

1. Об'єднати більше двох значень одночасно:

   =A2&B2&C2

   

2. Не просто об'єднувати комірки в Google Sheets, а й розділяти їх різними символами:

   =A2&" "&B2&"; "&C2

   

Якщо ви все ще не отримали бажаного результату за допомогою цих опцій, є ще одна функція, яку можна спробувати.

Як використовувати CONCATENATE в Google Sheets

Я вважаю, що функція CONCATENATE в Google Sheets є першою, яку слід використовувати, коли мова йде про додавання декількох записів разом.

ОБ'ЄДНАННЯ текстових рядків і чисел в Google Таблицях

Шаблон формули складається з наступних аргументів:

• string1 перший рядок, до якого потрібно додати інші значення. Цей аргумент є обов'язковим.
• string2, ... означає всі інші рядки, які ви можете додати. Цей аргумент є необов'язковим.

Примітка. Запис результату буде складатися з рядків у порядку їх появи у формулі.

Якщо я адаптую формулу до своїх даних, то отримаю ось це:

=CONCATENATE(A2,B2,C2)

Або, оскільки функція приймає діапазони:

=CONCATENATE(A2:D2)

Відразу можна помітити першу перевагу функції Google Sheets CONCATENATE: вона легко об'єднує більше двох комірок з текстом і числами.

Google Таблиці: об'єднуємо рядки з роздільниками

Об'єднати комірки в Google Таблицях - це півсправи. Але щоб результат виглядав красиво і читабельно, варто додати кілька додаткових символів.

Якщо залишити формулу як є, то вона просто склеїть все докупи: BonnieJacksonCA , Бонні Джексон і т.д. Але Google Sheets CONCATENATE теж приймає символи в якості аргументів.

Таким чином, щоб додати деякі роздільники для читабельності, згадуйте їх у формулі в подвійних лапках:

=CONCATENATE(A2," ",B2,", ",C2)

Тут я хочу об'єднати А2 і В2 через пробіл і відокремити В2 від С2 комою і пробілом:

Ви можете використовувати практично будь-який символ у такій функції, але розрив рядка вимагає іншого підходу.

Порада: Якщо в деяких стовпчиках, які ви об'єднуєте, є порожні клітинки, є ще одна функція, яка може вас зацікавити. TEXTJOIN не просто об'єднує клітинки в Google Таблицях, а ігнорує порожні клітинки:

=TEXTJOIN(" ",TRUE,A2:C2)

Ось як це працює:

1. В якості першого аргументу вкажіть бажаний роздільник - "Роздільник простір (Для мене.
2. Покладіть ПРАВДА як другий аргумент, щоб пропустити порожні клітинки або НЕПРАВДА включити їх у результат.
3. Введіть діапазон для об'єднання.

Об'єднання з розривом рядка в Google Таблицях

Хоча очевидно, як ввести більшість розділових знаків у функцію, ви не можете ввести розрив рядка таким же чином. Але, на щастя, Google дозволяє вам розіграти багато різних карт.

Є функція, яка допомагає отримати спеціальні символи - вона називається CHAR. Розумієте, у кожного символу є місце в таблиці Юнікоду. Вам просто потрібно подати у функцію порядковий номер символу з цієї таблиці, і вона поверне сам символ.

Ось формула для отримання розриву рядка:

=CHAR(10)

Додайте його у формулу для об'єднання з розривом рядка в Google Таблицях:

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)

Об'єднання дати та часу в Google Таблицях

Якщо ви спробуєте об'єднати дату і час в Google Таблицях одним із зазначених вище способів, це не спрацює. Ваша таблиця поверне цифри:

Для правильного поєднання дати і часу в Google Таблицях використовуйте функцію ТЕКСТ:

• де кількість будь-яке число, дату або час, які Ви бажаєте отримати у бажаному форматі
• і формат це модель, яку ви хотіли б бачити в результаті.

Порада. У моєму прикладі я буду посилатися на комірки з датами і часом, але ви можете використовувати одиниці виміру дати/часу або навіть такі функції, як DATE або TIME безпосередньо у формулі.

1. Я використовую першу ТЕКСТОВУ формулу для зміни формату дати з 7/9/2019 до 9 липня 2019 року :

   =TEXT(B2, "D MMM YYYY")

2. Другий ТЕКСТ повертає час:

   =TEXT(C2, "HH:MM:SS")

3. Використовуючи їх у CONCATENATE, Google Sheets дозволяє мені поєднувати дату та час у потрібному форматі з іншими символами або текстом:

   =CONCATENATE(TEXT(B2, "D MMM YYYY"),", ",TEXT(C2, "HH:MM:SS"))

Об'єднання стовпців в Google Таблицях

З невеликими корективами всі згадані мною способи здатні об'єднати стовпці в Google Таблицях.

Приклад 1. Google Таблиці CONCAT

Щоб об'єднати цілі стовпці в Google Sheets за допомогою CONCAT, виділіть весь діапазон, який повинен містити результат (C2:C11 в моєму випадку) і введіть свою формулу, обернувши її в АРМАЙФОРМУЛУ:

=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))

Примітка: Ви можете використовувати функцію ОБ'ЄДНАТИ, але вона об'єднає всі записи в одній комірці, оскільки легко об'єднує декілька комірок і діапазонів даних.

Приклад 2. Оператор конкатенації

Створення формул масивів для об'єднання стовпців в Google Sheets за допомогою амперсанду і додавання роздільників при цьому:

=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)

Це виглядає добре, але я маю вказати на деякі серйозні недоліки.

Якщо у вас занадто багато колонок, перерахування їх усіх може стати головним болем, особливо якщо ви випадково пропустите/повторите/переплутаєте якісь символи.

Крім того, якщо ви вирішите додати більше стовпців до формули пізніше, вам доведеться відредагувати кожен існуючий діапазон у формулі вручну.

Наступний приклад вирішує ці проблеми.

Приклад 3. Запит до Google Таблиць

Функція ЗАПИТ в Google Sheets також підходить для об'єднання декількох стовпців в Google Sheets. Подивіться:

=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))

Ви можете подумати, що ця дивна формула не піддається вашому розумінню, але дозвольте мені розкласти її по поличках для вас:

1. =TRANSPOSE(A2:D10) перетворює рядки даних у стовпці.
2. =QUERY(TRANSPOSE(A2:D10),,9^9) об'єднує записи в кожному стовпці у верхні комірки.

   Порада. Коли я поклав 9^9 у формулу, я переконуюся, що всі рядки з усіх стовпців будуть витягнуті в перший рядок, як якщо б вони були заголовками. Це 9^9 оскільки цей вираз включає всі можливі комірки електронної таблиці (пам'ятаєте обмеження на 10М комірок?) і легко запам'ятовується :)

3. =TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9)) бере цей рядок заголовка з QUERY і перетворює його в стовпець, як у мене.

Ось переваги об'єднання стовпців в Google Таблицях за допомогою запиту QUERY:

• не потрібно виділяти весь стовпець, як це робиться для формул масивів
• у формулі не потрібно згадувати кожен стовпчик, якщо вони не є суміжними. У такому випадку формула буде виглядати так:

  =TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

Об'єднання та додавання тексту за позиціями

Ви вже знаєте, що за допомогою функції CONCATENATE можна додавати пропущений текст, цифри та символи до рядків.

Порада. Дивіться більше формул про це в цьому підручнику.

Але якщо записів для об'єднання занадто багато, будь-які зайві символи можуть розширити формулу набагато більше, ніж ви планували. У таких випадках краще об'єднати комірки в Google Таблицях як є або використовувати прості роздільники, наприклад, пробіл, а вже після цього додавати текст. У цьому вам допоможе наш спеціальний інструмент.

Додавання тексту по позиції вставляє будь-які символи і рядки по вказаній вами позиції, ніяких формул не потрібно. Давайте я покажу вам, як це працює.

У попередньому прикладі QUERY об'єднав для мене імена та номери телефонів, але я хотів би додати абревіатури країн: (США/КАНАДА) перед телефонними номерами, які починаються з +1 і ВЕЛИКОБРИТАНІЯ до +44 :

Розділення комірок в Google Таблицях

Якщо ви об'єднуєте клітинки в таблицях Google, швидше за все, вам потрібно буде розділити їх назад. Існує три способи зробити це:

1. Побудуйте формулу за допомогою функції SPLIT Google Sheets.
2. Використовуйте стандартний інструмент електронних таблиць - Розбиття тексту на колонки.
3. Або спробуйте розширену версію вбудованого інструменту - Розбиття тексту на колонки для Google Таблиць:

Він дозволяє розділяти клітинки будь-яким роздільником або навіть набором роздільників, розглядаючи їх як одне ціле і включаючи при необхідності сполучники. Він також пропонує можливість розділяти клітинки в Google Таблицях за позицією.

Порада. Існує можливість витягувати дані з комірок Google Таблиць, а не розділяти вміст.

Як об'єднати комірки в Google Таблицях без формул

Якщо освоєння різних формул не входить у ваші плани, вам стане в нагоді надбудова "Об'єднання значень". Надбудова швидко об'єднує записи в рядках, стовпцях або весь діапазон клітинок. Її можливості кристально зрозумілі, і все, що вам потрібно зробити, - це вибрати діапазон і вирішити, як повинен виглядати результат.

1. Ви можете вибрати комбінувати колонки в Google Таблицях - навіть несуміжні, відокремлюйте їх комами та пробілами, а результат розміщуйте праворуч від вихідних записів:

Якщо вас зацікавив цей інструмент, ви можете ознайомитися з усіма його можливостями на цій спеціальній сторінці або в цьому короткому відеоуроці:

Дізнайтеся, як використовувати функцію Об'єднати повторювані рядки в цьому відео:

Сподіваюся, ви вже вирішили, який із способів найкраще підходить для вашого випадку. Якщо у вас є якісь інші способи, будь ласка, поділіться ними з нами в коментарях нижче :)