"Конкатенация" обычно означает соединение чего-либо в серию или цепочку. Эта операция используется всякий раз, когда вам нужно соединить текст из нескольких ячеек Google Sheets. В этой статье собраны самые популярные и простые решения, которые помогут вам решить головоломку конкатенации.

Каким бы большим ни был ваш набор данных, вы можете столкнуться с задачей объединения нескольких ячеек в Google Sheets вместе. И я не сомневаюсь, что вы захотите не только сохранить все значения от потери, но и добавить несколько запятых, пробелов или других символов, или даже разделить эти записи другим текстом.

Что ж, электронные таблицы предлагают несколько инструментов для решения этой задачи.

Функция CONCAT в Google Sheets

Функция CONCAT - это упрощенная версия CONCATENATE из Google Sheets:

Чтобы объединить ячейки с помощью этой функции, нужно перечислить необходимые значения:

• значение1 - запись, к которой должно быть добавлено значение2.
• значение2 - значение для присоединения.

Чтобы получить одну строку из двух текстовых или числовых единиц, формула будет выглядеть следующим образом, с каждой записью в двойных кавычках:

=CONCAT("2019:", "Король Лев")

В реальности ваши данные, скорее всего, уже находятся в ячейках. Вы можете ссылаться на эти ячейки напрямую, а не вводить каждое число или текст в качестве аргумента. Таким образом, формула для реальных данных будет выглядеть следующим образом:

=CONCAT(A2,B2)

Совет. Чтобы скопировать формулу во весь столбец, выделите ячейку с формулой и дважды щелкните по маленькому квадратику в правом нижнем углу ячейки. Формула автоматически заполнит весь столбец до самого конца таблицы.

Как вы можете видеть, функция очень проста, но она имеет важное значение слабые места :

• он объединяет только две ячейки в Google Sheets за один раз.
• он не может объединять столбцы, строки или другие большие диапазоны данных, он принимает только отдельные ячейки. Если вы попытаетесь объединить несколько ячеек, вы либо получите ошибку, либо будут объединены только первые два значения, как показано здесь:

  =CONCAT(A2:A11,B2:B11)

  

Альтернатива CONCAT: оператор конкатенации ampersand (&)

В формулах существует множество различных операторов для различных целей. Конкатенация не является исключением. Использование в формулах символа амперсанда (&) вместо функции CONCAT даст вам тот же результат:

=A2&B2

Но мало кто знает, что этот оператор конкатенации более гибкий. Вот что он может сделать:

1. Объедините более двух значений за один раз:

   =A2&B2&C2

   

2. Не только объединять ячейки в Google Sheets, но и разделять их различными символами:

   =A2&" "&B2&"; "&C2

   

Если вы все еще не получили желаемого результата с помощью этих опций, есть еще одна функция, которую можно попробовать.

Как использовать CONCATENATE в Google Sheets

Я считаю, что функция Google Sheets CONCATENATE является первой, которую следует использовать, когда речь идет о сложении нескольких записей вместе.

КОНКАТЕНТАЦИЯ текстовых строк и чисел в Google Sheets

Шаблон формулы состоит из следующих аргументов:

• строка1 это первая строка, к которой вы хотите добавить другие значения. Этот аргумент является обязательным.
• string2, ... обозначает все остальные строки, которые вы можете захотеть добавить. Этот аргумент необязателен.

Примечание. Запись результата будет состоять из строк в порядке их появления в формуле.

Если я адаптирую формулу к своим данным, то получу следующее:

=CONCATENATE(A2,B2,C2)

Или, поскольку функция принимает диапазоны:

=CONCATENATE(A2:D2)

Вы можете сразу заметить первое преимущество Google Sheets CONCATENATE: он легко объединяет более двух ячеек с текстом и числами.

Google Sheets: конкатенация строк с разделителями

Объединить ячейки в Google Sheets - это полдела. Но чтобы результат выглядел красиво и читабельно, необходимо добавить несколько дополнительных символов.

Если вы оставите формулу как есть, она просто склеит все вместе: BonnieJacksonCA , BonnieJacksonIN , и т.д. Но Google Sheets CONCATENATE также принимает символы в качестве аргументов.

Таким образом, чтобы добавить некоторые разделители для удобочитаемости, упомяните их в формуле в двойных кавычках:

=CONCATENATE(A2," ",B2,", ",C2)

Здесь я хочу объединить A2 & B2 с пробелом и отделить B2 от C2 запятой и пробелом:

Вы можете свободно использовать практически любой символ в такой функции, однако перевод строки требует другого подхода.

Совет. Если в некоторых столбцах, которые вы объединяете, есть пустые ячейки, вас может заинтересовать еще одна функция. TEXTJOIN не просто объединяет ячейки в Google Sheets, но и игнорирует пробелы:

=TEXTJOIN(" ",TRUE,A2:C2)

Вот как это работает:

1. Укажите желаемый разделитель в качестве первого аргумента - пространство (" ") для меня.
2. Поместите TRUE в качестве второго аргумента, чтобы пропустить пустые ячейки или FALSE чтобы включить их в результат.
3. Введите диапазон для объединения.

Конкатенация с переводом строки в Google Sheets

Хотя очевидно, как ввести большинство разделителей в функцию, вы не можете набрать перенос строки таким же образом. Но, к счастью, Google позволяет вам разыграть множество разных карт.

Существует функция, которая помогает получить специальные символы - она называется CHAR. Видите ли, каждый символ имеет свое место в таблице Unicode. Вам просто нужно передать в функцию порядковый номер символа из этой таблицы, и она вернет сам символ.

Вот формула для получения переноса строки:

=CHAR(10)

Добавьте его в формулу для конкатенации с переносом строки в Google Sheets:

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)

Объединение даты и времени в Google Sheets

Если вы попытаетесь объединить дату и время в Google Sheets с помощью одного из описанных выше методов, это не сработает. Ваша таблица будет возвращать числа:

Чтобы правильно объединить дату и время в Google Sheets, используйте функцию ТЕКСТ:

• где номер это любое число, дата или время, которое вы хотите получить в нужном формате
• и формат это шаблон, который вы хотели бы видеть в результате.

Совет. В моем примере я буду ссылаться на ячейки с датами и временем, но вы можете использовать единицы даты/времени или даже такие функции, как DATE или TIME непосредственно в формуле.

1. Я использую первую формулу TEXT для изменения формата даты с 7/9/2019 на 9 Jul 2019 :

   =TEXT(B2, "D MMM YYYY")

2. Второй ТЕКСТ возвращает время:

   =TEXT(C2, "HH:MM:SS")

3. Используя их в CONCATENATE, Google Sheets позволяет мне комбинировать дату и время в нужном формате с другими символами или текстом:

   =CONCATENATE(TEXT(B2, "D MMM YYYY"),", ",TEXT(C2, "HH:MM:SS"))

Объединение столбцов в Google Sheets

С небольшими корректировками все упомянутые мной способы могут быть использованы для объединения столбцов в Google Sheets.

Пример 1. Google Sheets CONCAT

Чтобы объединить целые столбцы в Google Sheets с помощью CONCAT, выберите весь диапазон, который должен содержать результат (C2:C11 в моем случае), и введите свою формулу, обернув ее в ARRAYFORMULA:

=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))

Примечание. Вы можете использовать функцию CONCATENATE, но она объединит все записи в одной ячейке, так как легко объединяет несколько ячеек и диапазонов данных.

Пример 2. Оператор конкатенации

Создание формул массива для объединения столбцов в Google Sheets с помощью амперсанда и одновременного добавления разделителей:

=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)

Это выглядит хорошо, но я должен отметить некоторые основные минусы.

Если у вас слишком много столбцов, перечисление их всех может стать мучением, особенно если вы случайно пропустите/дублируете/перепутаете какие-либо символы.

Кроме того, если впоследствии вы решите добавить в формулу дополнительные столбцы, вам придется вручную редактировать каждый существующий диапазон в формуле.

Следующий пример решает эти проблемы.

Пример 3. Запрос в Google Sheets

Функция Google Sheets QUERY также подходит для объединения нескольких столбцов в Google Sheets. Посмотрите:

=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))

Вам может показаться, что эта странная формула недоступна вашему пониманию, но позвольте мне разложить для вас все ее части:

1. =TRANSPOSE(A2:D10) превращает строки данных в столбцы.
2. =QUERY(TRANSPOSE(A2:D10),,9^9) объединяет записи в каждом столбце в верхние ячейки.

   Совет. Когда я ставлю 9^9 в формулу, я убеждаюсь, что все строки из всех столбцов будут втянуты в первую строку, как если бы они были заголовками. Это и есть 9^9 поскольку это выражение включает все возможные ячейки в электронной таблице (помните ограничение на 10М ячеек?) и легко запоминается. :)

3. =TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9)) берет эту строку заголовка из QUERY и превращает ее в столбец, подобный тому, который я получил.

Вот преимущества объединения столбцов в Google Sheets с помощью QUERY:

• вам не нужно выделять весь столбец, как это делается для формул массива
• вам не нужно упоминать каждый столбец в формуле, если они не являются смежными. В этом случае формула будет выглядеть следующим образом:

  =TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

  Смотрите также: Как заморозить панели в Excel (заблокировать строки и столбцы)

Конкатенация и добавление текста по позиции

Вы уже знаете, что с помощью функции CONCATENATE можно добавлять в строки недостающий текст, числа и символы.

Совет. Смотрите больше формул по этому вопросу в этом учебнике.

Но если записей для объединения слишком много, любые дополнительные символы могут расширить вашу формулу намного больше, чем вы планировали. В таких случаях лучше объединить ячейки в Google Sheets как есть или использовать простые разделители, такие как пробел, и добавить текст после этого. В этом вам поможет наш специальный инструмент.

Добавление текста по позиции вставляет любые символы и строки по указанной позиции, формулы не нужны. Позвольте мне показать вам, как это работает.

В предыдущем примере QUERY соединил для меня имена и номера телефонов. Но я хотел бы добавить аббревиатуры стран: (США/ЦА) перед номерами телефонов, которые начинаются с +1 и ВЕЛИКОБРИТАНИЯ до +44 :

Разделение ячеек в Google Sheets

Если вы объединяете ячейки в Google Sheets, есть вероятность, что в какой-то момент вам понадобится разделить их обратно. Существует три способа сделать это:

1. Постройте формулу с помощью функции SPLIT в Google Sheets.
2. Используйте стандартный инструмент электронных таблиц - разделите текст на колонки.
3. Или попробуйте расширенную версию встроенного инструмента - Разделить текст на колонки для Google Sheets:

Она позволяет разделять ячейки по любому разделителю или даже по набору разделителей, рассматривая их как одно целое и включая конъюнкцию, если это необходимо. Она также предлагает возможность разделения ячеек в Google Sheets по позиции.

Совет. Существует возможность извлекать данные из ячеек Google Sheets, а не разбивать содержимое.

Как объединить ячейки в Google Sheets без формул

Если освоение различных формул не входит в ваши планы, вам поможет наше дополнение Merge Values. Это дополнение быстро объединяет записи в строках, столбцах или во всем диапазоне ячеек. Его опции предельно ясны, и все, что вам нужно сделать, это выбрать диапазон и решить, как должен выглядеть результат.

1. Вы можете выбрать объединить колонки в Google Sheets - даже несмежные, разделяйте их запятыми и пробелами и помещайте результат справа от исходных записей:

Если вас заинтересовал этот инструмент, вы можете ознакомиться со всеми его возможностями на этой специальной странице или в этом коротком видеоуроке:

В этом видеоролике вы узнаете, как использовать функцию "Объединить дубликаты строк":

Надеюсь, вы уже решили, какой из этих способов больше всего подходит для вашего случая. Если у вас на примете есть другие способы, поделитесь с нами в разделе комментариев ниже :)