"Concatenate" bi gelemperî tê wateya girêdana tiştek bi rêzek an zincîreyekê. Dema ku hûn hewce ne ku hûn ji gelek hucreyên Google Sheets tevlê nivîsê bibin, ev kar tê bikar anîn. Ev gotar çareseriyên herî populer û hêsan berhev dike da ku ji we re bibe alîkar ku hûn kêşeya pevgirêdanê çareser bikin.

Detanûsa we çiqas mezin be jî, dibe ku hûn bi peywira berhevkirina çend şaneyên di Google Sheets bi hev re werin. Û gumana min tune ku hûn ê ne tenê bixwazin ku hûn hemî nirxan winda nekin, lê di heman demê de hin nîgar, valahiyek, an tîpên din jî lê zêde bikin, an jî wan tomaran bi nivîsek din veqetînin.

Belê, pelên belavokan gelek amûran pêşkêş dikin ji bo vê xebatê.

Fonksiyon CONCAT Pelên Google

Fonksiyon CONCAT guhertoyek sadekirî ya Google Sheets CONCATENATE ye:

Ji bo tevlêbûna şaneyan bi vê fonksiyonê re, divê hûn nirxên pêwîst binivîsin:

• nirx1 - tomarek ku divê nirx2 jê re were zêdekirin.
• nirx2 - nirxa ku tev lê bibe.

Ji bo ku yek rêzek ji 2 yekeyên nivîsê an hejmarî werbigire, formula dê wekî jêrîn xuya bike, her tomar bi du-navdêran ve tê xuyang kirin:

=CONCAT("2019:","The Lion King")

Di rastiyê de, daneyên we bi îhtîmalek mezin berê di hucreyan de ne. Li şûna ku hûn her hejmar an nivîsê wekî arguman binivîsin, hûn dikarin rasterast wan şaneyan binav bikin. Ji ber vê yekê formula daneyên rastîn dê bi vî rengî be:

=CONCAT(A2,B2)

Tip. Ji bo kopîkirina formula xwe li tevahiya stûnê, hucreyê hilbijêrinbi formulê re û du caran çarçika piçûk a li quncikê rastê yê binê hucreyê bikirtînin. Tevahiya stûn dê bixweber bi formula, heya dawiya tabloyê were dagirtin.

Wekî ku hûn dibînin, fonksiyon pir hêsan e, lê xalên qels ên sereke hene :

• ew di carekê de tenê du şaneyên Google Sheets dike yek.
• ew nikare stûn, rêz, an rêzikên din ên daneya mezin berhev bike, ew tenê şaneyên yekane digire. Ger hûn hewl bidin ku hûn çend şaneyan bigihînin hev, hûn ê an xeletiyek bibînin an jî tenê du nirxên pêşîn dê werin hev, mîna vê:

  =CONCAT(A2:A11,B2:B11)

  

Alternatîf CONCAT: ampersand operatorê hevgirtinê (&)

Di formulan de ji bo armancên cihêreng gelek operatorên cihêreng hene. Têkilî ne îstîsnayek e. Li şûna fonksiyona CONCAT di formulan de tîpek ampersand (&) bikar bînin dê heman encamê ji we re peyda bike:

=A2&B2

Lê hindik hûn dizanin ku ev operatora hevgirtinê maqûltir e. Ya ku ew dikare bike ev e:

1. Zêdetirî du nirxan di carekê de bike yek:

   =A2&B2&C2

   

2. Ne tenê şaneyên yek di Google Sheets de, lê di heman demê de wan bi tîpên cihêreng jî ji hev veqetînin:

   =A2&" "&B2&"; "&C2

   

Heke hûn dîsa jî bi van vebijarkan encama xwestinê negirin , fonksiyonek din heye ku meriv biceribîne.

Meriv çawa CONCATENATE-ê di pelên Google de bikar tîne

Ez bawer dikim fonksiyona Google Sheets CONCATENATE yekem e ku bikar tînedema dor tê ser pêvekirina çend tomaran bi hev re.

Helcên nivîsê û jimareyan di Google Sheets de BİXWÎNE BİXWÎNE

Nimûneya formula ji van argumanan pêk tê:

• string1 rêzika yekem e ku hûn dixwazin nirxên din lê zêde bikin. Ev arguman pêwîst e.
• string2, … ji bo hemû rêzikên din ên ku hûn bixwazin lê zêde bikin radiweste. Ev arguman vebijarkî ye.

Nîşe. Qeyda encam dê ji rêzan li gorî rêza xuyabûna wan di formulê de pêk were.

Heke ez formula li gorî daneyên xwe biguherim, ez ê vê bistînim:

=CONCATENATE(A2,B2,C2)

An jî, ji ber ku fonksiyon rêzikan qebûl dike:

=CONCATENATE(A2:D2)

Hûn dikarin tavilê feydeya yekem a Google Sheets CONCATENATE bibînin: ew bi hêsanî bi du şaneyan hem bi nivîsê hem jî bi hejmaran re dibe hev.

Google Sheets: rêzan bi veqetankeran re digihîne hev

Tevhevkirina hucreyên di Google Sheets de nîvê xebatê ye. Lê ji bo ku encam xweş û xwendî xuya bike, divê hûn hin karakterên zêde lê zêde bikin.

Heke hûn formula wek xwe bihêlin, ew ê her tiştî bi hev re bihêle: BonnieJacksonCA , BonnieJacksonIN , hwd. Lê Google Sheets CONCATENATE tîpan jî wekî arguman digire.

Ji ber vê yekê, ji bo ku ji bo xwendinê hin veqetandî lê zêde bike, wan di formulê de bi ducaran binav bike:

=CONCATENATE(A2," ",B2,", ",C2)

Li vir ez dixwazim A2 & amp; B2 bi valahiyê û B2 ji C2 bi komma û veqetînespace:

Tu azad î ku hema hema her karakterek di fonksiyona bi vî rengî de bikar bîne, lê dîsa jî veqetandina rêzek nêzîkatiyek cûda hewce dike.

Serişte. Ger di hin stûnên ku hûn li hev dikin de şaneyên vala hebin, fonksiyonek din heye ku hûn jê re eleqedar bibin> Li vir çawa kar dike:

1. Ciwankera xwestî wekî argumana yekem nîşan bidin – vala (" ") ji bo min.
2. Bixin RAST wekî argumana duyemîn ji bo derbasbûna şaneyên vala an jî FALSE ji bo ku wan di encamê de bihewîne.
3. Rêbera ku ji bo yekbûnê têkevin.

Di Google Sheets de bi veqetandina rêzê re têkildar bin

Her çend eşkere ye ku meriv çawa piraniya veqetankeran têxe fonksiyonê, hûn nekarin li wir bi heman rengî şikestinekê binivîsin. Lê bextewar Google dihêle hûn gelek kartên cihêreng bilîzin.

Fonksiyonek heye ku ji bo bidestxistina karakterên taybetî dibe alîkar - jê re CHAR tê gotin. Hûn dibînin, her karakter di tabloya Unicode de cîhek heye. Tenê pêdivî ye ku hûn jimareya rêzî ya karakterê ji wê tabloyê bixin fonksiyonê û ya paşîn dê karakterê bi xwe vegerîne.

Li vir formulek heye ku ji bo veqetandina rêzê bigire:

=CHAR(10)

Wê têxe formulê da ku bi şiklê rêzê ve di Pelên Google-ê de were girêdan:

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)

Dîrok û demjimêr di Google Sheets de bidin hev

Heke hûn hewl bidin ku bi yek ji rêbazan dîrok û demjimêrê di Google Sheets de bi hev re bikinli jor, ew ê nexebite. Rûpelê we yê berbelav wê hejmaran vegerîne:

Ji bo ku di Google Sheets de dîrok û dem rast tevbigerin, fonksiyona TEXT bikar bînin:

• li cihê ku hejmar her hejmar, tarîx, an dema ku hûn dixwazin di forma xwestî de bi dest bixin
• û format qalibê ku hûn dixwazin bikin e. encamê bibînin.

Tip. Di mînaka min de, ez ê şaneyên bi tarîx û demjimêran re referans bikim, lê hûn azad in ku hûn yekîneyên tarîx/demê an jî fonksiyonên wekî DATE an TIME rasterast di formula de bikar bînin.

1. Ez formula TEXT ya yekem bikar tînim da ku formata tarîxê ji 7/9/2019 berbi 9 tîrmeh 2019 :

   =TEXT(B2,"D MMM YYYY")

2. TEXT-ya duyemîn wextê vedigerîne:

   =TEXT(C2,"HH:MM:SS")

3. Bi karanîna van li CONCATENATE, Google Sheets dihêle ku ez tarîx û demjimêrê di forma xwestî de bi tîpên din an nivîsarên din re berhev bikim:

   =CONCATENATE(TEXT(B2,"D MMM YYYY"),", ",TEXT(C2,"HH:MM:SS"))

Di Google Sheets de stûnan bidin hev

Bi verastkirinên sivik, hemî awayên ku min behs kirin dikarin stûnên di Google Sheets de bikin yek.

Mînak 1. Google Sheets CONCAT

Ji bo ku tev stûnên di Google Sheets bi CONCAT re bibin yek, tevahiya rêza ku divê encam dihewîne hilbijêrin (C2:C11 di rewşa min de) û pelçiqandina formula xwe binivîse ew di ARRAYFORMULA de:

=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))

Nîşe. Hûn dikarin fonksiyona CONCATENATE bikar bînin, lê ew ê di nav yek hucreyê de tev li hemî tomaran bibe ji ber ku ew bi hêsanî gelek hucre û rêzikên daneyê digihîne hev.

Mînak 2.Operatorê hevgirtinê

Formulên rêzê biafirînin da ku stûnên di Google Sheets de bi karanîna ampersand-ê bi hev veqetînin û di heman demê de veqetandaran lê zêde bikin:

=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)

Ev baş xuya dike, lê divê ez hin kêmasiyên mezin destnîşan bikim.

Heke gelek stûnên we hebin, jimartina wan hemiyan dikare bibe êşek di stûyê de, nemaze heke hûn bi xeletî her karakteran bavêjin/duber bikin/ tevlihev bikin. .

Herwiha, ger hûn biryar bidin ku paşê stûnên din li formulê zêde bikin, divê hûn her rêzeka heyî ya di formulê de bi destan biguherînin.

Mînaka din van pirsgirêkan çareser dike.

Mînak 3. Google Sheets QUERY

Fonksiyon Google Sheets QUERY ji bo yekkirina çend stûnên Google Sheets jî guncan e. Binêrin:

=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))

Dibe ku hûn difikirin ku ev formula xerîb ji destê we nayê, lê bila ez hemî perçeyên wê ji we re ragihînim:

1. =TRANSPOSE(A2:D10) rêzên daneyan dizivirîne stûnan.
2. =QUERY(TRANSPOSE(A2:D10),,9^9) tomarên di her stûnekê de li hev dike hucreyên jorîn.

   Tip. Dema ku min 9^9 xiste nav formulê, ez piştrast dikim ku hemî rêzên ji hemî stûnan dê di rêza yekem de werin kişandin mîna ku ew sernivîs bin. Ew 9^9 e ji ber ku ev biwêj hemî şaneyên mimkun di pelgeyê de vedihewîne (sînorê şaneyên 10M bi bîr tîne?) û bi hêsanî tê bîranîn. :)

3. =TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9)) wê rêza sernivîsê ji QUERY digire û vedigerîne stûnek mînayeka ku min heye.

Li vir feydeyên yekkirina stûnên di Google Sheets de bi karanîna QUERY hene:

• ne hewce ye ku hûn wekî ku hûn dikin tevahiya stûnê hilbijêrin ji bo formulên rêzê
• hûn ne hewce ne ku her stûnek di formulê de behs bikin heya ku ew ne cîran bin. Di vê rewşê de, li vir formula dê çawa xuya bike:

  =TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

Nivîs bi pozîsyonê ve girêbide û lê zêde bike

Hûn berê dizanin ku hûn dikarin nivîsa wenda, hejmaran lê zêde bikin. , û tîpên rêzikên we bi karûbarê CONCATENATE bikar bînin.

Serişte. Zêdetir formulên li ser wê di vê tutoriyê de bibînin.

Lê heke gelek tomar hene ku tevlê bibin, her karakterên zêde dikarin formula we ji ya ku we plan kiriye wêdetir dirêj bike. Di rewşên bi vî rengî de, çêtir e ku hûn şaneyên di Google Sheets de wekî wan werin yek kirin an jî veqetandekên hêsan ên mîna cîh bikar bînin û piştî wê nivîsê zêde bikin. Amûrek me ya taybetî dê ji we re bibe alîkar.

Nivîs bi pozîsyonê zêde bikin, her tîp û rêzan li gorî pozîsyona ku hûn diyar dikin têxe, tu formulas ne hewce ye. Bihêle ez nîşanî we bidim ka ew çawa dixebite.

Di mînaka berê de QUERY ji bo min nav û hejmarên têlefonê li hev kir. Lê ez dixwazim kurtenivîsên welat lê zêde bikim: (USA/CA) berî hejmarên têlefonê yên ku bi +1 dest pê dikin û UK berî +44 :

Di Google Sheets de şaneyan ji hev veqetînin

Heke hûn di Google Sheets de şaneyan li hev bikin, îhtîmal heye ku hûn hewce ne ku wan carek din ji hev veqetînin. . Sê awayên kirina wê hene:

1. Formulek çêbikinkarûbarê SPLIT-ê Google Sheets bikar tîne.
2. Amûra pelgeya berbelav a standard bikar bînin – Nivîsar li stûnan dabeş bikin.
3. An jî guhertoya pêşkeftî ya amûra navmalî biceribînin – Ji bo Google Sheets nivîsê li stûnan dabeş bikin:

Ew dihêle hûn hucreyan bi her veqetanker an jî hetta komek veqetanker veqetînin, wan wekî yek bihesibînin û heke hewce be pêwendiyan tê de bikin. Di heman demê de vebijarka dabeşkirina hucreyên di Google Sheets de li gorî pozîsyonê jî pêşkêşî dike.

Tip. Vebijarkek heye ku meriv daneyan ji şaneyên Google Sheets derxe li şûna perçekirina naverokê.

Hûn çawa di Google Sheets de bêyî formul hucreyan bikin yek

Heke serwerkirina formulên cihê ne beşek ji plana we be, hûn ê ji pêveka meya Merge Values ​​sûd werbigirin. Pêvek zû di rêz, stûn, an tevahiya rêza hucreyan de tomaran dike. Vebijarkên wê zelal in, û tiştê ku hûn bikin ev e ku rêzê hilbijêrin û biryarê bidin ka encam çawa xuya dike.

1. Hûn dikarin di Google Sheets de stûnan berhev bikin — yên ne cîran jî, wan bi kommas û valahiyan ji hev veqetînin û encamê li rastê tomarên orîjînal bixin:

Heke we bi amûrê re eleqedar bû, hûn dikarin lê binêrinBi her tiştê ku ew li ser vê rûpelê taybetî an jî di vê dersa vîdyoya kurt de dike:

Fêr bibe ka meriv çawa di vê vîdyoyê de Rêzên Ducarî Têkel Bikin :

Ez hêvî dikim heya niha we biryar daye ka kîjan ji awayan herî baş li gorî doza we ye. Ger di hişê we de rêbazên din hene, ji kerema xwe di beşa şîroveyan de li jêr bi me re parve bikin :)