Mục lục
"Nối" thường có nghĩa là liên kết một thứ gì đó lại với nhau thành một chuỗi hoặc một chuỗi. Thao tác này được sử dụng bất cứ khi nào bạn cần nối văn bản từ nhiều ô trong Google Trang tính. Bài viết này thu thập các giải pháp phổ biến và dễ dàng nhất để giúp bạn giải câu đố ghép nối.
Cho dù tập dữ liệu của bạn có lớn đến đâu, bạn vẫn có thể gặp phải nhiệm vụ kết hợp nhiều ô trong Google Trang tính lại với nhau. Và tôi chắc chắn rằng bạn sẽ không chỉ muốn giữ cho tất cả các giá trị không bị mất mà còn thêm một số dấu phẩy, dấu cách hoặc các ký tự khác hay thậm chí là tách các bản ghi đó bằng văn bản khác.
Chà, bảng tính cung cấp một số công cụ cho tác vụ này.
Hàm CONCAT của Google Trang tính
Hàm CONCAT là phiên bản đơn giản hóa của Google Trang tính CONCATENATE:
=CONCAT(value1, value2)Để nối các ô bằng chức năng này, bạn cần liệt kê các giá trị bắt buộc:
- giá trị1 – bản ghi mà giá trị2 sẽ được nối vào.
- value2 – giá trị để nối.
Để lấy một chuỗi từ 2 đơn vị văn bản hoặc số, công thức sẽ như bên dưới, với mỗi bản ghi nằm trong dấu ngoặc kép:
=CONCAT("2019:","The Lion King")
Trên thực tế, rất có thể dữ liệu của bạn đã có sẵn trong các ô. Bạn có thể tham khảo trực tiếp các ô đó thay vì đặt từng số hoặc văn bản làm đối số. Vì vậy, công thức dữ liệu thực sẽ như sau:
=CONCAT(A2,B2)
Mẹo. Để sao chép công thức của bạn vào toàn bộ cột, hãy chọn ôvới công thức và bấm đúp vào hình vuông nhỏ ở góc dưới cùng bên phải của ô. Toàn bộ cột sẽ được tự động điền bằng công thức, cho đến cuối bảng.
Như bạn có thể thấy, chức năng này cực kỳ đơn giản, nhưng nó có điểm yếu lớn :
- nó chỉ hợp nhất hai ô trong Google Trang tính cùng một lúc.
- nó không thể kết hợp các cột, hàng hoặc các phạm vi dữ liệu lớn khác, nó chỉ lấy các ô đơn lẻ. Nếu cố nối nhiều ô, bạn sẽ gặp lỗi hoặc chỉ hai giá trị đầu tiên được nối, như sau:
=CONCAT(A2:A11,B2:B11)
Thay thế CONCAT: toán tử nối dấu và (&)
Có rất nhiều toán tử khác nhau cho các mục đích khác nhau trong công thức. Ghép nối không phải là một ngoại lệ. Sử dụng ký tự dấu và (&) trong công thức thay vì hàm CONCAT sẽ cung cấp cho bạn kết quả tương tự:
=A2&B2
Nhưng bạn có biết rất ít rằng toán tử nối này linh hoạt hơn. Đây là những gì nó có thể làm:
- Hợp nhất nhiều hơn hai giá trị cùng một lúc:
=A2&B2&C2
- Không chỉ hợp nhất các ô trong Google Trang tính mà còn phân tách chúng bằng các ký tự khác nhau:
=A2&" "&B2&"; "&C2
Nếu bạn vẫn không nhận được kết quả mong muốn với các tùy chọn này , còn một chức năng nữa để thử.
Cách sử dụng CONCATENATE trong Google Trang tính
Tôi tin rằng chức năng CONCATENATE trong Google Trang tính là chức năng đầu tiên sử dụngkhi nói đến việc nối nhiều bản ghi lại với nhau.
KẾT HỢP chuỗi văn bản và số trong Google Trang tính
Mẫu công thức bao gồm các đối số sau:
=CONCATENATE(string1, [string2, . ..])- string1 là chuỗi đầu tiên bạn muốn nối các giá trị khác vào. Đối số này là bắt buộc.
- string2, … là viết tắt của tất cả các chuỗi khác mà bạn có thể muốn nối thêm. Đối số này là tùy chọn.
Lưu ý. Bản ghi kết quả sẽ bao gồm các chuỗi theo thứ tự xuất hiện của chúng trong công thức.
Nếu tôi điều chỉnh công thức cho phù hợp với dữ liệu của mình, tôi sẽ nhận được:
=CONCATENATE(A2,B2,C2)
Hoặc, vì hàm chấp nhận các khoảng:
=CONCATENATE(A2:D2)
Bạn có thể nhận thấy ngay ưu điểm đầu tiên của Google Trang tính CONCATENATE: tính năng này dễ dàng nối hai ô có cả văn bản và số.
Google Trang tính: nối chuỗi bằng dấu phân cách
Kết hợp các ô trong Google Trang tính là một nửa công việc. Nhưng để làm cho kết quả trông đẹp mắt và dễ đọc, bạn nên thêm một số ký tự bổ sung.
Nếu bạn giữ nguyên công thức, nó sẽ chỉ dán mọi thứ lại với nhau: BonnieJacksonCA , BonnieJacksonIN , v.v. Tuy nhiên, Google Trang tính CONCATENATE cũng lấy các ký tự làm đối số.
Vì vậy, để thêm một số dấu phân tách để dễ đọc, hãy đề cập chúng trong dấu ngoặc kép trong công thức:
=CONCATENATE(A2," ",B2,", ",C2)
Ở đây tôi muốn nối A2 & B2 bằng dấu cách và tách B2 khỏi C2 bằng dấu phẩy vàdấu cách:
Bạn có thể tự do sử dụng hầu hết mọi ký tự trong hàm như thế này, tuy nhiên, dấu ngắt dòng yêu cầu một cách tiếp cận khác.
Mẹo. Trong trường hợp có các ô trống trong một số cột mà bạn đang hợp nhất, có một chức năng khác mà bạn có thể quan tâm. TEXTJOIN không chỉ hợp nhất các ô trong Google Trang tính mà còn bỏ qua các ô trống:
=TEXTJOIN(" ",TRUE,A2:C2)
Đây là cách nó hoạt động:
- Cho tôi biết dấu phân cách mong muốn làm đối số đầu tiên – dấu cách (" ") cho tôi.
- Đặt TRUE làm đối số thứ hai để bỏ qua các ô trống hoặc FALSE để đưa chúng vào kết quả.
- Nhập phạm vi để hợp nhất.
Nối với dấu ngắt dòng trong Google Trang tính
Mặc dù rõ ràng là cách nhập hầu hết các dấu phân cách cho hàm, nhưng bạn không thể nhập dấu ngắt dòng theo cùng một cách ở đó. Nhưng thật may là Google cho phép bạn chơi nhiều loại thẻ khác nhau.
Có một chức năng giúp lấy các ký tự đặc biệt – đó là chức năng CHAR. Bạn thấy đấy, mỗi ký tự có một vị trí trong bảng Unicode. Bạn chỉ cần nhập số thứ tự của ký tự từ bảng đó vào hàm và hàm sau sẽ trả về chính ký tự đó.
Đây là công thức để ngắt dòng:
=CHAR(10)
Thêm nó vào công thức để nối với dấu ngắt dòng trong Google Trang tính:
=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)
Kết hợp ngày và giờ trong Google Trang tính
Nếu bạn cố gắng kết hợp ngày và giờ trong Google Trang tính bằng một trong các phương phápở trên, nó sẽ không hoạt động. Bảng tính của bạn sẽ trả về các số:
Để kết hợp chính xác ngày và giờ trong Google Trang tính, hãy sử dụng hàm TEXT:
=TEXT(số, định dạng)- trong đó số là bất kỳ số, ngày tháng hoặc thời gian nào bạn muốn nhận ở định dạng mong muốn
- và định dạng là mẫu bạn muốn hãy xem kết quả.
Mẹo. Trong ví dụ của tôi, tôi sẽ tham chiếu các ô có ngày và giờ, nhưng bạn có thể tự do sử dụng các đơn vị ngày/giờ hoặc thậm chí các hàm như NGÀY hoặc GIỜ trực tiếp trong công thức.
- Tôi sử dụng công thức TEXT đầu tiên để thay đổi định dạng ngày từ 7/9/2019 thành 9/7/2019 :
=TEXT(B2,"D MMM YYYY") - Văn bản thứ hai trả về thời gian:
=TEXT(C2,"HH:MM:SS") - Khi sử dụng những giá trị này trong CONCATENATE, Google Trang tính cho phép tôi kết hợp ngày và giờ ở định dạng mong muốn với các ký tự hoặc văn bản khác:
=CONCATENATE(TEXT(B2,"D MMM YYYY"),", ",TEXT(C2,"HH:MM:SS"))
Kết hợp các cột trong Google Trang tính
Với những điều chỉnh nhỏ, tất cả các cách tôi đã đề cập đều có khả năng hợp nhất các cột trong Google Trang tính.
Ví dụ 1. Google Trang tính CONCAT
Để hợp nhất toàn bộ cột trong Google Trang tính với CONCAT, hãy chọn toàn bộ dải ô chứa kết quả (trong trường hợp của tôi là C2:C11) và nhập gói công thức của bạn nó trong ARRAYFORMULA:
=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))
Lưu ý. Bạn có thể sử dụng hàm CONCATENATE, nhưng hàm này sẽ nối tất cả các bản ghi trong một ô vì nó dễ dàng hợp nhất nhiều ô và phạm vi dữ liệu.
Ví dụ 2.Toán tử nối
Tạo công thức mảng để kết hợp các cột trong Google Trang tính bằng cách sử dụng dấu và đồng thời thêm dấu phân cách:
=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)
Điều này có vẻ tốt, nhưng tôi phải chỉ ra một số nhược điểm chính.
Nếu bạn có quá nhiều cột, việc liệt kê tất cả các cột có thể trở nên khó khăn, đặc biệt nếu bạn vô tình bỏ qua/trùng lặp/nhầm lẫn bất kỳ ký tự nào .
Ngoài ra, nếu bạn quyết định thêm nhiều cột hơn vào công thức sau này, bạn sẽ phải chỉnh sửa từng và mọi phạm vi hiện có trong công thức theo cách thủ công.
Ví dụ tiếp theo sẽ giải quyết những vấn đề này.
Ví dụ 3. Google Trang tính QUERY
Hàm Google Trang tính QUERY cũng phù hợp để hợp nhất một số cột trong Google Trang tính. Hãy xem:
=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))
Bạn có thể nghĩ rằng công thức kỳ lạ này nằm ngoài tầm hiểu biết của mình, nhưng hãy để tôi trình bày tất cả các chi tiết của nó cho bạn:
- =TRANSPOSE(A2:D10) biến các hàng dữ liệu thành các cột.
- =QUERY(TRANSPOSE(A2:D10),,9^9) hợp nhất các bản ghi trong mỗi cột vào tế bào trên cùng.
Mẹo. Khi tôi đặt 9^9 vào công thức, tôi đảm bảo rằng tất cả các hàng từ tất cả các cột sẽ được kéo vào hàng đầu tiên như thể chúng là các tiêu đề. Nó là 9^9 vì biểu thức này bao gồm tất cả các ô có thể có trong bảng tính (bạn có nhớ giới hạn cho 10 triệu ô không?) và rất dễ nhớ. :)
- =TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9)) lấy hàng tiêu đề đó từ QUERY và biến nó thành một cột nhưmột cái tôi có.
Dưới đây là các đặc quyền của việc hợp nhất các cột trong Google Trang tính bằng QUERY:
- bạn không cần phải chọn toàn bộ cột như vẫn làm đối với công thức mảng
- bạn không cần đề cập đến từng cột trong công thức trừ khi chúng không liền kề nhau. Trong trường hợp này, đây là giao diện của công thức:
=TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))
Nối và thêm văn bản theo vị trí
Bạn đã biết rằng mình có thể thêm văn bản, số bị thiếu và các ký tự cho chuỗi của bạn bằng cách sử dụng hàm CONCATENATE.
Mẹo. Xem thêm các công thức về điều đó trong hướng dẫn này.
Nhưng nếu có quá nhiều bản ghi để tham gia, bất kỳ ký tự thừa nào cũng có thể mở rộng công thức của bạn ra ngoài những gì bạn đã lên kế hoạch. Trong những trường hợp như thế này, tốt hơn hết bạn nên hợp nhất các ô trong Google Trang tính như hiện tại hoặc sử dụng các dấu phân cách đơn giản như dấu cách và thêm văn bản sau đó. Một công cụ đặc biệt của chúng tôi sẽ giúp bạn.
Thêm văn bản theo vị trí sẽ chèn bất kỳ ký tự và chuỗi nào theo vị trí bạn chỉ định, không cần công thức. Để tôi chỉ cho bạn cách nó hoạt động.
Trong ví dụ trước, QUERY đã kết hợp tên và số điện thoại cho tôi. Nhưng tôi muốn thêm chữ viết tắt quốc gia: (USA/CA) trước các số điện thoại bắt đầu bằng +1 và UK trước +44 :
Tách ô trong Google Trang tính
Nếu kết hợp các ô trong Google Trang tính, có thể bạn sẽ cần phải tách chúng lại vào một lúc nào đó . Có ba cách để làm điều đó:
- Xây dựng công thứcsử dụng chức năng SPLIT của Google Trang tính.
- Sử dụng công cụ bảng tính tiêu chuẩn – Chia văn bản thành cột.
- Hoặc dùng thử phiên bản nâng cao của công cụ tích hợp sẵn – Chia văn bản thành cột cho Google Trang tính:
Tính năng này cho phép bạn tách các ô bằng bất kỳ dấu phân cách hoặc thậm chí các bộ dấu phân cách nào, coi chúng là một và bao gồm các liên từ nếu cần. Nó cũng cung cấp tùy chọn chia ô trong Google Sheets theo vị trí.
Mẹo. Có một tùy chọn để trích xuất dữ liệu từ các ô trong Google Trang tính thay vì chia nhỏ nội dung.
Cách hợp nhất các ô trong Google Trang tính mà không cần công thức
Nếu việc thành thạo các công thức khác nhau không nằm trong kế hoạch của bạn, thì bạn sẽ hưởng lợi từ tiện ích bổ sung Giá trị hợp nhất của chúng tôi. Tiện ích bổ sung nhanh chóng kết hợp các bản ghi trong hàng, cột hoặc toàn bộ phạm vi ô. Các tùy chọn của nó rất rõ ràng và tất cả những gì bạn phải làm là chọn phạm vi và quyết định xem kết quả sẽ trông như thế nào.
- Bạn có thể chọn kết hợp các cột trong Google Trang tính — ngay cả những bản ghi không liền kề, hãy phân tách chúng bằng dấu phẩy và dấu cách, đồng thời đặt kết quả ở bên phải bản ghi gốc:
Nếu bạn quan tâm đến công cụ này, bạn có thể xemthông qua mọi thứ nó thực hiện trên trang đặc biệt này hoặc trong video hướng dẫn ngắn này:
Tìm hiểu cách sử dụng Kết hợp các hàng trùng lặp trong video này :
Tôi hy vọng bây giờ bạn đã quyết định được cách nào phù hợp nhất với trường hợp của mình. Nếu bạn có bất kỳ phương pháp nào khác, vui lòng chia sẻ với chúng tôi trong phần bình luận bên dưới :)
