V učbeniku je prikazano, kako ustvariti spustni seznam Excel, ki je odvisen od druge celice, z uporabo novih dinamičnih funkcij polja.

Ustvarjanje preprostega spustnega seznama v Excelu je enostavno. Ustvarjanje večnivojskega kaskadnega spustnega seznama je bilo vedno izziv. V zgornjem povezanem priročniku so opisani štirje različni pristopi, od katerih vsak vključuje noro število korakov, množico različnih formul in peščico omejitev v zvezi z večbesednimi vnosi, praznimi celicami itd.

Dobra novica je, da so bile te metode zasnovane za različice Excela pred dinamično uporabo. Uvedba dinamičnih polj v Excelu 365 je spremenila vse! Z novimi funkcijami dinamičnih polj je ustvarjanje spustnega seznama z več odvisnimi elementi vprašanje nekaj minut, če ne celo sekund. Brez trikov, opozoril in nesmislov. Samo hitre, preproste in enostavne rešitve.

Opombe:

• Ta novi dinamični način izdelave spustnih seznamov deluje samo v Excelu 365 in Excelu 2021. V preddinamičnem Excelu boste morali to narediti na star način, kot je opisano v poglavju Ustvarjanje odvisnega spustnega seznama v Excelu 2019 - 2007.
• Ta rešitev velja za eno vrstico. Če želite kopirati izbirne sezname navzdol več vrstic , nato sledite navodilom v spustnem seznamu Odvisno za več vrstic.

Kako narediti dinamični spustni seznam v Excelu

Ta primer prikazuje splošni pristop k ustvarjanju kaskadnega spustnega seznama v Excelu z uporabo novih funkcij dinamičnega polja.

Recimo, da imate seznam sadja v stolpcu A in izvoznikov v stolpcu B. Dodaten zaplet je, da imena sadja niso razvrščena v skupine, ampak so razpršena po stolpcu. Cilj je v prvi spustni meni prikazati edinstvena imena sadja, v drugem spustnem meniju pa glede na uporabnikovo izbiro prikazati ustrezne izvoznike.



Če želite v Excelu ustvariti dinamični odvisni spustni seznam, naredite naslednje korake:

1. Pridobite elemente za glavni spustni seznam

Za začetek bomo iz stolpca A izluščili vsa različna imena sadja. To lahko storimo z uporabo funkcije UNIQUE v njeni najpreprostejši obliki - kot prvi argument navedemo seznam sadja ( polje ) in izpustite preostale neobvezne argumente, saj nam delujejo kot privzeti:

=UNIQUE(A3:A15)

Formula se prenese v G3, po pritisku tipke Enter pa se rezultati samodejno prelijejo v naslednje celice.



Poglej tudi: Excelova funkcija TRIM - hiter način za odstranjevanje dodatnih presledkov

2. Ustvarite glavni spustni seznam

Če želite ustvariti primarni spustni seznam, konfigurirajte pravilo Excel Data Validation na ta način:

• Izberite celico, v kateri želite prikazati spustno okno (v našem primeru D3).
• Na Podatki v zavihku Podatkovna orodja skupino, kliknite Potrjevanje podatkov .
• V Potrjevanje podatkov v pogovornem oknu naredite naslednje:
  • Pod naslovom Omogočite , izberite Seznam .
  • V Vir: vnesite sklic na razpon razlitja, ki ga izpiše formula UNIQUE. Pri tem vnesite oznako hash takoj za sklicem na celico, kot na primer: =$G$3#

    To se imenuje referenca na razlivno območje in ta sintaksa se nanaša na celotno območje ne glede na to, koliko se razširi ali skrči.

  • Kliknite . V REDU da zaprete pogovorno okno.

  

Vaš primarni spustni seznam je pripravljen!



3. Pridobite elemente za odvisni spustni seznam

Da bi dobili vnose za drugi spustni meni, bomo filtrirali vrednosti v stolpcu B na podlagi vrednosti, izbrane v prvem spustnem meniju. To lahko storimo s pomočjo druge funkcije dinamičnega polja, imenovane FILTER:

=FILTER(B3:B15, A3:A15=D3)

Pri čemer so B3:B15 izvorni podatki za odvisno padajočo celico, A3:A15 izvorni podatki za glavno padajočo celico, D3 pa je glavna padajoča celica.

Če želite preveriti, ali formula deluje pravilno, lahko na prvem spustnem seznamu izberete neko vrednost in opazujete rezultate, ki jih vrne FILTER. Odlično! :)



4. Naredite odvisni spustni seznam

Če želite ustvariti drugi spustni seznam, konfigurirajte merila za preverjanje podatkov enako kot za prvi spustni seznam v koraku 2. Vendar se tokrat sklicujte na razpon razlitja, ki ga vrne funkcija FILTER: =$H$3#



To je to! Vaš spustni seznam, odvisen od programa Excel, je pripravljen za uporabo.



Nasveti in opombe:

• Če želite imeti vključeni novi vnosi v spustnem seznamu samodejno , svoje izvorne podatke oblikujte kot Excelovo tabelo. Lahko pa v formule vključite nekaj praznih celic, kot je prikazano v tem primeru.
• Če so v izvirnih podatkih vrzeli, lahko filtriranje praznih mest z uporabo te rešitve.
• Na naslov razvrščanje po abecedi elementov spustne vrstice, formule zavijte v funkcijo SORT, kot je razloženo v tem primeru.

Kako ustvariti več odvisnih spustnih seznamov v Excelu

V prejšnjem primeru smo ustvarili spustni seznam, ki je odvisen od druge celice. Kaj pa, če potrebujete večnivojsko hierarhijo, tj. 3. spustni seznam, ki je odvisen od 2. seznama, ali celo 4. spustni seznam, ki je odvisen od 3. seznama. Je to mogoče? Da, lahko nastavite poljubno število odvisnih seznamov (razumno število, seveda :).

V tem primeru smo v stolpec C postavili države/pokrajine, v G3 pa želimo dodati ustrezen spustni meni:



Če želite v Excelu ustvariti več odvisnih spustnih seznamov, morate storiti naslednje:

1. Nastavite prvi spustni seznam

Glavni spustni seznam je ustvarjen z enakimi koraki kot v prejšnjem primeru (glejte korake 1 in 2 zgoraj). Edina razlika je v referenčnem območju razlitja, ki ga vnesete v polje Vir: škatla.

Tokrat je formula UNIQUE v E8, glavni spustni seznam pa bo v E3. Izberete E3, kliknete Potrjevanje podatkov in navedite to referenco: =$E$8#



2. Konfigurirajte drugi spustni seznam

Kot ste morda opazili, stolpec B zdaj vsebuje več pojavitev istih izvoznikov. Toda na spustnem seznamu želite imeti samo edinstvena imena, kajne? Če želite izločiti vse podvojene pojavitve, okoli formule FILTER ovijte funkcijo UNIQUE in vnesite to posodobljeno formulo v F8:

=UNIQUE(FILTER(B3:B15, A3:A15=E3))

Pri čemer so B3:B15 izvorni podatki za drugo spustno okno, A3:A15 izvorni podatki za prvo spustno okno, E3 pa je prva celica spustnega okna.

Nato za merila za preverjanje podatkov uporabite naslednje referenčno območje razlitja: =$F$8#



3. Nastavite tretji spustni seznam

Za zbiranje elementov za 3. spustni seznam uporabite formulo FILTER z več merili. Prvo merilo preveri celoten seznam sadja glede na vrednost, izbrano v 1. spustnem seznamu (A3:A15=E3), drugo merilo pa preveri seznam izvoznikov glede na izbiro v 2. spustnem seznamu (B3:B15=F3). Celotna formula je v G8:

=FILTER(C3:C15, (A3:A15=E3) * (B3:B15=F3))

Če boste dodali več odvisnih spustnih vrstic (4., 5. itd.), bo stolpec C najverjetneje vseboval več pojavitev istega elementa. Če želite preprečiti, da bi se podvojeni elementi pojavili v pripravljalni tabeli in posledično v 3. spustni vrstici, uporabite formulo FILTER v funkciji UNIQUE, kot smo storili v prejšnjem koraku:

=UNIQUE(FILTER(C3:C15, (A3:A15=E3) * (B3:B15=F3)))

Nazadnje morate ustvariti še eno pravilo za preverjanje podatkov, in sicer s tem Vir: referenca: =$G$8#



Vaš spustni seznam z več odvisniki je pripravljen za uporabo!



Nasvet. Na podoben način lahko dobite predmete za nadaljnji spustni seznami Če stolpec D vsebuje izvorne podatke za vaš 4. spustni seznam, lahko vnesete naslednjo formulo v H8, da pridobite ustrezne elemente:

=UNIQUE(FILTER(D3:D15, (A3:A15=E3) * (B3:B15=F3) * (C3:C15=G3)))

Kako ustvariti razširljiv spustni seznam v Excelu

Ko ustvarite spustni seznam, vas bo morda najprej zanimalo, kaj se zgodi, ko v izvorne podatke dodate nove elemente. Ali se bo spustni seznam samodejno posodobil? Če so izvorni podatki oblikovani kot tabela Excel, potem se bo dinamični spustni seznam, obravnavan v prejšnjih primerih, samodejno razširil brez vašega truda, saj so tabele Excel po svoji naravi razširljive.

Poglej tudi: Dodajanje vrstic v Google Sheets, brisanje, zamrznitev ali odklepanje vrstic

Če uporaba Excelove tabele ni mogoča, lahko spustni seznam razširite na ta način:

• Na naslov vključiti nove podatke. samodejno, ko se doda na seznam virov, dodajte nekaj dodatnih celic v polja, na katera se sklicujejo vaše formule.
• Na naslov izključite prazne celice , konfigurirajte formule tako, da ne upoštevajo praznih celic, dokler se ne zapolnijo.

Ob upoštevanju teh dveh točk natančno prilagodimo formule v naši tabeli za pripravo podatkov. Pravila za preverjanje podatkov ne zahtevajo nobenih prilagoditev.

Formula za glavno spustno okno

Z imeni sadja v A3:A15 v polje dodamo 5 dodatnih celic za morebitne nove vnose. Poleg tega v funkcijo UNIQUE vgradimo funkcijo FILTER, da izločimo edinstvene vrednosti brez praznih mest.

Glede na zgoraj navedeno je formula v G3 takšna:

=UNIQUE(FILTER(A3:A20, A3:A20""))

Formula za odvisno spustno okno

Formule v G3 ni treba veliko prilagajati - le razširite polja z nekaj več celicami:

=FILTER(B3:B20, A3:A20=D3)

Rezultat je popolnoma dinamičen razširljiv odvisni spustni seznam:



Kako razvrstiti spustni seznam po abecedi

Želite razvrstiti spustni seznam po abecedi, ne da bi se pri tem posluževali izvornih podatkov? Novi dinamični Excel ima posebno funkcijo tudi za to! V tabeli za pripravo podatkov preprosto ovijte funkcijo SORT okoli obstoječih formul.

Pravila za preverjanje podatkov so konfigurirana natanko tako, kot je opisano v prejšnjih primerih.

Razvrščanje od A do Ž

Ker je privzeta možnost naraščajoče razvrščanje, lahko obstoječe formule vnesete v polje argumenta SORT, pri čemer izpustite vse druge argumente, ki so neobvezni.

Za glavna padajoča vrstica (formula v G3):

=SORT(UNIQUE(FILTER(A3:A20, A3:A20"")))

Za odvisna padajoča vrstica (formula v H3):

=SORT(FILTER(B3:B20, A3:A20=D3))

Končano! Oba spustna seznama sta razvrščena po abecedi od A do Ž.



Razvrščanje od Z do A

Če želite razvrščati po padajočem vrstnem redu, morate nastaviti tretji argument ( sort_order ) funkcije SORT na -1.

Za glavna padajoča vrstica (formula v G3):

=SORT(UNIQUE(FILTER(A3:A20, A3:A20"")), 1, -1)

Za odvisna padajoča vrstica (formula v H3):

=SORT(FILTER(B3:B20, A3:A20=D3), 1, -1)

S tem boste razvrstili podatke v pripravljalni tabeli in elemente na spustnih seznamih od Z do A:



Tako lahko v Excelu ustvarite dinamični spustni seznam s pomočjo novih funkcij dinamičnega polja. V nasprotju s tradicionalnimi metodami ta pristop odlično deluje za eno- in večbesedne vnose ter poskrbi za vse prazne celice. Hvala za branje in upam, da se naslednji teden vidimo na našem blogu!

Praktični delovni zvezek za prenos

Excelov odvisni spustni seznam (.xlsx datoteka)