Tutorial menunjukkan cara membuat senarai lungsur turun Excel bergantung pada sel lain dengan menggunakan fungsi tatasusunan dinamik baharu.

Membuat senarai juntai bawah mudah dalam Excel adalah mudah. Membuat drop-down lata berbilang peringkat sentiasa menjadi cabaran. Tutorial yang dipautkan di atas menerangkan empat pendekatan berbeza, setiap satu termasuk beberapa langkah yang gila, sekumpulan formula yang berbeza dan segelintir pengehadan yang berkaitan dengan entri berbilang perkataan, sel kosong, dll.

Itulah keburukan berita. Berita baiknya ialah kaedah tersebut telah direka untuk versi pra-dinamik Excel. Pengenalan tatasusunan dinamik dalam Excel 365 telah mengubah segala-galanya! Dengan fungsi tatasusunan dinamik baharu, mencipta senarai juntai bawah bergantung berbilang memerlukan masa beberapa minit, jika tidak beberapa saat. Tiada helah, tiada kaveat, tiada karut. Hanya penyelesaian yang pantas, mudah dan mudah diikuti.

Nota:

• Cara tatasusunan dinamik baharu ini untuk membuat senarai lungsur turun hanya berfungsi dalam Excel 365 dan Excel 2021. Dalam Excel pra-dinamik, anda perlu melakukannya dengan cara lama seperti yang diterangkan dalam Mencipta lungsur turun bergantung dalam Excel 2019 - 2007.
• Penyelesaian ini adalah untuk satu baris. Jika anda ingin menyalin senarai pilihan anda ke bawah berbilang baris , kemudian ikut arahan dalam senarai juntai bawah Bergantung untuk berbilang baris.

Cara membuat senarai lungsur turun dinamik dalam Excel

Contoh ini menunjukkan umumpendekatan untuk mencipta senarai juntai bawah dalam Excel dengan menggunakan fungsi tatasusunan dinamik baharu.

Andaikan anda mempunyai senarai buah dalam lajur A dan pengeksport dalam lajur B. Komplikasi tambahan ialah nama buah-buahan tidak berkumpulan tetapi bertaburan di seluruh lajur. Matlamatnya adalah untuk meletakkan nama buah unik dalam menu lungsur pertama dan bergantung pada pilihan pengguna tunjukkan pengeksport yang berkaitan dalam lungsur kedua.



Untuk mencipta senarai juntai bawah bergantung dinamik dalam Excel, jalankan langkah berikut:

1. Dapatkan item untuk senarai juntai bawah utama

Sebagai permulaan, kami akan mengekstrak semua nama buah yang berbeza dari lajur A. Ini boleh dilakukan dengan menggunakan fungsi UNIK dalam bentuk paling mudah - sediakan senarai buah untuk hujah pertama ( array ) dan tinggalkan baki argumen pilihan kerana lalainya berfungsi dengan baik untuk kita:

=UNIQUE(A3:A15)

Formula pergi ke G3 dan selepas menekan kekunci Enter keputusan tumpah ke dalam sel seterusnya secara automatik.



2. Cipta lungsur turun utama

Untuk membuat senarai lungsur turun utama anda, konfigurasikan peraturan Pengesahan Data Excel dengan cara ini:

• Pilih sel yang anda mahu lungsur turun dipaparkan (D3 dalam kes kami).
• Pada tab Data , dalam kumpulan Alat Data , klik Pengesahan Data .
• Dalam kotak dialog Pengesahan Data , lakukan perkara berikut:
  • Di bawah Benarkan , pilih Senarai .
  • Dalam kotak Sumber , masukkan rujukan kepada keluaran julat tumpahan oleh formula UNIK. Untuk ini, taip teg cincang sejurus selepas rujukan sel, seperti ini: =$G$3#

    Ini dipanggil rujukan julat tumpahan dan sintaks ini merujuk kepada keseluruhan julat tanpa mengira berapa banyak ia mengembang atau mengecut.

  • Klik OK untuk menutup dialog.

  

Titisan utama anda- senarai bawah telah selesai!



3. Dapatkan item untuk senarai lungsur turun bergantung

Untuk mendapatkan entri bagi menu lungsur kedua, kami akan menapis nilai dalam lajur B berdasarkan nilai yang dipilih dalam menu lungsur pertama. Ini boleh dilakukan dengan bantuan fungsi tatasusunan dinamik lain yang dipanggil FILTER:

=FILTER(B3:B15, A3:A15=D3)

Di mana B3:B15 ialah data sumber untuk lungsur turun bergantung anda, A3:A15 ialah data sumber untuk lungsur turun utama anda dan D3 ialah sel lungsur turun utama.

Untuk memastikan formula berfungsi dengan betul, anda boleh memilih beberapa nilai dalam senarai lungsur pertama dan memerhatikan hasil yang dikembalikan oleh FILTER. Sempurna! :)



4. Buat lungsur turun bergantung

Untuk membuat senarai lungsur turun kedua, konfigurasikan kriteria pengesahan data sama seperti yang anda lakukan untuk lungsur turun pertama pada langkah 2. Tetapi kali ini, rujuk julat tumpahan yang dikembalikan oleh fungsi FILTER: =$H$3#



Lihat juga: Bagaimana untuk menambah trendline dalam carta Excel

Itu sahaja! Senarai lungsur turun bergantung Excel anda sedia untuk digunakan.



Petua dannota:

• Untuk memasukkan entri baharu dalam senarai lungsur turun secara automatik , formatkan data sumber anda sebagai jadual Excel. Atau anda boleh memasukkan beberapa sel kosong dalam formula anda seperti yang ditunjukkan dalam contoh ini.
• Jika data asal anda mengandungi sebarang jurang, anda boleh menapis kosong dengan menggunakan penyelesaian ini.
• Untuk mengisih mengikut abjad item lungsur turun, bungkus formula anda dalam fungsi SORT seperti yang dijelaskan dalam contoh ini.

Cara membuat senarai lungsur turun berbilang bergantung dalam Excel

Dalam contoh sebelumnya, kami membuat senarai juntai bawah bergantung pada sel lain. Tetapi bagaimana jika anda memerlukan hierarki berbilang peringkat, iaitu lungsur ke-3 bergantung pada senarai ke-2, atau pun lungsur ke-4 bergantung pada senarai ke-3. Adakah itu mungkin? Ya, anda boleh menyediakan sebarang bilangan senarai bergantung (suatu bilangan yang munasabah, sudah tentu :).

Untuk contoh ini, kami telah meletakkan negeri / wilayah dalam lajur C dan kini sedang mencari untuk menambah lungsur turun yang sepadan menu dalam G3:



Untuk membuat senarai lungsur turun berbilang bergantung dalam Excel, ini yang anda perlu lakukan:

1. Sediakan lungsur turun pertama

Senarai lungsur turun utama dibuat dengan langkah yang sama seperti dalam contoh sebelumnya (sila lihat langkah 1 dan 2 di atas). Satu-satunya perbezaan ialah rujukan julat tumpahan yang anda masukkan dalam kotak Sumber .

Kali ini, formula UNIK berada dalam E8, dan lungsur turun utamasenarai akan berada dalam E3. Jadi, anda pilih E3, klik Pengesahan Data dan berikan rujukan ini: =$E$8#



2. Konfigurasikan drop down kedua

Seperti yang mungkin anda perhatikan, kini lajur B mengandungi berbilang kejadian pengeksport yang sama. Tetapi anda hanya mahu nama unik dalam senarai lungsur turun anda, bukan? Untuk meninggalkan semua kejadian pendua, bungkus fungsi UNIK di sekeliling formula FILTER anda dan masukkan formula yang dikemas kini ini dalam F8:

=UNIQUE(FILTER(B3:B15, A3:A15=E3))

Di mana B3:B15 ialah data sumber untuk drop down kedua , A3:A15 ialah data sumber untuk lungsur pertama dan E3 ialah sel lungsur pertama.

Selepas itu, gunakan rujukan julat tumpahan berikut untuk kriteria Pengesahan Data: =$F$8#



3. Sediakan drop down ketiga

Untuk mengumpulkan item bagi senarai drop down ke-3, gunakan formula FILTER dengan berbilang kriteria. Kriteria pertama menyemak keseluruhan senarai buah berbanding nilai yang dipilih dalam lungsur turun pertama (A3:A15=E3) manakala kriteria kedua menguji senarai pengeksport terhadap pemilihan dalam lungsur ke-2 (B3:B15=F3). Formula lengkap pergi ke G8:

=FILTER(C3:C15, (A3:A15=E3) * (B3:B15=F3))

Jika anda akan menambah lebih banyak menu lungsur bergantung (ke-4, ke-5, dsb.), maka kemungkinan besar lajur C akan mengandungi berbilang kejadian yang sama item. Untuk mengelakkan pendua daripada masuk ke dalam jadual penyediaan, dan seterusnya dalam lungsur ke-3, sarang formula FILTER dalamfungsi UNIK seperti yang kita lakukan dalam langkah sebelumnya:

=UNIQUE(FILTER(C3:C15, (A3:A15=E3) * (B3:B15=F3)))

Perkara terakhir yang perlu anda lakukan ialah mencipta satu lagi peraturan Pengesahan Data dengan rujukan Sumber ini: =$G$8#



Senarai lungsur turun berbilang bergantung anda boleh digunakan!



Petua. Dengan cara yang sama, anda boleh mendapatkan item untuk drop-down seterusnya . Dengan mengandaikan lajur D mengandungi data sumber untuk senarai lungsur ke-4 anda, anda boleh memasukkan formula berikut dalam H8 untuk mendapatkan semula item yang sepadan:

=UNIQUE(FILTER(D3:D15, (A3:A15=E3) * (B3:B15=F3) * (C3:C15=G3)))

Cara membuat senarai juntai bawah yang boleh dikembangkan dalam Excel

Selepas membuat lungsur turun, kebimbangan pertama anda mungkin tentang perkara yang berlaku apabila anda menambah item baharu pada data sumber. Adakah senarai juntai bawah akan dikemas kini secara automatik? Jika data asal anda diformatkan sebagai jadual Excel, maka ya, senarai lungsur turun dinamik yang dibincangkan dalam contoh sebelumnya akan berkembang secara automatik tanpa sebarang usaha di sisi anda kerana jadual Excel boleh dikembangkan mengikut sifatnya.

Jika bagi sesetengah pihak sebab menggunakan jadual Excel bukan pilihan, anda boleh menjadikan senarai lungsur turun anda boleh dikembangkan dengan cara ini:

• Untuk menyertakan data baharu secara automatik semasa ia ditambahkan pada senarai sumber, tambahkan beberapa sel tambahan pada tatasusunan yang dirujuk dalam formula anda.
• Untuk tidak termasuk sel kosong , konfigurasikan formula untuk mengabaikan sel kosong sehingga ia diisi.

Mengingat kedua-dua perkara ini, mari kita memperhalusi formulajadual penyediaan data kami. Peraturan Pengesahan Data tidak memerlukan sebarang pelarasan sama sekali.

Formula untuk menu lungsur utama

Dengan nama buah dalam A3:A15, kami menambah 5 sel tambahan pada tatasusunan untuk memenuhi kemungkinan entri baru. Selain itu, kami membenamkan fungsi FILTER ke dalam UNIQUE untuk mengekstrak nilai unik tanpa kosong.

Memandangkan perkara di atas, formula dalam G3 mengambil bentuk ini:

=UNIQUE(FILTER(A3:A20, A3:A20""))

Formula untuk lungsur turun bergantung

Formula dalam G3 tidak memerlukan banyak pengubahsuaian - cuma panjangkan tatasusunan dengan beberapa sel lagi:

=FILTER(B3:B20, A3:A20=D3)

Hasilnya ialah penurunan bergantung boleh dikembangkan sepenuhnya yang dinamik senarai bawah:



Bagaimana untuk mengisih senarai juntai bawah mengikut abjad

Ingin menyusun senarai lungsur anda mengikut abjad tanpa menggunakan data sumber? Excel dinamik baharu mempunyai fungsi khas untuk ini juga! Dalam jadual penyediaan data anda, hanya bungkus fungsi SORT di sekeliling formula sedia ada anda.

Peraturan pengesahan data dikonfigurasikan betul-betul seperti yang diterangkan dalam contoh sebelumnya.

Untuk mengisih dari A hingga Z

Memandangkan susunan isihan menaik ialah pilihan lalai, anda hanya boleh menyarangkan formula sedia ada anda dalam array argumen SORT, mengetepikan semua argumen lain yang menjadi pilihan.

Untuk turun turun utama (rumus dalam G3):

=SORT(UNIQUE(FILTER(A3:A20, A3:A20"")))

Untuk lungsur turun bergantung (rumus dalam H3):

=SORT(FILTER(B3:B20, A3:A20=D3))

Lihat juga: Sisipkan kotak pilihan dalam Excel: buat senarai semak interaktif atau senarai tugasan

Selesai! Kedua-dua senarai juntai bawah mendapatdiisih mengikut abjad A hingga Z.



Untuk mengisih dari Z ke A

Untuk mengisih dalam tertib menurun, anda perlu menetapkan argumen ke-3 ( sort_order ) fungsi SORT ke -1.

Untuk dropdown utama (formula dalam G3):

=SORT(UNIQUE(FILTER(A3:A20, A3:A20"")), 1, -1)

Untuk lungsur turun bergantung (rumus dalam H3):

=SORT(FILTER(B3:B20, A3:A20=D3), 1, -1)

Ini akan mengisih kedua-dua data dalam jadual penyediaan dan item dalam senarai lungsur dari Z ke A :



Begitulah cara membuat senarai lungsur turun dinamik dalam Excel dengan bantuan fungsi tatasusunan dinamik baharu. Tidak seperti kaedah tradisional, pendekatan ini berfungsi dengan sempurna untuk entri tunggal dan berbilang perkataan dan menjaga sebarang sel kosong. Terima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan!

Buku kerja berlatih untuk muat turun

Senarai lungsur turun bergantung Excel (fail.xlsx)