De tutorial lit sjen hoe't jo in Excel-útklaplist meitsje kinne ôfhinklik fan in oare sel troch nije dynamyske array-funksjes te brûken.

In ienfâldige útklaplist yn Excel oanmeitsje is maklik. It meitsjen fan in multi-level cascading drop-down hat altyd in útdaging west. It boppesteande keppele tutorial beskriuwt fjouwer ferskillende oanpakken, elk ynklusyf in gekke oantal stappen, in bosk ferskillende formules, en in hânfol beheiningen oangeande mearwurdyngongen, lege sellen, ensfh.

Dat wie it minne nijs. It goede nijs is dat dy metoaden binne ûntworpen foar pre-dynamyske ferzjes fan Excel. De ynfiering fan dynamyske arrays yn Excel 365 hat alles feroare! Mei nije dynamyske arrayfunksjes is it meitsjen fan in meardere ôfhinklike dellûklist in kwestje fan minuten, as net sekonden. Gjin trúkjes, gjin caveats, gjin ûnsin. Allinnich fluch, rjochtlinige en maklik te folgjen oplossingen.

Opmerkingen:

• Dizze nije dynamyske array-manier foar it meitsjen fan dropdown-listen wurket allinnich yn Excel 365 en Excel 2021. Yn pre-dynamyske Excel sille jo it op 'e lange âlderwetske manier moatte dwaan lykas beskreaun yn In ôfhinklik dropdown oanmeitsje yn Excel 2019 - 2007.
• Dizze oplossing is foar ien rige. As jo ​​jo picklists meardere rigen kopiearje wolle, folgje dan de ynstruksjes yn Ofhinklike dellûklist foar meardere rigen.

Hoe meitsje jo in dynamyske útklaplist yn Excel

Dit foarbyld lit it algemien sjenoanpak foar it meitsjen fan in cascadearjende dellûklist yn Excel troch de nije dynamyske arrayfunksjes te brûken.

Stel dat jo in list hawwe mei fruit yn kolom A en eksporteurs yn kolom B. In ekstra komplikaasje is dat de fruitnammen net binne groepearre, mar ferspraat oer de kolom. It doel is om de unike fruchtnammen yn it earste drop-down te setten en ôfhinklik fan de seleksje fan de brûker de relevante eksporteurs yn it twadde drop-down sjen te litten.



Om in dynamyske ôfhinklike dellûklist yn Excel, fier dizze stappen út:

1. Krij items foar de haadútklaplist

Om te begjinnen sille wy alle ferskillende fruitnammen út kolom A ekstrahearje. Dit kin dien wurde troch de UNIQUE-funksje yn syn ienfâldichste foarm te brûken - leverje de fruitlist foar it earste argumint ( array ) en lit de oerbleaune opsjonele arguminten wegerje, om't harren standertynstellingen goed foar ús wurkje:

=UNIQUE(A3:A15)

De formule giet nei G3, en nei it yndrukken fan de Enter-toets de resultaten spielje automatysk nei de folgjende sellen.



2. Meitsje it haadútklapmenu

Om jo primêre útklaplist te meitsjen, konfigurearje in Excel-gegevensvalidaasjeregel op dizze manier:

• Selektearje in sel wêryn jo wolle dat it útklapmenu ferskynt (D3 yn ús gefal).
• Op de Data ljepper, yn de Data Tools groep, klik Data Validation .
• Doch it folgjende yn it dialoochfinster Gegevensvalidaasje :
  • Selektearje ûnder Tastean List .
  • Yn it fak Boarne , fier de ferwizing nei de útfier fan it spillbereik troch de UNIEKE formule. Typ hjirfoar de hash-tag rjochts nei de selferwizing, lykas dit: =$G$3#

    Dit wurdt in spillbereikreferinsje neamd, en dizze syntaksis ferwiist nei it hiele berik, nettsjinsteande hoefolle it útwreidet of kontraktearret.

  • Klik op OK om it dialoochfinster te sluten.

  

Jo primêre drop- down list is klear!



3. Krij items foar de ôfhinklike útklaplist

Om yngongen te krijen foar it sekundêre útklapmenu, sille wy de wearden yn kolom B filterje op basis fan de wearde dy't selektearre is yn it earste útklapmenu. Dit kin dien wurde mei help fan in oare dynamyske arrayfunksje neamd FILTER:

=FILTER(B3:B15, A3:A15=D3)

Wêr't B3:B15 de boarnegegevens binne foar jo ôfhinklike dropdown, A3:A15 binne de boarnegegevens foar jo haadútklapmenu, en D3 is de haadútklapsel.

Om derfoar te soargjen dat de formule goed wurket, kinne jo wat wearde selektearje yn 'e earste útklaplist en observearje de resultaten weromjûn troch FILTER. Perfekt! :)



4. Meitsje de ôfhinklike dellûk

Om de twadde dellûklist te meitsjen, konfigurearje de gegevensvalidaasjekritearia krekt lykas jo dien hawwe foar de earste dropdown by stap 2. Mar dizze kear ferwize jo nei it spillbereik weromjûn troch de FILTER-funksje: =$H$3#

Sjoch ek: Hoe tekens te tellen yn Excel: totale as spesifike tekens yn in sel of berik



Dat is it! Jo Excel-ôfhinklike útklaplist is klear foar gebrûk.



Tips ennotysjes:

• Om de nije yngongen opnommen te hawwen yn 'e dellûklist automatysk , formatearje jo boarnegegevens as in Excel-tabel. Of jo kinne in pear lege sellen yn jo formules opnimme lykas yn dit foarbyld oantoand.
• As jo ​​orizjinele gegevens gjin gatten befetsje, kinne jo blanken filterje troch dizze oplossing te brûken.
• Om alfabetisch te sortearjen items fan in dropdown, wrap jo formules yn 'e SORT-funksje lykas útlein yn dit foarbyld.

Hoe kinne jo meardere ôfhinklike dellûklist meitsje yn Excel

Yn it foarige foarbyld hawwe wy in dellûklist makke ôfhinklik fan in oare sel. Mar wat as jo in hiërargy op meardere nivo's nedich binne, dus in 3e dropdown ôfhinklik fan 'e 2e list, of sels in 4e dropdown ôfhinklik fan 'e 3e list. Is dat mooglik? Ja, jo kinne elk oantal ôfhinklike listen ynstelle (in ridlik oantal, fansels :).

Foar dit foarbyld hawwe wy steaten / provinsjes yn kolom C pleatst, en sykje wy no in oerienkommende dropdown ta te foegjen menu yn G3:



Om in meardere ôfhinklike dellûklist te meitsjen yn Excel, dit is wat jo moatte dwaan:

1. Set de earste dellûk del

De haadútklaplist wurdt makke mei krekt deselde stappen as yn it foarige foarbyld (sjoch asjebleaft stappen 1 en 2 hjirboppe). It ienige ferskil is de referinsje fan it spillbereik dy't jo ynfiere yn it fak Boarne .

Dizze kear is de UNIEKE formule yn E8, en de haaddrop-downlist giet te wêzen yn E3. Dus, jo selektearje E3, klikje op Gegevensvalidaasje , en leverje dizze referinsje: =$E$8#



2. Konfigurearje de twadde drop-down

Lykas jo miskien hawwe opfallen, befettet kolom B no meardere foarfallen fan deselde eksporteurs. Mar jo wolle allinich unike nammen yn jo útklaplist, krekt? Om alle dûbele foarfallen fuort te litten, wikkel de UNIEKE funksje om jo FILTER-formule, en fier dizze bywurke formule yn yn F8:

=UNIQUE(FILTER(B3:B15, A3:A15=E3))

Wêr B3:B15 de boarnegegevens binne foar de twadde dropdown , A3:A15 binne de boarne gegevens foar de earste dropdown, en E3 is de earste dropdown sel.

Dêrnei, brûk de folgjende spillbereik referinsje foar de Data Validation kritearia: =$F$8#



3. Stel it tredde drop-down-menu op

Om de items te sammeljen foar de 3e útklaplist, brûk de FILTER-formule mei meardere kritearia. It earste kritearium kontrolearret de folsleine fruitlist tsjin de wearde selektearre yn 'e 1e dropdown (A3: A15 = E3), wylst it twadde kritearium de list fan eksporteurs testet tsjin de seleksje yn' e 2e dropdown (B3: B15 = F3). De folsleine formule giet nei G8:

=FILTER(C3:C15, (A3:A15=E3) * (B3:B15=F3))

As jo ​​mear ôfhinklike dropdowns taheakje wolle (4e, 5e, ensfh.), dan sil kolom C wierskynlik meardere foarkommens fan deselde befetsje ûnderdiel. Om foar te kommen dat duplikaten yn 'e tariedingstabel komme, en dus yn' e 3e dropdown, nêst de FILTER-formule ynde UNIEKE funksje lykas wy dien hawwe yn 'e foarige stap:

=UNIQUE(FILTER(C3:C15, (A3:A15=E3) * (B3:B15=F3)))

It lêste wat jo moatte dwaan is noch ien regel foar gegevensvalidaasje te meitsjen mei dizze Boarne referinsje: =$G$8#



Jo meardere ôfhinklike dellûklist is goed om te gean!



Tip. Op in fergelykbere manier kinne jo items krije foar folgjende dropdowns . Oannommen dat kolom D de boarnegegevens foar jo 4e útklaplist befettet, kinne jo de folgjende formule yn H8 ynfiere om de oerienkommende items werom te heljen:

=UNIQUE(FILTER(D3:D15, (A3:A15=E3) * (B3:B15=F3) * (C3:C15=G3)))

Hoe meitsje jo in útwreidbere dropdownlist yn Excel

Nei it oanmeitsjen fan in dropdown, kin jo earste soarch wêze oer wat der bart as jo nije items tafoegje oan de boarnegegevens. Sil de dellûklist automatysk bywurkje? As jo ​​orizjinele gegevens binne opmakke as Excel-tabel, dan ja, in dynamyske útklaplist besprutsen yn 'e foargeande foarbylden sil automatysk útwreidzje sûnder ynspanning fan jo kant, om't Excel-tabellen útwreidzje kinne troch har aard.

As foar guon reden dat it brûken fan in Excel-tabel gjin opsje is, jo kinne jo útklaplist útwreidzje op dizze manier:

• Om nije gegevens op te nimmen automatysk as it wurdt tafoege oan de boarnelist, foegje in pear ekstra sellen ta oan de arrays nei ferwiisd yn jo formules.
• Om lege sellen út te sluten , konfigurearje de formules om lege sellen te negearjen oant se fol wurde.

Mei dizze twa punten yn gedachten hâlde, litte wy de formules fineús data tarieding tabel. De regels foar gegevensvalidaasje fereaskje hielendal gjin oanpassingen.

Sjoch ek: Excel RIGHT funksje mei formule foarbylden

Formule foar it haadútklapmenu

Mei de fruitnammen yn A3:A15 foegje wy 5 ekstra sellen ta oan de array om te soargjen foar mooglike nije yngongen. Dêrnjonken ynbêde wy de FILTER-funksje yn UNIQUE om unike wearden sûnder blanks te ekstrahearjen.

Sjoen it boppesteande nimt de formule yn G3 dizze foarm oan:

=UNIQUE(FILTER(A3:A20, A3:A20""))

Formule foar de ôfhinklik dropdown

De formule yn G3 hat net folle tweaking nedich - ferlingje gewoan de arrays mei in pear mear sellen:

=FILTER(B3:B20, A3:A20=D3)

It resultaat is in folslein dynamysk útwreidbere ôfhinklike drop dellist:



Hoe sortearje de dellûklist alfabetysk

Wolle jo dellûklist alfabetysk regelje sûnder de boarnegegevens te brûken? De nije dynamyske Excel hat dêr ek in spesjale funksje foar! Wrapje yn jo gegevenstariedingstabel gewoan de SORT-funksje om jo besteande formules hinne.

De regels foar gegevensvalidaasje binne krekt konfigureare lykas beskreaun yn 'e foarige foarbylden.

Om te sortearjen fan A oant Z

Om't de oprinnende sortearfolchoarder de standertopsje is, kinne jo gewoan jo besteande formules yn it array -argumint fan SORT nêstje, en alle oare arguminten dy't opsjoneel binne weilitte.

Foar de haad dropdown (de formule yn G3):

=SORT(UNIQUE(FILTER(A3:A20, A3:A20"")))

Foar it ôfhinklike dropdown (de formule yn H3):

=SORT(FILTER(B3:B20, A3:A20=D3))

Klear! Beide dellûklisten krijealfabetysk sortearre A oant Z.



Om te sortearjen fan Z nei A

Om yn ôfnimmende folchoarder te sortearjen, moatte jo it 3e argumint ynstelle ( sort_order ) fan de SORT-funksje nei -1.

Foar it haadútklapmenu (de formule yn G3):

=SORT(UNIQUE(FILTER(A3:A20, A3:A20"")), 1, -1)

Foar de de ôfhinklike dropdown (de formule yn H3):

=SORT(FILTER(B3:B20, A3:A20=D3), 1, -1)

Dit sil sawol de gegevens yn 'e tariedingstabel as de items yn' e dropdown-listen sortearje fan Z oant A :



Dat is hoe't jo in dynamyske útklaplist meitsje kinne yn Excel mei help fan de nije dynamyske arrayfunksjes. Oars as de tradisjonele metoaden wurket dizze oanpak perfekt foar yngongen mei ien en mear wurd en soarget foar alle lege sellen. Tankewol foar it lêzen en hoopje jo nije wike op ús blog te sjen!

Oefeningswurkboek foar download

Excel-ôfhinklike dellûklist (.xlsx-bestân)