V tomto učebnom texte sa dozviete, čo je vzorec poľa programu Excel, ako ho správne zadať do pracovných hárkov a ako používať konštanty poľa a funkcie poľa.

Vzorce poľa v programe Excel sú mimoriadne výkonným nástrojom a jedným z najťažších na zvládnutie. Jediný vzorec poľa môže vykonať viacero výpočtov a nahradiť tisíce bežných vzorcov. 90 % používateľov nikdy nepoužilo funkcie poľa vo svojich pracovných hárkoch jednoducho preto, že sa ich bojí začať učiť.

Vzorce polí sú skutočne jednou z najzamotanejších funkcií programu Excel, ktoré sa treba naučiť. Cieľom tohto návodu je čo najviac uľahčiť a uľahčiť učenie.

Čo je pole v programe Excel?

Skôr ako začneme s funkciami a vzorcami poľa, ujasnime si, čo znamená pojem "pole". Pole je v podstate kolekcia položiek. Položky môžu byť textové alebo číselné a môžu sa nachádzať v jednom riadku alebo stĺpci, alebo vo viacerých riadkoch a stĺpcoch.

Ak by ste napríklad vložili svoj týždenný zoznam potravín do formátu tabuľky programu Excel, vyzeral by takto:

{"Mlieko", "Vajcia", "Maslo", "Kukuričné vločky"}

Ak potom vyberiete bunky A1 až D1, do panela vzorcov zadáte vyššie uvedené pole, pred ktoré vložíte znak rovnosti (=), a stlačíte CTRL + SHIFT + ENTER , dostanete nasledujúci výsledok:

Práve ste vytvorili jednorozmerné horizontálne pole. Zatiaľ nič hrozné, však?

Čo je vzorec poľa v programe Excel?

Rozdiel medzi vzorcom poľa a bežným vzorcom spočíva v tom, že vzorec poľa spracováva niekoľko hodnôt namiesto jednej. Inými slovami, vzorec poľa v programe Excel vyhodnocuje všetky jednotlivé hodnoty v poli a vykonáva viacero výpočtov na jednej alebo viacerých položkách podľa podmienok vyjadrených vo vzorci.

Nielenže vzorec poľa môže pracovať s viacerými hodnotami súčasne, ale môže tiež vrátiť niekoľko hodnôt naraz. Takže výsledky vrátené vzorcom poľa sú tiež poľom.

Vzorce polí sú k dispozícii vo všetkých verziách aplikácie Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 a nižších.

A teraz je zrejme ten správny čas na vytvorenie prvého vzorca poľa.

Jednoduchý príklad vzorca poľa programu Excel

Predpokladajme, že v stĺpci B máte nejaké položky, ich ceny sú v stĺpci C a chcete vypočítať celkový súčet všetkých predajov.

Samozrejme, nič vám nebráni v tom, aby ste najskôr vypočítali medzisúčty v každom riadku pomocou niečoho takého, ako je =B2*C2 a potom tieto hodnoty spočítajte:

Vzorec poľa vás však môže ušetriť ďalších stlačení klávesov, pretože prinúti Excel ukladať priebežné výsledky do pamäte, a nie do ďalšieho stĺpca. Takže stačí jeden vzorec poľa a 2 rýchle kroky:

1. Vyberte prázdnu bunku a zadajte do nej nasledujúci vzorec:

   =SUM(B2:B6*C2:C6)

2. Stlačením klávesovej skratky CTRL + SHIFT + ENTER dokončite vzorec poľa.

   Keď to urobíte, Microsoft Excel obklopí vzorec {vlnitými zátvorkami}, čo je vizuálne označenie vzorca poľa.

   Vzorec vynásobí hodnoty v jednotlivých riadkoch zadaného poľa (bunky B2 až C6), sčíta čiastkové súčty a vypíše celkový súčet:

   

Tento jednoduchý príklad ukazuje, aký výkonný môže byť vzorec poľa. Keď pracujete so stovkami a tisíckami riadkov údajov, len si predstavte, koľko času môžete ušetriť zadaním jedného vzorca poľa v jedinej bunke.

Prečo používať vzorce v programe Excel?

Vzorce poľa programu Excel sú najšikovnejším nástrojom na vykonávanie zložitých výpočtov a komplexných úloh. Jediný vzorec poľa môže nahradiť doslova stovky bežných vzorcov. Vzorce poľa sú veľmi dobré na úlohy, ako napr:

• Súčet čísel, ktoré spĺňajú určité podmienky, napríklad súčet N najväčších alebo najmenších hodnôt v rozsahu.
• Súčet každého druhého riadku alebo každého N-teho riadku alebo stĺpca, ako je uvedené v tomto príklade.
• Spočítajte počet všetkých alebo určitých znakov v zadanom rozsahu. Tu je vzorec pre pole, ktorý počíta všetky znaky, a ďalší vzorec, ktorý počíta ľubovoľné dané znaky.

Ako zadať vzorec poľa v programe Excel (Ctrl + Shift + Enter)

Ako už viete, kombinácia troch klávesov CTRL + SHIFT + ENTER je čarovným dotykom, ktorý zmení bežný vzorec na vzorec poľa.

Pri zadávaní vzorca poľa v programe Excel je potrebné pamätať na 4 dôležité veci:

1. Po dokončení písania vzorca a súčasnom stlačení klávesov CTRL SHIFT ENTER program Excel automaticky uzavrie vzorec medzi {vlnité zátvorky}. Keď vyberiete takúto bunku (bunky), v paneli vzorcov uvidíte zátvorky, čo vám napovie, že sa tam nachádza vzorec poľa.
2. Ručné písanie zátvoriek okolo vzorca nebude fungovať. Na dokončenie vzorca poľa musíte stlačiť klávesovú skratku Ctrl+Shift+Enter.
3. Pri každej úprave vzorca poľa zátvorky zmiznú a na uloženie zmien musíte znova stlačiť klávesovú skratku Ctrl+Shift+Enter.
4. Ak zabudnete stlačiť klávesovú skratku Ctrl+Shift+Enter, vzorec sa bude správať ako bežný vzorec a spracuje len prvú hodnotu (hodnoty) v zadanom poli (poliach).

Keďže všetky vzorce poľa programu Excel vyžadujú stlačenie klávesovej skratky Ctrl + Shift + Enter, niekedy sa nazývajú Vzorce CSE .

Použitie klávesu F9 na vyhodnotenie častí vzorca poľa

Pri práci so vzorcami polí v programe Excel môžete pozorovať, ako počítajú a ukladajú svoje položky (vnútorné polia), aby sa zobrazil konečný výsledok, ktorý vidíte v bunke. Ak to chcete urobiť, vyberte jeden alebo niekoľko argumentov v zátvorkách funkcie a potom stlačte kláves F9. Ak chcete ukončiť režim vyhodnocovania vzorcov, stlačte kláves Esc.

V uvedenom príklade, ak chcete zobraziť čiastkové súčty všetkých produktov, vyberte B2:B6*C2:C6, stlačte F9 a dostanete nasledujúci výsledok.

Poznámka: Dbajte na to, že pred stlačením klávesu F9 musíte vybrať niektorú časť vzorca, inak kláves F9 jednoducho nahradí váš vzorec vypočítanou hodnotou (hodnotami).

Vzorce jednobunkového a viacbunkového poľa v programe Excel

Vzorec poľa programu Excel môže vrátiť výsledok v jednej bunke alebo vo viacerých bunkách. Vzorec poľa zadaný v rozsahu buniek sa nazýva viacbunkový vzorec Vzorec poľa, ktorý sa nachádza v jednej bunke, sa nazýva vzorec pre jednu bunku .

Existuje niekoľko funkcií Excelu, ktoré sú určené na vrátenie viacbunkových polí, napríklad TRANSPOSE, TREND, FREQUENCY, LINEST atď.

Ostatné funkcie, ako napríklad SUM, AVERAGE, AGGREGATE, MAX, MIN, môžu vypočítať výrazy poľa, keď sú zadané do jednej bunky pomocou klávesovej skratky Ctrl + Shift + Enter .

Nasledujúce príklady ukazujú, ako použiť vzorec jednobunkového a viacbunkového poľa.

Príklad 1. Vzorec pre jednobunkové pole

Predpokladajme, že máte dva stĺpce s počtom predaných položiek v dvoch rôznych mesiacoch, napríklad stĺpce B a C, a chcete zistiť maximálny nárast predaja.

Za normálnych okolností by ste pridali ďalší stĺpec, napríklad stĺpec D, ktorý by vypočítal zmenu predaja pre každý produkt pomocou vzorca, ako je =C2-B2 a potom nájdite maximálnu hodnotu v tomto ďalšom stĺpci =MAX(D:D) .

Vzorec poľa nepotrebuje ďalší stĺpec, pretože dokonale uchováva medzivýsledky v pamäti. Stačí teda zadať nasledujúci vzorec a stlačiť klávesovú skratku Ctrl + Shift + Enter :

=MAX(C2:C6-B2:B6)

Príklad 2. Vzorec pre viacbunkové pole v programe Excel

V predchádzajúcom príklade SUM predpokladajte, že musíte zaplatiť 10 % daň z každého predaja a chcete vypočítať výšku dane pre každý produkt pomocou jedného vzorca.

Vyberte rozsah prázdnych buniek, napríklad D2:D6, a do panela vzorcov zadajte nasledujúci vzorec:

=B2:B6 * C2:C6 * 0,1

Po stlačení klávesovej skratky Ctrl + Shift + Enter , Excel umiestni inštanciu vášho vzorca poľa do každej bunky vybraného rozsahu a dostanete nasledujúci výsledok:

Príklad 3. Použitie funkcie poľa programu Excel na vrátenie viacbunkového poľa

Ako už bolo spomenuté, Microsoft Excel poskytuje niekoľko tzv. "funkcií polí", ktoré sú špeciálne navrhnuté na prácu s viacbunkovými poľami. Jednou z takýchto funkcií je TRANSPOSE a my ju využijeme na transpozíciu vyššie uvedenej tabuľky, t. j. na prevod riadkov na stĺpce.

1. Vyberte prázdny rozsah buniek, do ktorých chcete vyvolať transponovanú tabuľku. Keďže prevádzame riadky na stĺpce, nezabudnite vybrať rovnaký počet riadkov a stĺpcov, ako má vaša zdrojová tabuľka stĺpcov, resp. riadkov. V tomto príklade vyberáme 6 stĺpcov a 4 riadky.
2. Stlačením tlačidla F2 vstúpte do režimu úprav.
3. Zadajte vzorec a stlačte klávesovú skratku Ctrl + Shift + Enter .

V našom príklade je vzorec nasledovný:

=TRANSPOSE($A$1:$D$6)

Výsledok bude vyzerať podobne:

Takto používate TRANSPOSE ako vzorec CSE poľa v programe Excel 2019 a starších. V programe Excel s dynamickým poľom to funguje aj ako bežný vzorec. Ak sa chcete dozvedieť ďalšie spôsoby transpozície v programe Excel, pozrite si tento návod: Ako prepínať stĺpce a riadky v programe Excel.

Ako pracovať so vzorcami s viacbunkovým poľom

Pri práci so vzorcami viacbunkových polí v programe Excel sa uistite, že dodržiavate tieto pravidlá, aby ste získali správne výsledky:

1. Vyberte rozsah buniek, do ktorých chcete vypísať výsledky pred zadanie vzorca.
2. Na vymazať vzorca viacbunkového poľa, buď vyberte všetky bunky, ktoré ho obsahujú, a stlačte DELETE , alebo vyberte celý vzorec na paneli vzorcov, stlačte DELETE a potom stlačte Ctrl + Shift + Enter .
3. Nemôžete upravovať ani presúvať obsah jednotlivých buniek vo vzorci poľa, ani nemôžete vkladať nové bunky do vzorca poľa s viacerými bunkami alebo z neho vymazávať existujúce bunky. Vždy, keď sa o to pokúsite, program Microsoft Excel vyhodí upozornenie " Nemôžete zmeniť časť poľa ".
4. Na zmršťovanie vzorca, t. j. ak ho chcete použiť na menej buniek, musíte najprv odstrániť existujúci vzorec a potom zadať nový.
5. Na rozšíriť vzorca, t. j. použiť ho na viac buniek, vyberte všetky bunky obsahujúce aktuálny vzorec a prázdne bunky, v ktorých ho chcete mať, stlačením klávesy F2 sa prepnite do režimu úprav, upravte odkazy vo vzorci a stlačením kláves Ctrl + Shift + Enter ho aktualizujte.
6. V tabuľkách programu Excel nie je možné používať vzorce s viacbunkovým poľom.
7. Vzorec viacbunkového poľa by ste mali zadať v rozsahu buniek rovnakej veľkosti, ako je výsledné pole vrátené vzorcom. Ak váš vzorec poľa Excel vytvorí pole väčšie ako vybraný rozsah, nadbytočné hodnoty sa na pracovnom hárku nezobrazia. Ak je pole vrátené vzorcom menšie ako vybraný rozsah, v ďalších bunkách sa zobrazia chyby #N/A.

Ak váš vzorec môže vrátiť pole s premenlivým počtom prvkov, zadajte ho v rozsahu rovnom alebo väčšom, ako je maximálne pole vrátené vzorcom, a zabaľte vzorec do funkcie IFERROR, ako je uvedené v tomto príklade.

Konštanty poľa Excel

V programe Microsoft Excel je konštanta poľa jednoducho súbor statických hodnôt. Tieto hodnoty sa pri kopírovaní vzorca do iných buniek alebo hodnôt nikdy nemenia.

Príklad konštanty poľa vytvorenej zo zoznamu potravín ste už videli na samom začiatku tohto učebného materiálu. Teraz sa pozrieme, aké ďalšie typy polí existujú a ako ich vytvoriť.

Existujú 3 typy konštánt poľa:

1. Horizontálna konštanta poľa

Konštanta horizontálneho poľa sa nachádza v riadku. Ak chcete vytvoriť konštantu riadkového poľa, zadajte hodnoty oddelené čiarkami a uzavrite ich do zátvoriek, napríklad {1,2,3,4}.

Poznámka: Pri vytváraní konštanty poľa by ste mali otváracie a zatváracie zátvorky zadať ručne.

Ak chcete do tabuľky zadať horizontálne pole, vyberte príslušný počet prázdnych buniek v riadku, zadajte vzorec ={1,2,3,4} v paneli vzorcov a stlačte klávesovú skratku Ctrl + Shift + Enter. Výsledok bude podobný tomuto:

Ako vidíte na obrázku, Excel zabalí konštantu poľa do ďalšej sady zátvoriek presne tak, ako keď zadávate vzorec poľa.

2. Konštanta vertikálneho poľa

Konštanta vertikálneho poľa sa nachádza v stĺpci. Vytvárate ju rovnakým spôsobom ako horizontálne pole s tým rozdielom, že položky ohraničujete napríklad bodkočiarkami:

={11; 22; 33; 44}

3. Konštanta dvojrozmerného poľa

Ak chcete vytvoriť dvojrozmerné pole, oddeľte každý riadok bodkočiarkou a každý stĺpec údajov čiarkou.

={"a", "b", "c"; 1, 2, 3}

Práca s konštantami polí programu Excel

Konštanty poľa sú jedným zo základných kameňov vzorca poľa programu Excel. Nasledujúce informácie a tipy vám môžu pomôcť pri ich čo najefektívnejšom používaní.

1. Prvky konštanty poľa

   Konštanta poľa môže obsahovať čísla, textové hodnoty, logické symboly (TRUE a FALSE) a chybové hodnoty oddelené čiarkami alebo bodkočiarkami.

   Číselnú hodnotu môžete zadať ako celé číslo, desatinné číslo alebo vo vedeckom zápise. Ak používate textové hodnoty, mali by byť obklopené dvojitými úvodzovkami (") ako v každom vzorci programu Excel.

   Konštanta poľa nemôže obsahovať iné polia, odkazy na bunky, rozsahy, dátumy, definované názvy, vzorce alebo funkcie.

2. Pomenovanie konštánt poľa

   Ak chcete uľahčiť používanie konštanty poľa, dajte jej meno:

   • Prepnite na Karta Vzorce> Definované názvy a kliknite na tlačidlo Definovať názov Prípadne stlačte klávesovú skratku Ctrl + F3 a kliknite na položku Nový .
   • Zadajte názov do Názov
   • V Vzťahuje sa na zadajte položky konštanty poľa obklopené zátvorkami s predchádzajúcim znakom rovnosti (=). Napríklad:

     ={"Su", "Po", "Tu", "St", "Čt", "Pia", "So"}

     

   • Kliknutím na tlačidlo OK uložte pomenované pole a zatvorte okno.

   Ak chcete v hárku zadať pomenovanú konštantu poľa, vyberte toľko buniek v riadku alebo stĺpci, koľko je položiek v poli, do panela vzorcov zadajte názov poľa, ktorému predchádza znak =, a stlačte klávesovú skratku Ctrl + Shift + Enter .

   Výsledok by mal byť podobný tomuto:

   

3. Predchádzanie chybám

   Ak konštanta poľa nefunguje správne, skontrolujte, či sa nevyskytli nasledujúce problémy:

   • Oddeľte prvky konštanty poľa správnym znakom - čiarkou v horizontálnych konštantách poľa a bodkočiarkou vo vertikálnych.
   • Vyberte rozsah buniek, ktorý presne zodpovedá počtu položiek v konštante poľa. Ak vyberiete viac buniek, každá ďalšia bunka bude mať chybu #N/A. Ak vyberiete menej buniek, vloží sa len časť poľa.

Používanie konštánt poľa vo vzorcoch programu Excel

Teraz, keď ste sa oboznámili s pojmom konštanty poľa, pozrime sa, ako môžete používať polia informulov na riešenie praktických úloh.

Príklad 1. Súčet N najväčších/najmenších čísel v rozsahu

Začnete vytvorením vertikálnej konštanty poľa obsahujúcej toľko čísel, koľko chcete sčítať. Ak chcete napríklad sčítať 3 najmenšie alebo najväčšie čísla v rozsahu, konštanta poľa je {1,2,3}.

Potom vezmete funkciu LARGE alebo SMALL, v prvom parametri zadáte celý rozsah buniek a v druhom parametri uvediete konštantu poľa. Nakoniec ju vložíte do funkcie SUM takto:

Súčet 3 najväčších čísel: =SUM(LARGE(rozsah, {1,2,3})

Súčet 3 najmenších čísel: =SUM(SMALL(rozsah, {1,2,3})

Nezabudnite stlačiť klávesovú skratku Ctrl + Shift + Enter, pretože zadávate vzorec poľa, a dostanete nasledujúci výsledok:

Podobným spôsobom môžete vypočítať priemer N najmenších alebo najväčších hodnôt v rozsahu:

Priemer 3 najvyšších čísel: =AVERAGE(LARGE(range, {1,2,3})

Priemer spodných 3 čísel: =AVERAGE(SMALL(range, {1,2,3})

Príklad 2. Vzorec poľa na počítanie buniek s viacerými podmienkami

Predpokladajme, že máte zoznam objednávok a chcete zistiť, koľkokrát daný predajca predal dané produkty.

Najjednoduchším spôsobom by bolo použitie vzorca COUNTIFS s viacerými podmienkami. Ak však chcete zahrnúť veľa produktov, váš vzorec COUNTIFS môže narásť do príliš veľkých rozmerov. Ak ho chcete urobiť kompaktnejším, môžete použiť COUNTIFS spolu so SUM a do jedného alebo viacerých argumentov zahrnúť napríklad konštantu poľa:

=SUM(COUNTIFS(range1, "criteria1", range2, {"criteria1", "criteria2"})

Skutočný vzorec môže vyzerať takto:

=SUM(COUNTIFS(B2:B9, "sally", C2:C9, {"jablká", "citróny"})

Naše vzorové pole pozostáva len z dvoch prvkov, pretože cieľom je demonštrovať tento prístup. Do vzorcov skutočného poľa môžete zahrnúť toľko prvkov, koľko vyžaduje vaša obchodná logika, za predpokladu, že celková dĺžka vzorca nepresiahne 8 192 znakov v aplikácii Excel 2019 - 2007 (1 024 znakov v aplikácii Excel 2003 a nižších) a váš počítač je dostatočne výkonný na spracovanie veľkých polí.Viac informácií nájdete v časti Obmedzenia vzorcov polí.

A tu je príklad pokročilého vzorca pre pole, ktorý nájde súčet všetkých zodpovedajúcich hodnôt v tabuľke: SUM a VLOOKUP s konštantou poľa.

Operátory AND a OR vo vzorcoch poľa programu Excel

Operátor poľa hovorí vzorcu, ako chcete spracovať polia - pomocou logiky AND alebo OR.

• Operátor AND je hviezdička (*), ktorá je symbolom násobenia. Dáva programu Excel pokyn, aby vrátil hodnotu TRUE, ak sa všetky podmienky vyhodnotia ako TRUE.
• Operátor OR je znamienko plus (+). Vracia hodnotu TRUE, ak je ktorákoľvek z podmienok v danom výraze vyhodnotená ako TRUE.

Vzorec poľa s operátorom AND

V tomto príklade zistíme súčet predajov, kde je predajca Mike A produkt je Jablká :

=SUM((A2:A9="Mike") * (B2:B9="Jablká") * (C2:C9))

Alebo

=SUM(IF(((A2:A9="Mike") * (B2:B9="Jablká")), (C2:C9))

Technicky tento vzorec násobí prvky troch polí na rovnakých pozíciách. Prvé dve polia sú reprezentované hodnotami TRUE a FALSE, ktoré sú výsledkom porovnania A2:A9 s Mike" a B2:B9 s "Apples". Tretie pole obsahuje predajné čísla z rozsahu C2:C9. Ako každá matematická operácia, násobenie konvertuje TRUE a FALSE na 1, resp. 0. A pretoženásobenie nulou dáva vždy nulu, výsledné pole má pri nesplnení jednej alebo oboch podmienok hodnotu 0. Ak sú splnené obe podmienky, do výsledného poľa sa dostane príslušný prvok z tretieho poľa (napr. 1*1*C2 = 10). Výsledkom násobenia je teda toto pole: {10;0;0;30;0;0;0;0}. Nakoniec funkcia SUM sčíta prvky poľa a vráti výsledok 40.

Vzorec poľa programu Excel s operátorom OR

Nasledujúci vzorec s operátorom OR (+) sčíta všetky predaje, v ktorých je predajca Mike OR produkt Jablká:

=SUM(IF(((A2:A9="Mike") + (B2:B9="Jablká")), (C2:C9))

V tomto vzorci sčítate prvky prvých dvoch polí (čo sú podmienky, ktoré chcete testovať) a dostanete TRUE (>0), ak sa aspoň jedna podmienka vyhodnotí ako TRUE; FALSE (0), ak sa všetky podmienky vyhodnotia ako FALSE. Potom IF kontroluje, či je výsledok sčítania väčší ako 0, a ak je, SUM sčíta príslušný prvok tretieho poľa (C2:C9).

Tip. V moderných verziách Excelu nie je potrebné na tento druh úloh používať vzorec poľa - jednoduchý vzorec SUMIFS ich zvládne dokonale. Napriek tomu sa operátory AND a OR vo vzorcoch poľa môžu ukázať ako užitočné v zložitejších scenároch, nehovoriac o veľmi dobrej gymnastike mysle : )

Dvojitý unárny operátor vo vzorcoch poľa programu Excel

Ak ste niekedy pracovali so vzorcami polí v programe Excel, je pravdepodobné, že ste sa stretli s niekoľkými vzorcami, ktoré obsahovali dvojitú pomlčku (--), a možno ste sa čudovali, na čo sa používa.

Dvojitá pomlčka, ktorá sa odborne nazýva dvojitý unárny operátor, sa používa na konverziu nečíselných logických hodnôt (TRUE / FALSE) vrátených niektorými výrazmi na 1 a 0, ktorým funkcia poľa rozumie.

Nasledujúci príklad vám snáď uľahčí pochopenie. Predpokladajme, že máte zoznam dátumov v stĺpci A a chcete vedieť, koľko dátumov pripadá na január bez ohľadu na rok.

Nasledujúci vzorec je účinný:

=SUM(--(MONTH(A2:A10)=1))

Keďže ide o vzorec poľa programu Excel, nezabudnite ho dokončiť stlačením klávesovej skratky Ctrl + Shift + Enter.

Ak vás zaujíma nejaký iný mesiac, nahraďte 1 zodpovedajúcim číslom. Napríklad 2 znamená február, 3 znamená marec atď. Ak chcete vzorec spružniť, môžete v niektorej bunke zadať číslo mesiaca, ako je to znázornené na snímke:

A teraz si analyzujme, ako tento vzorec pre pole funguje. Funkcia MONTH vráti mesiac každého dátumu v bunkách A2 až A10 reprezentovaný poradovým číslom, ktoré vytvára pole {2;1;4;2;12;1;2;12;1}.

Potom sa každý prvok poľa porovná s hodnotou v bunke D1, čo je v tomto príklade číslo 1. Výsledkom tohto porovnania je pole logických hodnôt TRUE a FALSE. Ako si pamätáte, môžete vybrať určitú časť vzorca poľa a stlačením klávesu F9 zistiť, čomu sa táto časť rovná:

Nakoniec musíte tieto logické hodnoty previesť na 1 a 0, ktorým funkcia SUM rozumie. Na to je potrebný dvojitý unárny operátor. Prvý unárny operátor mení hodnoty TRUE/FALSE na -1/0. Druhý unárny operátor tieto hodnoty neguje, t. j. obracia znamienko a mení ich na +1 a 0, ktorým väčšina funkcií Excelu rozumie a pracuje s nimi. Ak odstránite dvojitý unárny operátorz uvedeného vzorca, nebude to fungovať.

Dúfam, že vám tento krátky návod pomohol na ceste k zvládnutiu vzorcov polí Excelu. Budúci týždeň budeme pokračovať v práci s poliami Excelu a zameriame sa na pokročilé príklady vzorcov. Prosím, zostaňte naladení a ďakujem vám za čítanie!