Ebben a bemutatóban megtanulhatja, hogy mi az Excel tömbképlet, hogyan kell helyesen beírni a munkalapokba, és hogyan használhatja a tömbállandókat és a tömbfüggvényeket.

A tömbképletek az Excelben rendkívül hatékony eszköz, és az egyik legnehezebben elsajátítható. Egyetlen tömbképlet több számítást is elvégezhet, és több ezer szokásos képletet helyettesíthet. És mégis, a felhasználók 90%-a még soha nem használt tömbfüggvényeket a munkalapjain, egyszerűen azért, mert fél elkezdeni megtanulni őket.

A tömbképletek valóban az egyik legzavarosabb Excel-funkció, amelyet meg kell tanulni. Ennek a bemutatónak az a célja, hogy a tanulási folyamatot a lehető legkönnyebbé és simábbá tegye.

Mi az a tömb az Excelben?

Mielőtt a tömbfüggvényekkel és képletekkel foglalkoznánk, tisztázzuk, mit jelent a "tömb" kifejezés. A tömb lényegében elemek gyűjteménye. Az elemek lehetnek szövegek vagy számok, és lehetnek egyetlen sorban vagy oszlopban, vagy több sorban és oszlopban.

Például, ha a heti bevásárlólistát egy Excel tömb formátumba helyezné, az így nézne ki:

{"Tej", "Tojás", "Vaj", "Kukoricapehely"}

Ezután, ha kijelöli az A1-től D1-ig terjedő cellákat, beírja a fenti tömböt egy egyenlőségjel (=) előtt a képletsorba, és megnyomja a CTRL + SHIFT + ENTER billentyűkombinációt, a következő eredményt kapja:

Amit most csináltál, az egy egydimenziós vízszintes tömb létrehozása. Eddig semmi szörnyűség, igaz?

Mi az a tömbképlet az Excelben?

A különbség a tömbképlet és a hagyományos képlet között az, hogy a tömbképlet több értéket dolgoz fel egy helyett. Más szóval, az Excelben a tömbképlet kiértékeli a tömb összes egyedi értékét, és több számítást végez egy vagy több elemen a képletben kifejezett feltételeknek megfelelően.

Egy tömbképlet nem csak egyszerre több értékkel tud foglalkozni, hanem egyszerre több értéket is visszaadhat. Tehát a tömbképlet által visszaadott eredmények is tömbök.

A tömbképletek az Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 és alacsonyabb verziókban is elérhetők.

És most úgy tűnik, itt az ideje, hogy létrehozd az első tömbképletedet.

Egyszerű példa az Excel tömbképletre

Tegyük fel, hogy a B oszlopban van néhány tétel, az áraik a C oszlopban, és ki akarja számítani az összes értékesítés végösszegét.

Természetesen semmi sem akadályozza meg, hogy először minden sorban kiszámítsuk a részösszegeket az alábbi egyszerű módszerrel =B2*C2 majd összegezze ezeket az értékeket:

A tömbképlet azonban megkímélheti Önt ezektől az extra billentyűleütésektől, mivel ráveszi az Excelt, hogy a közbenső eredményeket a memóriában tárolja, nem pedig egy további oszlopban. Tehát mindössze egyetlen tömbképletre és 2 gyors lépésre van szükség:

1. Jelöljön ki egy üres cellát, és írja be a következő képletet:

   =SUM(B2:B6*C2:C6)

2. Nyomja meg a CTRL + SHIFT + ENTER billentyűkombinációt a tömbképlet befejezéséhez.

   Ha ezt megteszi, a Microsoft Excel a képletet {curly braces} zárójelekkel veszi körül, ami vizuálisan is jelzi, hogy tömbképletről van szó.

   A képlet megszorozza a megadott tömb minden egyes sorában (B2-től C6-ig terjedő cellákban) lévő értékeket, összeadja a részösszegeket, és kiadja a végösszeget:

   

Ez az egyszerű példa megmutatja, milyen hatékony lehet egy tömbképlet. Ha több száz és ezer sornyi adattal dolgozik, gondoljon csak bele, mennyi időt takaríthat meg egyetlen tömbképlet egyetlen cellába történő beírásával.

Miért használjon tömbképleteket az Excelben?

Az Excel tömbképletek a legpraktikusabb eszköz kifinomult számítások elvégzéséhez és összetett feladatok elvégzéséhez. Egyetlen tömbképlet szó szerint több száz szokásos képletet helyettesíthet. A tömbképletek nagyon jók az olyan feladatokhoz, mint például:

• Bizonyos feltételeknek megfelelő számok összegzése, például egy tartomány N legnagyobb vagy legkisebb értékének összegzése.
• Minden második sor vagy minden N-edik sor vagy oszlop összegzése, ahogyan ez a példa mutatja.
• Megszámolja az összes vagy bizonyos karakterek számát egy megadott tartományban. Itt van egy tömbképlet, amely az összes karaktert számolja, és egy másik, amely bármely adott karaktert számolja.

Tömbképlet beírása az Excelben (Ctrl + Shift + Enter)

Mint már tudod, a 3 billentyű CTRL + SHIFT + ENTER kombinációja egy varázslatos érintés, amely egy hagyományos képletet tömbképletté alakít.

Amikor tömbképletet adunk meg az Excelben, 4 fontos dolgot kell szem előtt tartanunk:

1. Miután befejezte a képlet beírását, és egyidejűleg lenyomta a CTRL SHIFT ENTER billentyűket, az Excel automatikusan a képletet {szöges zárójelek} közé zárja. Ha kijelöl egy ilyen cellát (cellákat), a képletsoron láthatja a zárójeleket, ami jelzi, hogy egy tömbképlet van benne.
2. Ha kézzel írja be a zárójeleket a képlet köré, az nem fog működni. A Ctrl+Shift+Enter billentyűkombinációt kell megnyomnia a tömbképlet befejezéséhez.
3. Minden alkalommal, amikor egy tömbképletet szerkeszt, a zárójelek eltűnnek, és a módosítások mentéséhez újra le kell nyomnia a Ctrl+Shift+Enter billentyűkombinációt.
4. Ha elfelejti lenyomni a Ctrl+Shift+Enter billentyűkombinációt, a képlet úgy fog viselkedni, mint egy szokásos képlet, és csak a megadott tömb(ök) első értékét (értékeit) dolgozza fel.

Mivel az Excel összes tömbképletéhez a Ctrl + Shift + Enter billentyűkombinációra van szükség, ezeket néha úgy is nevezik CSE képletek .

Az F9 billentyűvel kiértékelheti a tömbképlet részeit

Az Excelben tömbképletekkel dolgozva megfigyelheti, hogyan számítják ki és tárolják az elemeiket (belső tömbjeiket), hogy megjelenítsék a cellában látható végeredményt. Ehhez jelölje ki a függvény zárójelén belül egy vagy több argumentumot, majd nyomja meg az F9 billentyűt. A képletkiértékelési módból való kilépéshez nyomja meg az Esc billentyűt.

A fenti példában az összes termék részösszegének megtekintéséhez válassza ki a B2:B6*C2:C6 elemet, nyomja meg az F9 billentyűt, és a következő eredményt kapja.

Megjegyzés: Kérjük, figyeljen arra, hogy az F9 billentyű lenyomása előtt ki kell jelölnie a képlet valamelyik részét, különben az F9 billentyű egyszerűen a kiszámított érték(ek)kel helyettesíti a képletet.

Egycellás és többcellás tömbképletek az Excelben

Az Excel tömbképlet egy vagy több cellában is adhat eredményt. A cellatartományba beírt tömbképletet nevezik többcellás képlet Az egyetlen cellában található tömbi képletet nevezik egysejtű képlet .

Létezik néhány olyan Excel tömbfüggvény, amelyet többcellás tömbök visszaadására terveztek, például TRANSPOSE, TREND, FREQUENCY, LINEST stb.

Más függvények, mint például a SUM, AVERAGE, AGGREGATE, MAX, MIN, a Ctrl + Shift + Enter billentyűkombinációval egyetlen cellába beírva tömbkifejezéseket számíthatnak ki.

A következő példák egycellás és többcellás tömbképlet használatát mutatják be.

Példa 1. Egycellás tömb képlete

Tegyük fel, hogy két oszlopban, mondjuk a B és a C oszlopban szerepel az eladott termékek száma két különböző hónapban, és meg szeretné találni a maximális értékesítési növekedést.

Normális esetben egy további oszlopot, mondjuk a D oszlopot adnánk hozzá, amely kiszámítja az egyes termékek értékesítésének változását a következő képlet segítségével =C2-B2 , majd keressük meg a maximális értéket ebben a további oszlopban. =MAX(D:D) .

A tömbképletnek nincs szüksége további oszlopra, mivel tökéletesen tárolja a köztes eredményeket a memóriában. Tehát csak írja be a következő képletet, és nyomja meg a Ctrl + Shift + Enter billentyűkombinációt:

=MAX(C2:C6-B2:B6)

Példa 2. Többcellás tömb képlete az Excelben

Az előző SUM példában tegyük fel, hogy minden egyes eladás után 10% adót kell fizetnie, és az adó összegét minden egyes termékre vonatkozóan egyetlen képlettel szeretné kiszámítani.

Jelölje ki az üres cellák tartományát, mondjuk D2:D6, és írja be a következő képletet a képletsorba:

=B2:B6 * C2:C6 * 0.1

A Ctrl + Shift + Enter billentyűkombináció megnyomása után az Excel a kiválasztott tartomány minden egyes cellájába elhelyezi a tömbképlet egy példányát, és a következő eredményt kapja:

Példa 3. Excel tömbfüggvény használata egy többcellás tömb visszaadására

Mint már említettük, a Microsoft Excel biztosít néhány úgynevezett "tömbfüggvényt", amelyeket kifejezetten a többcellás tömbök kezelésére terveztek. A TRANSPOSE az egyik ilyen függvény, és ezt fogjuk használni a fenti táblázat transzponálására, azaz a sorok oszlopokká alakítására.

1. Jelöljön ki egy üres cellatartományt, ahová az átváltott táblázatot ki szeretné adni. Mivel a sorokat oszlopokká alakítjuk, ügyeljen arra, hogy ugyanannyi sort és oszlopot válasszon ki, mint ahány oszlopot és sort a forrástábla tartalmaz. Ebben a példában 6 oszlopot és 4 sort választunk ki.
2. Nyomja meg az F2 billentyűt a szerkesztési módba való belépéshez.
3. Írja be a képletet, és nyomja meg a Ctrl + Shift + Enter billentyűkombinációt.

Példánkban a képlet a következő:

=TRANSPOSE($A$1:$D$6)

Az eredmény ehhez hasonlóan fog kinézni:

Így használja a TRANSPOSE-t CSE tömbképletként az Excel 2019-ben és korábban. A Dynamic Array Excelben ez normál képletként is működik. Az Excelben történő transzponálás egyéb módjainak megismeréséhez tekintse meg ezt a bemutatót: Hogyan válthatunk oszlopokat és sorokat az Excelben.

Hogyan dolgozzunk többcellás tömbképletekkel?

Amikor többcellás tömbképletekkel dolgozik az Excelben, a helyes eredmények érdekében mindenképpen kövesse az alábbi szabályokat:

1. Válassza ki a cellák azon tartományát, ahol az eredményeket ki szeretné adni. a előtt a képlet beírása.
2. A címre. delete egy többcellás tömbképletet, vagy jelölje ki az összes cellát, amely tartalmazza, és nyomja meg a DELETE gombot, vagy jelölje ki a teljes képletet a képletsorban, nyomja meg a DELETE gombot, majd nyomja meg a Ctrl + Shift + Enter billentyűkombinációt.
3. Nem szerkesztheti vagy mozgathatja egy tömbképletben lévő egyes cellák tartalmát, és nem szúrhat be új cellákat egy többcellás tömbképletbe, illetve nem törölheti a meglévő cellákat egy többcellás tömbképletből. Amikor ezzel próbálkozik, a Microsoft Excel a következő figyelmeztetést adja ki: " Egy tömb egy részét nem lehet megváltoztatni ".
4. A címre. zsugorodik egy tömbképletet, azaz ha kevesebb cellára szeretné alkalmazni, akkor először törölnie kell a meglévő képletet, majd be kell írnia egy újat.
5. A címre. bővítsd a oldalt. egy tömbképletet, azaz több cellára is alkalmazza, jelölje ki az összes olyan cellát, amely tartalmazza az aktuális képletet, valamint az üres cellákat, ahol azt szeretné, hogy az legyen, nyomja meg az F2 billentyűt a szerkesztési módba való átváltáshoz, állítsa be a hivatkozásokat a képletben, és nyomja meg a Ctrl + Shift + Enter billentyűkombinációt a frissítéshez.
6. Az Excel táblázatokban nem használhat többcellás tömbképleteket.
7. A többcellás tömbképletet olyan cellatartományba kell beírnia, amelynek mérete megegyezik a képlet által visszaadott tömb méretével. Ha az Excel tömbképlet a kiválasztott tartománynál nagyobb tömböt eredményez, a többletértékek nem fognak megjelenni a munkalapon. Ha a képlet által visszaadott tömb kisebb, mint a kiválasztott tartomány, a #N/A hibák extra cellákban fognak megjelenni.

Ha a képlet változó számú elemet tartalmazó tömböt adhat vissza, adja meg a képlet által visszaadott maximális tömbnek megfelelő vagy annál nagyobb tartományban, és csomagolja be a képletet az IFERROR függvénybe, ahogyan ez a példa mutatja.

Excel tömbi konstansok

A Microsoft Excelben a tömbkonstans egyszerűen statikus értékek halmaza. Ezek az értékek soha nem változnak, amikor egy képletet másol más cellákra vagy értékekre.

A bemutató legelején már láttál egy példát egy élelmiszerbolt listából létrehozott tömbállandóra. Most nézzük meg, milyen más tömbtípusok léteznek, és hogyan hozhatod létre őket.

A tömbállandóknak 3 típusa létezik:

1. Vízszintes tömbi állandó

Egy vízszintes tömbi konstans egy sorban található. Egy soros tömbi konstans létrehozásához írja be az értékeket vesszővel elválasztva, majd zárójelekbe zárva, például {1,2,3,4}.

Megjegyzés: Tömbkonstans létrehozásakor a nyitó és záró zárójeleket kézzel kell beírni.

Ha vízszintes tömböt szeretne beírni egy táblázatkezelőbe, jelölje ki a megfelelő számú üres cellát egy sorban, írja be a következő képletet ={1,2,3,4} a képletsoron, és nyomja meg a Ctrl + Shift + Enter billentyűkombinációt. Az eredmény ehhez hasonló lesz:

Amint a képernyőképen látható, az Excel egy tömbi állandót egy másik zárójelbe csomagol, pontosan úgy, mint amikor egy tömbi képletet ad meg.

2. Függőleges tömbi konstans

A függőleges tömbállandó egy oszlopban található. Ugyanúgy hozhatja létre, mint egy vízszintes tömböt, azzal a különbséggel, hogy az elemeket például pontosvesszővel határolja el:

={11; 22; 33; 44}

3. Kétdimenziós tömbi konstans

Kétdimenziós tömb létrehozásához az egyes sorokat pontosvesszővel, az egyes oszlopokat pedig vesszővel választja el.

={"a", "b", "c"; 1, 2, 3}

Munka Excel tömbi konstansokkal

A tömbi konstansok az Excel tömbi képletek egyik sarokkövei. Az alábbi információk és tippek segíthetnek a leghatékonyabb használatukban.

1. Egy tömbi konstans elemei

   Egy tömbkonstans tartalmazhat számokat, szöveges értékeket, boolékat (TRUE és FALSE) és hibaértékeket, vesszővel vagy pontosvesszővel elválasztva.

   A numerikus értéket egész számként, tizedesjegyként vagy tudományos jelöléssel adhatja meg. Ha szöveges értékeket használ, azokat idézőjelek (") közé kell tenni, mint bármely Excel-képletben.

   A tömbkonstans nem tartalmazhat más tömböket, cellahivatkozásokat, tartományokat, dátumokat, meghatározott neveket, képleteket vagy függvényeket.

2. Tömbi konstansok elnevezése

   Egy tömbkonstans könnyebb használatához adjunk neki nevet:

   • Váltson a Képletek lap> Meghatározott nevek csoport és kattintson a Név meghatározása Alternatívaként nyomja meg a Ctrl + F3 billentyűkombinációt, majd kattintson a Új .
   • Írja be a nevet a Név
   • A A következőkre vonatkozik mezőbe írja be a tömbkonstans elemeit zárójelben, az előző egyenlőségjel (=) előtaggal körülvéve. Például:

     ={"Su", "Mo", "Tu", "We", "Th", "Fr", "Sa"}

     

   • Kattintson az OK gombra a megnevezett tömb mentéséhez, és zárja be az ablakot.

   A megnevezett tömbkonstans megadásához egy lapon jelölje ki egy sorban vagy oszlopban annyi cellát, ahány elem van a tömbben, írja be a tömb nevét a képletsorba az = jellel megelőzve, és nyomja meg a Ctrl + Shift + Enter billentyűkombinációt.

   Az eredménynek ehhez kell hasonlítania:

   

3. Hibák megelőzése

   Ha a tömbállandó nem működik megfelelően, ellenőrizze a következő problémákat:

   • Határolja el a tömbállandó elemeit a megfelelő karakterrel - vesszővel a vízszintes tömbállandóknál és pontosvesszővel a függőlegeseknél.
   • Olyan cellatartományt választott ki, amely pontosan megegyezik a tömbállandó elemeinek számával. Ha több cellát választ ki, minden egyes további cellában a #N/A hiba jelenik meg. Ha kevesebb cellát választ ki, a tömbnek csak egy része kerül beillesztésre.

Tömbi konstansok használata Excel képletekben

Most, hogy megismerkedtél a tömbi konstansok fogalmával, nézzük meg, hogyan használhatod a tömbi informatikai képleteket a gyakorlati feladatok megoldásához.

Példa 1. Az N legnagyobb/kisebb számok összege egy tartományban

Kezdjük egy függőleges tömbkonstans létrehozásával, amely annyi számot tartalmaz, ahányat össze akarunk adni. Ha például egy tartományban a 3 legkisebb vagy legnagyobb számot szeretnénk összeadni, a tömbkonstans {1,2,3}.

Ezután vegyük a LARGE vagy SMALL függvényt, az első paraméterben adjuk meg a cellák teljes tartományát, a másodikban pedig a tömbkonstansot. Végül ágyazzuk be a SUM függvénybe, így:

Adja össze a legnagyobb 3 számot: =SUM(LARGE(range, {1,2,3}))

Adjuk össze a legkisebb 3 számot: =SUM(SMALL(range, {1,2,3}))

Ne felejtse el lenyomni a Ctrl + Shift + Enter billentyűkombinációt, mivel egy tömbképletet ad meg, és a következő eredményt kapja:

Hasonló módon kiszámíthatja egy tartomány N legkisebb vagy legnagyobb értékének átlagát:

Az első 3 szám átlaga: =AVERAGE(LARGE(range, {1,2,3}))

Az alsó 3 szám átlaga: =AVERAGE(SMALL(range, {1,2,3}))

Példa 2. Tömbképlet a több feltételhez tartozó cellák számolásához

Tegyük fel, hogy van egy listája a megrendelésekről, és szeretné tudni, hogy egy adott eladó hányszor adott el adott terméket.

A legegyszerűbb megoldás egy COUNTIFS formula használata több feltétellel. Ha azonban sok terméket szeretne bevonni, a COUNTIFS formula mérete túl nagyra nőhet. A tömörebbé tétel érdekében használhatja a COUNTIFS-t a SUM-mal együtt, és például egy vagy több argumentumban egy tömbi állandót is megadhat:

=SUM(COUNTIFS(range1, "criteria1", range2, {"criteria1", "criteria2"}))

A valós képlet a következőképpen nézhet ki:

=SUM(COUNTIFS(B2:B9, "sally", C2:C9, {"alma", "citrom"}))

A mi mintatömbünk csak két elemet tartalmaz, mivel a cél a megközelítés bemutatása. A valódi tömbképletekben annyi elemet tartalmazhat, amennyit az üzleti logika megkövetel, feltéve, hogy a képlet teljes hossza nem haladja meg a 8.192 karaktert az Excel 2019 - 2007-ben (1.024 karaktert az Excel 2003-ban és annál alacsonyabb verzióban), és a számítógép elég erős a nagy tömbök feldolgozásához.további részletekért lásd a tömbképletek korlátait.

Íme egy fejlett tömbi képlet példa, amely egy táblázatban található összes egyező érték összegét találja meg: SUM és VLOOKUP egy tömbi konstanssal.

AND és OR operátorok az Excel tömbképletekben

A tömboperátor megmondja a képletnek, hogyan kívánja feldolgozni a tömböket - ÉS vagy VAGY logikával.

• Az ÉS operátor a csillag (*), amely a szorzás szimbóluma. Arra utasítja az Excelt, hogy akkor adja vissza a TRUE értéket, ha MINDEN feltétel TRUE értékű.
• A VAGY operátor a plusz jel (+), amely akkor adja vissza a TRUE értéket, ha az adott kifejezésben szereplő bármelyik feltétel TRUE értékű.

Tömbképlet az AND operátorral

Ebben a példában az eladások összegét keressük, ahol az értékesítő személy Mike ÉS a termék Alma :

=SUM((A2:A9="Mike") * (B2:B9="Alma") * (C2:C9))

Vagy

=SUM(IF(((A2:A9="Mike") * (B2:B9="Alma")), (C2:C9))))

Gyakorlatilag ez a képlet a három tömb azonos pozícióban lévő elemeit szorozza meg. Az első két tömböt a TRUE és FALSE értékek képviselik, amelyek az A2:A9 és Mike", illetve a B2:B9 és az "Alma" összehasonlításának eredményei. A harmadik tömb a C2:C9 tartományból származó eladási számokat tartalmazza. Mint minden matematikai művelet, a szorzás a TRUE és FALSE értékeket 1-re, illetve 0-ra alakítja át. És mivel aa 0-val való szorzás mindig nullát ad, a kapott tömb 0, ha valamelyik vagy mindkét feltétel nem teljesül. Ha mindkét feltétel teljesül, akkor a harmadik tömb megfelelő eleme kerül a végső tömbbe (pl. 1*1*C2 = 10). Tehát a szorzás eredménye ez a tömb lesz: {10;0;0;0;30;0;0;0;0;0;0;0}. Végül a SUM függvény összeadja a tömb elemeit, és 40-es eredményt ad vissza.

Excel tömbképlet az OR operátorral

A következő tömbképlet a VAGY operátorral (+) összeadja az összes olyan eladást, ahol az értékesítő személy Mike VAGY termék a következő Alma:

=SUM(IF(((A2:A9="Mike") + (B2:B9="Alma")), (C2:C9))))

Ebben a képletben összeadjuk az első két tömb elemeit (amelyek a tesztelni kívánt feltételek), és TRUE (>0) értéket kapunk, ha legalább egy feltétel TRUE értékű; FALSE (0), ha az összes feltétel FALSE értékű. Ezután IF ellenőrzi, hogy az összeadás eredménye nagyobb-e 0-nál, és ha igen, a SUM összeadja a harmadik tömb (C2:C9) megfelelő elemét.

Tipp. Az Excel modern verzióiban nincs szükség tömbképlet használatára az ilyen jellegű feladatokhoz - egy egyszerű SUMIFS képlet tökéletesen kezeli ezeket. Mindazonáltal a tömbképletekben lévő AND és OR operátorok hasznosnak bizonyulhatnak összetettebb forgatókönyvekben, nem beszélve egy nagyon jó elmés tornáról : ).

Dupla unáris operátor az Excel tömbképletekben

Ha valaha is dolgozott már tömbképletekkel az Excelben, akkor valószínűleg találkozott néhány olyan képlettel, amely dupla kötőjelet (--) tartalmazott, és talán elgondolkodott azon, hogy mire is használják.

A dupla kötőjel, amelyet technikailag a kettős unáris operátor, arra szolgál, hogy bizonyos kifejezések által visszaadott nem számszerű Boolean értékeket (TRUE / FALSE) 1 és 0 értékekké alakítson, amelyeket egy tömbfüggvény megérthet.

A következő példa remélhetőleg megkönnyíti a dolgok megértését. Tegyük fel, hogy az A oszlopban van egy dátumokat tartalmazó lista, és szeretnénk tudni, hogy hány dátum fordul elő januárban, függetlenül az évszámtól.

A következő képlet remekül fog működni:

=SUM(--(MONTH(A2:A10)=1))

Mivel ez egy Excel tömbképlet, ne feledje, hogy a Ctrl + Shift + Enter billentyűkombinációt kell megnyomnia a befejezéshez.

Ha valamilyen más hónap érdekli, akkor az 1-et helyettesítse a megfelelő számmal. Például a 2 a februárt jelenti, a 3 a márciust, és így tovább. Hogy a képletet rugalmasabbá tegye, megadhatja a hónap számát valamelyik cellában, ahogy a képernyőképen látható:

Most pedig elemezzük, hogyan működik ez a tömbképlet. A MONTH függvény az A2-től A10-ig terjedő cellákban lévő minden egyes dátum hónapját adja vissza, amelyet egy sorszámmal ábrázol, és amely a {2;1;4;2;12;1;2;12;1} tömböt állítja elő.

Ezután a tömb minden egyes elemét összehasonlítjuk a D1 cellában lévő értékkel, ami ebben a példában az 1-es szám. Az összehasonlítás eredménye egy TRUE és FALSE Boolean értékekből álló tömb. Mint emlékszik, a tömbképlet egy bizonyos részét kijelölheti, és az F9 billentyű lenyomásával megnézheti, hogy az a rész minek felel meg:

Végül ezeket a Boole-értékeket át kell alakítani 1-es és 0-s értékekké, amelyeket a SUM függvény megérthet. És ehhez van szükség a dupla unáris operátorra. Az első unáris operátor a TRUE/FALSE értékeket -1/0-ra kényszeríti, a második unáris pedig negálja az értékeket, azaz megfordítja az előjelet, +1-re és 0-ra alakítja őket, amelyeket a legtöbb Excel függvény megért és tud velük dolgozni. Ha eltávolítjuk a dupla unáris operátort.a fenti képletből, nem fog működni.

Remélem, hogy ez a rövid bemutató hasznosnak bizonyult az Excel tömbképletek elsajátításához vezető úton. Jövő héten folytatjuk az Excel tömbökkel, a fejlett képletekre összpontosítva. Kérem, maradjanak velünk, és köszönjük, hogy elolvasták!