In deze zelfstudie leert u wat een Excel-arrayformule is, hoe u deze correct in uw werkbladen invoert, en hoe u arrayconstanten en arrayfuncties gebruikt.

Matrixformules in Excel zijn een uiterst krachtig hulpmiddel en een van de moeilijkste om onder de knie te krijgen. Een enkele matrixformule kan meerdere berekeningen uitvoeren en duizenden gebruikelijke formules vervangen. En toch heeft 90% van de gebruikers nog nooit matrixfuncties in hun werkbladen gebruikt, gewoon omdat ze bang zijn om ze te leren.

Inderdaad, matrixformules zijn een van de meest verwarrende Excel-functies om te leren. Het doel van deze handleiding is de leercurve zo gemakkelijk en soepel mogelijk te maken.

Wat is een matrix in Excel?

Voordat we beginnen met arrayfuncties en -formules, moeten we eerst uitzoeken wat de term "array" betekent. In wezen is een array een verzameling items. De items kunnen tekst of getallen zijn en ze kunnen in een enkele rij of kolom staan, of in meerdere rijen en kolommen.

Als u bijvoorbeeld uw wekelijkse boodschappenlijstje in een Excel-matrixformaat zet, ziet het er als volgt uit:

{Melk, eieren, boter, maïsvlokken.}

Als u vervolgens de cellen A1 tot en met D1 selecteert, in de formulebalk de bovenstaande reeks invoert voorafgegaan door een gelijkheidsteken (=) en op CTRL + SHIFT + ENTER drukt, krijgt u het volgende resultaat:

Wat je zojuist hebt gedaan is een eendimensionale horizontale matrix maken. Niets vreselijks tot nu toe, toch?

Wat is een matrixformule in Excel?

Het verschil tussen een matrixformule en een gewone formule is dat een matrixformule meerdere waarden verwerkt in plaats van slechts één. Met andere woorden, een matrixformule in Excel evalueert alle individuele waarden in een matrix en voert meerdere berekeningen uit op één of meerdere items volgens de voorwaarden die in de formule zijn uitgedrukt.

Een matrixformule kan niet alleen meerdere waarden tegelijk behandelen, maar ook meerdere waarden tegelijk teruggeven. Het resultaat dat een matrixformule teruggeeft, is dus ook een matrix.

Array-formules zijn beschikbaar in alle versies van Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 en lager.

En nu lijkt de tijd rijp om uw eerste matrixformule te maken.

Eenvoudig voorbeeld van een Excel-matrixformule

Stel, u hebt een aantal artikelen in kolom B, hun prijzen in kolom C, en u wilt het totaal van alle verkopen berekenen.

Natuurlijk belet niets u om eerst subtotalen in elke rij te berekenen met iets eenvoudigs als =B2*C2 en dan die waarden optellen:

Een matrixformule kan u echter die extra toetsaanslagen besparen, omdat Excel de tussenresultaten in het geheugen opslaat in plaats van in een extra kolom. Er is dus maar één matrixformule nodig en twee snelle stappen:

1. Selecteer een lege cel en voer daarin de volgende formule in:

   =SUM(B2:B6*C2:C6)

2. Druk op de sneltoets CTRL + SHIFT + ENTER om de matrixformule te voltooien.

   Zodra u dit doet, omringt Microsoft Excel de formule met {curly braces}, wat een visuele indicatie is van een matrixformule.

   Wat de formule doet is de waarden in elke afzonderlijke rij van de gespecificeerde matrix (cellen B2 tot en met C6) vermenigvuldigen, de subtotalen bij elkaar optellen en het eindtotaal weergeven:

   

Dit eenvoudige voorbeeld laat zien hoe krachtig een matrixformule kan zijn. Wanneer u werkt met honderden en duizenden rijen gegevens, bedenk dan eens hoeveel tijd u kunt besparen door één matrixformule in te voeren in één enkele cel.

Waarom matrixformules gebruiken in Excel?

Excel matrixformules zijn het handigste hulpmiddel om geavanceerde berekeningen uit te voeren en complexe taken uit te voeren. Een enkele matrixformule kan letterlijk honderden gebruikelijke formules vervangen. Matrixformules zijn zeer geschikt voor taken als:

• Som getallen op die aan bepaalde voorwaarden voldoen, bijvoorbeeld som N grootste of kleinste waarden in een bereik.
• Tel elke andere rij op, of elke N-de rij of kolom, zoals in dit voorbeeld.
• Tel het aantal van alle of bepaalde tekens in een opgegeven bereik. Hier is een matrixformule die alle tekens telt, en een andere die bepaalde tekens telt.

Hoe een matrixformule invoeren in Excel (Ctrl + Shift + Enter)

Zoals u al weet, is de combinatie van de 3 toetsen CTRL + SHIFT + ENTER een magische toets die een gewone formule verandert in een matrixformule.

Bij het invoeren van een matrixformule in Excel zijn er 4 belangrijke dingen om in gedachten te houden:

1. Zodra u klaar bent met het typen van de formule en tegelijkertijd de toetsen CTRL SHIFT ENTER hebt ingedrukt, sluit Excel de formule automatisch in tussen {curly braces}. Wanneer u zo'n cel(len) selecteert, ziet u de accolades in de formulebalk, wat u een aanwijzing geeft dat er een matrixformule in staat.
2. Handmatig de accolades rond een formule typen werkt niet. U moet op de sneltoets Ctrl+Shift+Enter drukken om een matrixformule te voltooien.
3. Telkens wanneer u een matrixformule bewerkt, verdwijnen de accolades en moet u opnieuw op Ctrl+Shift+Enter drukken om de wijzigingen op te slaan.
4. Als u vergeet op Ctrl+Shift+Enter te drukken, zal uw formule zich gedragen als een gewone formule en alleen de eerste waarde(n) in de opgegeven matrix(en) verwerken.

Omdat voor alle Excel-rijfformules Ctrl + Shift + Enter moet worden ingedrukt, worden ze soms aangeduid als CSE-formules .

De F9-toets gebruiken om delen van een matrixformule te evalueren

Wanneer u werkt met matrixformules in Excel, kunt u zien hoe zij hun items (interne matrices) berekenen en opslaan om het eindresultaat weer te geven dat u in een cel ziet. Selecteer daartoe een of meer argumenten binnen de haakjes van een functie en druk vervolgens op de toets F9. Om de evaluatiemodus van de formule te verlaten, drukt u op de Esc-toets.

In het bovenstaande voorbeeld, om de subtotalen van alle producten te zien, selecteert u B2:B6*C2:C6, drukt u op F9 en krijgt u het volgende resultaat.

Let op: u moet een deel van de formule selecteren voordat u op F9 drukt, anders vervangt de F9-toets uw formule door de berekende waarde(n).

Formules voor één en meerdere cellen in Excel

Excel-arrayformules kunnen een resultaat opleveren in een enkele cel of in meerdere cellen. Een arrayformule die in een bereik van cellen wordt ingevoerd, wordt een meercellige formule Een matrixformule in een enkele cel heet een formule voor één cel .

Er bestaan een paar Excel-arrayfuncties die zijn ontworpen om multi-cell arrays terug te geven, bijvoorbeeld TRANSPOSE, TREND, FREQUENCY, LINEST, enz.

Andere functies, zoals SUM, AVERAGE, AGGREGATE, MAX, MIN, kunnen matrixuitdrukkingen berekenen wanneer deze in één cel worden ingevoerd met behulp van Ctrl + Shift + Enter .

De volgende voorbeelden laten zien hoe u een ééncellige en een meercellige matrixformule kunt gebruiken.

Voorbeeld 1. Een matrixformule voor één cel

Stel u hebt twee kolommen met het aantal verkochte artikelen in 2 verschillende maanden, zeg kolommen B en C, en u wilt de maximale omzetstijging vinden.

Normaal gesproken zou u een extra kolom toevoegen, bijvoorbeeld kolom D, die de omzetverandering voor elk product berekent met een formule als =C2-B2 en vind dan de maximumwaarde in die extra kolom =MAX(D:D) .

Een matrixformule heeft geen extra kolom nodig omdat de tussenresultaten perfect in het geheugen worden opgeslagen. U voert dus gewoon de volgende formule in en drukt op Ctrl + Shift + Enter :

=MAX(C2:C6-B2:B6)

Voorbeeld 2. Een formule met meerdere cellen in Excel

In het vorige SUM-voorbeeld, stel dat u van elke verkoop 10% belasting moet betalen en u wilt het belastingbedrag voor elk product met één formule berekenen.

Selecteer het bereik van lege cellen, zeg D2:D6, en voer de volgende formule in de formulebalk in:

=B2:B6 * C2:C6 * 0.1

Zodra u op Ctrl + Shift + Enter drukt, plaatst Excel een instantie van uw matrixformule in elke cel van het geselecteerde bereik, en krijgt u het volgende resultaat:

Voorbeeld 3. Een Excel-arrayfunctie gebruiken om een meercellige array terug te geven

Zoals reeds vermeld, biedt Microsoft Excel een aantal zogenaamde "matrixfuncties" die speciaal zijn ontworpen om te werken met matrices met meerdere cellen. TRANSPOSE is een van die functies en we gaan die gebruiken om de bovenstaande tabel te transponeren, d.w.z. rijen om te zetten in kolommen.

1. Selecteer een leeg cellenbereik waar u de getransponeerde tabel wilt uitvoeren. Aangezien we rijen naar kolommen converteren, moet u hetzelfde aantal rijen en kolommen selecteren als uw brontabel respectievelijk kolommen en rijen heeft. In dit voorbeeld selecteren we 6 kolommen en 4 rijen.
2. Druk op F2 om de bewerkingsmodus te openen.
3. Voer de formule in en druk op Ctrl + Shift + Enter .

In ons voorbeeld is de formule:

=TRANSPOSE($A$1:$D$6)

Het resultaat ziet er ongeveer zo uit:

Dit is hoe u TRANSPOSE gebruikt als een CSE-arrayformule in Excel 2019 en eerder. In Dynamic Array Excel werkt dit ook als een gewone formule. Als u andere manieren wilt leren om te transponeren in Excel, bekijk dan deze tutorial: Hoe kolommen en rijen te verwisselen in Excel.

Hoe werkt u met formules met meerdere cellen?

Wanneer u in Excel werkt met formules uit meerdere cellen, moet u deze regels volgen om de juiste resultaten te verkrijgen:

1. Selecteer het cellenbereik waarin u de resultaten wilt uitvoeren voor de formule invoeren.
2. Naar verwijder een matrixformule met meerdere cellen te verwijderen, selecteer dan alle cellen die de formule bevatten en druk op DELETE , of selecteer de hele formule in de formulebalk, druk op DELETE en druk vervolgens op Ctrl + Shift + Enter .
3. U kunt de inhoud van een individuele cel in een matrixformule niet bewerken of verplaatsen, noch kunt u nieuwe cellen invoegen in of bestaande cellen verwijderen uit een matrixformule met meerdere cellen. Wanneer u dit probeert, geeft Microsoft Excel de waarschuwing " U kunt een deel van een matrix niet wijzigen ".
4. Naar krimp een matrixformule, d.w.z. om deze op minder cellen toe te passen, moet u eerst de bestaande formule wissen en dan een nieuwe invoeren.
5. Naar uitbreiden een matrixformule, d.w.z. toepassen op meer cellen, selecteer alle cellen die de huidige formule bevatten plus lege cellen waar u de formule wilt hebben, druk op F2 om over te schakelen naar de bewerkingsmodus, pas de verwijzingen in de formule aan en druk op Ctrl + Shift + Enter om de formule bij te werken.
6. U kunt geen formules met meerdere cellen gebruiken in Excel-tabellen.
7. U moet een meercellige matrixformule invoeren in een cellenbereik van dezelfde grootte als de resulterende matrix die door de formule wordt geretourneerd. Als uw Excel-matrixformule een matrix produceert die groter is dan het geselecteerde bereik, verschijnen de overtollige waarden niet op het werkblad. Als een matrix die door de formule wordt geretourneerd kleiner is dan het geselecteerde bereik, verschijnen er #N/A-fouten in extra cellen.

Indien uw formule een matrix met een variabel aantal elementen kan retourneren, voer deze dan in een bereik in dat gelijk is aan of groter is dan de maximale matrix die door de formule wordt geretourneerd en wikkel uw formule in de functie IFERROR, zoals in dit voorbeeld wordt gedemonstreerd.

Excel matrixconstanten

In Microsoft Excel is een matrixconstante gewoon een reeks statische waarden. Deze waarden veranderen nooit wanneer u een formule kopieert naar andere cellen of waarden.

Je zag al een voorbeeld van een array-constante die is gemaakt van een boodschappenlijst in het begin van deze tutorial. Laten we nu eens kijken welke andere array-types er bestaan en hoe je die maakt.

Er bestaan 3 soorten matrixconstanten:

1. Horizontale matrixconstante

Een horizontale matrixconstante staat in een rij. Om een matrixconstante te maken, typt u de waarden gescheiden door komma's en zet u ze tussen accolades, bijvoorbeeld {1,2,3,4}.

Opmerking: Als u een matrixconstante maakt, moet u de accolades handmatig openen en sluiten.

Om een horizontale matrix in een spreadsheet in te voeren, selecteert u het overeenkomstige aantal lege cellen in een rij, typt u de formule ={1,2,3,4} in de formulebalk, en druk op Ctrl + Shift + Enter . Het resultaat ziet er ongeveer zo uit:

Zoals u in de schermafbeelding ziet, verpakt Excel een matrixconstante in een andere set accolades, precies zoals het doet wanneer u een matrixformule invoert.

2. Verticale matrixconstante

Een verticale matrixconstante bevindt zich in een kolom. U maakt hem op dezelfde manier als een horizontale matrix, met als enige verschil dat u de items bijvoorbeeld met puntkomma's afbakent:

={11; 22; 33; 44}

3. Tweedimensionale matrixconstante

Om een tweedimensionale array te maken, scheidt u elke rij door een puntkomma en elke kolom met gegevens door een komma.

={"a", "b", "c"; 1, 2, 3}

Werken met Excel-arrayconstanten

Matrixconstanten zijn een van de hoekstenen van een Excel-arrayformule. De volgende informatie en tips kunnen u helpen ze zo efficiënt mogelijk te gebruiken.

1. Elementen van een matrixconstante

   Een arrayconstante kan getallen, tekstwaarden, Booleans (TRUE en FALSE) en foutwaarden bevatten, gescheiden door komma's of puntkomma's.

   U kunt een numerieke waarde invoeren als een geheel getal, een decimaal getal of in wetenschappelijke notatie. Als u tekstwaarden gebruikt, moeten deze tussen dubbele aanhalingstekens (") staan, zoals in elke Excel-formule.

   Een matrixconstante kan geen andere matrices, celverwijzingen, bereiken, datums, gedefinieerde namen, formules of functies bevatten.

2. Naamgeving van matrixconstanten

   Om een arrayconstante gemakkelijker te gebruiken, geeft u hem een naam:

   • Schakel over naar de Tabblad Formules> Gedefinieerde namen groep en klik op Naam definiëren Of druk op Ctrl + F3 en klik op Nieuw .
   • Typ de naam in de Naam
   • In de Verwijst naar box, voer de items van uw matrixconstante in, omgeven door accolades met het voorafgaande gelijkheidsteken (=). Bijvoorbeeld:

     ={"Su", "Mo", "Tu", "We", "Th", "Fr", "Sa"}

     

   • Klik op OK om de genoemde array op te slaan en het venster te sluiten.

   Om de genoemde matrixconstante in een blad in te voeren, selecteert u zoveel cellen in een rij of kolom als er items in uw matrix zijn, typt u de naam van de matrix in de formulebalk voorafgegaan door het = teken en drukt u op Ctrl + Shift + Enter .

   Het resultaat zou hier op moeten lijken:

   

3. Fouten voorkomen

   Als uw matrixconstante niet correct werkt, controleer dan op de volgende problemen:

   • Scheid de elementen van uw matrixconstante met het juiste teken - komma in horizontale matrixconstanten en puntkomma in verticale.
   • Selecteer een bereik van cellen dat precies overeenkomt met het aantal items in uw matrixconstante. Als u meer cellen selecteert, krijgt elke extra cel de fout #N/A. Als u minder cellen selecteert, wordt slechts een deel van de matrix ingevoegd.

Matrixconstanten gebruiken in Excel-formules

Nu u vertrouwd bent met het concept van array-constanten, laten we eens kijken hoe u arrays-informules kunt gebruiken om uw praktische taken op te lossen.

Voorbeeld 1. Som N grootste / kleinste getallen in een reeks op

U begint met het maken van een verticale matrixconstante die zoveel getallen bevat als u wilt optellen. Als u bijvoorbeeld 3 kleinste of grootste getallen in een bereik wilt optellen, is de matrixconstante {1,2,3}.

Vervolgens neemt u de functie LARGE of SMALL, specificeert u het hele cellenbereik in de eerste parameter en neemt u de matrixconstante op in de tweede. Tenslotte neemt u de functie op in de SUM-functie, als volgt:

Tel de 3 grootste getallen bij elkaar op: =SUM(LARGE(range, {1,2,3}))

Tel de kleinste 3 getallen bij elkaar op: =SUM(SMALL(range, {1,2,3}))

Vergeet niet op Ctrl + Shift + Enter te drukken omdat u een matrixformule invoert, en u krijgt het volgende resultaat:

Op soortgelijke wijze kunt u het gemiddelde berekenen van N kleinste of grootste waarden in een bereik:

Gemiddelde van de top 3 nummers: =AVERAGE(LARGE(range, {1,2,3}))

Gemiddelde van de onderste 3 nummers: =AVERAGE(SMALL(range, {1,2,3}))

Voorbeeld 2. Matrixformule om cellen met meerdere voorwaarden te tellen

Stel, u hebt een lijst met bestellingen en u wilt weten hoe vaak een bepaalde verkoper bepaalde producten heeft verkocht.

De eenvoudigste manier is het gebruik van een COUNTIFS-formule met meerdere voorwaarden. Als u echter veel producten wilt opnemen, kan uw COUNTIFS-formule te groot worden. Om het compacter te maken, kunt u COUNTIFS gebruiken in combinatie met SUM en bijvoorbeeld een matrixconstante opnemen in een of meer argumenten:

=SUM(COUNTIFS(range1, "criteria1", range2, {"criteria1", "criteria2"}))

De echte formule kan er als volgt uitzien:

=SUM(COUNTIFS(B2:B9, "sally", C2:C9, {"appels", "citroenen"})

Onze voorbeeldarray bestaat uit slechts twee elementen omdat het doel is de aanpak te demonstreren. In uw echte arrayformules kunt u zoveel elementen opnemen als uw bedrijfslogica vereist, op voorwaarde dat de totale lengte van de formule niet langer is dan 8.192 tekens in Excel 2019 - 2007 (1.024 tekens in Excel 2003 en lager) en uw computer krachtig genoeg is om grote arrays te verwerken.zie de beperkingen van matrixformules voor meer details.

En hier is een voorbeeld van een geavanceerde matrixformule die de som vindt van alle overeenkomende waarden in een tabel: SUM en VLOOKUP met een matrixconstante.

EN en OF operatoren in Excel matrixformules

Een matrixoperator vertelt de formule hoe u de matrices wilt verwerken - met AND- of OR-logica.

• De AND operator is het sterretje (*) dat het vermenigvuldigingssymbool is en Excel opdraagt WAAR te geven indien ALLE voorwaarden WAAR zijn.
• De OR-operator is het plusteken (+). Deze geeft WAAR als ELKE voorwaarde in een gegeven uitdrukking WAAR is.

Matrixformule met de AND-operator

In dit voorbeeld vinden we de som van de verkopen waarbij de verkoper Mike en het product is Appels :

=SUM((A2:A9="Mike") * (B2:B9="Appels") * (C2:C9))

Of

=SUM(IF((A2:A9="Mike") * (B2:B9="Appels")), (C2:C9))

Technisch gezien vermenigvuldigt deze formule de elementen van de drie matrices op dezelfde posities. De eerste twee matrices worden voorgesteld door de waarden TRUE en FALSE, die het resultaat zijn van de vergelijking van A2:A9 met Mike" en B2:B9 met "Appels". De derde matrix bevat de verkoopcijfers van het bereik C2:C9. Zoals elke wiskundige bewerking zet vermenigvuldiging TRUE en FALSE om in respectievelijk 1 en 0. En omdatvermenigvuldigen met 0 geeft altijd nul, de resulterende matrix heeft 0 wanneer aan een van beide voorwaarden niet is voldaan. Indien aan beide voorwaarden is voldaan, komt het overeenkomstige element uit de derde matrix in de uiteindelijke matrix (bijv. 1*1*C2 = 10). Het resultaat van de vermenigvuldiging is dus deze matrix: {10;0;0;30;0;0;0;0}. Tenslotte telt de SUM-functie de elementen van de matrix op en geeft een resultaat van 40.

Excel-arrayformule met de OR-operator

De volgende matrixformule met de OR-operator (+) telt alle verkopen op waarbij de verkoper Mike OF het product is Appels:

=SUM(IF((A2:A9="Mike") + (B2:B9="Appels")), (C2:C9))

In deze formule telt u de elementen van de eerste twee matrices (de voorwaarden die u wilt testen) bij elkaar op, en krijgt u TRUE (>0) als ten minste één voorwaarde op TRUE uitkomt; FALSE (0) als alle voorwaarden op FALSE uitkomen. Vervolgens controleert IF of het resultaat van de optelling groter is dan 0, en als dat zo is, telt SUM een overeenkomstig element van de derde matrix (C2:C9) op.

Tip. In moderne versies van Excel is het niet nodig om voor dit soort taken een matrixformule te gebruiken - een eenvoudige SUMIFS-formule kan ze perfect afhandelen. Niettemin kunnen de AND- en OR-operatoren in matrixformules nuttig blijken in complexere scenario's, laat staan een zeer goede gymnastiek van de geest : )

Dubbele unary operator in Excel matrixformules

Als u ooit hebt gewerkt met matrixformules in Excel, is de kans groot dat u er een paar bent tegengekomen met een dubbel streepje (--) en dat u zich hebt afgevraagd waar dat voor diende.

Een dubbel streepje, dat technisch gezien het dubbele unaire operator, wordt gebruikt om niet-numerieke Booleaanse waarden (TRUE / FALSE) die door sommige uitdrukkingen worden geretourneerd, om te zetten in 1 en 0 die een matrixfunctie kan begrijpen.

Het volgende voorbeeld maakt het hopelijk gemakkelijker te begrijpen. Stel, u hebt een lijst met datums in kolom A en u wilt weten hoeveel datums in januari voorkomen, ongeacht het jaar.

De volgende formule werkt prima:

=SUM(--(MONTH(A2:A10)=1))

Aangezien dit een Excel-arrayformule is, moet u niet vergeten op Ctrl + Shift + Enter te drukken om de formule te voltooien.

Als u geïnteresseerd bent in een andere maand, vervangt u 1 door een overeenkomstig nummer. Bijvoorbeeld, 2 staat voor februari, 3 voor maart, enzovoort. Om de formule flexibeler te maken, kunt u het maandnummer in een cel opgeven, zoals in de schermafbeelding wordt getoond:

En laten we nu analyseren hoe deze matrixformule werkt. De MONTH-functie geeft de maand van elke datum in de cellen A2 tot en met A10 terug, vertegenwoordigd door een volgnummer, dat de matrix {2;1;4;2;12;1;2;12;1} oplevert.

Daarna wordt elk element van de matrix vergeleken met de waarde in cel D1, die in dit voorbeeld nummer 1 is. Het resultaat van deze vergelijking is een matrix van Booleaanse waarden TRUE en FALSE. Zoals u zich herinnert, kunt u een bepaald deel van een matrixformule selecteren en op F9 drukken om te zien wat dat deel betekent:

Tenslotte moet je deze Booleaanse waarden omzetten in 1's en 0's die de SUM-functie kan begrijpen. En dit is waar de dubbele unary operator voor nodig is. De eerste unary codeert TRUE/FALSE naar -1/0, respectievelijk. De tweede unary ontkent de waarden, d.w.z. keert het teken om, waardoor ze veranderen in +1 en 0, die de meeste Excel-functies kunnen begrijpen en waarmee ze kunnen werken. Als je de dubbele unary verwijdertvan de bovenstaande formule, zal het niet werken.

Ik hoop dat deze korte handleiding nuttig is gebleken op uw weg naar het beheersen van Excel-arrayformules. Volgende week gaan we verder met Excel-arrays door ons te richten op geavanceerde formulevoorbeelden. Blijf kijken en bedankt voor het lezen!