Selles õpetuses saate teada, mis on Exceli massiivi valem, kuidas seda oma töölehtedel õigesti sisestada ning kuidas kasutada massiivi konstande ja massiivi funktsioone.

Exceli massiivi valemid on äärmiselt võimas vahend ja üks kõige raskemini omandatavaid. Üks massiivi valem võib teha mitmeid arvutusi ja asendada tuhandeid tavalisi valemeid. Ja ikkagi ei ole 90% kasutajatest oma töölehtedel kunagi kasutanud massiivi funktsioone lihtsalt sellepärast, et nad ei julge neid õppima hakata.

Tõepoolest, massiivi valemid on üks kõige segadusttekitavamaid Exceli funktsioone, mida õppida. Selle õpetuse eesmärk on muuta õppimine võimalikult lihtsaks ja sujuvaks.

Mis on Exceli massiiv?

Enne kui me alustame massiivi funktsioonide ja valemitega, selgitame välja, mida tähendab mõiste "massiivi". Põhimõtteliselt on massiivi elementide kogum. Elementid võivad olla tekst või numbrid ja need võivad asuda ühes reas või veerus või mitmes reas ja veerus.

Näiteks kui te paneksite oma iganädalase toidunimekirja Exceli massiivi formaati, näeks see välja järgmiselt:

{"Piim", "Munad", "Või", "Maisihelbed"}

Kui te valite lahtrid A1 kuni D1, sisestate ülaltoodud massiivi, millele eelneb võrdusmärk (=) valemiribal ja vajutate CTRL + SHIFT + ENTER , saate järgmise tulemuse:

See, mida te just tegite, on ühe-mõõtmelise horisontaalse massiivi loomine. Siiani ei ole midagi hirmsat, eks ole?

Mis on massiivi valem Excelis?

Erinevus massiivi valemi ja tavalise valemi vahel seisneb selles, et massiivi valem töötleb ühe väärtuse asemel mitut väärtust. Teisisõnu, massiivi valem Excelis hindab kõiki üksikuid väärtusi massiivi ja teeb mitu arvutust ühe või mitme elemendi kohta vastavalt valemis väljendatud tingimustele.

Massiivivalem ei saa mitte ainult käsitleda korraga mitut väärtust, vaid ta võib ka tagastada mitu väärtust korraga. Seega on massiivivalemi tagastatud tulemused samuti massiiv.

Ruutvalemid on saadaval kõigis Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 ja madalamates versioonides.

Ja nüüd näib olevat õige aeg luua oma esimene massiivi valem.

Lihtne näide Exceli massiivi valemi kohta

Oletame, et teil on mõned kaubad veerus B, nende hinnad veerus C ja te soovite arvutada kogu müügi kogusumma.

Loomulikult ei takista miski arvutamast kõigepealt vahesummasid igas reas midagi nii lihtsat kui =B2*C2 ja seejärel summeerige need väärtused:

Kuid massiivi valemiga saate säästa need lisaklahvivajutused, sest see paneb Exceli salvestama vahetulemused mällu, mitte täiendavasse veergu. Seega piisab vaid ühest massiivi valemist ja 2 kiirest sammust:

1. Valige tühi lahter ja sisestage sinna järgmine valem:

   =SUM(B2:B6*C2:C6)

2. Vajutage klahvikombinatsiooni CTRL + SHIFT + ENTER, et lõpetada massiivi valem.

   Kui te seda teete, ümbritseb Microsoft Excel valemit {kitsaste sulgude} abil, mis on visuaalne märge massiivi valemile.

   Valem korrutab määratud massiivi iga rea (lahtrid B2 kuni C6) väärtused, liidab vahesummad kokku ja väljastab kogusumma:

   

See lihtne näide näitab, kui võimas võib olla massiivi valem. Kui töötate sadade ja tuhandete andmereadidega, siis mõelge, kui palju aega saate säästa, kui sisestate ühe massiivi valemi ühte lahtrisse.

Miks kasutada Excelis massiivi valemeid?

Exceli massiivi valemid on kõige käepärasem vahend keerukate arvutuste tegemiseks ja keeruliste ülesannete täitmiseks. Üks massiivi valem võib asendada sõna otseses mõttes sadu tavalisi valemeid. Massiivi valemid on väga head selliste ülesannete jaoks nagu:

• Teatud tingimustele vastavate arvude summeerimine, näiteks N suurima või väikseima väärtuse summeerimine vahemikus.
• Summeerige iga teine rida või iga N-nes reas või veerus, nagu on näidatud selles näites.
• Loendage kõigi või teatud tähemärkide arvu kindlaksmääratud vahemikus. Siin on massiivi valem, mis loeb kõiki tähemärke, ja teine, mis loeb mis tahes kindlaid tähemärke.

Kuidas sisestada Exceli massiivi valemit (Ctrl + Shift + Enter)

Nagu te juba teate, on 3 klahvi CTRL + SHIFT + ENTER kombinatsioon võluväli, mis muudab tavalise valemi massiivi valemiks.

Massiivivalemi sisestamisel Excelis tuleb silmas pidada 4 olulist asja:

1. Kui olete valemi sisestamise lõpetanud ja samaaegselt vajutanud klahve CTRL SHIFT ENTER, siis Excel ümbritseb valemi automaatselt {sõõrdsulgude} vahele. Kui valite sellise lahtri(d), näete valemiribal sulgusid, mis annab teile märku, et seal on massiivi valem.
2. Valemi ümber olevate sulgude käsitsi kirjutamine ei toimi. Massiivivalemi täitmiseks tuleb vajutada klahvikombinatsiooni Ctrl+Shift+Enter.
3. Iga kord, kui muudate massiivi valemit, kaovad sulgud ja muudatuste salvestamiseks peate uuesti vajutama Ctrl+Shift+Enter.
4. Kui unustate vajutada Ctrl+Shift+Enter, käitub teie valem nagu tavaline valem ja töötleb ainult esimest väärtust (esimesi väärtusi) määratud massiivi(de)s.

Kuna kõik Exceli massiivi valemid nõuavad Ctrl + Shift + Enter vajutamist, nimetatakse neid mõnikord ka CSE valemid .

Kasutage klahvi F9, et hinnata massiivi valemi osi

Kui töötate Excelis massiivi valemitega, saate jälgida, kuidas need arvutavad ja salvestavad oma elemente (sisemised massiivid), et kuvada lahtris kuvatav lõpptulemus. Selleks valige üks või mitu argumenti funktsiooni sulgudes ja vajutage klahvi F9. Valemi hindamise režiimist väljumiseks vajutage klahvi Esc.

Ülaltoodud näites valite kõigi toodete vahesummade vaatamiseks B2:B6*C2:C6, vajutate F9 ja saate järgmise tulemuse.

Märkus. Pöörake tähelepanu, et enne F9 klahvi vajutamist peate valima mingi osa valemist, vastasel juhul asendab F9 klahv lihtsalt teie valemi arvutatud väärtuse(te)ga.

Ühe lahtri ja mitme lahtri massiivi valemid Excelis

Exceli massiivi valem võib tagastada tulemuse ühes lahtris või mitmes lahtris. Maatriksvalemit, mis on sisestatud lahtrite vahemikku, nimetatakse mitme lahtri valemiga Ühes lahtris asuvat massiivi valemit nimetatakse ühe raku valemiga .

On olemas mõned Exceli massiivi funktsioonid, mis on mõeldud mitme lahtri massiivi tagastamiseks, näiteks TRANSPOSE, TREND, FREQUENCY, LINEST jne.

Muud funktsioonid, nagu SUMMA, AVERAGE, AGGREGATE, MAX, MIN, võivad arvutada massiivi väljendeid, kui need sisestatakse ühte lahtrisse, kasutades Ctrl + Shift + Enter .

Järgmised näited näitavad, kuidas kasutada ühe ja mitme lahtri massiivi valemit.

Näide 1. Ühe lahtri massiivi valem

Oletame, et teil on kaks veergu, kus on loetletud kahe erineva kuu jooksul müüdud toodete arv, näiteks veerud B ja C, ja te soovite leida maksimaalse müügikasvu.

Tavaliselt lisate täiendava veeru, näiteks veeru D, mis arvutab iga toote müügi muutuse, kasutades sellist valemit nagu =C2-B2 ja seejärel leida maksimaalne väärtus selles lisasambas =MAX(D:D) .

Massiivvalem ei vaja täiendavat veergu, kuna see salvestab vahetulemused suurepäraselt mällu. Seega, sisestage lihtsalt järgmine valem ja vajutage Ctrl + Shift + Enter :

=MAX(C2:C6-B2:B6)

Näide 2. Mitme lahtri massiivi valem Excelis

Eelmise SUMM-i näite puhul oletame, et peate maksma 10% maksu igalt müügilt ja soovite arvutada maksusumma iga toote kohta ühe valemiga.

Valige tühjade lahtrite vahemik, näiteks D2:D6, ja sisestage valemiribale järgmine valem:

=B2:B6 * C2:C6 * 0,1

Kui vajutate Ctrl + Shift + Enter , paigutab Excel teie massiivi valemi eksemplari valitud vahemiku igasse lahtrisse ja saate järgmise tulemuse:

Näide 3. Exceli massiivi funktsiooni kasutamine mitme lahtri massiivi tagastamiseks

Nagu juba mainitud, pakub Microsoft Excel mõningaid nn "massiivi funktsioone", mis on spetsiaalselt mõeldud töötamiseks mitme lahtri massiividega. TRANSPOSE on üks sellistest funktsioonidest ja me kasutame seda ülaltoodud tabeli transponeerimiseks, st ridade teisendamiseks veergudeks.

1. Valige tühi lahtrite vahemik, kuhu soovite transponeeritud tabeli väljastada. Kuna me teisendame read veergudeks, valige kindlasti sama arv ridu ja veerge, kui teie lähtetabelis on vastavalt veerge ja ridu. Selles näites valime 6 veergu ja 4 rida.
2. Vajutage F2, et siseneda redigeerimisrežiimi.
3. Sisestage valem ja vajutage Ctrl + Shift + Enter .

Meie näites on valem:

=TRANSPOSE($A$1:$D$6)

Tulemus näeb välja umbes nii:

Nii kasutate TRANSPOSE'i CSE massiivi valemina Excel 2019 ja varasemates programmides. Dünaamilise massiivi Excelis töötab see ka tavalise valemina. Kui soovite õppida teisi Excelis transponeerimise viise, vaadake seda õpetust: Kuidas vahetada veerge ja ridu Excelis.

Kuidas töötada mitme lahtri massiivi valemitega

Kui töötate Excelis mitme lahtri massiivi valemitega, järgige kindlasti neid reegleid, et saada õigeid tulemusi:

1. Valige lahtrite vahemik, mille tulemused soovite väljastada. enne sisestades valemi.
2. aadressile kustutada mitme lahtri massiivi valemit, valige kas kõik seda sisaldavad lahtrid ja vajutage DELETE , või valige kogu valem valemiribal, vajutage DELETE ja seejärel vajutage Ctrl + Shift + Enter .
3. Te ei saa muuta ega liigutada üksiku lahtri sisu massiivi valemis, samuti ei saa te lisada uusi lahtreid või kustutada olemasolevaid lahtreid mitme lahtri massiivi valemis. Kui te seda proovite teha, annab Microsoft Excel hoiatuse " Te ei saa muuta massiivi osa ".
4. aadressile Kahanemine massiivi valemit, st et seda vähematele lahtritele rakendada, peate kõigepealt olemasoleva valemi kustutama ja seejärel sisestama uue valemi.
5. aadressile laiendada massiivi valemit, st rakendada seda rohkematele lahtritele, valige kõik lahtrid, mis sisaldavad praegust valemit, pluss tühjad lahtrid, kuhu soovite seda lisada, vajutage F2, et lülituda redigeerimisrežiimi, kohandage valemi viited ja vajutage Ctrl + Shift + Enter, et seda uuendada.
6. Exceli tabelites ei saa kasutada mitme lahtri massiivi valemeid.
7. Te peaksite sisestama mitme lahtri massiivi valemi sellisesse lahtrite vahemikku, mis on sama suur kui valemi poolt tagastatud tulemuseks olev massiivi. Kui teie Exceli massiivi valem annab valitud vahemikust suurema massiivi, ei ilmu üleliigsed väärtused töölehel. Kui valemi poolt tagastatud massiivi on valitud vahemikust väiksem, ilmuvad #N/A vead ekstra lahtritesse.

Kui teie valem võib tagastada muutuva arvu elementidega massiivi, sisestage see vahemikku, mis on võrdne või suurem kui valemiga tagastatav maksimaalne massiiviosa, ja ümbritsege oma valem IFERROR funktsiooniga, nagu on näidatud selles näites.

Exceli massiivi konstandid

Microsoft Excelis on massiivkonstant lihtsalt staatiliste väärtuste kogum. Need väärtused ei muutu kunagi, kui kopeerite valemi teistesse lahtritesse või väärtustesse.

Nägite juba selle õpetuse alguses näite, kuidas toidukaupade nimekirjast luuakse massiivi konstant. Nüüd vaatame, millised teised massiivi tüübid on olemas ja kuidas neid luua.

On olemas 3 tüüpi massiivi konstandid:

1. Horisontaalne massiivi konstant

Horisontaalne massiivi konstant asub reas. Rida massiivi konstandi loomiseks kirjuta väärtused komadega eraldatuna ja pane need sulgudesse, näiteks {1,2,3,4}.

Märkus. Massiivikonstanda loomisel tuleb avavad ja sulgevad sulgurid käsitsi sisestada.

Horisontaalse massiivi sisestamiseks arvutustabeli, valige vastav arv tühje lahtreid reas, sisestage valemit ={1,2,3,4} valemiribal ja vajutage Ctrl + Shift + Enter . Tulemus on sarnane sellele:

Nagu näete ekraanipildil, mähib Excel massiivi konstandi teise hulga sulgude sisse, täpselt nii, nagu ta teeb seda massiivi valemi sisestamisel.

2. Vertikaalne massiivi konstant

Vertikaalne massiivi konstant asub veerus. Selle loote samamoodi nagu horisontaalse massiivi, ainsa erinevusega, et piirate elemendid näiteks semikooloniga:

={11; 22; 33; 44}

3. Kahemõõtmeline massiivi konstant

Kahemõõtmelise massiivi loomiseks eraldate iga rea semikooloniga ja iga andmeveerg komaga.

={"a", "b", "c"; 1, 2, 3}

Töötamine Exceli massiivi konstandidega

Massiivikonstandid on üks Exceli massiivi valemite nurgakividest. Järgnev teave ja näpunäited võivad aidata teil neid kõige tõhusamalt kasutada.

1. Massiivkonstandi elemendid

   Massiivkonstant võib sisaldada numbreid, tekstiväärtusi, boolesid (TRUE ja FALSE) ja veaväärtusi, mis on eraldatud komadega või semikooloniga.

   Numbrilise väärtuse saate sisestada täisarvuna, kümnendmärgina või teaduslikus märkimisviisis. Kui kasutate tekstiväärtusi, tuleb need ümbritseda topeltlauselausetega (") nagu mis tahes Exceli valemis.

   Massiivikonstant ei saa sisaldada teisi massiive, lahtriviiteid, vahemikke, kuupäevi, määratletud nimesid, valemeid või funktsioone.

2. Massiivkonstandide nimetamine

   Et massiivi konstanti oleks lihtsam kasutada, andke sellele nimi:

   • Lülita ümber Valemite vahekaart> Määratletud nimed rühma ja klõpsake Määrake nimi Teise võimalusena vajutage Ctrl + F3 ja klõpsake nuppu Uus .
   • Sisestage nimi lahtrisse Nimi
   • In the Viitab lahtrisse sisestage oma massiivi konstandi elemendid, mis on ümbritsetud sulgudes eelneva võrdsusmärgiga (=). Näiteks:

     ={"Su", "Mo", "Tu", "We", "Th", "Fr", "Sa"}

     

   • Vajutage OK, et salvestada oma nimega massiivi ja sulgeda aken.

   Nimelise massiivi konstandi sisestamiseks lehel valige reas või veerus nii palju lahtreid, kui on teie massiivi elemente, sisestage valemiribale massiivi nimi, millele eelneb =-märk, ja vajutage Ctrl + Shift + Enter .

   Tulemus peaks sarnanema sellele:

   

3. Vigade vältimine

   Kui teie massiivi konstant ei tööta õigesti, kontrollige, kas esineb järgmisi probleeme:

   • Eraldage oma massiivikonstandi elemendid õigete tähtedega - horisontaalsete massiivikonstantide puhul koma ja vertikaalsete puhul semikoolon.
   • Valige lahtrite vahemik, mis vastab täpselt teie massiivikonstandi elementide arvule. Kui valite rohkem lahtreid, siis on iga lisarakk #N/A viga. Kui valite vähem lahtreid, siis sisestatakse ainult osa massiivist.

Massiivkonstandide kasutamine Exceli valemites

Nüüd, kui te olete tuttav massiivi konstandide mõistega, vaatame, kuidas te saate kasutada massiividega informaatilisi valemeid oma praktiliste ülesannete lahendamiseks.

Näide 1. Summa N suurim / väikseim arv vahemikus

Alustuseks loote vertikaalse massiivi konstandi, mis sisaldab nii palju numbreid, kui soovite summeerida. Näiteks kui soovite summeerida 3 väikseimat või suurimat arvu vahemikus, on massiivi konstant {1,2,3}.

Seejärel võtad kas LARGE või SMALL funktsiooni, määrad esimeses parameetris kogu rakkude vahemiku ja lisad teises parameetris massiivi konstandi. Lõpuks põimid selle funktsiooni SUM funktsiooni, näiteks nii:

Summeerige 3 suurimat arvu: =SUM(LARGE(range, {1,2,3}))

Summeerige 3 väikseimat arvu: =SUM(SMALL(range, {1,2,3}))

Ärge unustage vajutada Ctrl + Shift + Enter, kuna sisestate massiivi valemit, ja saate järgmise tulemuse:

Samamoodi saab arvutada vahemiku N väikseima või suurima väärtuse keskmist:

3 parima numbri keskmine: =AVERAGE(LARGE(range, {1,2,3}))

3 alumise numbri keskmine: =AVERAGE(SMALL(range, {1,2,3}))

Näide 2. Massiivvalem mitme tingimusega lahtrite loendamiseks

Oletame, et teil on tellimuste nimekiri ja te soovite teada, mitu korda on konkreetne müüja müünud teatud tooteid.

Lihtsaim viis oleks kasutada mitme tingimusega valemit COUNTIFS. Kui aga soovite kaasata palju tooteid, võib teie valem COUNTIFS muutuda liiga suureks. Kompaktsemaks muutmiseks võite kasutada COUNTIFS-i koos SUM-iga ja lisada ühes või mitmes argumendis näiteks massiivi konstandi:

=SUM(COUNTIFS(vahemik1, "kriteerium1", vahemik2, {"kriteerium1", "kriteerium2"}))

Tegelik valem võib välja näha järgmiselt:

=SUM(COUNTIFS(B2:B9, "sally", C2:C9, {"õunad", "sidrunid"}))

Meie näidismassiiv koosneb ainult kahest elemendist, sest eesmärk on näidata lähenemisviisi. Oma tõelistes massiivi valemites võite lisada nii palju elemente, kui teie äriloogika nõuab, tingimusel, et valemi kogupikkus ei ületa 8192 tähemärki Excel 2019 - 2007 (1024 tähemärki Excel 2003 ja madalamad) ja teie arvuti on piisavalt võimas suurte massiivide töötlemiseks.vt lähemalt massiivi valemite piirangud.

Ja siin on täiustatud massiivi valemi näide, mis leiab kõigi tabelis olevate sobivate väärtuste summa: SUM ja VLOOKUP koos massiivi konstandiga.

AND- ja OR-operaatorid Exceli massiivi valemites

Massiivioperaator ütleb valemile, kuidas soovite massiivide töötlemist teostada - kasutades AND- või OR-logikat.

• AND-operaator on tärn (*), mis on korrutamise sümbol. See annab Excelile korralduse tagastada TRUE, kui KÕIK tingimused annavad tulemuseks TRUE.
• OR-operaator on plussmärk (+). See tagastab TRUE, kui KÕIK antud väljendi tingimustest annab tulemuseks TRUE.

Array valem AND operaatoriga

Selles näites leiame müügi summa, kus müüja on Mike JA toode on Õunad :

=SUM((A2:A9="Mike") * (B2:B9="Õunad") * (C2:C9))

Või

=SUM(IF(((A2:A9="Mike") * (B2:B9="Õunad")), (C2:C9)))

Tehniliselt korrutab see valem kolme massiivi elemente samadel positsioonidel. Kaks esimest massiivi on esindatud väärtustega TRUE ja FALSE, mis on A2:A9 võrdlemise tulemused "Mike" ja B2:B9 "Apples". Kolmas massiivi sisaldab müüginumbreid vahemikust C2:C9. Nagu iga matemaatiline operatsioon, teisendab korrutamine TRUE ja FALSE vastavalt 1 ja 0. Ja kunakorrutamine 0-ga annab alati nulli, tulemuseks on 0, kui üks või mõlemad tingimused ei ole täidetud. Kui mõlemad tingimused on täidetud, satub vastav element kolmandast massiivist lõppmassiivi (nt 1*1*C2 = 10). Seega on korrutamise tulemus selline massiivi: {10;0;0;0;30;0;0;0;0;0;0}. Lõpuks liidab funktsioon SUM massiivi elemendid kokku ja tagastab tulemuseks 40.

Exceli massiivi valem OR-operaatoriga

Järgmine massiivi valem OR-operaatoriga (+) liidab kokku kõik müügitehingud, kus müüja on Mike OR toode on Õunad:

=SUM(IF(((A2:A9="Mike") + (B2:B9="Õunad")), (C2:C9)))

Selles valemis liidetakse kahe esimese massiivi elemendid kokku (mis on tingimused, mida tahetakse testida) ja saad TRUE (>0), kui vähemalt üks tingimus annab tulemuseks TRUE; FALSE (0), kui kõik tingimused annavad tulemuseks FALSE. Seejärel kontrollib IF, kas liitmise tulemus on suurem kui 0, ja kui see on nii, siis liidab SUM kokku kolmanda massiivi (C2:C9) vastava elemendi.

Vihje. Exceli tänapäevastes versioonides ei ole vaja sellisteks ülesanneteks kasutada massiivi valemit - lihtne valem SUMIFS saab nendega suurepäraselt hakkama. Sellest hoolimata võivad AND ja OR operaatorid massiivi valemites osutuda kasulikuks keerulisemates stsenaariumides, rääkimata väga heast mõttetööst : )

Topelt-unaarne operaator Exceli massiivi valemites

Kui olete kunagi Excelis töötanud massiivi valemitega, siis on tõenäoline, et olete kohanud mõnda valemit, mis sisaldab topeltkriipsu (--), ja olete võib-olla mõelnud, milleks seda kasutatakse.

Topeltkriips, mida tehniliselt nimetatakse kahekordne unaarne operaator, kasutatakse mitte-numbriliste boolaarsete väärtuste (TRUE / FALSE) teisendamiseks mõnede väljendite poolt tagastatud väärtusteks 1 ja 0, millest massiivi funktsioon saab aru.

Järgmine näide teeb loodetavasti asja arusaadavamaks. Oletame, et teil on veerus A kuupäevade nimekiri ja te tahate teada, mitu kuupäeva toimub jaanuaris, sõltumata aastast.

Järgmine valem töötab suurepäraselt:

=SUM(--(MONTH(A2:A10)=1))

Kuna tegemist on Exceli massiivi valemiga, ärge unustage selle täitmiseks vajutada Ctrl + Shift + Enter.

Kui olete huvitatud mõnest muust kuust, asendage 1 vastava numbriga. 2 tähistab näiteks veebruari, 3 tähendab märtsi jne. Et valem oleks paindlikum, võite määrata kuu numbri mõnes lahtris, nagu on näidatud ekraanipildil:

Ja nüüd analüüsime, kuidas see massiivi valem töötab. Funktsioon MONTH tagastab iga lahtrites A2 kuni A10 oleva kuupäeva kuu, mida esindab järjekorranumber, mis toodab massiivi {2;1;4;2;12;1;2;12;1}.

Pärast seda võrreldakse iga massiivi elementi lahtris D1 oleva väärtusega, mis antud näites on number 1. Selle võrdluse tulemuseks on massiiv Boole'i väärtustest TRUE ja FALSE. Nagu mäletate, saate valida teatud osa massiivi valemist ja vajutada F9, et näha, millega see osa võrdub:

Lõpuks tuleb need Boole'i väärtused teisendada 1 ja 0 väärtusteks, millest funktsioon SUMMA saab aru. Ja selleks ongi vaja topelt unaarne operaatorit. Esimene unaarne teisendab väärtused TRUE/FALSE vastavalt -1/0. Teine unaarne eitab väärtused, s.t. muudab märgi vastupidiseks, muutes need +1 ja 0, millest enamik Exceli funktsioone saab aru ja millega saab töötada. Kui eemaldada topelt unaarne operaatorigaülaltoodud valemist, siis see ei tööta.

Ma loodan, et see lühike õpetus on osutunud kasulikuks teie teel Exceli massiivi valemite omandamiseks. Järgmisel nädalal jätkame Exceli massiividega, keskendudes edasijõudnud valemite näidetele. Palun jääge kursis ja tänan teid lugemise eest!