Dans ce tutoriel, vous apprendrez ce qu'est une formule de tableau Excel, comment la saisir correctement dans vos feuilles de calcul, et comment utiliser les constantes et les fonctions de tableau.

Les formules de tableau dans Excel sont un outil extrêmement puissant et l'un des plus difficiles à maîtriser. Une seule formule de tableau peut effectuer de multiples calculs et remplacer des milliers de formules habituelles. Et pourtant, 90 % des utilisateurs n'ont jamais utilisé de fonctions de tableau dans leurs feuilles de calcul, simplement parce qu'ils ont peur de commencer à les apprendre.

En effet, les formules de tableau sont l'une des fonctions d'Excel les plus difficiles à apprendre. L'objectif de ce tutoriel est de rendre la courbe d'apprentissage aussi facile et fluide que possible.

Qu'est-ce qu'un tableau dans Excel ?

Avant d'aborder les fonctions et formules de tableau, il convient de définir la signification du terme "tableau". Un tableau est essentiellement une collection d'éléments, qu'il s'agisse de texte ou de chiffres, et qui peuvent se trouver sur une seule ligne ou colonne, ou sur plusieurs lignes et colonnes.

Par exemple, si vous mettez votre liste de courses hebdomadaire dans un format de tableau Excel, elle ressemblera à ceci :

{"Lait", "Oeufs", "Beurre", "Corn flakes"}

Ensuite, si vous sélectionnez les cellules A1 à D1, saisissez le tableau ci-dessus précédé du signe égal (=) dans la barre de formule et appuyez sur CTRL + SHIFT + ENTER , vous obtiendrez le résultat suivant :

Ce que vous venez de faire, c'est de créer un tableau horizontal unidimensionnel. Rien d'épouvantable jusqu'ici, n'est-ce pas ?

Qu'est-ce qu'une formule de tableau dans Excel ?

En d'autres termes, une formule de tableau dans Excel évalue toutes les valeurs individuelles d'un tableau et effectue plusieurs calculs sur un ou plusieurs éléments en fonction des conditions exprimées dans la formule.

Non seulement une formule de tableau peut traiter plusieurs valeurs simultanément, mais elle peut également renvoyer plusieurs valeurs à la fois. Ainsi, les résultats renvoyés par une formule de tableau sont également un tableau.

Les formules de tableau sont disponibles dans toutes les versions d'Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 et inférieures.

Et maintenant, il semble que ce soit le bon moment pour vous de créer votre première formule de tableau.

Exemple simple de formule de tableau Excel

Supposons que vous ayez des articles dans la colonne B, leurs prix dans la colonne C, et que vous vouliez calculer le total général de toutes les ventes.

Bien sûr, rien ne vous empêche de calculer d'abord les sous-totaux de chaque ligne avec quelque chose d'aussi simple que =B2*C2 et ensuite additionner ces valeurs :

Cependant, une formule de tableau peut vous épargner ces frappes supplémentaires puisqu'elle permet à Excel de stocker les résultats intermédiaires en mémoire plutôt que dans une colonne supplémentaire. Il suffit donc d'une seule formule de tableau et de deux étapes rapides :

1. Sélectionnez une cellule vide et saisissez-y la formule suivante :

   =SOMME(B2:B6*C2:C6)

   Voir également: Comment supprimer un message électronique bloqué dans la boîte d'envoi d'Outlook ou le renvoyer ?
2. Appuyez sur le raccourci clavier CTRL + SHIFT + ENTER pour compléter la formule du tableau.

   Une fois que vous avez fait cela, Microsoft Excel entoure la formule de {accolades}, ce qui est une indication visuelle d'une formule de tableau.

   Cette formule multiplie les valeurs de chaque ligne individuelle du tableau spécifié (cellules B2 à C6), additionne les sous-totaux et affiche le total général :

   

Ce simple exemple montre à quel point une formule de tableau peut être puissante. Lorsque vous travaillez avec des centaines et des milliers de lignes de données, pensez au temps que vous pouvez gagner en saisissant une formule de tableau dans une seule cellule.

Pourquoi utiliser des formules de tableau dans Excel ?

Les formules de tableau Excel sont l'outil le plus pratique pour effectuer des calculs sophistiqués et réaliser des tâches complexes. Une seule formule de tableau peut remplacer littéralement des centaines de formules habituelles. Les formules de tableau sont très utiles pour des tâches telles que.. :

• Additionner les nombres qui répondent à certaines conditions, par exemple additionner les N valeurs les plus grandes ou les plus petites d'une plage.
• Faites la somme d'une ligne sur deux, ou d'une ligne ou d'une colonne sur N, comme le montre cet exemple.
• Comptez le nombre de tous les caractères ou de certains caractères dans une plage spécifiée. Voici une formule de tableau qui compte tous les caractères, et une autre qui compte des caractères donnés.

Comment entrer une formule de tableau dans Excel (Ctrl + Shift + Enter)

Comme vous le savez déjà, la combinaison des 3 touches CTRL + SHIFT + ENTER est une touche magique qui transforme une formule ordinaire en formule de tableau.

Lorsque vous saisissez une formule de tableau dans Excel, il y a 4 choses importantes à garder à l'esprit :

1. Une fois que vous avez fini de taper la formule et que vous avez appuyé simultanément sur les touches CTRL SHIFT ENTER, Excel enferme automatiquement la formule entre des {accolades}. Lorsque vous sélectionnez une ou plusieurs cellules de ce type, vous pouvez voir les accolades dans la barre de formule, ce qui vous indique qu'une formule de tableau s'y trouve.
2. Si vous tapez manuellement les accolades autour d'une formule, cela ne fonctionnera pas. Vous devez appuyer sur le raccourci Ctrl+Shift+Enter pour compléter une formule de tableau.
3. Chaque fois que vous modifiez une formule de tableau, les accolades disparaissent et vous devez appuyer à nouveau sur Ctrl+Shift+Enter pour enregistrer les modifications.
4. Si vous oubliez d'appuyer sur Ctrl+Shift+Enter, votre formule se comportera comme une formule habituelle et ne traitera que la ou les premières valeurs du ou des tableaux spécifiés.

Comme toutes les formules de tableau Excel nécessitent d'appuyer sur Ctrl + Shift + Enter, elles sont parfois appelées Formules du CSE .

Utilisez la touche F9 pour évaluer des parties d'une formule de tableau.

Lorsque vous travaillez avec des formules de tableau dans Excel, vous pouvez observer comment elles calculent et stockent leurs éléments (tableaux internes) pour afficher le résultat final que vous voyez dans une cellule. Pour ce faire, sélectionnez un ou plusieurs arguments entre les parenthèses d'une fonction, puis appuyez sur la touche F9. Pour quitter le mode d'évaluation de la formule, appuyez sur la touche Echap.

Dans l'exemple ci-dessus, pour voir les sous-totaux de tous les produits, vous sélectionnez B2:B6*C2:C6, appuyez sur F9 et obtenez le résultat suivant.

Note : Veuillez noter que vous devez sélectionner une partie de la formule avant d'appuyer sur F9, sinon la touche F9 remplacera simplement votre formule par la ou les valeurs calculées.

Formules de tableaux à cellule unique et à cellules multiples dans Excel

Une formule de tableau Excel peut renvoyer un résultat dans une seule ou plusieurs cellules. Une formule de tableau entrée dans une plage de cellules est appelée un formule multi-cellules Une formule de tableau résidant dans une seule cellule est appelée une formule unicellulaire .

Il existe quelques fonctions de tableau Excel conçues pour renvoyer des tableaux à plusieurs cellules, par exemple TRANSPOSE, TREND, FREQUENCY, LINEST, etc.

D'autres fonctions, telles que SUM, AVERAGE, AGGREGATE, MAX, MIN, peuvent calculer des expressions de tableau lorsqu'elles sont saisies dans une seule cellule en utilisant Ctrl + Shift + Enter .

Les exemples suivants montrent comment utiliser une formule de tableau à cellule unique et à cellules multiples.

Exemple 1 : formule d'un tableau à cellule unique

Supposons que vous ayez deux colonnes indiquant le nombre d'articles vendus au cours de deux mois différents, disons les colonnes B et C, et que vous souhaitiez trouver l'augmentation maximale des ventes.

Normalement, vous ajouteriez une colonne supplémentaire, disons la colonne D, qui calcule la variation des ventes pour chaque produit à l'aide d'une formule telle que =C2-B2 et ensuite trouver la valeur maximale dans cette colonne supplémentaire =MAX(D:D) .

Une formule de type tableau n'a pas besoin de colonne supplémentaire puisqu'elle stocke parfaitement les résultats intermédiaires en mémoire. Il suffit donc de saisir la formule suivante et d'appuyer sur Ctrl + Shift + Enter :

=MAX(C2:C6-B2:B6)

Exemple 2 : Une formule de tableau à plusieurs cellules dans Excel

Dans l'exemple précédent SUM, supposons que vous deviez payer une taxe de 10 % sur chaque vente et que vous vouliez calculer le montant de la taxe pour chaque produit avec une seule formule.

Sélectionnez la plage de cellules vides, disons D2:D6, et saisissez la formule suivante dans la barre de formule :

=B2:B6 * C2:C6 * 0,1

Une fois que vous aurez appuyé sur Ctrl + Shift + Enter , Excel placera une instance de votre formule de tableau dans chaque cellule de la plage sélectionnée, et vous obtiendrez le résultat suivant :

Exemple 3 : Utilisation d'une fonction de tableau Excel pour renvoyer un tableau à plusieurs cellules

Comme nous l'avons déjà mentionné, Microsoft Excel fournit quelques fonctions dites "de tableau" qui sont spécialement conçues pour travailler avec des tableaux à cellules multiples. TRANSPOSE est l'une de ces fonctions et nous allons l'utiliser pour transposer le tableau ci-dessus, c'est-à-dire convertir les lignes en colonnes.

1. Sélectionnez une plage vide de cellules dans laquelle vous souhaitez générer le tableau transposé. Étant donné que nous convertissons des lignes en colonnes, veillez à sélectionner le même nombre de lignes et de colonnes que votre tableau source. Dans cet exemple, nous sélectionnons 6 colonnes et 4 lignes.
2. Appuyez sur F2 pour entrer dans le mode d'édition.
3. Entrez la formule et appuyez sur Ctrl + Shift + Enter .

Dans notre exemple, la formule est la suivante :

=TRANSPOSE($A$1:$D$6)

Le résultat va ressembler à ceci :

C'est ainsi que vous utilisez TRANSPOSE comme formule de tableau CSE dans Excel 2019 et antérieur. Dans Excel Dynamic Array, cela fonctionne également comme une formule ordinaire. Pour apprendre d'autres façons de transposer dans Excel, veuillez consulter ce tutoriel : Comment permuter les colonnes et les lignes dans Excel.

Comment travailler avec des formules de tableaux à cellules multiples

Lorsque vous travaillez avec des formules de tableaux à plusieurs cellules dans Excel, veillez à respecter les règles suivantes pour obtenir des résultats corrects :

1. Sélectionnez la plage de cellules dans laquelle vous souhaitez afficher les résultats. avant en entrant la formule.
2. A supprimer une formule de tableau à plusieurs cellules, sélectionnez toutes les cellules qui la contiennent et appuyez sur SUPPRIMER , ou sélectionnez la formule entière dans la barre de formule, appuyez sur SUPPRIMER , puis appuyez sur Ctrl + Shift + Enter .
3. Vous ne pouvez pas modifier ou déplacer le contenu d'une cellule individuelle dans une formule de tableau, ni insérer de nouvelles cellules dans une formule de tableau à plusieurs cellules, ni supprimer des cellules existantes dans une formule de tableau à plusieurs cellules. Vous ne pouvez pas modifier une partie d'un tableau ".
4. A rétrécir une formule de tableau, c'est-à-dire pour l'appliquer à un nombre réduit de cellules, vous devez d'abord supprimer la formule existante, puis en saisir une nouvelle.
5. A étendre une formule de tableau, c'est-à-dire l'appliquer à un plus grand nombre de cellules, sélectionnez toutes les cellules contenant la formule actuelle ainsi que les cellules vides où vous souhaitez l'appliquer, appuyez sur F2 pour passer en mode édition, ajustez les références dans la formule et appuyez sur Ctrl + Shift + Enter pour la mettre à jour.
6. Vous ne pouvez pas utiliser les formules de tableaux à cellules multiples dans les tableaux Excel.
7. Vous devez saisir une formule de tableau à plusieurs cellules dans une plage de cellules de la même taille que le tableau retourné par la formule. Si votre formule de tableau Excel produit un tableau plus grand que la plage sélectionnée, les valeurs excédentaires n'apparaîtront pas sur la feuille de calcul. Si le tableau retourné par la formule est plus petit que la plage sélectionnée, des erreurs #N/A apparaîtront dans les cellules supplémentaires.

Si votre formule peut renvoyer un tableau comportant un nombre variable d'éléments, saisissez-le dans une plage égale ou supérieure au tableau maximal renvoyé par la formule et enveloppez votre formule dans la fonction IFERROR, comme le montre cet exemple.

Constantes des tableaux Excel

Dans Microsoft Excel, une constante de tableau est simplement un ensemble de valeurs statiques. Ces valeurs ne changent jamais lorsque vous copiez une formule vers d'autres cellules ou valeurs.

Vous avez déjà vu un exemple de tableau constant créé à partir d'une liste de courses au tout début de ce tutoriel. Voyons maintenant quels autres types de tableaux existent et comment les créer.

Il existe 3 types de constantes de tableau :

1. constante du réseau horizontal

Pour créer une constante de tableau de ligne, saisissez les valeurs séparées par des virgules et mettez-les entre accolades, par exemple {1,2,3,4}.

Remarque : lorsque vous créez une constante de tableau, vous devez saisir manuellement les accolades ouvrantes et fermantes.

Pour saisir un tableau horizontal dans une feuille de calcul, sélectionnez le nombre correspondant de cellules vides dans une ligne, tapez la formule suivante ={1,2,3,4} dans la barre de formule, et appuyez sur Ctrl + Shift + Enter . Le résultat sera similaire à celui-ci :

Comme vous le voyez dans la capture d'écran, Excel enferme une constante de tableau dans un autre ensemble d'accolades, exactement comme il le fait lorsque vous saisissez une formule de tableau.

2. constante du réseau vertical

Une constante de tableau vertical réside dans une colonne. Vous la créez de la même manière qu'un tableau horizontal, à la seule différence que vous délimitez les éléments par des points-virgules, par exemple :

={11 ; 22 ; 33 ; 44}

3. constante du réseau bidimensionnel

Pour créer un tableau à deux dimensions, vous séparez chaque ligne par un point-virgule et chaque colonne de données par une virgule.

={"a", "b", "c" ; 1, 2, 3}

Travailler avec les constantes des tableaux Excel

Les constantes de tableau sont l'une des pierres angulaires d'une formule de tableau Excel. Les informations et conseils suivants peuvent vous aider à les utiliser de la manière la plus efficace possible.

1. Éléments d'une constante de tableau

   Une constante de tableau peut contenir des nombres, des valeurs textuelles, des booléens (VRAI et FAUX) et des valeurs d'erreur, séparés par des virgules ou des points-virgules.

   Vous pouvez saisir une valeur numérique sous la forme d'un nombre entier, décimal ou en notation scientifique. Si vous utilisez des valeurs de texte, elles doivent être entourées de guillemets (") comme dans toute formule Excel.

   Une constante de tableau ne peut pas inclure d'autres tableaux, références de cellules, plages, dates, noms définis, formules ou fonctions.

2. Nommer les constantes des tableaux

   Pour faciliter l'utilisation d'une constante de tableau, donnez-lui un nom :

   • Passez à la Onglet Formules> ; Noms définis et cliquez sur Définir le nom Vous pouvez également appuyer sur Ctrl + F3 et cliquer sur le lien suivant Nouveau .
   • Tapez le nom dans le champ Nom
   • Dans le Fait référence à saisissez les éléments de votre constante de tableau, entourés entre accolades et précédés du signe d'égalité (=). Par exemple :

     ={"Su", "Mo", "Tu", "We", "Th", "Fr", "Sa"}

     

   • Cliquez sur OK pour enregistrer votre tableau nommé et fermer la fenêtre.

   Pour entrer la constante du tableau nommé dans une feuille, sélectionnez autant de cellules dans une ligne ou une colonne qu'il y a d'éléments dans votre tableau, tapez le nom du tableau dans la barre de formule précédé du signe = et appuyez sur Ctrl + Shift + Enter .

   Le résultat devrait ressembler à ceci :

   

3. Prévention des erreurs

   Si la constante de votre tableau ne fonctionne pas correctement, vérifiez les problèmes suivants :

   • Délimitez les éléments de votre constante de tableau avec le caractère approprié - virgule dans les constantes de tableau horizontales et point-virgule dans les constantes de tableau verticales.
   • Sélectionnez une plage de cellules qui correspond exactement au nombre d'éléments de votre constante de tableau. Si vous sélectionnez plus de cellules, chaque cellule supplémentaire présentera l'erreur #N/A. Si vous sélectionnez moins de cellules, seule une partie du tableau sera insérée.

Utilisation de constantes de tableau dans les formules Excel

Maintenant que vous êtes familiarisé avec le concept des constantes de tableau, voyons comment vous pouvez utiliser les informulas de tableau pour résoudre vos tâches pratiques.

Exemple 1 : Somme des N plus grands / plus petits nombres d'une plage.

Vous commencez par créer une constante de tableau verticale contenant autant de nombres que vous voulez additionner. Par exemple, si vous voulez additionner 3 nombres plus petits ou plus grands dans une plage, la constante de tableau est {1,2,3}.

Ensuite, vous prenez la fonction LARGE ou SMALL, vous spécifiez une plage entière de cellules dans le premier paramètre et vous incluez la constante du tableau dans le second. Enfin, vous l'intégrez dans la fonction SUM, comme ceci :

Additionnez les 3 plus grands nombres : =SUM(LARGE(gamme, {1,2,3}))

Additionnez les 3 plus petits nombres : =SUM(SMALL(plage, {1,2,3}))

N'oubliez pas d'appuyer sur Ctrl + Shift + Enter puisque vous saisissez une formule de tableau, et vous obtiendrez le résultat suivant :

De la même manière, vous pouvez calculer la moyenne des N plus petites ou plus grandes valeurs d'une plage :

Moyenne des 3 premiers chiffres : =AVERAGE(LARGE(range, {1,2,3}))

Moyenne des 3 derniers chiffres : =AVERAGE(SMALL(range, {1,2,3}))

Exemple 2 : Formule de tableau pour compter les cellules avec plusieurs conditions

Supposons que vous ayez une liste de commandes et que vous vouliez savoir combien de fois un vendeur donné a vendu des produits donnés.

La méthode la plus simple consiste à utiliser une formule COUNTIFS avec plusieurs conditions. Cependant, si vous souhaitez inclure de nombreux produits, votre formule COUNTIFS risque de devenir trop volumineuse. Pour la rendre plus compacte, vous pouvez utiliser COUNTIFS avec SUM et inclure une constante de tableau dans un ou plusieurs arguments, par exemple :

=SUM(COUNTIFS(range1, "criteria1", range2, {"criteria1", "criteria2"}))

La formule réelle peut se présenter comme suit :

=SUM(COUNTIFS(B2:B9, "sally", C2:C9, {"apples", "lemons"}))

Dans vos formules de tableau réelles, vous pouvez inclure autant d'éléments que votre logique d'entreprise l'exige, à condition que la longueur totale de la formule ne dépasse pas 8 192 caractères dans Excel 2019 - 2007 (1 024 caractères dans Excel 2003 et inférieur) et que votre ordinateur soit suffisamment puissant pour traiter des tableaux de grande taille.voir les limites des formules de tableau pour plus de détails.

Et voici un exemple de formule de tableau avancée qui trouve la somme de toutes les valeurs correspondantes dans un tableau : SUM et VLOOKUP avec une constante de tableau.

Opérateurs AND et OR dans les formules de tableau Excel

Un opérateur de tableau indique à la formule comment vous voulez traiter les tableaux - en utilisant la logique ET ou OU.

• L'opérateur ET est l'astérisque (*), qui est le symbole de la multiplication. Il indique à Excel de retourner VRAI si TOUTES les conditions sont évaluées comme étant VRAIES.
• L'opérateur OR est le signe plus (+). Il renvoie VRAI si TOUTES les conditions d'une expression donnée sont évaluées à VRAI.

Formule de tableau avec l'opérateur AND

Dans cet exemple, nous trouvons la somme des ventes où le vendeur est Mike ET le produit est Pommes :

=SUM((A2:A9="Mike") * (B2:B9="Pommes") * (C2:C9))

Ou

=SUM(IF(((A2:A9="Mike") * (B2:B9="Pommes")), (C2:C9))))

Techniquement, cette formule multiplie les éléments des trois tableaux dans les mêmes positions. Les deux premiers tableaux sont représentés par les valeurs VRAI et FAUX qui sont les résultats de la comparaison de A2:A9 à Mike" et B2:B9 à "Apples". Le troisième tableau contient les numéros de vente de la plage C2:C9. Comme toute opération mathématique, la multiplication convertit VRAI et FAUX en 1 et 0, respectivement. Et parce queLa multiplication par 0 donne toujours zéro, le tableau résultant a 0 si l'une ou l'autre ou les deux conditions ne sont pas remplies. Si les deux conditions sont remplies, l'élément correspondant du troisième tableau entre dans le tableau final (par exemple, 1*1*C2 = 10). Ainsi, le résultat de la multiplication est ce tableau : {10;0;0;30;0;0;0;0}. Enfin, la fonction SUM additionne les éléments du tableau et renvoie un résultat de 40.

Formule de tableau Excel avec l'opérateur OR

La formule de tableau suivante avec l'opérateur OR (+) additionne toutes les ventes où le vendeur est Mike OU le produit est Des pommes :

=SUM(IF(((A2:A9="Mike") + (B2:B9="Pommes")), (C2:C9))))

Dans cette formule, vous additionnez les éléments des deux premiers tableaux (qui sont les conditions que vous voulez tester), et obtenez VRAI (>0) si au moins une condition est évaluée à VRAI ; FAUX (0) lorsque toutes les conditions sont évaluées à FAUX. Ensuite, IF vérifie si le résultat de l'addition est supérieur à 0, et si c'est le cas, SUM additionne un élément correspondant du troisième tableau (C2:C9).

Conseil : dans les versions modernes d'Excel, il n'est pas nécessaire d'utiliser une formule de tableau pour ce type de tâches - une simple formule SUMIFS les gère parfaitement. Néanmoins, les opérateurs AND et OR dans les formules de tableau peuvent s'avérer utiles dans des scénarios plus complexes, sans parler d'une très bonne gymnastique de l'esprit : ).

Double opérateur unaire dans les formules de tableau Excel

Si vous avez déjà travaillé avec des formules de tableau dans Excel, il est probable que vous en ayez rencontré quelques-unes contenant un double tiret (--) et que vous vous soyez demandé à quoi il servait.

Un double tiret, qui s'appelle techniquement le opérateur unaire double, est utilisé pour convertir les valeurs booléennes non numériques (VRAI / FAUX) retournées par certaines expressions en 1 et 0 qu'une fonction tableau peut comprendre.

Supposons que vous ayez une liste de dates dans la colonne A et que vous vouliez savoir combien de dates ont lieu en janvier, quelle que soit l'année.

La formule suivante fonctionnera à merveille :

=SUM(--(MONTH(A2:A10)=1))

Comme il s'agit d'une formule de tableau Excel, n'oubliez pas d'appuyer sur Ctrl + Shift + Enter pour la compléter.

Si vous êtes intéressé par un autre mois, remplacez 1 par le numéro correspondant. Par exemple, 2 signifie février, 3 signifie mars, et ainsi de suite. Pour rendre la formule plus flexible, vous pouvez spécifier le numéro du mois dans une cellule, comme illustré dans la capture d'écran :

La fonction MONTH renvoie le mois de chaque date dans les cellules A2 à A10 représenté par un numéro de série, ce qui produit le tableau {2;1;4;2;12;1;2;12;1}.

Ensuite, chaque élément du tableau est comparé à la valeur de la cellule D1, qui est le numéro 1 dans cet exemple. Le résultat de cette comparaison est un tableau de valeurs booléennes VRAI et FAUX. Comme vous vous en souvenez, vous pouvez sélectionner une certaine partie d'une formule de tableau et appuyer sur F9 pour voir à quoi correspond cette partie :

Enfin, vous devez convertir ces valeurs booléennes en 1 et 0 que la fonction SOMME peut comprendre. Et c'est pour cela que l'opérateur double unaire est nécessaire. Le premier unaire convertit VRAI/FAUX en -1/0, respectivement. Le second unaire nie les valeurs, c'est-à-dire inverse le signe, les transformant en +1 et 0, que la plupart des fonctions Excel peuvent comprendre et utiliser. Si vous supprimez le double unairede la formule ci-dessus, cela ne fonctionnera pas.

J'espère que ce court tutoriel vous a aidé à maîtriser les formules des tableaux Excel. La semaine prochaine, nous poursuivrons notre étude des tableaux Excel en nous concentrant sur des exemples de formules avancées. Restez à l'écoute et merci de votre lecture !