Opplæringen forklarer syntaksen og grunnleggende bruk av VELG-funksjonen og gir noen få ikke-trivielle eksempler som viser hvordan du bruker en VELG-formel i Excel.

VELG er en av disse Excel-funksjoner som kanskje ikke ser nyttige ut alene, men kombinert med andre funksjoner gir en rekke fantastiske fordeler. På det mest grunnleggende nivået bruker du VELG-funksjonen for å få en verdi fra en liste ved å spesifisere posisjonen til den verdien. Videre i denne opplæringen finner du flere avanserte bruksområder som absolutt er verdt å utforske.

Excel VELG-funksjon - syntaks og grunnleggende bruk

VELG-funksjonen i Excel er designet for å returnere en verdi fra listen basert på en spesifisert posisjon.

Funksjonen er tilgjengelig i Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 og Excel 2007.

Syntaksen til VELG-funksjonen er som følger:

Hvor:

Index_num (obligatorisk) - posisjonen til verdien som skal returneres. Det kan være et hvilket som helst tall mellom 1 og 254, en cellereferanse eller en annen formel.

Verdi1, verdi2, … - en liste med opptil 254 verdier å velge mellom. Verdi1 er obligatorisk, andre verdier er valgfrie. Disse kan være tall, tekstverdier, cellereferanser, formler eller definerte navn.

Her er et eksempel på en VELG-formel i den enkleste formen:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

Formelen returnerer "Amy" fordi index_num er 3 og "Amy" er den tredje verdien i listen:

Excel CHOOSE-funksjonen - 3 ting å huske!

CHOOSE er en veldig enkel funksjon, og du vil neppe støte på noen problemer med å implementere den i regnearkene dine. Hvis resultatet returnert av CHOOSE-formelen din er uventet eller ikke resultatet du lette etter, kan det være på grunn av følgende årsaker:

1. Antallet verdier å velge mellom er begrenset til 254.
2. Hvis indeksnummer er mindre enn 1 eller større enn antall verdier i listen, vil #VERDI! feil returneres.
3. Hvis argumentet indeksnummer er en brøk, avkortes det til det laveste heltall.

Hvordan bruke VELG-funksjonen i Excel - formel eksempler

De følgende eksemplene viser hvordan CHOOSE kan utvide mulighetene til andre Excel-funksjoner og gi alternative løsninger til noen vanlige oppgaver, også til de som anses som ugjennomførbare av mange.

Excel CHOOSE i stedet for nestede IF-er

En av de hyppigste oppgavene i Excel er å returnere forskjellige verdier basert på en spesifisert tilstand. I de fleste tilfeller kan dette gjøres ved å bruke en klassisk nestet IF-setning. Men VELG-funksjonen kan være et raskt og lettfattelig alternativ.

Eksempel 1. Returner forskjellige verdier basert på betingelse

Forutsatt at du har en kolonne med elevpoeng og du vil merke poengsummene basert påfølgende forhold:

En måte å gjøre dette på er å legge noen IF-formler inne i hverandre:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

En annen måte er å velge en etikett som tilsvarer tilstanden:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

Slik fungerer denne formelen:

I argumentet index_num evaluerer du hver betingelse og returnerer TRUE hvis betingelsen er oppfylt, ellers FALSE. For eksempel oppfyller verdien i celle B2 de tre første betingelsene, så vi får dette mellomresultatet:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

Gi at i de fleste Excel-formler tilsvarer TRUE 1 og FALSE til 0, er vår formelen gjennomgår denne transformasjonen:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

Etter at addisjonsoperasjonen er utført, har vi:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

Som resultat er den tredje verdien i liste returneres, som er "Bra".

Tips:

• For å gjøre formelen mer fleksibel kan du bruke cellereferanser i stedet for hardkodede etiketter, for eksempel:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

• Hvis ingen av betingelsene dine er SANN, vil indeksnummer -argumentet settes til 0, noe som tvinger formelen til å returnere #VERDI! feil. For å unngå dette, pakk ganske enkelt CHOOSE inn i IFERROR-funksjonen slik:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

Eksempel 2. Utfør forskjellige beregninger basert på tilstand

På lignende måte, dukan bruke Excel COOSE-funksjonen til å utføre én beregning i en serie med mulige beregninger/formler uten å legge flere IF-setninger inne i hverandre.

Som et eksempel, la oss beregne provisjonen til hver selger avhengig av salget deres:

Med salgsbeløpet i B2 har formelen følgende form:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

I stedet for å hardkode prosentene i formelen, du kan referere til den tilsvarende cellen i referansetabellen din, hvis det er noen. Bare husk å fikse referansene ved å bruke $-tegnet.

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

Excel VELG formel for å generere tilfeldige data

Som du sikkert vet, har Microsoft Excel en spesiell funksjon for å generere tilfeldige heltall mellom bunn- og topptallene du spesifiserer - RANDBETWEEN-funksjonen. Nest den i index_num -argumentet til VELG, og formelen din vil generere nesten alle tilfeldige data du ønsker.

For eksempel kan denne formelen produsere en liste over tilfeldige eksamensresultater:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

Formelens logikk er åpenbar: RANDBETWEEN genererer tilfeldige tall fra 1 til 4 og VELG returnerer en tilsvarende verdi fra den forhåndsdefinerte listen med fire verdier.

Merk. RANDBETWEEN er en flyktig funksjon og den beregner på nytt med hverendring du gjør i regnearket. Som et resultat vil listen over tilfeldige verdier også endres. For å forhindre at dette skjer, kan du erstatte formler med deres verdier ved å bruke funksjonen Lim inn spesial .

VELG formel for å gjøre en venstre Vlookup

Hvis du noen gang har utført et vertikalt oppslag i Excel, vet du at VLOOKUP-funksjonen bare kan søke i kolonnen lengst til venstre. I situasjoner når du trenger å returnere en verdi til venstre for oppslagskolonnen, kan du enten bruke INDEX / MATCH-kombinasjonen eller lure VLOOKUP ved å legge VELG-funksjonen inn i den. Slik gjør du det:

Forutsatt at du har en liste over poengsum i kolonne A, elevnavn i kolonne B, og du ønsker å hente poengsummen til en bestemt elev. Siden returkolonnen er til venstre for oppslagskolonnen, returnerer en vanlig Vlookup-formel #N/A-feilen:

For å fikse dette, få CHOOSE-funksjonen til å bytte posisjonene til kolonner, og forteller Excel at kolonne 1 er B og kolonne 2 er A:

=CHOOSE({1,2}, B2:B5, A2:A5)

Fordi vi leverer en matrise med {1,2} i indeksnummer argument, aksepterer CHOOSE-funksjonen områder i verdi -argumentene (normalt gjør den ikke det).

Nå, bygg inn formelen ovenfor i tabellmatrise -argumentet til VLOOKUP:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

Og voilà - et oppslag til venstre utføres uten problemer!

VELG formel for å returnere neste arbeid dag

Hvis du ikke er sikker på omdu bør gå på jobb i morgen eller kan bli hjemme og nyte den velfortjente helgen, Excel VELG-funksjonen kan finne ut når neste arbeidsdag er.

Forutsatt at arbeidsdagene dine er mandag til fredag, er formelen går som følger:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Virkelig ved første øyekast, ved en nærmere titt er formelens logikk lett å følge:

WEEKDAY (TODAY()) returnerer et serienummer som tilsvarer dagens dato, fra 1 (søndag) til 7 (lørdag). Dette tallet går til indeksnummer -argumentet i VELG-formelen vår.

Verdi1 - verdi7 (1,1,1,1,1, 3,2) bestemme hvor mange dager som skal legges til gjeldende dato. Hvis i dag er søndag - torsdag (indeks_nummer 1 - 5), legger du til 1 for å returnere neste dag. Hvis i dag er fredag ​​(indeks_nummer 6), legger du til 3 for å returnere neste mandag. Hvis i dag er lørdag (indeks_nummer 7), legger du til 2 for å returnere neste mandag igjen. Jepp, så enkelt er det :)

VELG formel for å returnere et egendefinert dag/månedsnavn fra dato

I situasjoner når du ønsker å få et dagsnavn i standardformatet som fullt navn ( mandag, tirsdag, osv.) eller kort navn (man, tir, osv.), kan du bruke TEKST-funksjonen som forklart i dette eksempelet: Hent ukedag fra dato i Excel.

Hvis du ønsker å returner en ukedag eller et månedsnavn i et tilpasset format, bruk VELG-funksjonen på følgende måte.

For å få en ukedag:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

For å få enmåned:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Hvor A2 er cellen som inneholder den opprinnelige datoen.

Jeg håper denne veiledningen har gitt deg noen ideer om hvordan du kan bruke VELG-funksjonen i Excel for å forbedre datamodellene dine. Jeg takker for at du leser og håper å se deg på bloggen vår neste uke!

Last ned øvelsesarbeidsbok

Excel VELG funksjonseksempler