Tutorial menunjukkan cara menggunakan IFERROR dalam Excel untuk menangkap ralat dan menggantikannya dengan sel kosong, nilai lain atau mesej tersuai. Anda akan belajar cara menggunakan fungsi IFERROR dengan Vlookup dan Padanan Indeks, dan bagaimana ia dibandingkan dengan IF ISERROR dan IFNA.

"Beri saya tempat untuk berdiri, dan saya akan menggerakkan bumi," Archimedes pernah berkata. "Beri saya formula, dan saya akan mengembalikannya sebagai ralat," kata pengguna Excel. Dalam tutorial ini, kami tidak akan melihat cara untuk mengembalikan ralat dalam Excel, kami lebih suka mempelajari cara menghalangnya untuk memastikan lembaran kerja anda bersih dan formula anda telus.

Fungsi IFERROR Excel - sintaks dan kegunaan asas

Fungsi IFERROR dalam Excel direka untuk memerangkap dan mengurus ralat dalam formula dan pengiraan. Lebih khusus lagi, IFERROR menyemak formula, dan jika ia menilai kepada ralat, mengembalikan nilai lain yang anda tentukan; jika tidak, mengembalikan hasil formula.

Sintaks fungsi Excel IFERROR adalah seperti berikut:

Di mana:

• Nilai (diperlukan) - perkara yang perlu diperiksa untuk ralat. Ia boleh menjadi formula, ungkapan, nilai atau rujukan sel.
• Value_if_error (diperlukan) - perkara yang perlu dikembalikan jika ralat ditemui. Ia boleh menjadi rentetan kosong (sel kosong), mesej teks, nilai berangka, formula atau pengiraan lain.

Sebagai contoh, apabila membahagi dua lajur nombor, andamungkin mendapat sekumpulan ralat yang berbeza jika salah satu lajur mengandungi sel kosong, sifar atau teks.

Untuk mengelakkan perkara itu daripada berlaku, gunakan fungsi IFERROR untuk menangkap dan mengendalikan ralat mengikut cara yang anda mahukan.

Jika ralat, kosongkan

Bekalkan rentetan kosong (") kepada argumen value_if_error untuk mengembalikan sel kosong jika ralat ditemui:

=IFERROR(A2/B2, "")

Jika ralat, tunjukkan mesej

Anda juga boleh memaparkan mesej anda sendiri dan bukannya notasi ralat standard Excel:

=IFERROR(A2/B2, "Error in calculation")

5 perkara yang perlu anda ketahui tentang fungsi Excel IFERROR

1. Fungsi IFERROR dalam Excel mengendalikan semua jenis ralat termasuk # DIV/0!, #N/A, #NAME?, #NULL!, #NUM!, #REF!, dan #VALUE!.
2. Bergantung pada kandungan value_if_error argumen, IFERROR boleh menggantikan ralat dengan mesej teks tersuai anda, nombor, tarikh atau nilai logik, hasil formula lain atau rentetan kosong (sel kosong).
3. Jika argumen nilai adalah sel kosong, ia dianggap sebagai rentetan kosong (''') tetapi bukan ralat.
4. IFERROR telah diperkenalkan dalam Excel 2007 dan tersedia dalam semua versi Excel 2010, Excel 2013, Excel 2016, Excel 2019, Excel 2021 dan Excel berikutnya 365.
5. Untuk memerangkap ralat dalam Excel 2003 dan versi terdahulu, gunakan fungsi ISERROR dalam kombinasi dengan IF, seperti yang ditunjukkan dalam contoh ini.

Contoh formula IFERROR

Contoh berikuttunjukkan cara menggunakan IFERROR dalam Excel dalam kombinasi dengan fungsi lain untuk mencapai tugas yang lebih kompleks.

Excel IFERROR dengan Vlookup

Salah satu kegunaan paling biasa bagi fungsi IFERROR ialah memberitahu pengguna bahawa nilai yang mereka cari tidak wujud dalam set data. Untuk ini, anda membalut formula VLOOKUP dalam IFERROR seperti ini:

Jika nilai carian tiada dalam jadual yang anda cari , formula Vlookup biasa akan mengembalikan ralat #N/A:

Untuk pemikiran pengguna anda, bungkus VLOOKUP dalam IFERROR dan paparkan yang lebih bermaklumat dan mesra pengguna mesej:

=IFERROR(VLOOKUP(A2, 'Lookup table'!$A$2:$B$4, 2,FALSE), "Not found")

Tangkapan skrin di bawah menunjukkan formula Iferror ini dalam Excel:

Jika anda ingin memerangkap hanya #N /A ralat tetapi bukan semua ralat, gunakan fungsi IFNA dan bukannya IFERROR.

Untuk lebih banyak contoh formula Excel IFERROR VLOOKUP, sila lihat tutorial ini:

• Iferror dengan Vlookup untuk memerangkap dan mengendalikan ralat
• Cara mendapatkan kejadian Nth nilai carian
• Cara mendapatkan semua kejadian nilai carian

Fungsi IFERROR Bersarang untuk melakukan Vlookup berurutan dalam Excel

Dalam situasi apabila anda perlu melakukan berbilang Vlookup berdasarkan sama ada Vlookup sebelumnya berjaya atau gagal, anda boleh menyusun dua atau lebih IFERROR berfungsi antara satu sama lain.

Andaikan anda mempunyai beberapa laporan jualan daripada cawangan serantau andasyarikat, dan anda ingin mendapatkan amaun untuk ID pesanan tertentu. Dengan A2 sebagai nilai carian dalam helaian semasa dan A2:B5 sebagai julat carian dalam 3 helaian carian (Laporan 1, Laporan 2 dan Laporan 3), formulanya adalah seperti berikut:

=IFERROR(VLOOKUP(A2,'Report 1'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 2'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 3'!A2:B5,2,0),"not found")))

Hasilnya akan kelihatan seperti ini:

Untuk penjelasan terperinci tentang logik formula, sila lihat Cara melakukan Vlookup berjujukan dalam Excel.

IFERROR dalam formula tatasusunan

Seperti yang mungkin anda ketahui, formula tatasusunan dalam Excel bertujuan untuk melaksanakan berbilang pengiraan dalam satu formula. Jika anda membekalkan formula tatasusunan atau ungkapan yang menghasilkan tatasusunan dalam argumen nilai bagi fungsi IFERROR, ia akan mengembalikan tatasusunan nilai untuk setiap sel dalam julat yang ditentukan. Contoh di bawah menunjukkan butiran.

Katakan, anda mempunyai Jumlah dalam lajur B dan Harga dalam lajur C dan anda ingin mengira Jumlah Kuantiti . Ini boleh dilakukan dengan menggunakan formula tatasusunan berikut, yang membahagikan setiap sel dalam julat B2:B4 dengan sel yang sepadan bagi julat C2:C4, dan kemudian menambah hasil:

=SUM($B$2:$B$4/$C$2:$C$4)

Formula berfungsi dengan baik selagi julat pembahagi tidak mempunyai sifar atau sel kosong. Jika terdapat sekurang-kurangnya satu nilai 0 atau sel kosong, #DIV/0! ralat dikembalikan:

Untuk membetulkan ralat itu, cuma lakukan pembahagian dalam fungsi IFERROR:

=SUM(IFERROR($B$2:$B$4/$C$2:$C$4,0))

Apa yang dilakukan oleh formulaadalah untuk membahagikan nilai dalam lajur B dengan nilai dalam lajur C dalam setiap baris (100/2, 200/5 dan 0/0) dan mengembalikan tatasusunan hasil {50; 40; #DIV/0!}. Fungsi IFERROR menangkap semua #DIV/0! ralat dan menggantikannya dengan sifar. Dan kemudian, fungsi SUM menambah nilai dalam tatasusunan yang terhasil {50; 40; 0} dan mengeluarkan hasil akhir (50+40=90).

Nota. Sila ingat bahawa formula tatasusunan harus dilengkapkan dengan menekan pintasan Ctrl + Shift + Enter.

IFERROR lwn. IF ISERROR

Sekarang anda tahu betapa mudahnya menggunakan fungsi IFERROR dalam Excel, anda mungkin tertanya-tanya mengapa sesetengah orang masih cenderung menggunakan gabungan IF ISERROR. Adakah ia mempunyai kelebihan berbanding IFERROR? tiada. Pada zaman dahulu Excel 2003 dan lebih rendah apabila IFERROR tidak wujud, JIKA ISERROR adalah satu-satunya cara yang mungkin untuk memerangkap ralat. Dalam Excel 2007 dan kemudian, ia hanyalah cara yang lebih kompleks untuk mencapai hasil yang sama.

Sebagai contoh, untuk menangkap ralat Vlookup, anda boleh menggunakan salah satu daripada formula di bawah.

Dalam Excel 2007 - Excel 2016:

Dalam semua versi Excel:

Perhatikan bahawa dalam formula IF ISERROR VLOOKUP, anda perlu Vlookup dua kali. Dalam bahasa Inggeris biasa, formula boleh dibaca seperti berikut: Jika Vlookup menghasilkan ralat, kembalikan "Tidak dijumpai", jika tidak, keluarkan hasil Vlookup.

Dan ini adalah real-contoh hayat formula Excel If Iserror Vlookup:

=IF(ISERROR(VLOOKUP(D2, A2:B5,2,FALSE)),"Not found", VLOOKUP(D2, A2:B5,2,FALSE ))

Untuk mendapatkan maklumat lanjut, sila lihat Menggunakan fungsi ISERROR dalam Excel.

IFERROR lwn. IFNA

Diperkenalkan dengan Excel 2013, IFNA ialah satu lagi fungsi untuk menyemak formula untuk ralat. Sintaksnya serupa dengan IFERROR:

Dalam cara apakah IFNA berbeza daripada IFERROR? Fungsi IFNA menangkap hanya ralat #N/A manakala IFERROR mengendalikan semua jenis ralat.

Dalam situasi yang manakah anda mungkin mahu menggunakan IFNA? Apabila tidak bijak untuk menyembunyikan semua kesilapan. Sebagai contoh, apabila bekerja dengan data penting atau sensitif, anda mungkin ingin dimaklumkan tentang kemungkinan kerosakan dalam set data anda dan mesej ralat Excel standard dengan simbol "#" boleh menjadi penunjuk visual yang jelas.

Mari kita lihat bagaimana anda boleh membuat formula yang memaparkan mesej "Tidak dijumpai" dan bukannya ralat N/A, yang muncul apabila nilai carian tidak terdapat dalam set data, tetapi membawa ralat Excel lain kepada perhatian anda.

Andaikata anda ingin menarik Qty. daripada jadual carian ke jadual ringkasan seperti yang ditunjukkan dalam tangkapan skrin di bawah. Menggunakan formula Excel Iferror Vlookup akan menghasilkan hasil yang menarik dari segi estetika, yang secara teknikalnya tidak betul kerana Lemon memang wujud dalam jadual carian:

Untuk menangkap # T/A tetapi paparkan ralat #DIV/0, gunakan fungsi IFNA dalam Excel 2013 dan Excel2016:

=IFNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE), "Not found")

Atau, gabungan IF ISNA dalam Excel 2010 dan versi terdahulu:

=IF(ISNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE)),"Not found", VLOOKUP(F3,$A$3:$D$6,4,FALSE))

Sintaks IFNA VLOOKUP dan IF ISNA Formula VLOOKUP adalah serupa dengan formula IFERROR VLOOKUP dan IF ISERROR VLOOKUP yang dibincangkan sebelum ini.

Seperti yang ditunjukkan dalam tangkapan skrin di bawah, formula Ifna Vlookup mengembalikan "Tidak dijumpai" hanya untuk item yang tidak terdapat dalam jadual carian ( Peach ). Untuk Lemon , ia menunjukkan #DIV/0! menunjukkan bahawa jadual carian kami mengandungi ralat bahagi dengan sifar:

Untuk butiran lanjut, sila lihat Menggunakan fungsi IFNA dalam Excel.

Amalan terbaik untuk menggunakan IFERROR dalam Excel

Sekarang anda sudah tahu bahawa fungsi IFERROR ialah cara paling mudah untuk menangkap ralat dalam Excel dan menutupnya dengan sel kosong, nilai sifar atau mesej tersuai anda sendiri. Walau bagaimanapun, itu tidak bermakna anda harus membalut setiap formula dengan pengendalian ralat. Pengesyoran mudah berikut boleh membantu anda mengekalkan keseimbangan.

1. Jangan memerangkap ralat tanpa sebab.
2. Balut bahagian terkecil formula dalam IFERROR.
3. Untuk mengendalikan ralat khusus sahaja, gunakan fungsi pengendalian ralat dengan skop yang lebih kecil:
   • IFNA atau IF ISNA untuk menangkap ralat #N/A sahaja.
   • ISERR untuk menangkap semua ralat kecuali untuk #N/A.

Beginilah cara anda menggunakan fungsi IFERROR dalam Excel untuk memerangkap dan mengendalikan ralat. Untuk melihat dengan lebih dekat formula yang dibincangkan dalam initutorial, anda dialu-alukan untuk memuat turun contoh buku kerja IFERROR Excel kami. Saya berterima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan.