Udžbenik pokazuje kako izbrojati ćelije s određenim tekstom u programu Excel. Pronaći ćete primjere formula za točno podudaranje, djelomično podudaranje i filtrirane ćelije.

Prošli tjedan smo pogledali kako brojati ćelije s tekstom u Excelu, što znači sve ćelije s bilo kojim tekstom. Kada analizirate velike dijelove informacija, možda ćete također željeti znati koliko ćelija sadrži određeni tekst. Ovaj vodič objašnjava kako to učiniti na jednostavan način.

Kako brojati ćelije s određenim tekstom u Excelu

Microsoft Excel ima posebnu funkciju za uvjetno brojanje ćelija, funkcija COUNTIF. Sve što trebate učiniti je navesti ciljni tekstualni niz u argumentu kriterija .

Evo generičke Excel formule za brojanje ćelija koje sadrže određeni tekst:

Sljedeći primjer pokazuje to na djelu. Pretpostavimo da imate popis ID-ova stavki u A2:A10 i želite prebrojati broj ćelija s određenim ID-om, recimo "AA-01". Upišite ovaj niz u drugi argument i dobit ćete ovu jednostavnu formulu:

=COUNTIF(A2:A10, "AA-01")

Da biste svojim korisnicima omogućili da broje ćelije s bilo kojim tekstom bez potrebe za izmjenom formule, unesite tekst u unaprijed definiranu ćeliju, recimo D1, i navedite referencu ćelije:

=COUNTIF(A2:A10, D1)

Napomena. Excelova funkcija COUNTIF ne razlikuje velika i mala slova , što znači da ne razlikuje velika i mala slova. Za obradu velikih i malih slovaznakova drugačije, koristite ovu formulu koja razlikuje velika i mala slova.

Kako brojati ćelije s određenim tekstom (djelomično podudaranje)

Formula o kojoj se raspravljalo u prethodnom primjeru točno odgovara kriterijima. Ako postoji barem jedan različit znak u ćeliji, na primjer dodatni razmak na kraju, to neće biti točno podudaranje i takva ćelija se neće računati.

Da biste pronašli broj ćelije koje sadrže određeni tekst kao dio svog sadržaja, koristite zamjenske znakove u svojim kriterijima, naime zvjezdicu (*) koja predstavlja bilo koji niz ili znakove. Ovisno o vašem cilju, formula može izgledati kao jedno od sljedećeg.

Broj ćelije koje sadrže određeni tekst na samo početku :

Broji ćelije koje sadrže određeni tekst na bilo kojoj poziciji :

Na primjer, da biste saznali koliko ćelija u rasponu A2:A10 počinje s "AA", upotrijebite ovu formulu:

=COUNTIF(A2:A10, "AA*")

Da biste dobili broj ćelija koje sadrže "AA" na bilo kojem položaju, upotrijebite ovo jedan:

=COUNTIF(A2:A10, "*AA*")

Da bi formule bile dinamičnije, zamijenite tvrdo kodirane nizove referencama ćelija.

Da biste brojali ćelije koje počinju određenim tekstom:

=COUNTIF(A2:A10, D1&"*")

Za prebrojavanje ćelija s određenim tekstom bilo gdje u njima:

=COUNTIF(A2:A10, "*"&D1&"*")

Snimak zaslona u nastavku prikazuje rezultate:

Brojite ćelije koje sadrže određeni tekst (razlikuje velika i mala slova)

U situaciji kada trebate razlikovativelika i mala slova, funkcija COUNTIF neće raditi. Ovisno o tome tražite li točno ili djelomično podudaranje, morat ćete izraditi drugu formulu.

Formula koja razlikuje velika i mala slova za brojanje ćelija s određenim tekstom (točno podudaranje)

Za brojanje broj ćelija s određenim tekstom koji prepoznaje veličinu teksta, koristit ćemo kombinaciju funkcija SUMPRODUCT i EXACT:

Kako funkcionira ova formula:

• EXACT uspoređuje svaku ćeliju u rasponu s uzorkom teksta i vraća niz TRUE i FALSE vrijednosti, TRUE predstavlja točna podudaranja, a FALSE sve ostale ćelije. Dvostruka crtica (koja se naziva double unary ) pretvara TRUE i FALSE u 1 i 0.
• SUMPRODUCT zbraja sve elemente niza. Taj zbroj je broj jedinica, što je broj podudaranja.

Na primjer, da dobijete broj ćelija u A2:A10 koje sadrže tekst u D1 i tretiraju velika i mala slova kao različite znakova, koristite ovu formulu:

=SUMPRODUCT(--EXACT(D1, A2:A10))

Formula koja razlikuje velika i mala slova za brojanje ćelija s određenim tekstom (djelomično podudaranje)

Za izgradnju formula koja razlikuje velika i mala slova koja može pronaći tekstualni niz od interesa bilo gdje u ćeliji, koristimo 3 različite funkcije:

Kako ova formula radi:

• Funkcija FIND koja razlikuje velika i mala slova pretražujeza ciljni tekst u svakoj ćeliji raspona. Ako uspije, funkcija vraća položaj prvog znaka, u protivnom #VALUE! greška. Radi jasnoće, ne moramo znati točan položaj, bilo koji broj (za razliku od pogreške) znači da ćelija sadrži ciljni tekst.
• Funkcija ISNUMBER obrađuje niz brojeva i vraćene pogreške pomoću FIND i pretvara brojeve u TRUE, a sve ostalo u FALSE. Dvostruki unarni (--) pretvara logičke vrijednosti u jedinice i nule.
• SUMPRODUCT zbraja niz 1 i 0 i vraća broj ćelija koje sadrže navedeni tekst kao dio svog sadržaja.

Da bismo testirali formulu na podacima iz stvarnog života, pronađimo koliko ćelija u A2:A10 sadrži unos podniza u D1:

=SUMPRODUCT(--(ISNUMBER(FIND(D1, A2:A10))))

A ovo vraća broj od 3 (ćelije A2, A3 i A6):

Kako brojati filtrirane ćelije s određenim tekstom

Za brojanje vidljivih stavki na filtriranom popisu morat ćete koristiti kombinaciju 4 ili više funkcija, ovisno o tome želite li točno ili djelomično podudaranje. Da bismo lakše pratili primjere, prvo brzo pogledajmo izvorne podatke.

Pretpostavimo da imate tablicu s ID-ovima narudžbi u stupcu B i Količina u stupcu C kao što je prikazano na slici ispod. Za sada vas zanimaju samo količine veće od 1 i prema tome ste filtrirali svoju tablicu. Thepitanje je – kako brojite filtrirane ćelije s određenim ID-om?

Formula za brojanje filtriranih ćelija s određenim tekstom (točno podudaranje)

Za brojanje filtriranih ćelije čiji sadržaj točno odgovara tekstualnom nizu uzorka, koristite jednu od sljedećih formula:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(B2:B10=F1))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(B2:B10=F1))

Gdje je F1 ogledni tekst, a B2:B10 ćelije za brojanje.

Kako ove formule funkcioniraju:

U srži obje formule izvodite 2 provjere:

1. Prepoznajte vidljive i skrivene retke. Za to koristite funkciju SUBTOTAL s argumentom function_num postavljenim na 103. Da biste dostavili sve pojedinačne reference ćelija u SUBTOTAL, upotrijebite INDIRECT (u prvoj formuli) ili kombinaciju OFFSET, ROW i MIN (u drugoj formuli). Budući da nam je cilj locirati vidljive i skrivene retke, zapravo nije važno koji stupac referencirati (A u našem primjeru). Rezultat ove operacije je niz 1 i 0 gdje jedinice predstavljaju vidljive retke, a nule - skrivene retke.
2. Pronađi ćelije koje sadrže dati tekst. U tu svrhu usporedite uzorak teksta (F1) s rasponom ćelija (B2:B10). Rezultat ove operacije je niz vrijednosti TRUE i FALSE, koje su prisiljene na 1 i 0 uz pomoć dvostrukog unarnog operatora.

Konačno, funkcija SUMPRODUCT množi elemente dvaju nizove na istim pozicijama, a zatim zbraja rezultirajući niz.Budući da množenje s nulom daje nulu, samo ćelije koje imaju 1 u oba niza imaju 1 u konačnom nizu. Zbroj 1 je broj filtriranih ćelija koje sadrže određeni tekst.

Formula za brojanje filtriranih ćelija s određenim tekstom (djelomično podudaranje)

Za brojanje filtriranih ćelija koje sadrže određeni tekst kao dio sadržaj ćelije, modificirajte gornje formule na sljedeći način. Umjesto usporedbe uzorka teksta s rasponom ćelija, tražite ciljni tekst pomoću ISNUMBER i FIND kao što je objašnjeno u jednom od prethodnih primjera:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISNUMBER(FIND(F1, B2:B10))))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(ISNUMBER(FIND(F1, B2:B10))))

Kao rezultat toga, formule će locirati dati tekstualni niz na bilo kojem mjestu u ćeliji:

Napomena. Funkcija SUBTOTAL sa 103 u argumentu function_num identificira sve skrivene ćelije, filtrirane i skrivene ručno. Kao rezultat toga, gornje formule broje samo vidljive ćelije bez obzira na to kako su nevidljive ćelije bile skrivene. Da biste isključili samo filtrirane ćelije, ali uključili one koje su ručno skrivene, koristite 3 za function_num .

Tako možete izbrojati ćelije s određenim tekstom u Excelu. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeći tjedan!

Dostupna preuzimanja

Excel formule za brojanje ćelija s određenim tekstom