Упатството покажува како да се брои бројот на ќелии со одреден текст во Excel. Ќе најдете примери на формула за точно совпаѓање, делумно совпаѓање и филтрирани ќелии.

Минатата недела разгледавме како да ги броиме ќелиите со текст во Excel, што значи сите ќелии со кој било текст. Кога анализирате големи делови од информации, можеби ќе сакате да знаете и колку ќелии содржат специфичен текст. Ова упатство објаснува како да го направите тоа на едноставен начин.

Како да броите ќелии со специфичен текст во Excel

Microsoft Excel има специјална функција за условно броење ќелии, функцијата COUNTIF. Сè што треба да направите е да ја внесете целната текстуална низа во аргументот критериуми .

Еве генеричка формула на Excel за броење на бројот на ќелии што содржат специфичен текст:

Следниот пример го покажува на дело. Да претпоставиме дека имате список со ID на ставки во A2:A10 и сакате да го броите бројот на ќелии со одреден идентификатор, да речете „AA-01“. Внесете ја оваа низа во вториот аргумент и ќе ја добиете оваа едноставна формула:

=COUNTIF(A2:A10, "AA-01")

За да им овозможите на вашите корисници да бројат ќелии со кој било даден текст без потреба да ја менувате формулата, внесете ја текст во однапред дефинирана ќелија, да речеме D1, и наведете ја референцата на ќелијата:

=COUNTIF(A2:A10, D1)

Забелешка. Функцијата Excel COUNTIF е неосетлива на букви , што значи дека не разликува големи букви. За лекување на големи и мали буквизнаците поинаку, користете ја оваа формула чувствителна на големи букви.

Како да се бројат ќелиите со одреден текст (делумно совпаѓање)

Формулата дискутирана во претходниот пример точно се совпаѓа со критериумите. Ако има барем еден различен знак во ќелијата, на пример дополнителен простор на крајот, тоа нема да биде точно совпаѓање и таквата ќелија нема да се брои.

За да го пронајдете бројот на ќелиите што содржат одреден текст како дел од нивната содржина, користете знаци со џокер во вашите критериуми, имено ѕвездичка (*) што претставува која било низа или знаци. Во зависност од вашата цел, формулата може да изгледа како една од следниве.

Бротајте ги ќелиите што содржат специфичен текст на на самиот почеток :

Бротајте ќелии што содржат одреден текст во која било позиција :

На пример, за да откриете колку ќелии во опсегот A2:A10 започнуваат со „AA“, користете ја оваа формула:

=COUNTIF(A2:A10, "AA*")

За да го добиете бројот на ќелии што содржат „AA“ во која било позиција, користете го ова еден:

=COUNTIF(A2:A10, "*AA*")

За да ги направите формулите подинамични, заменете ги тврдокодираните низи со референци на ќелиите.

За броење ќелии што почнуваат со одреден текст:

=COUNTIF(A2:A10, D1&"*")

За броење ќелии со одреден текст насекаде во нив:

=COUNTIF(A2:A10, "*"&D1&"*")

На сликата подолу се прикажани резултатите:

Бротајте ги ќелиите што содржат специфичен текст (чувствително на големи букви)

Во ситуација кога треба да разликуватеголеми и мали знаци, функцијата COUNTIF нема да работи. Во зависност од тоа дали барате точно или делумно совпаѓање, ќе треба да изградите друга формула.

Формула со осетливи букви за броење ќелии со специфичен текст (точно совпаѓање)

За броење бројот на ќелии со одреден текст што го препознаваат случајот на текстот, ќе користиме комбинација од функциите SUMPRODUCT и EXACT:

Како функционира оваа формула:

• EXACT ја споредува секоја ќелија во опсегот со примерокот на текстот и враќа низа од TRUE и FALSE вредности, TRUE претставува точно совпаѓање и FALSE сите други ќелии. Двојна цртичка (наречена двоен униарен ) ги принудува TRUE и FALSE во 1 и 0.
• SUMPRODUCT ги сумира сите елементи од низата. Тој збир е бројот на 1, што е бројот на совпаѓања.

На пример, за да се добие бројот на ќелии во A2:A10 што го содржат текстот во D1 и да се постапуваат со големи и мали букви како различни знаци, користете ја оваа формула:

=SUMPRODUCT(--EXACT(D1, A2:A10))

Формула чувствителна на букви за броење ќелии со специфичен текст (делумно совпаѓање)

За да се изгради формула чувствителна на големи букви што може да најде текстуална низа од интерес насекаде во ќелијата, користиме 3 различни функции:

Како функционира оваа формула:

• Функцијата FIND чувствителна на букви пребаруваза целниот текст во секоја ќелија од опсегот. Ако успее, функцијата ја враќа позицијата на првиот знак, инаку #VALUE! грешка. Заради јасност, не треба да ја знаеме точната позиција, кој било број (за разлика од грешката) значи дека ќелијата го содржи целниот текст.
• Функцијата ISNUMBER се справува со низата броеви и вратени грешки со FIND и ги конвертира броевите во ТОЧНО и сè друго во НЕТОЧНО. Двојниот унарен (--) ги принудува логичките вредности на едно и нули.
• SUMPRODUCT ја сумира низата од 1 и 0 и го враќа бројот на ќелии што го содржат наведениот текст како дел од нивната содржина.

За да ја тестираме формулата за реални податоци, ајде да откриеме колку ќелии во A2:A10 го содржат влезот на поднизата во D1:

=SUMPRODUCT(--(ISNUMBER(FIND(D1, A2:A10))))

И ова враќа броење од 3 (ќелии A2, A3 и A6):

Како да се бројат филтрирани ќелии со специфичен текст

Да се ​​бројат видливите ставки во филтриран список, ќе треба да користите комбинација од 4 или повеќе функции во зависност од тоа дали сакате точно или делумно совпаѓање. За да ги направиме примерите полесни за следење, прво да ги погледнеме изворните податоци.

Претпоставувајќи, имате табела со ИД на нарачки во колоната Б и Количина во колоната C како што е прикажано на сликата подолу. Засега ве интересираат само количини поголеми од 1 и соодветно ја филтриравте вашата табела. Напрашањето е – како ги броите филтрираните ќелии со одреден ID?

Формула за броење филтрирани ќелии со специфичен текст (точно совпаѓање)

За броење филтрирани ќелии чија содржина точно се совпаѓа со текстуалната низа на примерокот, користете една од следните формули:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(B2:B10=F1))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(B2:B10=F1))

Каде што F1 е примерок текст и B2:B10 се ќелиите да се брои.

Како функционираат овие формули:

Во суштината на двете формули, вршите 2 проверки:

1. Идентификувајте видливи и скриени редови. За ова, ја користите функцијата SUBTOTAL со аргументот function_num поставен на 103. За да ги наведете сите поединечни референци на ќелиите до SUBTOTAL, користете или INDIRECT (во првата формула) или комбинација од OFFSET, ROW и MIN (во втората формула). Бидејќи имаме за цел да лоцираме видливи и скриени редови, не е важно која колона да се повикува (А во нашиот пример). Резултатот од оваа операција е низа од 1 и 0 каде што едните претставуваат видливи редови и нули - скриени редови.
2. Најдете ќелии што содржат даден текст. За ова, споредете го примерокот на текстот (F1) со опсегот на ќелии (B2:B10). Резултатот од оваа операција е низа од TRUE и FALSE вредности, кои се принудени на 1 и 0 со помош на двојниот унарен оператор.

Конечно, функцијата SUMPRODUCT ги множи елементите на двете низи на истите позиции, а потоа ја сумира добиената низа.Бидејќи со множење со нула се добива нула, само ќелиите кои имаат 1 во двете низи имаат 1 во конечната низа. Збирот од 1 е бројот на филтрирани ќелии што го содржат наведениот текст.

Формула за броење филтрирани ќелии со специфичен текст (делумно совпаѓање)

За броење филтрирани ќелии што содржат одреден текст како дел од содржината на ќелијата, изменете ги горенаведените формули на следниот начин. Наместо да го споредувате примерокот на текстот со опсегот на ќелии, побарајте го целниот текст користејќи ISNUMBER и FIND како што е објаснето во еден од претходните примери:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISNUMBER(FIND(F1, B2:B10))))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(ISNUMBER(FIND(F1, B2:B10))))

Како резултат на тоа, формулите ќе лоцираат дадена текстуална низа во која било позиција во ќелијата:

Забелешка. Функцијата SUBTOTAL со 103 во аргументот function_num , ги идентификува сите скриени ќелии, филтрирани и сокриени рачно. Како резултат на тоа, горенаведените формули бројат само видливи ќелии без оглед на тоа како биле скриени невидливите ќелии. За да ги исклучите само филтрираните ќелии, но да ги вклучите оние што се скриени рачно, користете 3 за function_num .

Така се брои бројот на ќелии со одреден текст во Excel. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела!

Достапни преземања

Формули на Excel за броење ќелии со одреден текст