Водич показује како да пребројите број ћелија са одређеним текстом у Екцел-у. Наћи ћете примере формула за тачно подударање, делимично подударање и филтриране ћелије.

Прошле недеље смо погледали како да пребројимо ћелије са текстом у Екцел-у, што значи све ћелије са било којим текстом. Када анализирате велике комаде информација, можда ћете желети да знате колико ћелија садржи одређени текст. Овај водич објашњава како то да урадите на једноставан начин.

Како пребројати ћелије са одређеним текстом у Екцел-у

Мицрософт Екцел има посебну функцију за условно бројање ћелија, функција ЦОУНТИФ. Све што треба да урадите је да унесете циљни текстуални стринг у аргумент критеријум .

Ево генеричке Екцел формуле за пребројавање броја ћелија које садрже одређени текст:

Следећи пример то показује на делу. Претпоставимо да имате листу ИД-ова ставки у А2:А10 и желите да избројите број ћелија са одређеним ИД-ом, рецимо „АА-01“. Унесите овај стринг у други аргумент и добићете ову једноставну формулу:

=COUNTIF(A2:A10, "AA-01")

Да бисте омогућили својим корисницима да броје ћелије са било којим текстом без потребе за модификацијом формуле, унесите текст у унапред дефинисаној ћелији, рецимо Д1, и наведите референцу ћелије:

=COUNTIF(A2:A10, D1)

Напомена. Екцел функција ЦОУНТИФ је мала и велика слова , што значи да не разликује велика и мала слова. За третирање великих и малих словазнакове другачије, користите ову формулу која разликује велика и мала слова.

Како пребројати ћелије са одређеним текстом (делимично подударање)

Формула о којој се говори у претходном примеру тачно одговара критеријумима. Ако постоји бар један различит знак у ћелији, на пример додатни размак на крају, то неће бити потпуно подударање и таква ћелија се неће рачунати.

Да бисте пронашли број ћелије које садрже одређени текст као део свог садржаја, користите џокер знакове у вашим критеријумима, односно звездицу (*) која представља било коју секвенцу или знакове. У зависности од вашег циља, формула може изгледати као један од следећих.

Пребројите ћелије које садрже одређени текст на самом почетку :

Број ћелија које садрже одређени текст на било којој позицији :

На пример, да бисте пронашли колико ћелија у опсегу А2:А10 почиње са „АА“, користите ову формулу:

=COUNTIF(A2:A10, "AA*")

Да бисте добили број ћелија које садрже „АА“ на било којој позицији, користите ову један:

=COUNTIF(A2:A10, "*AA*")

Да бисте формуле учинили динамичнијим, замените чврсто кодиране стрингове референцама на ћелије.

Да бисте пребројали ћелије које почињу одређеним текстом:

=COUNTIF(A2:A10, D1&"*")

Да бисте пребројали ћелије са одређеним текстом било где у њима:

=COUNTIF(A2:A10, "*"&D1&"*")

Снимак екрана испод приказује резултате:

Број ћелија које садрже одређени текст (разликује велика и мала слова)

У ситуацији када треба да разликујетевелика и мала слова, функција ЦОУНТИФ неће радити. У зависности од тога да ли тражите тачно или делимично подударање, мораћете да направите другу формулу.

Формула осетљива на велика и мала слова за бројање ћелија са одређеним текстом (потпуно подударање)

За бројање број ћелија са одређеним текстом који препознаје велика и мала слова, користићемо комбинацију функција СУМПРОДУЦТ и ЕКСАЦТ:

Како ова формула функционише:

• ЕКСАЦТ упоређује сваку ћелију у опсегу са узорком текста и враћа низ вредности ТРУЕ и ФАЛСЕ, ТРУЕ представља тачна подударања, а ФАЛСЕ све остале ћелије. Двострука цртица (названа доубле унари ) наводи ТРУЕ и ФАЛСЕ у 1 и 0.
• СУМПРОДУЦТ сабира све елементе низа. Тај збир је број 1, што је број подударања.

На пример, да бисте добили број ћелија у А2:А10 које садрже текст у Д1 и руковале великим и малим словима као различитим знакова, користите ову формулу:

=SUMPRODUCT(--EXACT(D1, A2:A10))

Формула осетљива на велика и мала слова за бројање ћелија са одређеним текстом (делимично подударање)

Да бисте направили формула која разликује велика и мала слова која може да пронађе текстуални низ од интереса било где у ћелији, користимо 3 различите функције:

Како ова формула функционише:

• Фундација ФИНД осетљива на велика и мала слова претражујеза циљни текст у свакој ћелији опсега. Ако успе, функција враћа позицију првог знака, у супротном #ВРЕДНОСТ! грешка. Ради јасноће, не морамо да знамо тачну позицију, било који број (за разлику од грешке) значи да ћелија садржи циљни текст.
• Функција ИСНУМБЕР управља низом бројева и враћених грешака помоћу ФИНД и претвара бројеве у ТРУЕ, а све остало у ФАЛСЕ. Двоструки унар (--) приморава логичке вредности на јединице и нуле.
• СУМПРОДУЦТ сабира низ 1 и 0 и враћа број ћелија које садрже наведени текст као део свог садржаја.

Да бисмо тестирали формулу на подацима из стварног живота, хајде да пронађемо колико ћелија у А2:А10 садржи унос подстринга у Д1:

=SUMPRODUCT(--(ISNUMBER(FIND(D1, A2:A10))))

И ово враћа број од 3 (ћелије А2, А3 и А6):

Како пребројати филтриране ћелије са одређеним текстом

Да преброје видљиве ставке у филтрираној листи, мораћете да користите комбинацију од 4 или више функција у зависности од тога да ли желите тачно или делимично подударање. Да бисмо лакше пратили примере, хајде да прво брзо погледамо изворне податке.

Под претпоставком да имате табелу са ИД-овима поруџбине у колони Б и Количина у колони Ц као што је приказано на слици испод. За сада вас занимају само количине веће од 1 и у складу с тим сте филтрирали своју табелу. Тхепитање је – како рачунате филтриране ћелије са одређеним ИД-ом?

Формула за бројање филтрираних ћелија са одређеним текстом (потпуно подударање)

За бројање филтрираних ћелија ћелије чији се садржај тачно подудара са узорком текстуалног низа, користите једну од следећих формула:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(B2:B10=F1))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(B2:B10=F1))

Где је Ф1 пример текста, а Б2:Б10 ћелије за бројање.

Како функционишу ове формуле:

У основи обе формуле, вршите 2 провере:

1. Идентификујте видљиве и скривене редове. За ово користите функцију СУБТОТАЛ са аргументом фунцтион_нум постављеним на 103. Да бисте обезбедили све појединачне референце ћелије на СУБТОТАЛ, користите или ИНДИРЕКТНО (у првој формули) или комбинацију ОФФСЕТ, РОВ и МИН (у другој формули). Пошто нам је циљ да лоцирамо видљиве и скривене редове, није битно на коју колону ћемо референцирати (А у нашем примеру). Резултат ове операције је низ 1 и 0 где јединице представљају видљиве редове, а нуле - скривене редове.
2. Пронађи ћелије које садрже дати текст. За ово, упоредите узорак текста (Ф1) са опсегом ћелија (Б2:Б10). Резултат ове операције је низ ТРУЕ и ФАЛСЕ вредности, које су принуђене на 1 и 0 уз помоћ двоструког унарног оператора.

Коначно, функција СУМПРОДУЦТ множи елементе два низове на истим позицијама, а затим сабира резултујући низ.Пошто множење са нулом даје нулу, само ћелије које имају 1 у оба низа имају 1 у коначном низу. Збир 1 је број филтрираних ћелија које садрже наведени текст.

Формула за бројање филтрираних ћелија са одређеним текстом (делимично подударање)

За бројање филтрираних ћелија које садрже одређени текст као део садржај ћелије, измените горње формуле на следећи начин. Уместо да поредите текст примера са опсегом ћелија, потражите циљни текст користећи ИСНУМБЕР и ФИНД као што је објашњено у једном од претходних примера:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISNUMBER(FIND(F1, B2:B10))))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(ISNUMBER(FIND(F1, B2:B10))))

Као резултат, формуле ће лоцирати дати текстуални низ на било којој позицији у ћелији:

Напомена. Функција СУБТОТАЛ са 103 у аргументу фунцтион_нум идентификује све скривене ћелије, филтриране и скривене ручно. Као резултат тога, горње формуле броје само видљиве ћелије без обзира на то колико су невидљиве ћелије биле скривене. Да бисте искључили само филтриране ћелије, али укључили оне скривене ручно, користите 3 за број_функције .

Тако се рачуна број ћелија са одређеним текстом у Екцел-у. Захваљујем вам што сте читали и надам се да се видимо на нашем блогу следеће недеље!

Доступна преузимања

Екцел формуле за бројање ћелија са одређеним текстом