ट्युटोरियलले एक्सेलमा निश्चित पाठ भएका कक्षहरूको संख्या कसरी गणना गर्ने भनेर देखाउँछ। तपाईंले सटीक मिलान, आंशिक मिल्दो र फिल्टर गरिएका कक्षहरूका लागि सूत्र उदाहरणहरू फेला पार्नुहुनेछ।

गत हप्ता हामीले एक्सेलमा पाठका साथ कक्षहरू कसरी गणना गर्ने भनेर हेर्यौं, जसको अर्थ कुनै पनि पाठ भएका सबै कक्षहरू। जानकारीको ठूलो भागको विश्लेषण गर्दा, तपाइँ कति कक्षहरूमा विशिष्ट पाठ समावेश छ भनेर जान्न पनि सक्नुहुन्छ। यो ट्यूटोरियलले यसलाई सरल तरिकाले कसरी गर्ने भनेर बताउँछ।

एक्सेलमा विशिष्ट पाठ भएका कक्षहरू कसरी गणना गर्ने

माइक्रोसफ्ट एक्सेलसँग सशर्त रूपमा कक्षहरू गणना गर्न विशेष प्रकार्य छ, COUNTIF प्रकार्य। तपाईले गर्नु पर्ने भनेको लक्ष्य पाठ स्ट्रिङलाई मापदण्ड तर्कमा आपूर्ति गर्नु हो।

यहाँ विशिष्ट पाठ समावेश कक्षहरूको संख्या गणना गर्न सामान्य एक्सेल सूत्र छ:

निम्न उदाहरणले यसलाई कार्यमा देखाउँछ। मानौं, तपाईंसँग A2:A10 मा वस्तु आईडीहरूको सूची छ र तपाईं कुनै विशेष आईडीको साथ कक्षहरूको संख्या गणना गर्न चाहनुहुन्छ, भन्नुहोस् "AA-01"। दोस्रो आर्गुमेन्टमा यो स्ट्रिङ टाइप गर्नुहोस्, र तपाईंले यो सरल सूत्र पाउनुहुनेछ:

=COUNTIF(A2:A10, "AA-01")

तपाईँका प्रयोगकर्ताहरूलाई सूत्र परिमार्जन नगरी कुनै पनि पाठसँग कक्षहरू गणना गर्न सक्षम पार्न, इनपुट गर्नुहोस्। पूर्वनिर्धारित कक्षमा पाठ, D1 भन्नुहोस्, र सेल सन्दर्भ आपूर्ति गर्नुहोस्:

=COUNTIF(A2:A10, D1)

नोट। एक्सेल COUNTIF प्रकार्य केस-असंवेदनशील हो, यसको अर्थ यसले अक्षर केसलाई फरक पार्दैन। अपरकेस र लोअरकेस उपचार गर्नवर्णहरू फरक रूपमा, यो केस-संवेदनशील सूत्र प्रयोग गर्नुहोस्।

केही पाठ (आंशिक मिलान) संग कक्षहरू कसरी गणना गर्ने

अघिल्लो उदाहरणमा छलफल गरिएको सूत्रले मापदण्डसँग ठ्याक्कै मेल खान्छ। यदि सेलमा कम्तिमा एउटा फरक क्यारेक्टर छ भने, उदाहरणका लागि अन्त्यमा अतिरिक्त स्पेस, त्यो ठ्याक्कै मिल्ने छैन र त्यस्तो सेललाई गणना गरिने छैन।

को संख्या पत्ता लगाउन कक्षहरू जसले तिनीहरूको सामग्रीको अंशको रूपमा निश्चित पाठ समावेश गर्दछ, तपाईंको मापदण्डमा वाइल्डकार्ड क्यारेक्टरहरू प्रयोग गर्नुहोस्, कुनै पनि अनुक्रम वा वर्णहरू प्रतिनिधित्व गर्ने तारा चिन्ह (*)। तपाईंको लक्ष्यमा निर्भर गर्दै, सूत्र निम्न मध्ये एउटा जस्तो देखिन सक्छ।

सेलहरू गणना गर्नुहोस् जसमा विशिष्ट पाठ धेरै सुरुमा :

कुनै पनि स्थानमा निश्चित पाठ समावेश गर्ने कक्षहरू गणना गर्नुहोस् :

उदाहरणका लागि, दायरा A2:A10 मा कतिवटा कक्षहरू "AA" बाट सुरु हुन्छ पत्ता लगाउन, यो सूत्र प्रयोग गर्नुहोस्:

=COUNTIF(A2:A10, "AA*")

कुनै पनि स्थितिमा "AA" भएको कक्षहरूको गणना प्राप्त गर्न, यो प्रयोग गर्नुहोस्। एउटा:

=COUNTIF(A2:A10, "*AA*")

सूत्रहरूलाई थप गतिशील बनाउनको लागि, हार्डकोड गरिएका स्ट्रिङहरूलाई सेल सन्दर्भहरूसँग बदल्नुहोस्।

निश्चित पाठबाट सुरु हुने कक्षहरू गणना गर्न:

=COUNTIF(A2:A10, D1&"*")

कहीँ पनि निश्चित पाठ भएका कक्षहरू गणना गर्न:

=COUNTIF(A2:A10, "*"&D1&"*")

तलको स्क्रिनसटले परिणामहरू देखाउँछ:

विशिष्ट पाठ (केस-सेन्सिटिभ) समावेश गर्ने कक्षहरू गणना गर्नुहोस्

यदि तपाईंले फरक गर्न आवश्यक छअपरकेस र लोअरकेस क्यारेक्टरहरू, COUNTIF प्रकार्यले काम गर्दैन। तपाइँ एक सटीक वा आंशिक मिल्दो खोज्दै हुनुहुन्छ भन्नेमा निर्भर गर्दै, तपाइँले फरक सूत्र निर्माण गर्नुपर्नेछ।

केस-सेन्सेटिभ सूत्र विशिष्ट पाठ (सही मिल्दो) संग कक्षहरू गणना गर्न

गणना गर्न पाठ केस पहिचान गर्ने निश्चित पाठ भएका कक्षहरूको संख्या, हामी SUMPRODUCT र EXACT प्रकार्यहरूको संयोजन प्रयोग गर्नेछौं:

यस सूत्रले कसरी काम गर्छ:

• EXACT ले दायराको प्रत्येक कक्षलाई नमूना पाठसँग तुलना गर्छ र TRUE र FALSE मानहरूको एर्रे फर्काउँछ, TRUE ले ठ्याक्कै मिल्दोजुल्दो र FALSE अन्य सबै कक्षहरू प्रतिनिधित्व गर्दछ। डबल हाइफन ( डबल अनरी भनिन्छ) ले TRUE र FALSE लाई 1's र 0's मा जोड्छ।
• SUMPRODUCT ले एरेका सबै तत्वहरूलाई जोड्छ। त्यो योग 1 को संख्या हो, जुन मिल्ने संख्या हो।

उदाहरणका लागि, D1 मा पाठ समावेश गर्ने A2:A10 मा कक्षहरूको संख्या प्राप्त गर्न र अपरकेस र लोअरकेसलाई फरक रूपमा ह्यान्डल गर्न वर्णहरू, यो सूत्र प्रयोग गर्नुहोस्:

=SUMPRODUCT(--EXACT(D1, A2:A10))

केस-संवेदनशील सूत्र विशिष्ट पाठ (आंशिक मिलान) संग कक्षहरू गणना गर्न

निर्माण गर्न एउटा केस-संवेदनशील सूत्र जसले कक्षमा कहीं पनि रुचिको पाठ स्ट्रिङ फेला पार्न सक्छ, हामी 3 फरक प्रकार्यहरू प्रयोग गर्दैछौं:

यस सूत्रले कसरी काम गर्छ:

• केस-संवेदनशील FIND प्रकार्यले खोज्छदायराको प्रत्येक कक्षमा लक्षित पाठको लागि। यदि यो सफल भयो भने, प्रकार्यले पहिलो वर्णको स्थिति फर्काउँछ, अन्यथा #VALUE! त्रुटि। स्पष्टताको खातिर, हामीले सही स्थिति जान्न आवश्यक पर्दैन, कुनै पनि संख्या (त्रुटिको विपरीत) भनेको सेलले लक्षित पाठ समावेश गर्दछ।
• ISNUMBER प्रकार्यले संख्याहरूको एर्रे र फिर्ता गरिएका त्रुटिहरू ह्यान्डल गर्छ। FIND द्वारा र नम्बरहरूलाई TRUE र अरू कुनै कुरालाई FALSE मा रूपान्तरण गर्दछ। डबल युनरी (--) ले तार्किक मानहरूलाई एक र शून्यमा जोड दिन्छ।
• SUMPRODUCT ले 1's र 0's को array लाई जोड्छ र तिनीहरूको सामग्रीको अंशको रूपमा निर्दिष्ट पाठ समावेश गर्ने कक्षहरूको गणना फर्काउँछ।

वास्तविक-जीवन डाटामा सूत्र परीक्षण गर्न, A2:A10 मा D1:

=SUMPRODUCT(--(ISNUMBER(FIND(D1, A2:A10))))

मा कतिवटा कक्षहरू समावेश छन् पत्ता लगाउनुहोस् र यसले गणना फर्काउँछ 3 को (कोशिकाहरू A2, A3 र A6):

विशिष्ट पाठसँग फिल्टर गरिएका कक्षहरू कसरी गणना गर्ने

गणना गर्न दृश्य वस्तुहरू फिल्टर गरिएको सूचीमा, तपाईंले ठ्याक्कै वा आंशिक मिल्दो चाहनुहुन्छ भन्ने आधारमा 4 वा बढी प्रकार्यहरूको संयोजन प्रयोग गर्न आवश्यक छ। उदाहरणहरू पछ्याउन सजिलो बनाउनको लागि, पहिले स्रोत डेटामा द्रुत रूपमा हेरौं।

मान्दै, तपाईंसँग स्तम्भ B र मात्रा<2 मा अर्डर आईडी भएको तालिका छ।> तलको छविमा देखाइएको जस्तै स्तम्भ C मा। यस क्षणको लागि, तपाइँ 1 भन्दा बढी मात्रामा मात्र रुचि राख्नुहुन्छ र तपाइँले तदनुसार तपाइँको तालिका फिल्टर गर्नुभयो। दप्रश्न यो छ - तपाइँ एक विशेष आईडी संग फिल्टर गरिएका कक्षहरू कसरी गणना गर्नुहुन्छ?

विशिष्ट पाठसँग फिल्टर गरिएका कक्षहरू गणना गर्न सूत्र (सही मिल्दो)

फिल्टर गरिएको गणना गर्न कक्षहरू जसका सामग्रीहरू नमूना पाठ स्ट्रिङसँग ठ्याक्कै मेल खान्छ, निम्न मध्ये एउटा सूत्र प्रयोग गर्नुहोस्:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(B2:B10=F1))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(B2:B10=F1))

जहाँ F1 नमूना पाठ हो र B2:B10 कक्षहरू हुन्। गणना गर्न।

यी सूत्रहरूले कसरी काम गर्छ:

दुबै सूत्रहरूको मूलमा, तपाईंले २ जाँचहरू गर्नुहुन्छ:

1. देखिने र लुकेका पङ्क्तिहरू पहिचान गर्नुहोस्। यसका लागि, तपाईंले SUBTOTAL प्रकार्य प्रयोग गर्नुहोस् function_num तर्क 103 मा सेट गर्नुहोस्। SUBTOTAL मा सबै व्यक्तिगत सेल सन्दर्भहरू आपूर्ति गर्न, कि त INDIRECT (पहिलो सूत्रमा) वा OFFSET, ROW र MIN को संयोजन प्रयोग गर्नुहोस्। (दोस्रो सूत्रमा)। हामीले देखिने र लुकेका पङ्क्तिहरू पत्ता लगाउने लक्ष्य राखेकाले, कुन स्तम्भलाई सन्दर्भ गर्ने भन्ने कुराले कुनै फरक पर्दैन (हाम्रो उदाहरणमा A)। यस कार्यको परिणाम 1's र 0's को एर्रे हो जहाँ देखिने पङ्क्तिहरू र शून्यहरू - लुकेका पङ्क्तिहरू प्रतिनिधित्व गर्दछ।
2. दिईएको पाठ समावेश कक्षहरू फेला पार्नुहोस्। यसको लागि, सेलहरूको दायरा (B2:B10) विरुद्ध नमूना पाठ (F1) तुलना गर्नुहोस्। यस अपरेसनको नतिजा TRUE र FALSE मानहरूको एर्रे हो, जसलाई डबल युनरी अपरेटरको मद्दतले 1's र 0's मा जोडिन्छ।

अन्तमा, SUMPRODUCT प्रकार्यले दुई तत्वहरूलाई गुणन गर्छ। एरेहरूलाई एउटै स्थानहरूमा, र त्यसपछि नतिजा एरेको योग गर्दछ।किनकी शून्यले गुणन गर्दा शून्य हुन्छ, दुबै एरेमा १ भएको कक्षको अन्तिम एरेमा १ हुन्छ। 1 को योगफल निर्दिष्ट पाठ समावेश फिल्टर गरिएका कक्षहरूको संख्या हो।

विशिष्ट पाठ (आंशिक मिलान) संग फिल्टर गरिएका कक्षहरू गणना गर्न सूत्र

को अंशको रूपमा निश्चित पाठ समावेश फिल्टर गरिएका कक्षहरू गणना गर्न सेल सामग्रीहरू, माथिको सूत्रहरूलाई निम्न तरिकाले परिमार्जन गर्नुहोस्। सेलहरूको दायरासँग नमूना पाठ तुलना गर्नुको सट्टा, ISNUMBER र FIND प्रयोग गरेर लक्ष्य पाठ खोज्नुहोस् जुन अघिल्लो उदाहरणहरू मध्ये एउटामा व्याख्या गरिएको छ:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISNUMBER(FIND(F1, B2:B10))))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(ISNUMBER(FIND(F1, B2:B10))))

परिणामको रूपमा, सूत्रहरूले सेलमा कुनै पनि स्थानमा दिइएको पाठ स्ट्रिङ पत्ता लगाउनेछ:

नोट। function_num तर्कमा 103 सँग SUBTOTAL प्रकार्यले सबै लुकेका कक्षहरूलाई पहिचान गर्छ, फिल्टर आउट गरी म्यानुअल रूपमा लुकाइन्छ। नतिजाको रूपमा, माथिका सूत्रहरूले केवल दृश्य कक्षहरू गणना गर्दछन् जुन अदृश्य कक्षहरू लुकेका थिए। फिल्टर गरिएका कक्षहरू मात्र बहिष्कार गर्न तर म्यानुअल रूपमा लुकेकाहरूलाई समावेश गर्न, function_num को लागि 3 प्रयोग गर्नुहोस्।

यसरी एक्सेलमा निश्चित पाठ भएका कक्षहरूको संख्या गणना गर्ने। पढ्नुभएकोमा म तपाईंलाई धन्यवाद दिन्छु र अर्को हप्ता हाम्रो ब्लगमा भेट्ने आशा गर्छु!

उपलब्ध डाउनलोडहरू

निश्चित पाठसँग कक्षहरू गणना गर्न एक्सेल सूत्रहरू