Udhëzuesi tregon se si të numëroni numrin e qelizave me tekst të caktuar në Excel. Do të gjeni shembuj formulash për përputhjen e saktë, përputhjen e pjesshme dhe qelizat e filtruara.

Javën e kaluar ne shikuam se si të numërojmë qelizat me tekst në Excel, që do të thotë të gjitha qelizat me çdo tekst. Kur analizoni pjesë të mëdha informacioni, mund të dëshironi gjithashtu të dini se sa qeliza përmbajnë tekst specifik. Ky tutorial shpjegon se si ta bëni atë në një mënyrë të thjeshtë.

Si të numëroni qelizat me tekst specifik në Excel

Microsoft Excel ka një funksion të veçantë për të numëruar qelizat me kusht, funksionin COUNTIF. Gjithçka që duhet të bëni është të jepni vargun e tekstit të synuar në argumentin kriteret .

Këtu është një formulë e përgjithshme e Excel-it për të numëruar numrin e qelizave që përmbajnë tekst specifik:

Shembulli i mëposhtëm e tregon atë në veprim. Supozoni se keni një listë të ID-ve të artikujve në A2:A10 dhe dëshironi të numëroni numrin e qelizave me një ID të caktuar, të themi "AA-01". Shkruani këtë varg në argumentin e dytë dhe do të merrni këtë formulë të thjeshtë:

=COUNTIF(A2:A10, "AA-01")

Për t'i mundësuar përdoruesit tuaj të numërojnë qelizat me çdo tekst të dhënë pa pasur nevojë të modifikoni formulën, futni tekst në një qelizë të paracaktuar, le të themi D1, dhe jepni referencën e qelizës:

=COUNTIF(A2:A10, D1)

Shënim. Funksioni i Excel COUNTIF është i pandjeshëm ndaj shkronjave të vogla , që do të thotë se nuk dallon shkronjat. Për të trajtuar shkronjat e mëdha dhe të voglakaraktere ndryshe, përdorni këtë formulë të ndjeshme ndaj shkronjave.

Si të numërohen qelizat me tekst të caktuar (përputhje e pjesshme)

Formula e diskutuar në shembullin e mëparshëm përputhet saktësisht me kriteret. Nëse ka të paktën një karakter të ndryshëm në një qelizë, për shembull një hapësirë ​​shtesë në fund, kjo nuk do të jetë një përputhje e saktë dhe një qelizë e tillë nuk do të numërohet.

Për të gjetur numrin e qelizat që përmbajnë tekst të caktuar si pjesë e përmbajtjes së tyre, përdorin karaktere të gërmave në kriteret tuaja, përkatësisht një yll (*) që përfaqëson çdo sekuencë ose karaktere. Në varësi të qëllimit tuaj, një formulë mund të duket si një nga sa vijon.

Numëroni qelizat që përmbajnë tekst specifik në shumë fillimi :

Numëroni qelizat që përmbajnë tekst të caktuar në çdo pozicion :

Për shembull, për të gjetur se sa qeliza në intervalin A2:A10 fillojnë me "AA", përdorni këtë formulë:

=COUNTIF(A2:A10, "AA*")

Për të marrë numrin e qelizave që përmbajnë "AA" në çdo pozicion, përdorni këtë një:

=COUNTIF(A2:A10, "*AA*")

Për t'i bërë formulat më dinamike, zëvendësoni vargjet e koduara me referencat e qelizave.

Për të numëruar qelizat që fillojnë me tekst të caktuar:

=COUNTIF(A2:A10, D1&"*")

Për të numëruar qelizat me tekst të caktuar kudo në to:

=COUNTIF(A2:A10, "*"&D1&"*")

Pamja e ekranit më poshtë tregon rezultatet:

Numëroni qelizat që përmbajnë tekst specifik (të ndjeshme ndaj shkronjave të vogla)

Në situatën kur duhet të dallonishkronjat e mëdha dhe të vogla, funksioni COUNTIF nuk do të funksionojë. Në varësi të faktit nëse jeni duke kërkuar për një përputhje të saktë apo të pjesshme, do t'ju duhet të ndërtoni një formulë tjetër.

Formulë e ndjeshme ndaj shkronjave të vogla për të numëruar qelizat me tekst specifik (përputhje e saktë)

Për të numëruar numri i qelizave me tekst të caktuar që njohin rastin e tekstit, ne do të përdorim një kombinim të funksioneve SUMPRODUCT dhe EXACT:

Si funksionon kjo formulë:

• EXACT krahason secilën qelizë në diapazonin me tekstin e mostrës dhe kthen një grup vlerash TRUE dhe FALSE, TRUE që përfaqëson përputhjet e sakta dhe FALSE të gjitha qelizat e tjera. Një vizë e dyfishtë (e quajtur unary dyshe ) detyron TRUE dhe FALSE në 1 dhe 0.
• SUMPRODUCT mbledh të gjithë elementët e grupit. Kjo shumë është numri i 1-ve, që është numri i ndeshjeve.

Për shembull, për të marrë numrin e qelizave në A2:A10 që përmbajnë tekstin në D1 dhe për të trajtuar shkronjat e mëdha dhe të vogla si të ndryshme karaktere, përdorni këtë formulë:

=SUMPRODUCT(--EXACT(D1, A2:A10))

Formulë e ndjeshme ndaj shkronjave për të numëruar qelizat me tekst specifik (përputhje e pjesshme)

Për të ndërtuar një formulë e ndjeshme ndaj shkronjave të vogla që mund të gjejë një varg teksti me interes kudo në një qelizë, ne po përdorim 3 funksione të ndryshme:

Si funksionon kjo formulë:

• Funksioni FIND i ndjeshëm ndaj shkronjave të vogla kërkonpër tekstin e synuar në secilën qelizë të diapazonit. Nëse ka sukses, funksioni kthen pozicionin e karakterit të parë, përndryshe #VALUE! gabim. Për hir të qartësisë, nuk kemi nevojë të dimë pozicionin e saktë, çdo numër (në krahasim me gabimin) do të thotë që qeliza përmban tekstin e synuar.
• Funksioni ISNUMBER trajton grupin e numrave dhe gabimeve të kthyera nga FIND dhe i konverton numrat në TRUE dhe çdo gjë tjetër në FALSE. Një unar i dyfishtë (--) i detyron vlerat logjike në një dhe zero.
• SUMPRODUCT mbledh grupin e 1-ve dhe 0-ve dhe kthen numrin e qelizave që përmbajnë tekstin e specifikuar si pjesë të përmbajtjes së tyre.

Për të testuar formulën në të dhënat e jetës reale, le të gjejmë se sa qeliza në A2:A10 përmbajnë hyrjen e nënvargut në D1:

=SUMPRODUCT(--(ISNUMBER(FIND(D1, A2:A10))))

Dhe kjo kthen një numër nga 3 (qelizat A2, A3 dhe A6):

Si të numërohen qelizat e filtruara me tekst specifik

Për të numëruar artikuj të dukshëm në një listë të filtruar, do t'ju duhet të përdorni një kombinim të 4 ose më shumë funksioneve në varësi të faktit nëse dëshironi një përputhje të saktë ose të pjesshme. Për t'i bërë shembujt më të lehtë për t'u ndjekur, le t'i hedhim një vështrim të shpejtë të dhënave burimore.

Duke supozuar, ju keni një tabelë me ID-të e porosive në kolonën B dhe Sasia në kolonën C siç tregohet në imazhin më poshtë. Për momentin, jeni të interesuar vetëm për sasi më të mëdha se 1 dhe keni filtruar tabelën tuaj në përputhje me rrethanat. Tëpyetja është – si i numëroni qelizat e filtruara me një ID të caktuar?

Formula për të numëruar qelizat e filtruara me tekst specifik (përputhje e saktë)

Për të numëruar të filtruar qelizat, përmbajtja e të cilave përputhet saktësisht me vargun e tekstit të mostrës, përdorni një nga formulat e mëposhtme:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(B2:B10=F1))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(B2:B10=F1))

Ku F1 është teksti i mostrës dhe B2:B10 janë qelizat për të numëruar.

Si funksionojnë këto formula:

Në thelb të të dyja formulave, ju kryeni 2 kontrolle:

1. Identifikoni rreshtat e dukshëm dhe të fshehur. Për këtë, ju përdorni funksionin SUBTOTAL me argumentin funksioni_num të vendosur në 103. Për të furnizuar të gjitha referencat individuale të qelizave në SUBTOTAL, përdorni ose INDIRECT (në formulën e parë) ose një kombinim të OFFSET, ROW dhe MIN (në formulën e dytë). Meqenëse synojmë të gjejmë rreshtat e dukshëm dhe të fshehur, nuk ka shumë rëndësi se cilës kolonë t'i referohemi (A në shembullin tonë). Rezultati i këtij operacioni është një grup me 1 dhe 0 ku njësitë përfaqësojnë rreshta të dukshëm dhe zero - rreshta të fshehur.
2. Gjeni qelizat që përmbajnë tekstin e dhënë. Për këtë, krahasoni tekstin e mostrës (F1) me gamën e qelizave (B2:B10). Rezultati i këtij operacioni është një grup vlerash TRUE dhe FALSE, të cilat detyrohen në 1 dhe 0 me ndihmën e operatorit të dyfishtë unar.

Më në fund, funksioni SUMPRODUCT shumëzon elementet e të dyve vargjeve në të njëjtat pozicione, dhe më pas përmbledh vargun që rezulton.Për shkak se shumëzimi me zero jep zero, vetëm qelizat që kanë 1 në të dy vargjet kanë 1 në grupin përfundimtar. Shuma e 1 është numri i qelizave të filtruara që përmbajnë tekstin e specifikuar.

Formula për të numëruar qelizat e filtruara me tekst specifik (përputhje e pjesshme)

Për të numëruar qelizat e filtruara që përmbajnë tekst të caktuar si pjesë e përmbajtjen e qelizës, modifikoni formulat e mësipërme në mënyrën e mëposhtme. Në vend që të krahasoni tekstin e mostrës me gamën e qelizave, kërkoni për tekstin e synuar duke përdorur ISNUMBER dhe FIND siç shpjegohet në një nga shembujt e mëparshëm:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISNUMBER(FIND(F1, B2:B10))))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(ISNUMBER(FIND(F1, B2:B10))))

Si rezultat, formulat do të gjejnë një varg teksti të dhënë në çdo pozicion në një qelizë:

Shënim. Funksioni SUBTOTAL me 103 në argumentin funksioni_num , identifikon të gjitha qelizat e fshehura, të filtruara dhe të fshehura manualisht. Si rezultat, formulat e mësipërme numërojnë vetëm qeliza të dukshme pavarësisht se si ishin fshehur qelizat e padukshme. Për të përjashtuar vetëm qelizat e filtruara, por për të përfshirë ato të fshehura me dorë, përdorni 3 për funksioni_num .

Kjo është se si të numëroni numrin e qelizave me tekst të caktuar në Excel. Ju falënderoj që lexoni dhe shpresoj t'ju shohim në blogun tonë javën tjetër!

Shkarkimet e disponueshme

Formulat e Excel për të numëruar qelizat me tekst të caktuar