V učbeniku je prikazano, kako v Excelu prešteti število celic z določenim besedilom. Našli boste primere formul za natančno ujemanje, delno ujemanje in filtrirane celice.

Prejšnji teden smo si ogledali, kako v Excelu prešteti celice z besedilom, kar pomeni vse celice s poljubnim besedilom. Pri analizi velikih kosov informacij boste morda želeli vedeti tudi, koliko celic vsebuje določeno besedilo. V tem vodniku je pojasnjeno, kako to storiti na preprost način.

Kako šteti celice z določenim besedilom v Excelu

Microsoft Excel ima posebno funkcijo za pogojno štetje celic, funkcijo COUNTIF. Vse, kar morate storiti, je, da vnesete ciljni besedilni niz v merila argument.

Tukaj je splošna formula programa Excel za štetje števila celic, ki vsebujejo določeno besedilo:

V naslednjem primeru je prikazana v praksi. Recimo, da imate seznam ID-jev predmetov v A2:A10 in želite prešteti število celic z določenim ID-jem, na primer "AA-01". V drugi argument vnesite ta niz in dobili boste to preprosto formulo:

=COUNTIF(A2:A10, "AA-01")

Če želite uporabnikom omogočiti štetje celic s poljubnim besedilom, ne da bi jim bilo treba spreminjati formulo, vnesite besedilo v vnaprej določeno celico, na primer D1, in navedite sklic na celico:

=COUNTIF(A2:A10, D1)

Opomba: Excelova funkcija COUNTIF je razločevanje velikih in malih črk Za različno obravnavo velikih in malih črk uporabite to formulo, ki upošteva velikost črk.

Kako prešteti celice z določenim besedilom (delno ujemanje)

Formula iz prejšnjega primera se natančno ujema z merili. Če je v celici vsaj en drugačen znak, na primer dodaten presledek na koncu, to ne bo natančno ujemanje in taka celica ne bo upoštevana.

Če želite poiskati število celic, ki vsebujejo določeno besedilo kot del svoje vsebine, v merilih uporabite nadomestne znake, in sicer zvezdico (*), ki predstavlja poljubno zaporedje ali znake. Odvisno od vašega cilja je lahko formula videti kot ena od naslednjih.

Preštejte celice, ki vsebujejo določeno besedilo v zelo začetek :

Preštejte celice, ki vsebujejo določeno besedilo v kateri koli položaj :

Če želite na primer ugotoviti, koliko celic v območju A2:A10 se začne z "AA", uporabite to formulo:

=COUNTIF(A2:A10, "AA*")

Če želite pridobiti število celic, ki vsebujejo "AA" na katerem koli mestu, uporabite to:

=COUNTIF(A2:A10, "*AA*")

Če želite, da so formule bolj dinamične, nadomestite trdno zakodirane nize z referencami na celice.

Štetje celic, ki se začnejo z določenim besedilom:

=COUNTIF(A2:A10, D1& "*")

štetje celic z določenim besedilom kjer koli v njih:

=COUNTIF(A2:A10, "*"&D1&"*")

Spodnja slika zaslona prikazuje rezultate:

Preštejte celice, ki vsebujejo določeno besedilo (občutljivo na velike in male črke)

Če morate razlikovati med velikimi in malimi črkami, funkcija COUNTIF ne bo delovala. Glede na to, ali iščete natančno ali delno ujemanje, boste morali sestaviti drugačno formulo.

Formula za štetje celic z določenim besedilom (natančno ujemanje), občutljiva na velikost črk

Za štetje števila celic z določenim besedilom, ki prepoznava primer besedila, bomo uporabili kombinacijo funkcij SUMPRODUCT in EXACT:

Kako deluje ta formula:

• EXACT primerja vsako celico v območju z vzorčnim besedilom in vrne polje vrednosti TRUE in FALSE, pri čemer TRUE pomeni natančno ujemanje, FALSE pa vse druge celice. dvojno enopomensko ) pretvori TRUE in FALSE v 1 in 0.
• SUMPRODUCT sešteje vse elemente polja. Ta vsota je število 1, kar je število zadetkov.

Če želite na primer pridobiti število celic v A2:A10, ki vsebujejo besedilo v D1 in obravnavajo velike in male črke kot različne znake, uporabite to formulo:

=SUMPRODUKT(--EXACT(D1, A2:A10))

Formula za štetje celic z določenim besedilom, občutljiva na velikost črk (delno ujemanje)

Za sestavo formule, ki upošteva velike in male črke in lahko poišče želeni besedilni niz kjer koli v celici, uporabljamo 3 različne funkcije:

Kako deluje ta formula:

• Funkcija FIND, ki upošteva velikost črk, išče ciljno besedilo v vsaki celici območja. Če ji to uspe, funkcija vrne položaj prvega znaka, sicer pa napako #VALUE!. Zaradi jasnosti nam ni treba poznati natančnega položaja, vsaka številka (v nasprotju z napako) pomeni, da celica vsebuje ciljno besedilo.
• Funkcija ISNUMBER obdela polje števil in napak, ki ga vrne funkcija FIND, in pretvori števila v TRUE, vse drugo pa v FALSE. Dvojni enojnik (--) pretvori logične vrednosti v enice in ničle.
• SUMPRODUCT sešteje polje 1 in 0 ter vrne število celic, ki vsebujejo določeno besedilo kot del svoje vsebine.

Če želite formulo preizkusiti na resničnih podatkih, ugotovimo, koliko celic v A2:A10 vsebuje podrejen niz, vnesen v D1:

=SUMPRODUCT(--(ISNUMBER(FIND(D1, A2:A10))))

Ta vrne število 3 (celice A2, A3 in A6):

Kako šteti filtrirane celice z določenim besedilom

Za štetje vidni predmeti v filtriranem seznamu, boste morali uporabiti kombinacijo 4 ali več funkcij, odvisno od tega, ali želite natančno ali delno ujemanje. Za lažje spremljanje primerov si najprej na kratko oglejmo izvorne podatke.

Predvidevamo, da imate tabelo z ID-ji naročil v stolpcu B in Količina v stolpcu C, kot je prikazano na spodnji sliki. Trenutno vas zanimajo samo količine, večje od 1, zato ste tabelo ustrezno filtrirali. Vprašanje je - kako preštejete filtrirane celice z določenim id?

Formula za štetje filtriranih celic z določenim besedilom (natančno ujemanje)

Če želite prešteti filtrirane celice, katerih vsebina se natančno ujema z vzorčnim besedilnim nizom, uporabite eno od naslednjih formul:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(B2:B10=F1))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(B2:B10=F1))

Pri čemer je F1 vzorčno besedilo, B2:B10 pa so celice za štetje.

Kako te formule delujejo:

V jedru obeh formul sta 2 preverjanja:

1. Določite vidne in skrite vrstice. Za to uporabite funkcijo SUBTOTAL z ukazom function_num argument je nastavljen na 103. Če želite SUBTOTAL-u posredovati reference na vse posamezne celice, uporabite INDIRECT (v prvi formuli) ali kombinacijo OFFSET, ROW in MIN (v drugi formuli). Ker želimo najti vidne in skrite vrstice, je pravzaprav vseeno, na kateri stolpec se sklicujemo (A v našem primeru). Rezultat tega postopka je polje 1 in 0, kjer enice predstavljajo vidne vrstice.vrstice in ničle - skrite vrstice.
2. V ta namen primerjajte vzorčno besedilo (F1) z obsegom celic (B2:B10). Rezultat te operacije je polje vrednosti TRUE in FALSE, ki so s pomočjo dvojnega enojnega operatorja spremenjene v 1 in 0.

Nazadnje funkcija SUMPRODUCT pomnoži elemente obeh polj na istih mestih in nato sešteje dobljeno polje. Ker je rezultat množenja z ničlo nič, imajo v končnem polju 1 samo celice, ki imajo v obeh poljih 1. Vsota 1 je število filtriranih celic, ki vsebujejo določeno besedilo.

Formula za štetje filtriranih celic z določenim besedilom (delno ujemanje)

Če želite šteti filtrirane celice, ki vsebujejo določeno besedilo kot del vsebine celic, spremenite zgornje formule na naslednji način. Namesto da primerjate vzorčno besedilo z obsegom celic, poiščite ciljno besedilo z uporabo ISNUMBER in FIND, kot je razloženo v enem od prejšnjih primerov:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISNUMBER(FIND(F1, B2:B10))))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(ISNUMBER(FIND(F1, B2:B10))))

Tako bodo formule našle dani besedilni niz na katerem koli mestu v celici:

Opomba: Funkcija SUBTOTAL s 103 v function_num prepozna vse skrite celice, ki so bile filtrirane in skrite ročno. Zaradi tega zgornje formule štejejo le vidne celice ne glede na to, kako nevidne celice so bile skrite. Če želite izključiti samo filtrirane celice, vendar vključiti tiste, ki so bile skrite ročno, uporabite 3 za function_num .

To je način štetja števila celic z določenim besedilom v Excelu. Zahvaljujem se vam za branje in upam, da se naslednji teden vidimo na našem blogu!

Razpoložljivi prenosi

Excelove formule za štetje celic z določenim besedilom