Падручнік паказвае, як падлічыць колькасць вочак з пэўным тэкстам у Excel. Вы знойдзеце прыклады формул для дакладнага супадзення, частковага супадзення і адфільтраваных вочак.

На мінулым тыдні мы разгледзелі, як падлічыць вочкі з тэкстам у Excel, гэта значыць усе вочкі з любым тэкстам. Пры аналізе вялікіх фрагментаў інфармацыі вы таксама можаце ведаць, колькі ячэек змяшчае пэўны тэкст. Гэты падручнік тлумачыць, як гэта зрабіць простым спосабам.

Як падлічыць ячэйкі з пэўным тэкстам у Excel

Microsoft Excel мае спецыяльную функцыю для ўмоўнага падліку ячэек, функцыя COUNTIF. Усё, што вам трэба зрабіць, гэта ўвесці мэтавы тэкставы радок у аргумент крытэрыі .

Вось агульная формула Excel для падліку колькасці ячэек, якія змяшчаюць пэўны тэкст:

Наступны прыклад паказвае гэта ў дзеянні. Выкажам здагадку, у вас ёсць спіс ідэнтыфікатараў элементаў у A2:A10 і вы хочаце падлічыць колькасць ячэек з пэўным ідэнтыфікатарам, скажам, "AA-01". Увядзіце гэты радок у другі аргумент, і вы атрымаеце наступную простую формулу:

=COUNTIF(A2:A10, "AA-01")

Каб вашы карыстальнікі маглі лічыць ячэйкі з любым зададзеным тэкстам без неабходнасці змяняць формулу, увядзіце тэкст у прадвызначанай ячэйцы, скажам, D1, і падайце спасылку на ячэйку:

=COUNTIF(A2:A10, D1)

Заўвага. Функцыя Excel COUNTIF неадчувальная да рэгістра , што азначае, што яна не адрознівае рэгістр літар. Для лячэння вялікай і малой літарсімвалаў па-рознаму, выкарыстоўвайце гэтую формулу з улікам рэгістра.

Як падлічыць вочкі з пэўным тэкстам (частковае супадзенне)

Формула, разгледжаная ў папярэднім прыкладзе, цалкам адпавядае крытэрам. Калі ў ячэйцы ёсць хаця б адзін іншы сімвал, напрыклад, лішні прабел у канцы, гэта не будзе дакладным супадзеннем, і такая ячэйка не будзе залічана.

Каб знайсці колькасць ячэйкі, якія змяшчаюць пэўны тэкст як частку свайго змесціва, выкарыстоўвайце сімвалы падстаноўкі ў вашых крытэрах, а менавіта зорачку (*), якая прадстаўляе любую паслядоўнасць або сімвалы. У залежнасці ад вашай мэты, формула можа выглядаць наступным чынам.

Падлічыць вочкі, якія змяшчаюць пэўны тэкст у самым пачатку :

Падлік ячэек, якія змяшчаюць пэўны тэкст у любой пазіцыі :

Напрыклад, каб даведацца, колькі ячэек у дыяпазоне A2:A10 пачынаецца з "AA", выкарыстоўвайце наступную формулу:

=COUNTIF(A2:A10, "AA*")

Каб атрымаць колькасць ячэек, якія змяшчаюць "AA" у любой пазіцыі, выкарыстоўвайце гэта адзін:

=COUNTIF(A2:A10, "*AA*")

Каб зрабіць формулы больш дынамічнымі, заменіце жорсткія радкі спасылкамі на ячэйкі.

Каб падлічыць ячэйкі, якія пачынаюцца з пэўнага тэксту:

=COUNTIF(A2:A10, D1&"*")

Каб падлічыць ячэйкі з пэўным тэкстам у любым месцы:

=COUNTIF(A2:A10, "*"&D1&"*")

На скрыншоце ніжэй паказаны вынікі:

Падлік ячэек, якія ўтрымліваюць пэўны тэкст (з улікам рэгістра)

У сітуацыі, калі вам трэба адрозніцьвялікія і малыя літары, функцыя COUNTIF не будзе працаваць. У залежнасці ад таго, дакладнае ці частковае супадзенне вы шукаеце, вам прыйдзецца пабудаваць іншую формулу.

Формула з улікам рэгістра для падліку вочак з пэўным тэкстам (дакладнае супадзенне)

Для падліку колькасць вочак з пэўным тэкстам, распазнаючы рэгістр тэксту, мы будзем выкарыстоўваць камбінацыю функцый SUMPRODUCT і EXACT:

Як працуе гэтая формула:

• EXACT параўноўвае кожную ячэйку ў дыяпазоне з узорам тэксту і вяртае масіў значэнняў TRUE і FALSE, TRUE прадстаўляе дакладныя супадзенні, а FALSE — усе астатнія ячэйкі. Двайны злучок (званы падвойным унарным ) ператварае TRUE і FALSE у 1 і 0.
• SUMPRODUCT сумуе ўсе элементы масіва. Гэтая сума ўяўляе сабой лік адзінак, які з'яўляецца колькасцю супадзенняў.

Напрыклад, каб атрымаць колькасць ячэек у A2:A10, якія змяшчаюць тэкст у D1 і апрацоўваюць вялікія і малыя літары як розныя сімвалаў, выкарыстоўвайце наступную формулу:

=SUMPRODUCT(--EXACT(D1, A2:A10))

Формула з улікам рэгістра для падліку ячэек з пэўным тэкстам (частковае супадзенне)

Каб пабудаваць формула з улікам рэгістра, якая можа знайсці цікавы тэкставы радок у любым месцы ячэйкі, мы выкарыстоўваем 3 розныя функцыі:

Як працуе гэтая формула:

• Функцыя FIND з улікам рэгістра шукаедля мэтавага тэксту ў кожнай ячэйцы дыяпазону. Калі гэта ўдаецца, функцыя вяртае пазіцыю першага сімвала, у адваротным выпадку #VALUE! памылка. Дзеля яснасці, нам не трэба ведаць дакладную пазіцыю, любы лік (у адрозненне ад памылкі) азначае, што ячэйка змяшчае мэтавы тэкст.
• Функцыя ISNUMBER апрацоўвае масіў лікаў і памылак, якія вяртаюцца. з дапамогай FIND і пераўтворыць лічбы ў TRUE, а ўсё астатняе ў FALSE. Двайны унарны (--) пераводзіць лагічныя значэнні ў адзінкі і нулі.
• SUMPRODUCT сумуе масіў 1 і 0 і вяртае колькасць ячэек, якія ўтрымліваюць пэўны тэкст як частку свайго змесціва.

Каб праверыць формулу на рэальных дадзеных, давайце даведаемся, колькі ячэек у A2:A10 змяшчае падрадок, уведзены ў D1:

=SUMPRODUCT(--(ISNUMBER(FIND(D1, A2:A10))))

І гэта вяртае лік з 3 (ячэйкі A2, A3 і A6):

Як падлічыць адфільтраваныя вочкі з пэўным тэкстам

Каб падлічыць бачныя элементы у адфільтраваным спісе вам трэба будзе выкарыстоўваць камбінацыю з 4 ці больш функцый у залежнасці ад таго, хочаце вы дакладнае або частковае супадзенне. Каб зрабіць прыклады лягчэйшымі для пераймання, давайце спачатку хутка паглядзім на зыходныя дадзеныя.

Выкажам здагадку, што ў вас ёсць табліца з ідэнтыфікатарамі заказаў у слупку B і колькасцю у калонцы C, як паказана на малюнку ніжэй. На дадзены момант вас цікавяць толькі колькасці, большыя за 1, і вы адпаведным чынам адфільтравалі табліцу. Theпытанне - як падлічыць адфільтраваныя вочкі з пэўным ідэнтыфікатарам?

Формула для падліку адфільтраваных вочак з пэўным тэкстам (дакладнае супадзенне)

Для падліку адфільтраваных ячэйкі, змесціва якіх дакладна адпавядае ўзору тэкставага радка, выкарыстоўвайце адну з наступных формул:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(B2:B10=F1))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(B2:B10=F1))

Дзе F1 - узор тэксту, а B2:B10 - ячэйкі падлічыць.

Як працуюць гэтыя формулы:

У аснове абедзвюх формул вы выконваеце 2 праверкі:

1. Вызначыць бачныя і схаваныя радкі. Для гэтага вы выкарыстоўваеце функцыю SUBTOTAL з аргументам function_num , усталяваным у 103. Каб паставіць усе спасылкі на асобныя ячэйкі ў SUBTOTAL, выкарыстоўвайце або INDIRECT (у першай формуле), або камбінацыю OFFSET, ROW і MIN. (у другой формуле). Паколькі мы імкнемся знайсці бачныя і схаваныя радкі, не мае значэння, на які слупок спасылацца (у нашым прыкладзе A). Вынікам гэтай аперацыі з'яўляецца масіў з 1 і 0, дзе адзінкі прадстаўляюць бачныя радкі, а нулі - схаваныя радкі.
2. Знайдзіце ячэйкі, якія змяшчаюць зададзены тэкст. Для гэтага параўнайце ўзор тэксту (F1) з дыяпазонам вочак (B2:B10). Вынікам гэтай аперацыі з'яўляецца масіў значэнняў TRUE і FALSE, якія прыведзены да 1 і 0 з дапамогай двайнога ўнарнага аператара.

Нарэшце, функцыя SUMPRODUCT памнажае элементы двух масівы ў тых жа пазіцыях, а затым сумуе атрыманы масіў.Паколькі множанне на нуль дае нуль, толькі ячэйкі, якія маюць 1 у абодвух масівах, маюць 1 у канчатковым масіве. Сума адзінак - гэта колькасць адфільтраваных ячэек, якія ўтрымліваюць пэўны тэкст.

Формула для падліку адфільтраваных ячэек з пэўным тэкстам (частковае супадзенне)

Каб падлічыць адфільтраваныя вочкі, якія змяшчаюць пэўны тэкст як частку змесціва ячэйкі, змяніце прыведзеныя вышэй формулы наступным чынам. Замест таго, каб параўноўваць узор тэксту з дыяпазонам вочак, шукайце мэтавы тэкст з дапамогай ISNUMBER і FIND, як тлумачылася ў адным з папярэдніх прыкладаў:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISNUMBER(FIND(F1, B2:B10))))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(ISNUMBER(FIND(F1, B2:B10))))

У выніку формулы знойдуць зададзены тэкставы радок у любым месцы ячэйкі:

Заўвага. Функцыя SUBTOTAL са 103 у аргументе function_num вызначае ўсе схаваныя ячэйкі, адфільтраваныя і схаваныя ўручную. У выніку прыведзеныя вышэй формулы ўлічваюць толькі бачныя ячэйкі незалежна ад таго, як нябачныя ячэйкі былі схаваныя. Каб выключыць толькі адфільтраваныя ячэйкі, але ўключыць схаваныя ўручную, выкарыстоўвайце 3 для function_num .

Вось як можна падлічыць колькасць вочак з пэўным тэкстам у Excel. Я дзякую вам за чытанне і спадзяюся ўбачыць вас у нашым блогу на наступным тыдні!

Даступныя загрузкі

Формулы Excel для падліку вочак з пэўным тэкстам