Tutorial nunjukkeun cara ngitung jumlah sél anu nganggo téks tangtu dina Excel. Anjeun bakal mendakan conto rumus pikeun patandingan pasti, patandingan parsial sareng sél anu disaring.

Minggu kamari urang ningali kumaha ngitung sél nganggo téks dina Excel, hartosna sadaya sél nganggo téks naon waé. Nalika nganalisis sakumpulan inpormasi anu ageung, anjeun ogé hoyong terang sabaraha sél anu ngandung téks khusus. Tutorial ieu ngajelaskeun kumaha cara ngalakukeunana ku cara anu sederhana.

Cara ngitung sél nganggo téks khusus dina Excel

Microsoft Excel ngagaduhan pungsi khusus pikeun ngitung sél sacara kondisional, fungsi COUNTIF. Sadaya anu anjeun kedah laksanakeun nyaéta nyayogikeun string téks target dina argumen kriteria .

Ieu rumus Excel generik pikeun ngitung jumlah sél anu ngandung téks khusus:

Conto di handap nembongkeun eta dina aksi. Upami anjeun gaduh daptar ID item dina A2: A10 sareng anjeun badé ngitung jumlah sél anu nganggo id khusus, sebutkeun "AA-01". Ketik string ieu dina argumen kadua, sarta anjeun bakal meunang rumus basajan ieu:

=COUNTIF(A2:A10, "AA-01")

Pikeun ngaktipkeun pamaké anjeun ngitung sél jeung téks nu mana wae nu dibikeun tanpa kudu ngarobah rumus, asupkeun téks dina sél nu geus ditangtukeun, sebutkeun D1, sarta nyadiakeun rujukan sél:

=COUNTIF(A2:A10, D1)

Catetan. Fungsi Excel COUNTIF henteu sensitip hurup , hartina teu ngabedakeun hurup. Pikeun ngubaran hurup gede jeung leutikkarakter béda, make rumus hal-sénsitip ieu.

Kumaha carana ngitung sél kalawan téks tangtu (parsial cocok)

Rumus dibahas dina conto saméméhna cocog kritéria persis. Lamun aya sahanteuna hiji karakter béda dina sél, misalna hiji spasi tambahan dina tungtungna, éta moal cocok pasti tur sél misalna moal diitung.

Pikeun manggihan jumlah sél nu ngandung téks tangtu salaku bagian tina eusina, ngagunakeun karakter wildcard dina kriteria Anjeun, nyaéta tanda bintang (*) nu ngagambarkeun runtuyan atawa karakter. Gumantung kana tujuan anjeun, rumus tiasa sapertos salah sahiji di handap ieu.

Itung sél anu ngandung téks khusus dina mimiti pisan :

Itung sél anu ngandung téks tangtu dina posisi mana waé :

Contona, pikeun manggihan sabaraha sél dina rentang A2:A10 dimimitian ku "AA", make rumus ieu:

=COUNTIF(A2:A10, "AA*")

Pikeun ngitung jumlah sél nu ngandung "AA" dina posisi mana wae, make ieu hiji:

=COUNTIF(A2:A10, "*AA*")

Pikeun nyieun rumus leuwih dinamis, ganti string hardcoded ku rujukan sél.

Pikeun ngitung sél nu dimimitian ku téks nu tangtu:

=COUNTIF(A2:A10, D1&"*")

Pikeun ngitung sél nu aya téks nu tangtu di mana waé:

=COUNTIF(A2:A10, "*"&D1&"*")

Potret layar di handap nembongkeun hasil:

Itung sél nu ngandung téks husus (sénsitip leutik)

Dina kaayaan nalika anjeun kudu ngabédakeunaksara gede jeung aksara leutik, fungsi COUNTIF moal jalan. Gumantung kana naha anjeun milarian patandingan pasti atanapi parsial, anjeun kedah ngawangun rumus anu béda.

Rumus sénsitip-sénsitip pikeun ngitung sél kalayan téks khusus (cocok tepat)

Pikeun ngitung jumlah sél kalawan téks tangtu mikawanoh kasus téks, urang bakal ngagunakeun kombinasi fungsi SUMPRODUCT jeung EXACT:

Kumaha rumus ieu jalanna:

• EXACT ngabandingkeun unggal sél dina rentang ngalawan téks sampel sarta mulangkeun susunan nilai BENER jeung PALSU, BENER ngagambarkeun patandingan pasti jeung PALSU sadaya sél lianna. Tanda hubung ganda (disebut unary ganda ) maksakeun BENER jeung SALAH jadi 1 jeung 0.
• SUMPRODUCT nyimpulkeun sakabeh elemen array. Jumlah éta nyaéta jumlah 1, nyaéta jumlah patandingan.

Misalna, pikeun meunangkeun jumlah sél dina A2:A10 anu ngandung téks dina D1 sareng nanganan hurup ageung sareng leutik salaku béda. karakter, paké rumus ieu:

=SUMPRODUCT(--EXACT(D1, A2:A10))

Rumus sénsitip hurup pikeun ngitung sél kalayan téks husus (cocog parsial)

Pikeun ngawangun rumus case-sensitive nu bisa manggihan string téks nu dipikaresep di mana waé dina sél, urang ngagunakeun 3 fungsi béda:

Kumaha rumus ieu jalan:

• Fungsi FIND sensitip-huruf maluruhpikeun téks sasaran dina unggal sél rentang. Upami éta suksés, fungsina ngabalikeun posisi karakter anu munggaran, upami henteu #VALUE! kasalahan. Demi kajelasan, urang teu kudu nyaho posisi pasti, angka nu mana wae nu (sabalikna tina kasalahan) hartina sél ngandung téks target.
• Pungsi ISNUMBER handles susunan angka jeung kasalahan balik. ku FIND sarta ngarobah angka kana BENER jeung nanaon sejenna mun PALSU. Unary ganda (--) maksakeun nilai logis jadi hiji jeung nol.
• SUMPRODUCT nyimpulkeun susunan 1 jeung 0 sarta mulangkeun jumlah sél nu ngandung téks nu tangtu salaku bagian tina eusina.

Pikeun nguji rumus dina data kahirupan nyata, hayu urang teangan sabaraha sél dina A2:A10 ngandung input substring dina D1:

=SUMPRODUCT(--(ISNUMBER(FIND(D1, A2:A10))))

Sareng ieu ngabalikeun cacah. tina 3 (sél A2, A3 jeung A6):

Kumaha carana ngitung sél nu disaring ku téks husus

Pikeun ngitung item nu katingali dina daptar disaring, anjeun bakal kudu make kombinasi 4 atawa leuwih fungsi gumantung kana naha rék hiji patandingan pasti atanapi parsial. Pikeun ngagampangkeun conto-conto anu diturutan, hayu urang tingali heula data sumberna.

Anggap, anjeun gaduh tabel ID Pesenan dina kolom B sareng Jumlah dina kolom C siga gambar di handap. Pikeun momen, anjeun museurkeun ukur dina kuantitas leuwih gede ti 1 jeung anjeun nyaring tabel Anjeun sasuai. Thepatarosanana - kumaha carana ngitung sél disaring ku id nu tangtu?

Rumus ngitung sél disaring kalawan téks husus (cocok persis)

Pikeun cacah disaring sél anu eusina cocog persis jeung sampel string téks, make salah sahiji rumus ieu:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(B2:B10=F1))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(B2:B10=F1))

Dimana F1 mangrupa téks sampel sarta B2:B10 nyaéta sél pikeun ngitung.

Kumaha rumus ieu:

Dina inti kadua rumus, anjeun ngalakukeun 2 pamariksaan:

1. Identipikasi barisan anu katingali sareng disumputkeun. Jang ngalampahkeun ieu, anjeun nganggo fungsi SUBTOTAL sareng argumen function_num disetel ka 103. Pikeun nyayogikeun sadaya rujukan sél individu ka SUBTOTAL, paké INDIRECT (dina rumus munggaran) atanapi kombinasi OFFSET, ROW sareng MIN. (dina rumus kadua). Kusabab urang tujuanana pikeun milarian barisan anu katingali sareng disumputkeun, éta henteu masalah naon kolom anu dirujuk (A dina conto urang). Hasil tina operasi ieu mangrupa susunan 1 jeung 0 anu ngagambarkeun baris katempo jeung nol - baris disumputkeun.
2. Teangan sél nu ngandung téks dibikeun. Jang ngalampahkeun ieu, ngabandingkeun téks sampel (F1) jeung rentang sél (B2:B10). Hasil tina operasi ieu mangrupa susunan nilai BENER jeung PALSU, nu dipaksa jadi 1 jeung 0 kalayan bantuan operator unary ganda.

Ahirna, fungsi SUMPRODUCT ngalikeun unsur dua. arrays dina posisi anu sarua, lajeng sums Asép Sunandar Sunarya hasilna.Kusabab ngalikeun ku enol méré enol, ngan sél nu boga 1 dina duanana arrays boga 1 dina Asép Sunandar Sunarya final. Jumlah 1 nyaéta jumlah sél disaring anu ngandung téks nu tangtu.

Rumus pikeun ngitung sél disaring kalawan téks husus (cocok parsial)

Pikeun ngitung sél disaring ngandung téks tangtu salaku bagian tina eusi sél, ngaropéa rumus di luhur ku cara kieu. Gantina ngabandingkeun téks sampel jeung rentang sél, néangan téks target ku ngagunakeun ISNUMBER jeung FIND sakumaha dipedar dina salah sahiji conto saméméhna:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISNUMBER(FIND(F1, B2:B10))))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(ISNUMBER(FIND(F1, B2:B10))))

Hasilna, rumus bakal mendakan string téks anu dipasihkeun dina posisi mana waé dina sél:

Catetan. Fungsi SUBTOTAL sareng 103 dina argumen function_num , ngidentipikasi sadaya sél anu disumputkeun, disaring sareng disumputkeun sacara manual. Hasilna, rumus di luhur ngan ukur ngitung sél anu katingali henteu paduli kumaha sél anu teu katingali disumputkeun. Pikeun ngaluarkeun sél ukur anu disaring tapi kalebet anu disumputkeun sacara manual, paké 3 pikeun function_num .

Éta cara ngitung jumlah sél nganggo téks anu tangtu dina Excel. Kuring hatur nuhun pikeun maca sareng ngarepkeun anjeun tiasa ningali dina blog kami minggu payun!

Sadia undeuran

Rumus Excel pikeun ngitung sél sareng téks anu tangtu