Ipinapakita ng tutorial kung paano bilangin ang bilang ng mga cell na may ilang partikular na text sa Excel. Makakakita ka ng mga halimbawa ng formula para sa eksaktong tugma, bahagyang tugma at na-filter na mga cell.

Noong nakaraang linggo, tiningnan namin kung paano magbilang ng mga cell na may teksto sa Excel, ibig sabihin, lahat ng mga cell na may anumang teksto. Kapag nagsusuri ng malalaking tipak ng impormasyon, maaaring gusto mo ring malaman kung ilang cell ang naglalaman ng partikular na teksto. Ipinapaliwanag ng tutorial na ito kung paano ito gawin sa isang simpleng paraan.

Paano magbilang ng mga cell na may partikular na text sa Excel

May espesyal na function ang Microsoft Excel na may kondisyon na magbilang ng mga cell, ang COUNTIF function. Ang kailangan mo lang gawin ay ibigay ang target na text string sa criteria argument.

Narito ang isang generic na formula ng Excel upang mabilang ang bilang ng mga cell na naglalaman ng partikular na text:

Ipinapakita ito ng sumusunod na halimbawa sa pagkilos. Ipagpalagay, mayroon kang listahan ng mga ID ng item sa A2:A10 at gusto mong bilangin ang bilang ng mga cell na may partikular na id, sabihin ang "AA-01". I-type ang string na ito sa pangalawang argument, at makukuha mo ang simpleng formula na ito:

=COUNTIF(A2:A10, "AA-01")

Upang paganahin ang iyong mga user na magbilang ng mga cell na may anumang ibinigay na text nang hindi kailangang baguhin ang formula, ipasok ang text sa isang paunang natukoy na cell, sabihin ang D1, at ibigay ang cell reference:

=COUNTIF(A2:A10, D1)

Tandaan. Ang Excel COUNTIF function ay case-insensitive , ibig sabihin, hindi nito pinag-iiba ang letter case. Upang gamutin ang uppercase at lowercasemga character sa ibang paraan, gamitin itong case-sensitive na formula.

Paano magbilang ng mga cell na may ilang partikular na text (bahagyang tugma)

Ang formula na tinalakay sa nakaraang halimbawa ay eksaktong tumutugma sa pamantayan. Kung mayroong kahit isang magkaibang character sa isang cell, halimbawa ng dagdag na espasyo sa huli, hindi iyon magiging eksaktong tugma at hindi mabibilang ang naturang cell.

Upang mahanap ang bilang ng mga cell na naglalaman ng ilang partikular na text bilang bahagi ng mga nilalaman ng mga ito, gumamit ng mga wildcard na character sa iyong pamantayan, katulad ng asterisk (*) na kumakatawan sa anumang pagkakasunud-sunod o mga character. Depende sa iyong layunin, ang isang formula ay maaaring magmukhang isa sa mga sumusunod.

Bilangin ang mga cell na naglalaman ng partikular na text sa napakasimula :

Bilangin ang mga cell na naglalaman ng ilang partikular na text sa anumang posisyon :

Halimbawa, para malaman kung gaano karaming mga cell sa hanay na A2:A10 ang nagsisimula sa "AA", gamitin ang formula na ito:

=COUNTIF(A2:A10, "AA*")

Upang makuha ang bilang ng mga cell na naglalaman ng "AA" sa anumang posisyon, gamitin ito isa:

=COUNTIF(A2:A10, "*AA*")

Upang gawing mas dynamic ang mga formula, palitan ang mga hardcoded na string ng mga cell reference.

Upang bilangin ang mga cell na nagsisimula sa ilang partikular na text:

=COUNTIF(A2:A10, D1&"*")

Upang magbilang ng mga cell na may ilang partikular na text saanman sa mga ito:

=COUNTIF(A2:A10, "*"&D1&"*")

Ang screenshot sa ibaba ay nagpapakita ng mga resulta:

Bilangin ang mga cell na naglalaman ng partikular na text (case-sensitive)

Sa sitwasyon kung kailan kailangan mong mag-ibauppercase at lowercase na character, hindi gagana ang COUNTIF function. Depende sa kung naghahanap ka ng eksaktong o bahagyang tugma, kakailanganin mong bumuo ng ibang formula.

Case-sensitive na formula upang mabilang ang mga cell na may partikular na text (eksaktong tugma)

Upang mabilang ang bilang ng mga cell na may ilang partikular na text na kumikilala sa text case, gagamit kami ng kumbinasyon ng SUMPRODUCT at EXACT function:

Paano gumagana ang formula na ito:

• Inihahambing ng EXACT ang bawat cell sa hanay laban sa sample na text at nagbabalik ng array ng TRUE at FALSE value, TRUE na kumakatawan sa mga eksaktong tugma at FALSE sa lahat ng iba pang mga cell. Pinipilit ng double hyphen (tinatawag na double unary ) ang TRUE at FALSE sa 1's at 0's.
• SUMPRODUCT ay nagsusuma ng lahat ng elemento ng array. Ang kabuuan na iyon ay ang bilang ng 1, na ang bilang ng mga tugma.

Halimbawa, para makuha ang bilang ng mga cell sa A2:A10 na naglalaman ng text sa D1 at pangasiwaan ang uppercase at lowercase bilang magkaiba character, gamitin ang formula na ito:

=SUMPRODUCT(--EXACT(D1, A2:A10))

Case-sensitive na formula upang mabilang ang mga cell na may partikular na text (bahagyang tugma)

Upang bumuo isang case-sensitive na formula na makakahanap ng text string ng interes saanman sa isang cell, gumagamit kami ng 3 magkakaibang function:

Paano gumagana ang formula na ito:

• Ang case-sensitive na FIND function ay naghahanappara sa target na text sa bawat cell ng range. Kung magtagumpay ito, ibabalik ng function ang posisyon ng unang character, kung hindi ang #VALUE! pagkakamali. Para sa kalinawan, hindi namin kailangang malaman ang eksaktong posisyon, ang anumang numero (kumpara sa error) ay nangangahulugan na ang cell ay naglalaman ng target na text.
• Ang ISNUMBER function ay humahawak sa hanay ng mga numero at mga error na ibinalik. sa pamamagitan ng HANAPIN at i-convert ang mga numero sa TRUE at anumang bagay sa FALSE. Pinipilit ng dobleng unary (--) ang mga lohikal na halaga sa isa at mga zero.
• SUMPRODUCT ay nagsusuma ng hanay ng 1 at 0 at ibinabalik ang bilang ng mga cell na naglalaman ng tinukoy na teksto bilang bahagi ng kanilang mga nilalaman.

Upang subukan ang formula sa totoong buhay na data, hanapin natin kung gaano karaming mga cell sa A2:A10 ang naglalaman ng substring input sa D1:

=SUMPRODUCT(--(ISNUMBER(FIND(D1, A2:A10))))

At nagbabalik ito ng bilang ng 3 (mga cell A2, A3 at A6):

Paano bilangin ang mga na-filter na cell na may partikular na text

Upang bilangin ang nakikitang mga item sa isang na-filter na listahan, kakailanganin mong gumamit ng kumbinasyon ng 4 o higit pang mga function depende sa kung gusto mo ng eksaktong o bahagyang tugma. Upang gawing mas madaling sundin ang mga halimbawa, tingnan muna natin ang source data.

Ipagpalagay, mayroon kang talahanayan na may Mga Order ID sa column B at Dami sa column C tulad ng ipinapakita sa larawan sa ibaba. Sa ngayon, interesado ka lang sa mga dami na higit sa 1 at na-filter mo ang iyong talahanayan nang naaayon. Angang tanong ay – paano mo binibilang ang mga na-filter na cell na may partikular na id?

Formula para mabilang ang mga na-filter na cell na may partikular na text (eksaktong tugma)

Upang bilangin ang na-filter mga cell na ang mga nilalaman ay eksaktong tumutugma sa sample na string ng text, gumamit ng isa sa mga sumusunod na formula:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(B2:B10=F1))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(B2:B10=F1))

Kung saan ang F1 ay ang sample na text at B2:B10 ang mga cell upang mabilang.

Paano gumagana ang mga formula na ito:

Sa core ng parehong mga formula, nagsasagawa ka ng 2 pagsusuri:

1. Tukuyin ang nakikita at nakatagong mga hilera. Para dito, ginagamit mo ang function na SUBTOTAL na may argument na function_num na nakatakda sa 103. Upang maibigay ang lahat ng indibidwal na cell reference sa SUBTOTAL, gamitin ang alinman sa INDIRECT (sa unang formula) o kumbinasyon ng OFFSET, ROW at MIN (sa pangalawang formula). Dahil nilalayon naming hanapin ang mga nakikita at nakatagong mga row, hindi mahalaga kung aling column ang sasangguni (A sa aming halimbawa). Ang resulta ng operasyong ito ay isang array ng 1's at 0's kung saan ang mga ito ay kumakatawan sa mga nakikitang row at zero - hidden row.
2. Hanapin ang mga cell na naglalaman ng ibinigay na text. Para dito, ihambing ang sample na text (F1) laban sa hanay ng mga cell (B2:B10). Ang resulta ng operasyong ito ay isang array ng TRUE at FALSE value, na pinipilit sa 1's at 0's sa tulong ng double unary operator.

Sa wakas, pinaparami ng function ng SUMPRODUCT ang mga elemento ng dalawa. arrays sa parehong mga posisyon, at pagkatapos ay sums ang resultang array.Dahil ang pag-multiply sa zero ay nagbibigay ng zero, tanging ang mga cell na may 1 sa parehong array ay may 1 sa huling array. Ang kabuuan ng 1 ay ang bilang ng mga na-filter na cell na naglalaman ng tinukoy na text.

Formula para mabilang ang mga na-filter na cell na may partikular na text (bahagyang tugma)

Upang bilangin ang mga na-filter na cell na naglalaman ng ilang partikular na text bilang bahagi ng ang mga nilalaman ng cell, baguhin ang mga formula sa itaas sa sumusunod na paraan. Sa halip na ihambing ang sample na text sa hanay ng mga cell, hanapin ang target na text sa pamamagitan ng paggamit ng ISNUMBER at FIND gaya ng ipinaliwanag sa isa sa mga nakaraang halimbawa:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISNUMBER(FIND(F1, B2:B10))))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(ISNUMBER(FIND(F1, B2:B10))))

Bilang resulta, hahanapin ng mga formula ang isang ibinigay na string ng teksto sa anumang posisyon sa isang cell:

Tandaan. Ang function na SUBTOTAL na may 103 sa argument na function_num , ay kinikilala ang lahat ng mga nakatagong cell, na-filter at nakatago nang manu-mano. Bilang resulta, ang mga formula sa itaas ay nagbibilang lamang ng nakikitang mga cell anuman ang itinago ng mga invisible na cell. Upang ibukod lamang ang mga na-filter na cell ngunit isama ang mga nakatago nang manu-mano, gumamit ng 3 para sa function_num .

Iyan ay kung paano bilangin ang bilang ng mga cell na may ilang partikular na text sa Excel. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo!

Mga available na download

Mga formula ng Excel para mabilang ang mga cell na may ilang partikular na text