Tutorial menunjukkan cara menghitung jumlah sel dengan teks tertentu di Excel. Anda akan menemukan contoh rumus untuk pencocokan tepat, pencocokan parsial, dan sel yang difilter.

Minggu lalu kami melihat cara menghitung sel dengan teks di Excel, artinya semua sel dengan teks apa pun. Saat menganalisis sebagian besar informasi, Anda mungkin juga ingin mengetahui berapa banyak sel yang berisi teks tertentu. Tutorial ini menjelaskan cara melakukannya dengan cara yang sederhana.

Cara menghitung sel dengan teks tertentu di Excel

Microsoft Excel memiliki fungsi khusus untuk menghitung sel secara kondisional, fungsi COUNTIF. Yang harus Anda lakukan adalah menyediakan string teks target di kriteria argumen.

Berikut rumus Excel umum untuk menghitung jumlah sel yang berisi teks tertentu:

Misalkan, Anda memiliki daftar ID item di A2: A10 dan Anda ingin menghitung jumlah sel dengan id tertentu, katakanlah "AA-01". Ketik string ini di argumen kedua, dan Anda akan mendapatkan rumus sederhana ini:

=COUNTIF(A2:A10, "AA-01")

Untuk memungkinkan pengguna Anda menghitung sel dengan teks tertentu tanpa perlu memodifikasi rumusnya, masukkan teks dalam sel yang telah ditentukan sebelumnya, katakanlah D1, dan berikan referensi sel:

=COUNTIF(A2:A10, D1)

Catatan. Fungsi Excel COUNTIF adalah tidak peka huruf besar-kecil Untuk memperlakukan karakter huruf besar dan huruf kecil secara berbeda, gunakan rumus case-sensitive ini.

Cara menghitung sel dengan teks tertentu (pencocokan parsial)

Rumus yang dibahas dalam contoh sebelumnya cocok dengan kriteria dengan tepat. Jika ada setidaknya satu karakter berbeda dalam sel, misalnya spasi ekstra di akhir, itu tidak akan menjadi kecocokan yang tepat dan sel seperti itu tidak akan dihitung.

Untuk menemukan jumlah sel yang berisi teks tertentu sebagai bagian dari isinya, gunakan karakter wildcard dalam kriteriamu, yaitu tanda bintang (*) yang mewakili urutan atau karakter apa pun. Bergantung pada tujuanmu, rumus dapat terlihat seperti salah satu dari yang berikut ini.

Hitung sel yang berisi teks tertentu di sangat awal :

Hitung sel yang berisi teks tertentu dalam posisi apa pun :

Misalnya, untuk menemukan berapa banyak sel dalam rentang A2: A10 yang dimulai dengan "AA", gunakan rumus ini:

=COUNTIF(A2:A10, "AA*")

Untuk mendapatkan hitungan sel yang berisi "AA" di posisi mana pun, gunakan yang ini:

=COUNTIF(A2:A10, "*AA*")

Untuk membuat formula lebih dinamis, ganti string hardcoded dengan referensi sel.

Untuk menghitung sel yang dimulai dengan teks tertentu:

=COUNTIF(A2:A10, D1& "*")

Untuk menghitung sel dengan teks tertentu di mana saja di dalamnya:

=COUNTIF(A2:A10, "*"&D1&"*")

Tangkapan layar di bawah ini menunjukkan hasilnya:

Hitung sel yang berisi teks tertentu (case-sensitive)

Dalam situasi ketika Anda perlu membedakan karakter huruf besar dan huruf kecil, fungsi COUNTIF tidak akan berfungsi. Bergantung pada apakah Anda mencari kecocokan persis atau sebagian, Anda harus membuat rumus yang berbeda.

Rumus peka huruf besar-kecil untuk menghitung sel dengan teks tertentu (pencocokan tepat)

Untuk menghitung jumlah sel dengan teks tertentu yang mengenali kasus teks, kami akan menggunakan kombinasi fungsi SUMPRODUCT dan EXACT:

Bagaimana formula ini bekerja:

• EXACT membandingkan setiap sel dalam rentang terhadap teks sampel dan mengembalikan larik nilai TRUE dan FALSE, TRUE mewakili kecocokan persis dan FALSE semua sel lainnya. Tanda hubung ganda (disebut a unary ganda ) memaksa TRUE dan FALSE menjadi 1 dan 0.
• SUMPRODUCT menjumlahkan semua elemen larik. Jumlah itu adalah jumlah 1, yang merupakan jumlah kecocokan.

Misalnya, untuk mendapatkan jumlah sel di A2: A10 yang berisi teks di D1 dan menangani huruf besar dan kecil sebagai karakter yang berbeda, gunakan rumus ini:

=SUMPRODUCT(--EXACT(D1, A2:A10))

Rumus peka huruf besar-kecil untuk menghitung sel dengan teks tertentu (pencocokan parsial)

Untuk membuat rumus peka huruf besar-kecil yang dapat menemukan string teks yang menarik di mana saja dalam sel, kami menggunakan 3 fungsi berbeda:

Bagaimana formula ini bekerja:

• Fungsi FIND yang peka huruf besar-kecil mencari teks target di setiap sel rentang. Jika berhasil, fungsi mengembalikan posisi karakter pertama, jika tidak, kesalahan #VALUE! Demi kejelasan, kita tidak perlu mengetahui posisi pastinya, angka apa pun (sebagai lawan dari kesalahan) berarti sel berisi teks target.
• Fungsi ISNUMBER menangani larik angka dan kesalahan yang dikembalikan oleh FIND dan mengubah angka menjadi TRUE dan yang lainnya menjadi FALSE. Sebuah unary ganda (--) memaksa nilai logika menjadi satu dan nol.
• SUMPRODUCT menjumlahkan larik 1 dan 0 dan mengembalikan hitungan sel yang berisi teks yang ditentukan sebagai bagian dari isinya.

Untuk menguji rumus pada data kehidupan nyata, mari kita cari berapa banyak sel di A2:A10 yang berisi input substring di D1:

=SUMPRODUCT(--(ISNUMBER(FIND(D1, A2:A10))))

Dan ini mengembalikan hitungan 3 (sel A2, A3 dan A6):

Cara menghitung sel yang difilter dengan teks tertentu

Untuk menghitung item yang terlihat dalam daftar yang difilter, Anda perlu menggunakan kombinasi 4 fungsi atau lebih tergantung pada apakah Anda menginginkan kecocokan yang tepat atau sebagian. Agar contoh lebih mudah diikuti, mari kita lihat sekilas sumber datanya terlebih dahulu.

Dengan asumsi, Anda memiliki tabel dengan ID Pesanan di kolom B dan Kuantitas di kolom C seperti yang ditunjukkan pada gambar di bawah ini. Untuk saat ini, Anda hanya tertarik pada jumlah yang lebih besar dari 1 dan Anda memfilter tabel Anda sesuai dengan itu. Pertanyaannya adalah - bagaimana Anda menghitung sel yang difilter dengan id tertentu?

Formula untuk menghitung sel yang difilter dengan teks tertentu (pencocokan tepat)

Untuk menghitung sel yang difilter yang isinya sama persis dengan string teks sampel, gunakan salah satu rumus berikut:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(B2:B10=F1))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(B2:B10=F1))

Di mana F1 adalah teks sampel dan B2: B10 adalah sel yang akan dihitung.

Bagaimana formula ini bekerja:

Pada inti dari kedua formula, Anda melakukan 2 pemeriksaan:

1. Mengidentifikasi baris yang terlihat dan tersembunyi. Untuk ini, Anda menggunakan fungsi SUBTOTAL dengan fungsi function_num argumen diatur ke 103. Untuk menyediakan semua referensi sel individual ke SUBTOTAL, gunakan INDIRECT (dalam rumus pertama) atau kombinasi OFFSET, ROW, dan MIN (dalam rumus kedua). Karena kita bertujuan untuk menemukan baris yang terlihat dan tersembunyi, tidak masalah kolom mana yang akan direferensikan (A dalam contoh kita). Hasil dari operasi ini adalah larik 1 dan 0 di mana yang satu mewakili baris yang terlihat.baris dan nol - baris tersembunyi.
2. Temukan sel yang berisi teks yang diberikan. Untuk ini, bandingkan teks sampel (F1) dengan rentang sel (B2: B10). Hasil dari operasi ini adalah larik nilai TRUE dan FALSE, yang dipaksakan menjadi 1 dan 0 dengan bantuan operator unary ganda.

Terakhir, fungsi SUMPRODUCT mengalikan elemen dari dua larik di posisi yang sama, lalu menjumlahkan larik yang dihasilkan. Karena mengalikan dengan nol menghasilkan nol, hanya sel yang memiliki 1 di kedua larik yang memiliki 1 di larik akhir. Jumlah 1 adalah jumlah sel yang difilter yang berisi teks yang ditentukan.

Formula untuk menghitung sel yang difilter dengan teks tertentu (pencocokan parsial)

Untuk menghitung sel yang difilter yang berisi teks tertentu sebagai bagian dari konten sel, ubah rumus di atas dengan cara berikut. Alih-alih membandingkan teks sampel dengan rentang sel, cari teks target dengan menggunakan ISNUMBER dan FIND seperti yang dijelaskan di salah satu contoh sebelumnya:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISNUMBER(FIND(F1, B2:B10))))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(ISNUMBER(FIND(F1, B2:B10))))

Hasilnya, rumus akan menemukan string teks tertentu di posisi mana pun dalam sel:

Catatan. Fungsi SUBTOTAL dengan 103 di dalam function_num argumen, mengidentifikasi semua sel tersembunyi, disaring dan disembunyikan secara manual. Hasilnya, rumus di atas hanya menghitung sel yang terlihat terlepas dari bagaimana sel tak terlihat disembunyikan. Untuk mengecualikan hanya sel yang difilter tetapi menyertakan sel yang disembunyikan secara manual, gunakan 3 untuk function_num .

Itulah cara menghitung jumlah sel dengan teks tertentu di Excel. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

Unduhan yang tersedia

Rumus Excel untuk menghitung sel dengan teks tertentu