Dersdar nîşan dide ka meriv çawa di Excel de bi hin nivîsan re hejmara hucreyan bijmêre. Hûn ê mînakên formulê ji bo lihevhatina tam, lihevhatina qismî û şaneyên fîltrekirî bibînin.

Hefteya çûyî me nihêrî ka meriv çawa şaneyên bi nivîsê di Excel de têne hejmartin, yanî hemî şaneyên bi her nivîsê re. Dema ku hûn perçeyên mezin ên agahdarî analîz dikin, dibe ku hûn jî bixwazin ku hûn çend şaneyên nivîsek taybetî hene. Ev tutorial rave dike ka meriv çawa wiya bi awayek hêsan dike.

Çawa meriv şaneyan bi nivîsek taybetî di Excel de bijmêre

Microsoft Excel fonksiyonek taybetî heye ku bi şertê hucreyan bijmêre, fonksiyona COUNTIF. Tiştê ku divê hûn bikin ev e ku hûn rêzika nivîsê ya armancê di argumana krîteran de peyda bikin.

Li vir formula Excel-ê ya gelemperî heye ku jimara şaneyên ku nivîsek taybetî vedihewîne bijmêre:

Mînaka jêrîn wê di çalakiyê de nîşan dide. Bifikirin, di A2:A10 de navnîşek nasnameyên we hene û hûn dixwazin hejmara şaneyên bi nasnameyek taybetî bijmêrin, bibêjin "AA-01". Di argumana duyemîn de vê rêzê binivîsin, û hûn ê vê formula hêsan bistînin:

=COUNTIF(A2:A10, "AA-01")

Ji bo ku bikarhênerên xwe bikar bînin ku bêyî ku hewcedariya guherandina formulê bi her nivîsek diyarkirî re şaneyan bijmêrin, binivîsin. Nivîsar di şaneyek pêşwext de, bêje D1, û referansa şaneyê peyda bike:

=COUNTIF(A2:A10, D1)

Nîşe. Fonksîyona Excel COUNTIF nehesasîyeta mezin e , yanî ew haletên tîpan ji hev cuda nake. Ji bo dermankirina tîpên mezin û piçûkkarakterên cuda, vê formula-hesas-dozê bikar bînin.

Meriv çawa şaneyên bi hin metnekê re bijmêre (lihevhatina qismî)

Formula ku di mînaka berê de hatî nîqaş kirin bi pîvanan tam li hev dike. Ger di şaneyek de bi kêmanî karakterek cûda hebe, wek mînak di dawiyê de cîhek zêde, ew ê ne rast hevûdu be û şaneyek weha nayê jimartin.

Ji bo dîtina hejmara şaneyên ku hin nivîsan wekî beşek ji naveroka xwe vedihewînin, di pîvanên xwe de tîpên hovane bikar tînin, ango stêrka (*) ku her rêzek an tîpan temsîl dike. Li gorî armanca we, formûlek dikare wekî yek ji van jêrîn xuya bike.

Hapên ku nivîsa taybetî dihewîne li pir destpêk :

Bijmêre şaneyên ku hin nivîsan di her cihekê de hene :

Mînakî, ji bo ku hûn bibînin ka çend şaneyên di rêza A2:A10 de bi "AA" dest pê dikin, vê formulê bikar bînin:

=COUNTIF(A2:A10, "AA*")

Ji bo ku hejmara şaneyên ku "AA" hene li her pozîsyonê bistînin, vê bikar bînin yek:

=COUNTIF(A2:A10, "*AA*")

Ji bo ku formula dînamîktir bibin, rêzikên hişk bi referansên şaneyê biguherînin.

Ji bo hejmartina şaneyên ku bi hin nivîsan dest pê dikin:

=COUNTIF(A2:A10, D1&"*")

Ji bo jimartina şaneyên bi hin nivîsan li her derê di wan de:

=COUNTIF(A2:A10, "*"&D1&"*")

Pîneroya jêrîn encaman nîşan dide:

Hacreyên ku nivîsa taybetî dihewîne bijmêre (hesas bi mesela)

Di rewşek ku hûn hewce ne ku ji hev cuda bikintîpên mezin û piçûk, fonksiyona COUNTIF dê nexebite. Li gora ku hûn li hevhatineke tam an jî qismî digerin, hûn ê neçar bibin ku formula cûda ava bikin.

Formula hesas a dozê ji bo jimartina şaneyên bi nivîsa taybetî (lihevhatina rast)

Ji bo hejmartinê hejmara şaneyên bi hin metnên ku rewşa nivîsê nas dikin, em ê tevhevek fonksiyonên SUMPRODUCT û EXACT bikar bînin:

Ev formul çawa dixebite:

• EXACT her şaneyek di navberê de li hember metna nimûneyê dide ber hev û rêzek ji nirxên TRUE û FALSE vedigerîne, TRUE lihevhatinên rast û FALSE hemî şaneyên din vedigerîne. Daçeka ducar (ku jê re bi unarya ducar tê gotin) TRUE û FALSE di 1'yan û 0'yan de ferz dike.
• SUMPRODUCT hemû hêmanên rêzê berhev dike. Ew berhevok hejmara 1'yan e, ku hejmara hevberdanê ye.

Mînakî, ji bo bidestxistina hejmara şaneyên di A2:A10 de ku nivîsa di D1-ê de tê de heye û tîpên mezin û yên piçûk ji hev cuda dikin. tîpan, vê formulê bi kar bînin:

=SUMPRODUCT(--EXACT(D1, A2:A10))

Formula hesas a biçûk ji bo jimartina şaneyên bi nivîsa taybet (lihevhatina qismî)

Ji bo çêkirinê formulek hestiyar a ku dikare rêzika nivîsê ya balkêş li her derê şaneyek bibîne, em 3 fonksiyonên cihêreng bikar tînin:

Ev formula çawa dixebite:

• Fonksiyonek FIND-hesas a dozê digereji bo nivîsara armancê di her hucreya rêzê de. Ger ew biserkeve, fonksiyon pozîsyona karaktera yekem vedigerîne, wekî din #VALUE! şaşî. Ji bo zelaliyê, ne hewce ye ku em pozîsyona tam zanibin, her hejmar (li hember xeletiyê) tê vê wateyê ku şaneyê nivîsa mebestê dihewîne.
• Fonksiyon ISNUMBER rêza hejmar û xeletiyên hatine vegerandin digire dest. ji hêla FIND ve û jimareyan diguhezîne RAST û her tiştê din jî dike FALSE. Unaryek ducarî (--) nirxên mantiqî dike yek û sifir.
• SUMPRODUCT rêzika 1'yan û 0'yan berhev dike û hejmara şaneyên ku nivîsa diyarkirî dihewîne wekî beşek ji naveroka wan vedigerîne.

Ji bo ceribandina formula li ser daneyên jiyana rast, werin em bibînin ka çend şaneyên di A2:A10 de têketina binerdê di D1 de hene:

=SUMPRODUCT(--(ISNUMBER(FIND(D1, A2:A10))))

Û ev jimarek vedigerîne ji 3 (hucreyên A2, A3 û A6):

Meriv çawa şaneyên fîltrekirî bi nivîsa taybetî bijmêre

Ji bo hejmartina tiştên xuyayî di navnîşek fîlterkirî de, hûn ê hewce bikin ku hûn li gorî ka hûn lihevhatinek tam an jî qismî dixwazin, yekbûnek ji 4 an bêtir fonksiyonan bikar bînin. Ji bo şopandina mînakan hêsantir bibe, bila pêşî em bi lez li daneyên çavkaniyê mêze bikin.

Bi texmîna we tabloyek bi Nasnameyên fermanê di stûna B û Hejmar<2 de heye> di stûna C de mîna ku di wêneya jêrîn de tê xuyang kirin. Heya nuha, hûn tenê bi mîqdarên ji 1-ê mezintir eleqedar dibin û we li gorî vê tabloya xwe fîltre kir. Ewpirs ev e – tu çawa şaneyên fîltrekirî bi nasnameyeke taybetî dihejmêrim?

Formula jimartina şaneyên fîltrekirî bi nivîsa taybetî (hevhatina tam)

Hejmarkirina fîlterkirî şaneyên ku naveroka wan bi rêzika nivîsê ya nimûneyê tam li hev dikin, yek ji formûlên jêrîn bikar bînin:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(B2:B10=F1))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(B2:B10=F1))

Li ku derê F1 teksta nimûneyê ye û B2:B10 şaneyên jimartin.

Ev formula çawa dixebitin:

Di bingeha her du formulan de, hûn 2 kontrolan dikin:

1. Rêzên xuya û veşartî nas bikin. Ji bo vê yekê, hûn fonksiyona SUBTOTAL bi argumana function_num wekî 103-yê destnîşankirî bikar tînin. Ji bo ku hemî referansên hucreyê yên takekesî ji SUBTOTAL re peyda bikin, INDIRECT (di formula yekem de) an jî tevliheviya OFFSET, ROW û MIN bikar bînin. (di formula duyemîn de). Ji ber ku em armanc dikin ku rêzên xuya û veşartî bi cih bikin, bi rastî ne girîng e ku kîjan stûnê referans bikin (di mînaka me de A). Encama vê operasyonê komek ji 1 û 0yan e ku yek rêzên xuyayî û sifiran nîşan dide - rêzên veşartî.
2. Hêneyên ku tê de nivîsa hatî dayîn bibînin. Ji bo vê yekê, teksta nimûneyê (F1) li hember rêza hucreyan (B2: B10) bidin ber hev. Encama vê operasyonê komek nirxên TRUE û FALSE ye, ku bi alîkariya operatora ducarî ya yekane bi 1 û 0yan têne çewisandin.

Di dawiyê de, fonksiyona SUMPRODUCT hêmanên her duyan zêde dike. array di heman pozîsyonan de, û paşê array encam bi kurtî.Ji ber ku pirkirina bi sifirê sifir dide, tenê şaneyên ku di her du rêzikan de 1 heye di rêza dawîn de 1 heye. Berhevoka 1'yan hejmara şaneyên fîltrekirî ye ku nivîsa diyarkirî dihewîne.

Formula jimartina şaneyên fîlterkirî yên bi nivîsa taybetî (hevhatina qismî)

Hejmartina şaneyên parzkirî yên ku hin metn dihewîne wekî beşek ji naveroka hucreyê, formulên jorîn bi awayê jêrîn biguhezînin. Li şûna ku hûn metna nimûneyê li hember rêza hucreyan bidin ber hev, bi karanîna ISNUMBER û FIND ku di yek ji mînakên berê de hatî diyar kirin li metna armanc bigerin:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISNUMBER(FIND(F1, B2:B10))))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(ISNUMBER(FIND(F1, B2:B10))))

Di encamê de, formula dê rêzek nivîsê ya diyarkirî li her cîhekî di hucreyekê de bi cih bike:

Nîşe. Fonksiyona SUBTOTAL bi 103 di argumana function_num de, hemî şaneyên veşartî, ku bi destan têne fîlter kirin û veşartin nas dike. Di encamê de, formûlên jorîn tenê şaneyên xuyayî dihejmêrin bê ka şaneyên nedîtbar çawa hatine veşartin. Ji bo ku tenê şaneyên fîlterkirî neyên derxistin lê yên ku bi destan hatine veşartin tê de bin, 3 ji bo function_num bikar bînin.

Bi vî rengî meriv di Excel de hejmara şaneyên bi hin nivîsan re bijmêre. Ji bo xwendinê ez spasiya we dikim û hêvî dikim ku hefteya pêş me we li ser bloga xwe bibînim!

Daxistinên berdest

Formulên Excel ji bo hejmartina şaneyên bi hin nivîsan re